1: *> \brief \b DTRCON
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DTRCON + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dtrcon.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dtrcon.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dtrcon.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DTRCON( NORM, UPLO, DIAG, N, A, LDA, RCOND, WORK,
22: * IWORK, INFO )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER DIAG, NORM, UPLO
26: * INTEGER INFO, LDA, N
27: * DOUBLE PRECISION RCOND
28: * ..
29: * .. Array Arguments ..
30: * INTEGER IWORK( * )
31: * DOUBLE PRECISION A( LDA, * ), WORK( * )
32: * ..
33: *
34: *
35: *> \par Purpose:
36: * =============
37: *>
38: *> \verbatim
39: *>
40: *> DTRCON estimates the reciprocal of the condition number of a
41: *> triangular matrix A, in either the 1-norm or the infinity-norm.
42: *>
43: *> The norm of A is computed and an estimate is obtained for
44: *> norm(inv(A)), then the reciprocal of the condition number is
45: *> computed as
46: *> RCOND = 1 / ( norm(A) * norm(inv(A)) ).
47: *> \endverbatim
48: *
49: * Arguments:
50: * ==========
51: *
52: *> \param[in] NORM
53: *> \verbatim
54: *> NORM is CHARACTER*1
55: *> Specifies whether the 1-norm condition number or the
56: *> infinity-norm condition number is required:
57: *> = '1' or 'O': 1-norm;
58: *> = 'I': Infinity-norm.
59: *> \endverbatim
60: *>
61: *> \param[in] UPLO
62: *> \verbatim
63: *> UPLO is CHARACTER*1
64: *> = 'U': A is upper triangular;
65: *> = 'L': A is lower triangular.
66: *> \endverbatim
67: *>
68: *> \param[in] DIAG
69: *> \verbatim
70: *> DIAG is CHARACTER*1
71: *> = 'N': A is non-unit triangular;
72: *> = 'U': A is unit triangular.
73: *> \endverbatim
74: *>
75: *> \param[in] N
76: *> \verbatim
77: *> N is INTEGER
78: *> The order of the matrix A. N >= 0.
79: *> \endverbatim
80: *>
81: *> \param[in] A
82: *> \verbatim
83: *> A is DOUBLE PRECISION array, dimension (LDA,N)
84: *> The triangular matrix A. If UPLO = 'U', the leading N-by-N
85: *> upper triangular part of the array A contains the upper
86: *> triangular matrix, and the strictly lower triangular part of
87: *> A is not referenced. If UPLO = 'L', the leading N-by-N lower
88: *> triangular part of the array A contains the lower triangular
89: *> matrix, and the strictly upper triangular part of A is not
90: *> referenced. If DIAG = 'U', the diagonal elements of A are
91: *> also not referenced and are assumed to be 1.
92: *> \endverbatim
93: *>
94: *> \param[in] LDA
95: *> \verbatim
96: *> LDA is INTEGER
97: *> The leading dimension of the array A. LDA >= max(1,N).
98: *> \endverbatim
99: *>
100: *> \param[out] RCOND
101: *> \verbatim
102: *> RCOND is DOUBLE PRECISION
103: *> The reciprocal of the condition number of the matrix A,
104: *> computed as RCOND = 1/(norm(A) * norm(inv(A))).
105: *> \endverbatim
106: *>
107: *> \param[out] WORK
108: *> \verbatim
109: *> WORK is DOUBLE PRECISION array, dimension (3*N)
110: *> \endverbatim
111: *>
112: *> \param[out] IWORK
113: *> \verbatim
114: *> IWORK is INTEGER array, dimension (N)
115: *> \endverbatim
116: *>
117: *> \param[out] INFO
118: *> \verbatim
119: *> INFO is INTEGER
120: *> = 0: successful exit
121: *> < 0: if INFO = -i, the i-th argument had an illegal value
122: *> \endverbatim
123: *
124: * Authors:
125: * ========
126: *
127: *> \author Univ. of Tennessee
128: *> \author Univ. of California Berkeley
129: *> \author Univ. of Colorado Denver
130: *> \author NAG Ltd.
131: *
132: *> \date November 2011
133: *
134: *> \ingroup doubleOTHERcomputational
135: *
136: * =====================================================================
137: SUBROUTINE DTRCON( NORM, UPLO, DIAG, N, A, LDA, RCOND, WORK,
138: $ IWORK, INFO )
139: *
140: * -- LAPACK computational routine (version 3.4.0) --
141: * -- LAPACK is a software package provided by Univ. of Tennessee, --
142: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
143: * November 2011
144: *
145: * .. Scalar Arguments ..
146: CHARACTER DIAG, NORM, UPLO
147: INTEGER INFO, LDA, N
148: DOUBLE PRECISION RCOND
149: * ..
150: * .. Array Arguments ..
151: INTEGER IWORK( * )
152: DOUBLE PRECISION A( LDA, * ), WORK( * )
153: * ..
154: *
155: * =====================================================================
156: *
157: * .. Parameters ..
158: DOUBLE PRECISION ONE, ZERO
159: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
160: * ..
161: * .. Local Scalars ..
162: LOGICAL NOUNIT, ONENRM, UPPER
163: CHARACTER NORMIN
164: INTEGER IX, KASE, KASE1
165: DOUBLE PRECISION AINVNM, ANORM, SCALE, SMLNUM, XNORM
166: * ..
167: * .. Local Arrays ..
168: INTEGER ISAVE( 3 )
169: * ..
170: * .. External Functions ..
171: LOGICAL LSAME
172: INTEGER IDAMAX
173: DOUBLE PRECISION DLAMCH, DLANTR
174: EXTERNAL LSAME, IDAMAX, DLAMCH, DLANTR
175: * ..
176: * .. External Subroutines ..
177: EXTERNAL DLACN2, DLATRS, DRSCL, XERBLA
178: * ..
179: * .. Intrinsic Functions ..
180: INTRINSIC ABS, DBLE, MAX
181: * ..
182: * .. Executable Statements ..
183: *
184: * Test the input parameters.
185: *
186: INFO = 0
187: UPPER = LSAME( UPLO, 'U' )
188: ONENRM = NORM.EQ.'1' .OR. LSAME( NORM, 'O' )
189: NOUNIT = LSAME( DIAG, 'N' )
190: *
191: IF( .NOT.ONENRM .AND. .NOT.LSAME( NORM, 'I' ) ) THEN
192: INFO = -1
193: ELSE IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
194: INFO = -2
195: ELSE IF( .NOT.NOUNIT .AND. .NOT.LSAME( DIAG, 'U' ) ) THEN
196: INFO = -3
197: ELSE IF( N.LT.0 ) THEN
198: INFO = -4
199: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
200: INFO = -6
201: END IF
202: IF( INFO.NE.0 ) THEN
203: CALL XERBLA( 'DTRCON', -INFO )
204: RETURN
205: END IF
206: *
207: * Quick return if possible
208: *
209: IF( N.EQ.0 ) THEN
210: RCOND = ONE
211: RETURN
212: END IF
213: *
214: RCOND = ZERO
215: SMLNUM = DLAMCH( 'Safe minimum' )*DBLE( MAX( 1, N ) )
216: *
217: * Compute the norm of the triangular matrix A.
218: *
219: ANORM = DLANTR( NORM, UPLO, DIAG, N, N, A, LDA, WORK )
220: *
221: * Continue only if ANORM > 0.
222: *
223: IF( ANORM.GT.ZERO ) THEN
224: *
225: * Estimate the norm of the inverse of A.
226: *
227: AINVNM = ZERO
228: NORMIN = 'N'
229: IF( ONENRM ) THEN
230: KASE1 = 1
231: ELSE
232: KASE1 = 2
233: END IF
234: KASE = 0
235: 10 CONTINUE
236: CALL DLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
237: IF( KASE.NE.0 ) THEN
238: IF( KASE.EQ.KASE1 ) THEN
239: *
240: * Multiply by inv(A).
241: *
242: CALL DLATRS( UPLO, 'No transpose', DIAG, NORMIN, N, A,
243: $ LDA, WORK, SCALE, WORK( 2*N+1 ), INFO )
244: ELSE
245: *
246: * Multiply by inv(A**T).
247: *
248: CALL DLATRS( UPLO, 'Transpose', DIAG, NORMIN, N, A, LDA,
249: $ WORK, SCALE, WORK( 2*N+1 ), INFO )
250: END IF
251: NORMIN = 'Y'
252: *
253: * Multiply by 1/SCALE if doing so will not cause overflow.
254: *
255: IF( SCALE.NE.ONE ) THEN
256: IX = IDAMAX( N, WORK, 1 )
257: XNORM = ABS( WORK( IX ) )
258: IF( SCALE.LT.XNORM*SMLNUM .OR. SCALE.EQ.ZERO )
259: $ GO TO 20
260: CALL DRSCL( N, SCALE, WORK, 1 )
261: END IF
262: GO TO 10
263: END IF
264: *
265: * Compute the estimate of the reciprocal condition number.
266: *
267: IF( AINVNM.NE.ZERO )
268: $ RCOND = ( ONE / ANORM ) / AINVNM
269: END IF
270: *
271: 20 CONTINUE
272: RETURN
273: *
274: * End of DTRCON
275: *
276: END
CVSweb interface <joel.bertrand@systella.fr>