1: *> \brief \b DTPCON
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DTPCON + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dtpcon.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dtpcon.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dtpcon.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DTPCON( NORM, UPLO, DIAG, N, AP, RCOND, WORK, IWORK,
22: * INFO )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER DIAG, NORM, UPLO
26: * INTEGER INFO, N
27: * DOUBLE PRECISION RCOND
28: * ..
29: * .. Array Arguments ..
30: * INTEGER IWORK( * )
31: * DOUBLE PRECISION AP( * ), WORK( * )
32: * ..
33: *
34: *
35: *> \par Purpose:
36: * =============
37: *>
38: *> \verbatim
39: *>
40: *> DTPCON estimates the reciprocal of the condition number of a packed
41: *> triangular matrix A, in either the 1-norm or the infinity-norm.
42: *>
43: *> The norm of A is computed and an estimate is obtained for
44: *> norm(inv(A)), then the reciprocal of the condition number is
45: *> computed as
46: *> RCOND = 1 / ( norm(A) * norm(inv(A)) ).
47: *> \endverbatim
48: *
49: * Arguments:
50: * ==========
51: *
52: *> \param[in] NORM
53: *> \verbatim
54: *> NORM is CHARACTER*1
55: *> Specifies whether the 1-norm condition number or the
56: *> infinity-norm condition number is required:
57: *> = '1' or 'O': 1-norm;
58: *> = 'I': Infinity-norm.
59: *> \endverbatim
60: *>
61: *> \param[in] UPLO
62: *> \verbatim
63: *> UPLO is CHARACTER*1
64: *> = 'U': A is upper triangular;
65: *> = 'L': A is lower triangular.
66: *> \endverbatim
67: *>
68: *> \param[in] DIAG
69: *> \verbatim
70: *> DIAG is CHARACTER*1
71: *> = 'N': A is non-unit triangular;
72: *> = 'U': A is unit triangular.
73: *> \endverbatim
74: *>
75: *> \param[in] N
76: *> \verbatim
77: *> N is INTEGER
78: *> The order of the matrix A. N >= 0.
79: *> \endverbatim
80: *>
81: *> \param[in] AP
82: *> \verbatim
83: *> AP is DOUBLE PRECISION array, dimension (N*(N+1)/2)
84: *> The upper or lower triangular matrix A, packed columnwise in
85: *> a linear array. The j-th column of A is stored in the array
86: *> AP as follows:
87: *> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
88: *> if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
89: *> If DIAG = 'U', the diagonal elements of A are not referenced
90: *> and are assumed to be 1.
91: *> \endverbatim
92: *>
93: *> \param[out] RCOND
94: *> \verbatim
95: *> RCOND is DOUBLE PRECISION
96: *> The reciprocal of the condition number of the matrix A,
97: *> computed as RCOND = 1/(norm(A) * norm(inv(A))).
98: *> \endverbatim
99: *>
100: *> \param[out] WORK
101: *> \verbatim
102: *> WORK is DOUBLE PRECISION array, dimension (3*N)
103: *> \endverbatim
104: *>
105: *> \param[out] IWORK
106: *> \verbatim
107: *> IWORK is INTEGER array, dimension (N)
108: *> \endverbatim
109: *>
110: *> \param[out] INFO
111: *> \verbatim
112: *> INFO is INTEGER
113: *> = 0: successful exit
114: *> < 0: if INFO = -i, the i-th argument had an illegal value
115: *> \endverbatim
116: *
117: * Authors:
118: * ========
119: *
120: *> \author Univ. of Tennessee
121: *> \author Univ. of California Berkeley
122: *> \author Univ. of Colorado Denver
123: *> \author NAG Ltd.
124: *
125: *> \ingroup doubleOTHERcomputational
126: *
127: * =====================================================================
128: SUBROUTINE DTPCON( NORM, UPLO, DIAG, N, AP, RCOND, WORK, IWORK,
129: $ INFO )
130: *
131: * -- LAPACK computational routine --
132: * -- LAPACK is a software package provided by Univ. of Tennessee, --
133: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
134: *
135: * .. Scalar Arguments ..
136: CHARACTER DIAG, NORM, UPLO
137: INTEGER INFO, N
138: DOUBLE PRECISION RCOND
139: * ..
140: * .. Array Arguments ..
141: INTEGER IWORK( * )
142: DOUBLE PRECISION AP( * ), WORK( * )
143: * ..
144: *
145: * =====================================================================
146: *
147: * .. Parameters ..
148: DOUBLE PRECISION ONE, ZERO
149: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
150: * ..
151: * .. Local Scalars ..
152: LOGICAL NOUNIT, ONENRM, UPPER
153: CHARACTER NORMIN
154: INTEGER IX, KASE, KASE1
155: DOUBLE PRECISION AINVNM, ANORM, SCALE, SMLNUM, XNORM
156: * ..
157: * .. Local Arrays ..
158: INTEGER ISAVE( 3 )
159: * ..
160: * .. External Functions ..
161: LOGICAL LSAME
162: INTEGER IDAMAX
163: DOUBLE PRECISION DLAMCH, DLANTP
164: EXTERNAL LSAME, IDAMAX, DLAMCH, DLANTP
165: * ..
166: * .. External Subroutines ..
167: EXTERNAL DLACN2, DLATPS, DRSCL, XERBLA
168: * ..
169: * .. Intrinsic Functions ..
170: INTRINSIC ABS, DBLE, MAX
171: * ..
172: * .. Executable Statements ..
173: *
174: * Test the input parameters.
175: *
176: INFO = 0
177: UPPER = LSAME( UPLO, 'U' )
178: ONENRM = NORM.EQ.'1' .OR. LSAME( NORM, 'O' )
179: NOUNIT = LSAME( DIAG, 'N' )
180: *
181: IF( .NOT.ONENRM .AND. .NOT.LSAME( NORM, 'I' ) ) THEN
182: INFO = -1
183: ELSE IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
184: INFO = -2
185: ELSE IF( .NOT.NOUNIT .AND. .NOT.LSAME( DIAG, 'U' ) ) THEN
186: INFO = -3
187: ELSE IF( N.LT.0 ) THEN
188: INFO = -4
189: END IF
190: IF( INFO.NE.0 ) THEN
191: CALL XERBLA( 'DTPCON', -INFO )
192: RETURN
193: END IF
194: *
195: * Quick return if possible
196: *
197: IF( N.EQ.0 ) THEN
198: RCOND = ONE
199: RETURN
200: END IF
201: *
202: RCOND = ZERO
203: SMLNUM = DLAMCH( 'Safe minimum' )*DBLE( MAX( 1, N ) )
204: *
205: * Compute the norm of the triangular matrix A.
206: *
207: ANORM = DLANTP( NORM, UPLO, DIAG, N, AP, WORK )
208: *
209: * Continue only if ANORM > 0.
210: *
211: IF( ANORM.GT.ZERO ) THEN
212: *
213: * Estimate the norm of the inverse of A.
214: *
215: AINVNM = ZERO
216: NORMIN = 'N'
217: IF( ONENRM ) THEN
218: KASE1 = 1
219: ELSE
220: KASE1 = 2
221: END IF
222: KASE = 0
223: 10 CONTINUE
224: CALL DLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
225: IF( KASE.NE.0 ) THEN
226: IF( KASE.EQ.KASE1 ) THEN
227: *
228: * Multiply by inv(A).
229: *
230: CALL DLATPS( UPLO, 'No transpose', DIAG, NORMIN, N, AP,
231: $ WORK, SCALE, WORK( 2*N+1 ), INFO )
232: ELSE
233: *
234: * Multiply by inv(A**T).
235: *
236: CALL DLATPS( UPLO, 'Transpose', DIAG, NORMIN, N, AP,
237: $ WORK, SCALE, WORK( 2*N+1 ), INFO )
238: END IF
239: NORMIN = 'Y'
240: *
241: * Multiply by 1/SCALE if doing so will not cause overflow.
242: *
243: IF( SCALE.NE.ONE ) THEN
244: IX = IDAMAX( N, WORK, 1 )
245: XNORM = ABS( WORK( IX ) )
246: IF( SCALE.LT.XNORM*SMLNUM .OR. SCALE.EQ.ZERO )
247: $ GO TO 20
248: CALL DRSCL( N, SCALE, WORK, 1 )
249: END IF
250: GO TO 10
251: END IF
252: *
253: * Compute the estimate of the reciprocal condition number.
254: *
255: IF( AINVNM.NE.ZERO )
256: $ RCOND = ( ONE / ANORM ) / AINVNM
257: END IF
258: *
259: 20 CONTINUE
260: RETURN
261: *
262: * End of DTPCON
263: *
264: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dtpcon.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack