1: *> \brief \b DTBCON
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DTBCON + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dtbcon.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dtbcon.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dtbcon.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DTBCON( NORM, UPLO, DIAG, N, KD, AB, LDAB, RCOND, WORK,
22: * IWORK, INFO )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER DIAG, NORM, UPLO
26: * INTEGER INFO, KD, LDAB, N
27: * DOUBLE PRECISION RCOND
28: * ..
29: * .. Array Arguments ..
30: * INTEGER IWORK( * )
31: * DOUBLE PRECISION AB( LDAB, * ), WORK( * )
32: * ..
33: *
34: *
35: *> \par Purpose:
36: * =============
37: *>
38: *> \verbatim
39: *>
40: *> DTBCON estimates the reciprocal of the condition number of a
41: *> triangular band matrix A, in either the 1-norm or the infinity-norm.
42: *>
43: *> The norm of A is computed and an estimate is obtained for
44: *> norm(inv(A)), then the reciprocal of the condition number is
45: *> computed as
46: *> RCOND = 1 / ( norm(A) * norm(inv(A)) ).
47: *> \endverbatim
48: *
49: * Arguments:
50: * ==========
51: *
52: *> \param[in] NORM
53: *> \verbatim
54: *> NORM is CHARACTER*1
55: *> Specifies whether the 1-norm condition number or the
56: *> infinity-norm condition number is required:
57: *> = '1' or 'O': 1-norm;
58: *> = 'I': Infinity-norm.
59: *> \endverbatim
60: *>
61: *> \param[in] UPLO
62: *> \verbatim
63: *> UPLO is CHARACTER*1
64: *> = 'U': A is upper triangular;
65: *> = 'L': A is lower triangular.
66: *> \endverbatim
67: *>
68: *> \param[in] DIAG
69: *> \verbatim
70: *> DIAG is CHARACTER*1
71: *> = 'N': A is non-unit triangular;
72: *> = 'U': A is unit triangular.
73: *> \endverbatim
74: *>
75: *> \param[in] N
76: *> \verbatim
77: *> N is INTEGER
78: *> The order of the matrix A. N >= 0.
79: *> \endverbatim
80: *>
81: *> \param[in] KD
82: *> \verbatim
83: *> KD is INTEGER
84: *> The number of superdiagonals or subdiagonals of the
85: *> triangular band matrix A. KD >= 0.
86: *> \endverbatim
87: *>
88: *> \param[in] AB
89: *> \verbatim
90: *> AB is DOUBLE PRECISION array, dimension (LDAB,N)
91: *> The upper or lower triangular band matrix A, stored in the
92: *> first kd+1 rows of the array. The j-th column of A is stored
93: *> in the j-th column of the array AB as follows:
94: *> if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j;
95: *> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd).
96: *> If DIAG = 'U', the diagonal elements of A are not referenced
97: *> and are assumed to be 1.
98: *> \endverbatim
99: *>
100: *> \param[in] LDAB
101: *> \verbatim
102: *> LDAB is INTEGER
103: *> The leading dimension of the array AB. LDAB >= KD+1.
104: *> \endverbatim
105: *>
106: *> \param[out] RCOND
107: *> \verbatim
108: *> RCOND is DOUBLE PRECISION
109: *> The reciprocal of the condition number of the matrix A,
110: *> computed as RCOND = 1/(norm(A) * norm(inv(A))).
111: *> \endverbatim
112: *>
113: *> \param[out] WORK
114: *> \verbatim
115: *> WORK is DOUBLE PRECISION array, dimension (3*N)
116: *> \endverbatim
117: *>
118: *> \param[out] IWORK
119: *> \verbatim
120: *> IWORK is INTEGER array, dimension (N)
121: *> \endverbatim
122: *>
123: *> \param[out] INFO
124: *> \verbatim
125: *> INFO is INTEGER
126: *> = 0: successful exit
127: *> < 0: if INFO = -i, the i-th argument had an illegal value
128: *> \endverbatim
129: *
130: * Authors:
131: * ========
132: *
133: *> \author Univ. of Tennessee
134: *> \author Univ. of California Berkeley
135: *> \author Univ. of Colorado Denver
136: *> \author NAG Ltd.
137: *
138: *> \ingroup doubleOTHERcomputational
139: *
140: * =====================================================================
141: SUBROUTINE DTBCON( NORM, UPLO, DIAG, N, KD, AB, LDAB, RCOND, WORK,
142: $ IWORK, INFO )
143: *
144: * -- LAPACK computational routine --
145: * -- LAPACK is a software package provided by Univ. of Tennessee, --
146: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
147: *
148: * .. Scalar Arguments ..
149: CHARACTER DIAG, NORM, UPLO
150: INTEGER INFO, KD, LDAB, N
151: DOUBLE PRECISION RCOND
152: * ..
153: * .. Array Arguments ..
154: INTEGER IWORK( * )
155: DOUBLE PRECISION AB( LDAB, * ), WORK( * )
156: * ..
157: *
158: * =====================================================================
159: *
160: * .. Parameters ..
161: DOUBLE PRECISION ONE, ZERO
162: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
163: * ..
164: * .. Local Scalars ..
165: LOGICAL NOUNIT, ONENRM, UPPER
166: CHARACTER NORMIN
167: INTEGER IX, KASE, KASE1
168: DOUBLE PRECISION AINVNM, ANORM, SCALE, SMLNUM, XNORM
169: * ..
170: * .. Local Arrays ..
171: INTEGER ISAVE( 3 )
172: * ..
173: * .. External Functions ..
174: LOGICAL LSAME
175: INTEGER IDAMAX
176: DOUBLE PRECISION DLAMCH, DLANTB
177: EXTERNAL LSAME, IDAMAX, DLAMCH, DLANTB
178: * ..
179: * .. External Subroutines ..
180: EXTERNAL DLACN2, DLATBS, DRSCL, XERBLA
181: * ..
182: * .. Intrinsic Functions ..
183: INTRINSIC ABS, DBLE, MAX
184: * ..
185: * .. Executable Statements ..
186: *
187: * Test the input parameters.
188: *
189: INFO = 0
190: UPPER = LSAME( UPLO, 'U' )
191: ONENRM = NORM.EQ.'1' .OR. LSAME( NORM, 'O' )
192: NOUNIT = LSAME( DIAG, 'N' )
193: *
194: IF( .NOT.ONENRM .AND. .NOT.LSAME( NORM, 'I' ) ) THEN
195: INFO = -1
196: ELSE IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
197: INFO = -2
198: ELSE IF( .NOT.NOUNIT .AND. .NOT.LSAME( DIAG, 'U' ) ) THEN
199: INFO = -3
200: ELSE IF( N.LT.0 ) THEN
201: INFO = -4
202: ELSE IF( KD.LT.0 ) THEN
203: INFO = -5
204: ELSE IF( LDAB.LT.KD+1 ) THEN
205: INFO = -7
206: END IF
207: IF( INFO.NE.0 ) THEN
208: CALL XERBLA( 'DTBCON', -INFO )
209: RETURN
210: END IF
211: *
212: * Quick return if possible
213: *
214: IF( N.EQ.0 ) THEN
215: RCOND = ONE
216: RETURN
217: END IF
218: *
219: RCOND = ZERO
220: SMLNUM = DLAMCH( 'Safe minimum' )*DBLE( MAX( 1, N ) )
221: *
222: * Compute the norm of the triangular matrix A.
223: *
224: ANORM = DLANTB( NORM, UPLO, DIAG, N, KD, AB, LDAB, WORK )
225: *
226: * Continue only if ANORM > 0.
227: *
228: IF( ANORM.GT.ZERO ) THEN
229: *
230: * Estimate the norm of the inverse of A.
231: *
232: AINVNM = ZERO
233: NORMIN = 'N'
234: IF( ONENRM ) THEN
235: KASE1 = 1
236: ELSE
237: KASE1 = 2
238: END IF
239: KASE = 0
240: 10 CONTINUE
241: CALL DLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
242: IF( KASE.NE.0 ) THEN
243: IF( KASE.EQ.KASE1 ) THEN
244: *
245: * Multiply by inv(A).
246: *
247: CALL DLATBS( UPLO, 'No transpose', DIAG, NORMIN, N, KD,
248: $ AB, LDAB, WORK, SCALE, WORK( 2*N+1 ), INFO )
249: ELSE
250: *
251: * Multiply by inv(A**T).
252: *
253: CALL DLATBS( UPLO, 'Transpose', DIAG, NORMIN, N, KD, AB,
254: $ LDAB, WORK, SCALE, WORK( 2*N+1 ), INFO )
255: END IF
256: NORMIN = 'Y'
257: *
258: * Multiply by 1/SCALE if doing so will not cause overflow.
259: *
260: IF( SCALE.NE.ONE ) THEN
261: IX = IDAMAX( N, WORK, 1 )
262: XNORM = ABS( WORK( IX ) )
263: IF( SCALE.LT.XNORM*SMLNUM .OR. SCALE.EQ.ZERO )
264: $ GO TO 20
265: CALL DRSCL( N, SCALE, WORK, 1 )
266: END IF
267: GO TO 10
268: END IF
269: *
270: * Compute the estimate of the reciprocal condition number.
271: *
272: IF( AINVNM.NE.ZERO )
273: $ RCOND = ( ONE / ANORM ) / AINVNM
274: END IF
275: *
276: 20 CONTINUE
277: RETURN
278: *
279: * End of DTBCON
280: *
281: END
CVSweb interface <joel.bertrand@systella.fr>