Return to dtptri.f CVS log

Up to [local] / rpl / lapack / lapack

Initial revision

    1:       SUBROUTINE DTPTRI( UPLO, DIAG, N, AP, INFO )
    2: *
    3: *  -- LAPACK routine (version 3.2) --
    4: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
    5: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
    6: *     November 2006
    7: *
    8: *     .. Scalar Arguments ..
    9:       CHARACTER          DIAG, UPLO
   10:       INTEGER            INFO, N
   11: *     ..
   12: *     .. Array Arguments ..
   13:       DOUBLE PRECISION   AP( * )
   14: *     ..
   15: *
   16: *  Purpose
   17: *  =======
   18: *
   19: *  DTPTRI computes the inverse of a real upper or lower triangular
   20: *  matrix A stored in packed format.
   21: *
   22: *  Arguments
   23: *  =========
   24: *
   25: *  UPLO    (input) CHARACTER*1
   26: *          = 'U':  A is upper triangular;
   27: *          = 'L':  A is lower triangular.
   28: *
   29: *  DIAG    (input) CHARACTER*1
   30: *          = 'N':  A is non-unit triangular;
   31: *          = 'U':  A is unit triangular.
   32: *
   33: *  N       (input) INTEGER
   34: *          The order of the matrix A.  N >= 0.
   35: *
   36: *  AP      (input/output) DOUBLE PRECISION array, dimension (N*(N+1)/2)
   37: *          On entry, the upper or lower triangular matrix A, stored
   38: *          columnwise in a linear array.  The j-th column of A is stored
   39: *          in the array AP as follows:
   40: *          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
   41: *          if UPLO = 'L', AP(i + (j-1)*((2*n-j)/2) = A(i,j) for j<=i<=n.
   42: *          See below for further details.
   43: *          On exit, the (triangular) inverse of the original matrix, in
   44: *          the same packed storage format.
   45: *
   46: *  INFO    (output) INTEGER
   47: *          = 0:  successful exit
   48: *          < 0:  if INFO = -i, the i-th argument had an illegal value
   49: *          > 0:  if INFO = i, A(i,i) is exactly zero.  The triangular
   50: *                matrix is singular and its inverse can not be computed.
   51: *
   52: *  Further Details
   53: *  ===============
   54: *
   55: *  A triangular matrix A can be transferred to packed storage using one
   56: *  of the following program segments:
   57: *
   58: *  UPLO = 'U':                      UPLO = 'L':
   59: *
   60: *        JC = 1                           JC = 1
   61: *        DO 2 J = 1, N                    DO 2 J = 1, N
   62: *           DO 1 I = 1, J                    DO 1 I = J, N
   63: *              AP(JC+I-1) = A(I,J)              AP(JC+I-J) = A(I,J)
   64: *      1    CONTINUE                    1    CONTINUE
   65: *           JC = JC + J                      JC = JC + N - J + 1
   66: *      2 CONTINUE                       2 CONTINUE
   67: *
   68: *  =====================================================================
   69: *
   70: *     .. Parameters ..
   71:       DOUBLE PRECISION   ONE, ZERO
   72:       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
   73: *     ..
   74: *     .. Local Scalars ..
   75:       LOGICAL            NOUNIT, UPPER
   76:       INTEGER            J, JC, JCLAST, JJ
   77:       DOUBLE PRECISION   AJJ
   78: *     ..
   79: *     .. External Functions ..
   80:       LOGICAL            LSAME
   81:       EXTERNAL           LSAME
   82: *     ..
   83: *     .. External Subroutines ..
   84:       EXTERNAL           DSCAL, DTPMV, XERBLA
   85: *     ..
   86: *     .. Executable Statements ..
   87: *
   88: *     Test the input parameters.
   89: *
   90:       INFO = 0
   91:       UPPER = LSAME( UPLO, 'U' )
   92:       NOUNIT = LSAME( DIAG, 'N' )
   93:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
   94:          INFO = -1
   95:       ELSE IF( .NOT.NOUNIT .AND. .NOT.LSAME( DIAG, 'U' ) ) THEN
   96:          INFO = -2
   97:       ELSE IF( N.LT.0 ) THEN
   98:          INFO = -3
   99:       END IF
  100:       IF( INFO.NE.0 ) THEN
  101:          CALL XERBLA( 'DTPTRI', -INFO )
  102:          RETURN
  103:       END IF
  104: *
  105: *     Check for singularity if non-unit.
  106: *
  107:       IF( NOUNIT ) THEN
  108:          IF( UPPER ) THEN
  109:             JJ = 0
  110:             DO 10 INFO = 1, N
  111:                JJ = JJ + INFO
  112:                IF( AP( JJ ).EQ.ZERO )
  113:      $            RETURN
  114:    10       CONTINUE
  115:          ELSE
  116:             JJ = 1
  117:             DO 20 INFO = 1, N
  118:                IF( AP( JJ ).EQ.ZERO )
  119:      $            RETURN
  120:                JJ = JJ + N - INFO + 1
  121:    20       CONTINUE
  122:          END IF
  123:          INFO = 0
  124:       END IF
  125: *
  126:       IF( UPPER ) THEN
  127: *
  128: *        Compute inverse of upper triangular matrix.
  129: *
  130:          JC = 1
  131:          DO 30 J = 1, N
  132:             IF( NOUNIT ) THEN
  133:                AP( JC+J-1 ) = ONE / AP( JC+J-1 )
  134:                AJJ = -AP( JC+J-1 )
  135:             ELSE
  136:                AJJ = -ONE
  137:             END IF
  138: *
  139: *           Compute elements 1:j-1 of j-th column.
  140: *
  141:             CALL DTPMV( 'Upper', 'No transpose', DIAG, J-1, AP,
  142:      $                  AP( JC ), 1 )
  143:             CALL DSCAL( J-1, AJJ, AP( JC ), 1 )
  144:             JC = JC + J
  145:    30    CONTINUE
  146: *
  147:       ELSE
  148: *
  149: *        Compute inverse of lower triangular matrix.
  150: *
  151:          JC = N*( N+1 ) / 2
  152:          DO 40 J = N, 1, -1
  153:             IF( NOUNIT ) THEN
  154:                AP( JC ) = ONE / AP( JC )
  155:                AJJ = -AP( JC )
  156:             ELSE
  157:                AJJ = -ONE
  158:             END IF
  159:             IF( J.LT.N ) THEN
  160: *
  161: *              Compute elements j+1:n of j-th column.
  162: *
  163:                CALL DTPMV( 'Lower', 'No transpose', DIAG, N-J,
  164:      $                     AP( JCLAST ), AP( JC+1 ), 1 )
  165:                CALL DSCAL( N-J, AJJ, AP( JC+1 ), 1 )
  166:             END IF
  167:             JCLAST = JC
  168:             JC = JC - N + J - 2
  169:    40    CONTINUE
  170:       END IF
  171: *
  172:       RETURN
  173: *
  174: *     End of DTPTRI
  175: *
  176:       END