1: *> \brief \b ZGEBD2 reduces a general matrix to bidiagonal form using an unblocked algorithm.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZGEBD2 + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zgebd2.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zgebd2.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zgebd2.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZGEBD2( M, N, A, LDA, D, E, TAUQ, TAUP, WORK, INFO )
22: *
23: * .. Scalar Arguments ..
24: * INTEGER INFO, LDA, M, N
25: * ..
26: * .. Array Arguments ..
27: * DOUBLE PRECISION D( * ), E( * )
28: * COMPLEX*16 A( LDA, * ), TAUP( * ), TAUQ( * ), WORK( * )
29: * ..
30: *
31: *
32: *> \par Purpose:
33: * =============
34: *>
35: *> \verbatim
36: *>
37: *> ZGEBD2 reduces a complex general m by n matrix A to upper or lower
38: *> real bidiagonal form B by a unitary transformation: Q**H * A * P = B.
39: *>
40: *> If m >= n, B is upper bidiagonal; if m < n, B is lower bidiagonal.
41: *> \endverbatim
42: *
43: * Arguments:
44: * ==========
45: *
46: *> \param[in] M
47: *> \verbatim
48: *> M is INTEGER
49: *> The number of rows in the matrix A. M >= 0.
50: *> \endverbatim
51: *>
52: *> \param[in] N
53: *> \verbatim
54: *> N is INTEGER
55: *> The number of columns in the matrix A. N >= 0.
56: *> \endverbatim
57: *>
58: *> \param[in,out] A
59: *> \verbatim
60: *> A is COMPLEX*16 array, dimension (LDA,N)
61: *> On entry, the m by n general matrix to be reduced.
62: *> On exit,
63: *> if m >= n, the diagonal and the first superdiagonal are
64: *> overwritten with the upper bidiagonal matrix B; the
65: *> elements below the diagonal, with the array TAUQ, represent
66: *> the unitary matrix Q as a product of elementary
67: *> reflectors, and the elements above the first superdiagonal,
68: *> with the array TAUP, represent the unitary matrix P as
69: *> a product of elementary reflectors;
70: *> if m < n, the diagonal and the first subdiagonal are
71: *> overwritten with the lower bidiagonal matrix B; the
72: *> elements below the first subdiagonal, with the array TAUQ,
73: *> represent the unitary matrix Q as a product of
74: *> elementary reflectors, and the elements above the diagonal,
75: *> with the array TAUP, represent the unitary matrix P as
76: *> a product of elementary reflectors.
77: *> See Further Details.
78: *> \endverbatim
79: *>
80: *> \param[in] LDA
81: *> \verbatim
82: *> LDA is INTEGER
83: *> The leading dimension of the array A. LDA >= max(1,M).
84: *> \endverbatim
85: *>
86: *> \param[out] D
87: *> \verbatim
88: *> D is DOUBLE PRECISION array, dimension (min(M,N))
89: *> The diagonal elements of the bidiagonal matrix B:
90: *> D(i) = A(i,i).
91: *> \endverbatim
92: *>
93: *> \param[out] E
94: *> \verbatim
95: *> E is DOUBLE PRECISION array, dimension (min(M,N)-1)
96: *> The off-diagonal elements of the bidiagonal matrix B:
97: *> if m >= n, E(i) = A(i,i+1) for i = 1,2,...,n-1;
98: *> if m < n, E(i) = A(i+1,i) for i = 1,2,...,m-1.
99: *> \endverbatim
100: *>
101: *> \param[out] TAUQ
102: *> \verbatim
103: *> TAUQ is COMPLEX*16 array, dimension (min(M,N))
104: *> The scalar factors of the elementary reflectors which
105: *> represent the unitary matrix Q. See Further Details.
106: *> \endverbatim
107: *>
108: *> \param[out] TAUP
109: *> \verbatim
110: *> TAUP is COMPLEX*16 array, dimension (min(M,N))
111: *> The scalar factors of the elementary reflectors which
112: *> represent the unitary matrix P. See Further Details.
113: *> \endverbatim
114: *>
115: *> \param[out] WORK
116: *> \verbatim
117: *> WORK is COMPLEX*16 array, dimension (max(M,N))
118: *> \endverbatim
119: *>
120: *> \param[out] INFO
121: *> \verbatim
122: *> INFO is INTEGER
123: *> = 0: successful exit
124: *> < 0: if INFO = -i, the i-th argument had an illegal value.
125: *> \endverbatim
126: *
127: * Authors:
128: * ========
129: *
130: *> \author Univ. of Tennessee
131: *> \author Univ. of California Berkeley
132: *> \author Univ. of Colorado Denver
133: *> \author NAG Ltd.
134: *
135: *> \ingroup complex16GEcomputational
136: *
137: *> \par Further Details:
138: * =====================
139: *>
140: *> \verbatim
141: *>
142: *> The matrices Q and P are represented as products of elementary
143: *> reflectors:
144: *>
145: *> If m >= n,
146: *>
147: *> Q = H(1) H(2) . . . H(n) and P = G(1) G(2) . . . G(n-1)
148: *>
149: *> Each H(i) and G(i) has the form:
150: *>
151: *> H(i) = I - tauq * v * v**H and G(i) = I - taup * u * u**H
152: *>
153: *> where tauq and taup are complex scalars, and v and u are complex
154: *> vectors; v(1:i-1) = 0, v(i) = 1, and v(i+1:m) is stored on exit in
155: *> A(i+1:m,i); u(1:i) = 0, u(i+1) = 1, and u(i+2:n) is stored on exit in
156: *> A(i,i+2:n); tauq is stored in TAUQ(i) and taup in TAUP(i).
157: *>
158: *> If m < n,
159: *>
160: *> Q = H(1) H(2) . . . H(m-1) and P = G(1) G(2) . . . G(m)
161: *>
162: *> Each H(i) and G(i) has the form:
163: *>
164: *> H(i) = I - tauq * v * v**H and G(i) = I - taup * u * u**H
165: *>
166: *> where tauq and taup are complex scalars, v and u are complex vectors;
167: *> v(1:i) = 0, v(i+1) = 1, and v(i+2:m) is stored on exit in A(i+2:m,i);
168: *> u(1:i-1) = 0, u(i) = 1, and u(i+1:n) is stored on exit in A(i,i+1:n);
169: *> tauq is stored in TAUQ(i) and taup in TAUP(i).
170: *>
171: *> The contents of A on exit are illustrated by the following examples:
172: *>
173: *> m = 6 and n = 5 (m > n): m = 5 and n = 6 (m < n):
174: *>
175: *> ( d e u1 u1 u1 ) ( d u1 u1 u1 u1 u1 )
176: *> ( v1 d e u2 u2 ) ( e d u2 u2 u2 u2 )
177: *> ( v1 v2 d e u3 ) ( v1 e d u3 u3 u3 )
178: *> ( v1 v2 v3 d e ) ( v1 v2 e d u4 u4 )
179: *> ( v1 v2 v3 v4 d ) ( v1 v2 v3 e d u5 )
180: *> ( v1 v2 v3 v4 v5 )
181: *>
182: *> where d and e denote diagonal and off-diagonal elements of B, vi
183: *> denotes an element of the vector defining H(i), and ui an element of
184: *> the vector defining G(i).
185: *> \endverbatim
186: *>
187: * =====================================================================
188: SUBROUTINE ZGEBD2( M, N, A, LDA, D, E, TAUQ, TAUP, WORK, INFO )
189: *
190: * -- LAPACK computational routine --
191: * -- LAPACK is a software package provided by Univ. of Tennessee, --
192: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
193: *
194: * .. Scalar Arguments ..
195: INTEGER INFO, LDA, M, N
196: * ..
197: * .. Array Arguments ..
198: DOUBLE PRECISION D( * ), E( * )
199: COMPLEX*16 A( LDA, * ), TAUP( * ), TAUQ( * ), WORK( * )
200: * ..
201: *
202: * =====================================================================
203: *
204: * .. Parameters ..
205: COMPLEX*16 ZERO, ONE
206: PARAMETER ( ZERO = ( 0.0D+0, 0.0D+0 ),
207: $ ONE = ( 1.0D+0, 0.0D+0 ) )
208: * ..
209: * .. Local Scalars ..
210: INTEGER I
211: COMPLEX*16 ALPHA
212: * ..
213: * .. External Subroutines ..
214: EXTERNAL XERBLA, ZLACGV, ZLARF, ZLARFG
215: * ..
216: * .. Intrinsic Functions ..
217: INTRINSIC DCONJG, MAX, MIN
218: * ..
219: * .. Executable Statements ..
220: *
221: * Test the input parameters
222: *
223: INFO = 0
224: IF( M.LT.0 ) THEN
225: INFO = -1
226: ELSE IF( N.LT.0 ) THEN
227: INFO = -2
228: ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
229: INFO = -4
230: END IF
231: IF( INFO.LT.0 ) THEN
232: CALL XERBLA( 'ZGEBD2', -INFO )
233: RETURN
234: END IF
235: *
236: IF( M.GE.N ) THEN
237: *
238: * Reduce to upper bidiagonal form
239: *
240: DO 10 I = 1, N
241: *
242: * Generate elementary reflector H(i) to annihilate A(i+1:m,i)
243: *
244: ALPHA = A( I, I )
245: CALL ZLARFG( M-I+1, ALPHA, A( MIN( I+1, M ), I ), 1,
246: $ TAUQ( I ) )
247: D( I ) = DBLE( ALPHA )
248: A( I, I ) = ONE
249: *
250: * Apply H(i)**H to A(i:m,i+1:n) from the left
251: *
252: IF( I.LT.N )
253: $ CALL ZLARF( 'Left', M-I+1, N-I, A( I, I ), 1,
254: $ DCONJG( TAUQ( I ) ), A( I, I+1 ), LDA, WORK )
255: A( I, I ) = D( I )
256: *
257: IF( I.LT.N ) THEN
258: *
259: * Generate elementary reflector G(i) to annihilate
260: * A(i,i+2:n)
261: *
262: CALL ZLACGV( N-I, A( I, I+1 ), LDA )
263: ALPHA = A( I, I+1 )
264: CALL ZLARFG( N-I, ALPHA, A( I, MIN( I+2, N ) ), LDA,
265: $ TAUP( I ) )
266: E( I ) = DBLE( ALPHA )
267: A( I, I+1 ) = ONE
268: *
269: * Apply G(i) to A(i+1:m,i+1:n) from the right
270: *
271: CALL ZLARF( 'Right', M-I, N-I, A( I, I+1 ), LDA,
272: $ TAUP( I ), A( I+1, I+1 ), LDA, WORK )
273: CALL ZLACGV( N-I, A( I, I+1 ), LDA )
274: A( I, I+1 ) = E( I )
275: ELSE
276: TAUP( I ) = ZERO
277: END IF
278: 10 CONTINUE
279: ELSE
280: *
281: * Reduce to lower bidiagonal form
282: *
283: DO 20 I = 1, M
284: *
285: * Generate elementary reflector G(i) to annihilate A(i,i+1:n)
286: *
287: CALL ZLACGV( N-I+1, A( I, I ), LDA )
288: ALPHA = A( I, I )
289: CALL ZLARFG( N-I+1, ALPHA, A( I, MIN( I+1, N ) ), LDA,
290: $ TAUP( I ) )
291: D( I ) = DBLE( ALPHA )
292: A( I, I ) = ONE
293: *
294: * Apply G(i) to A(i+1:m,i:n) from the right
295: *
296: IF( I.LT.M )
297: $ CALL ZLARF( 'Right', M-I, N-I+1, A( I, I ), LDA,
298: $ TAUP( I ), A( I+1, I ), LDA, WORK )
299: CALL ZLACGV( N-I+1, A( I, I ), LDA )
300: A( I, I ) = D( I )
301: *
302: IF( I.LT.M ) THEN
303: *
304: * Generate elementary reflector H(i) to annihilate
305: * A(i+2:m,i)
306: *
307: ALPHA = A( I+1, I )
308: CALL ZLARFG( M-I, ALPHA, A( MIN( I+2, M ), I ), 1,
309: $ TAUQ( I ) )
310: E( I ) = DBLE( ALPHA )
311: A( I+1, I ) = ONE
312: *
313: * Apply H(i)**H to A(i+1:m,i+1:n) from the left
314: *
315: CALL ZLARF( 'Left', M-I, N-I, A( I+1, I ), 1,
316: $ DCONJG( TAUQ( I ) ), A( I+1, I+1 ), LDA,
317: $ WORK )
318: A( I+1, I ) = E( I )
319: ELSE
320: TAUQ( I ) = ZERO
321: END IF
322: 20 CONTINUE
323: END IF
324: RETURN
325: *
326: * End of ZGEBD2
327: *
328: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zgebd2.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack