Annotation of rpl/lapack/lapack/dsytrf.f, revision 1.1.1.1
1.1 bertrand 1: SUBROUTINE DSYTRF( UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO )
2: *
3: * -- LAPACK routine (version 3.2) --
4: * -- LAPACK is a software package provided by Univ. of Tennessee, --
5: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
6: * November 2006
7: *
8: * .. Scalar Arguments ..
9: CHARACTER UPLO
10: INTEGER INFO, LDA, LWORK, N
11: * ..
12: * .. Array Arguments ..
13: INTEGER IPIV( * )
14: DOUBLE PRECISION A( LDA, * ), WORK( * )
15: * ..
16: *
17: * Purpose
18: * =======
19: *
20: * DSYTRF computes the factorization of a real symmetric matrix A using
21: * the Bunch-Kaufman diagonal pivoting method. The form of the
22: * factorization is
23: *
24: * A = U*D*U**T or A = L*D*L**T
25: *
26: * where U (or L) is a product of permutation and unit upper (lower)
27: * triangular matrices, and D is symmetric and block diagonal with
28: * 1-by-1 and 2-by-2 diagonal blocks.
29: *
30: * This is the blocked version of the algorithm, calling Level 3 BLAS.
31: *
32: * Arguments
33: * =========
34: *
35: * UPLO (input) CHARACTER*1
36: * = 'U': Upper triangle of A is stored;
37: * = 'L': Lower triangle of A is stored.
38: *
39: * N (input) INTEGER
40: * The order of the matrix A. N >= 0.
41: *
42: * A (input/output) DOUBLE PRECISION array, dimension (LDA,N)
43: * On entry, the symmetric matrix A. If UPLO = 'U', the leading
44: * N-by-N upper triangular part of A contains the upper
45: * triangular part of the matrix A, and the strictly lower
46: * triangular part of A is not referenced. If UPLO = 'L', the
47: * leading N-by-N lower triangular part of A contains the lower
48: * triangular part of the matrix A, and the strictly upper
49: * triangular part of A is not referenced.
50: *
51: * On exit, the block diagonal matrix D and the multipliers used
52: * to obtain the factor U or L (see below for further details).
53: *
54: * LDA (input) INTEGER
55: * The leading dimension of the array A. LDA >= max(1,N).
56: *
57: * IPIV (output) INTEGER array, dimension (N)
58: * Details of the interchanges and the block structure of D.
59: * If IPIV(k) > 0, then rows and columns k and IPIV(k) were
60: * interchanged and D(k,k) is a 1-by-1 diagonal block.
61: * If UPLO = 'U' and IPIV(k) = IPIV(k-1) < 0, then rows and
62: * columns k-1 and -IPIV(k) were interchanged and D(k-1:k,k-1:k)
63: * is a 2-by-2 diagonal block. If UPLO = 'L' and IPIV(k) =
64: * IPIV(k+1) < 0, then rows and columns k+1 and -IPIV(k) were
65: * interchanged and D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
66: *
67: * WORK (workspace/output) DOUBLE PRECISION array, dimension (MAX(1,LWORK))
68: * On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
69: *
70: * LWORK (input) INTEGER
71: * The length of WORK. LWORK >=1. For best performance
72: * LWORK >= N*NB, where NB is the block size returned by ILAENV.
73: *
74: * If LWORK = -1, then a workspace query is assumed; the routine
75: * only calculates the optimal size of the WORK array, returns
76: * this value as the first entry of the WORK array, and no error
77: * message related to LWORK is issued by XERBLA.
78: *
79: * INFO (output) INTEGER
80: * = 0: successful exit
81: * < 0: if INFO = -i, the i-th argument had an illegal value
82: * > 0: if INFO = i, D(i,i) is exactly zero. The factorization
83: * has been completed, but the block diagonal matrix D is
84: * exactly singular, and division by zero will occur if it
85: * is used to solve a system of equations.
86: *
87: * Further Details
88: * ===============
89: *
90: * If UPLO = 'U', then A = U*D*U', where
91: * U = P(n)*U(n)* ... *P(k)U(k)* ...,
92: * i.e., U is a product of terms P(k)*U(k), where k decreases from n to
93: * 1 in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
94: * and 2-by-2 diagonal blocks D(k). P(k) is a permutation matrix as
95: * defined by IPIV(k), and U(k) is a unit upper triangular matrix, such
96: * that if the diagonal block D(k) is of order s (s = 1 or 2), then
97: *
98: * ( I v 0 ) k-s
99: * U(k) = ( 0 I 0 ) s
100: * ( 0 0 I ) n-k
101: * k-s s n-k
102: *
103: * If s = 1, D(k) overwrites A(k,k), and v overwrites A(1:k-1,k).
104: * If s = 2, the upper triangle of D(k) overwrites A(k-1,k-1), A(k-1,k),
105: * and A(k,k), and v overwrites A(1:k-2,k-1:k).
106: *
107: * If UPLO = 'L', then A = L*D*L', where
108: * L = P(1)*L(1)* ... *P(k)*L(k)* ...,
109: * i.e., L is a product of terms P(k)*L(k), where k increases from 1 to
110: * n in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
111: * and 2-by-2 diagonal blocks D(k). P(k) is a permutation matrix as
112: * defined by IPIV(k), and L(k) is a unit lower triangular matrix, such
113: * that if the diagonal block D(k) is of order s (s = 1 or 2), then
114: *
115: * ( I 0 0 ) k-1
116: * L(k) = ( 0 I 0 ) s
117: * ( 0 v I ) n-k-s+1
118: * k-1 s n-k-s+1
119: *
120: * If s = 1, D(k) overwrites A(k,k), and v overwrites A(k+1:n,k).
121: * If s = 2, the lower triangle of D(k) overwrites A(k,k), A(k+1,k),
122: * and A(k+1,k+1), and v overwrites A(k+2:n,k:k+1).
123: *
124: * =====================================================================
125: *
126: * .. Local Scalars ..
127: LOGICAL LQUERY, UPPER
128: INTEGER IINFO, IWS, J, K, KB, LDWORK, LWKOPT, NB, NBMIN
129: * ..
130: * .. External Functions ..
131: LOGICAL LSAME
132: INTEGER ILAENV
133: EXTERNAL LSAME, ILAENV
134: * ..
135: * .. External Subroutines ..
136: EXTERNAL DLASYF, DSYTF2, XERBLA
137: * ..
138: * .. Intrinsic Functions ..
139: INTRINSIC MAX
140: * ..
141: * .. Executable Statements ..
142: *
143: * Test the input parameters.
144: *
145: INFO = 0
146: UPPER = LSAME( UPLO, 'U' )
147: LQUERY = ( LWORK.EQ.-1 )
148: IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
149: INFO = -1
150: ELSE IF( N.LT.0 ) THEN
151: INFO = -2
152: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
153: INFO = -4
154: ELSE IF( LWORK.LT.1 .AND. .NOT.LQUERY ) THEN
155: INFO = -7
156: END IF
157: *
158: IF( INFO.EQ.0 ) THEN
159: *
160: * Determine the block size
161: *
162: NB = ILAENV( 1, 'DSYTRF', UPLO, N, -1, -1, -1 )
163: LWKOPT = N*NB
164: WORK( 1 ) = LWKOPT
165: END IF
166: *
167: IF( INFO.NE.0 ) THEN
168: CALL XERBLA( 'DSYTRF', -INFO )
169: RETURN
170: ELSE IF( LQUERY ) THEN
171: RETURN
172: END IF
173: *
174: NBMIN = 2
175: LDWORK = N
176: IF( NB.GT.1 .AND. NB.LT.N ) THEN
177: IWS = LDWORK*NB
178: IF( LWORK.LT.IWS ) THEN
179: NB = MAX( LWORK / LDWORK, 1 )
180: NBMIN = MAX( 2, ILAENV( 2, 'DSYTRF', UPLO, N, -1, -1, -1 ) )
181: END IF
182: ELSE
183: IWS = 1
184: END IF
185: IF( NB.LT.NBMIN )
186: $ NB = N
187: *
188: IF( UPPER ) THEN
189: *
190: * Factorize A as U*D*U' using the upper triangle of A
191: *
192: * K is the main loop index, decreasing from N to 1 in steps of
193: * KB, where KB is the number of columns factorized by DLASYF;
194: * KB is either NB or NB-1, or K for the last block
195: *
196: K = N
197: 10 CONTINUE
198: *
199: * If K < 1, exit from loop
200: *
201: IF( K.LT.1 )
202: $ GO TO 40
203: *
204: IF( K.GT.NB ) THEN
205: *
206: * Factorize columns k-kb+1:k of A and use blocked code to
207: * update columns 1:k-kb
208: *
209: CALL DLASYF( UPLO, K, NB, KB, A, LDA, IPIV, WORK, LDWORK,
210: $ IINFO )
211: ELSE
212: *
213: * Use unblocked code to factorize columns 1:k of A
214: *
215: CALL DSYTF2( UPLO, K, A, LDA, IPIV, IINFO )
216: KB = K
217: END IF
218: *
219: * Set INFO on the first occurrence of a zero pivot
220: *
221: IF( INFO.EQ.0 .AND. IINFO.GT.0 )
222: $ INFO = IINFO
223: *
224: * Decrease K and return to the start of the main loop
225: *
226: K = K - KB
227: GO TO 10
228: *
229: ELSE
230: *
231: * Factorize A as L*D*L' using the lower triangle of A
232: *
233: * K is the main loop index, increasing from 1 to N in steps of
234: * KB, where KB is the number of columns factorized by DLASYF;
235: * KB is either NB or NB-1, or N-K+1 for the last block
236: *
237: K = 1
238: 20 CONTINUE
239: *
240: * If K > N, exit from loop
241: *
242: IF( K.GT.N )
243: $ GO TO 40
244: *
245: IF( K.LE.N-NB ) THEN
246: *
247: * Factorize columns k:k+kb-1 of A and use blocked code to
248: * update columns k+kb:n
249: *
250: CALL DLASYF( UPLO, N-K+1, NB, KB, A( K, K ), LDA, IPIV( K ),
251: $ WORK, LDWORK, IINFO )
252: ELSE
253: *
254: * Use unblocked code to factorize columns k:n of A
255: *
256: CALL DSYTF2( UPLO, N-K+1, A( K, K ), LDA, IPIV( K ), IINFO )
257: KB = N - K + 1
258: END IF
259: *
260: * Set INFO on the first occurrence of a zero pivot
261: *
262: IF( INFO.EQ.0 .AND. IINFO.GT.0 )
263: $ INFO = IINFO + K - 1
264: *
265: * Adjust IPIV
266: *
267: DO 30 J = K, K + KB - 1
268: IF( IPIV( J ).GT.0 ) THEN
269: IPIV( J ) = IPIV( J ) + K - 1
270: ELSE
271: IPIV( J ) = IPIV( J ) - K + 1
272: END IF
273: 30 CONTINUE
274: *
275: * Increase K and return to the start of the main loop
276: *
277: K = K + KB
278: GO TO 20
279: *
280: END IF
281: *
282: 40 CONTINUE
283: WORK( 1 ) = LWKOPT
284: RETURN
285: *
286: * End of DSYTRF
287: *
288: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dsytrf.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack