Annotation of rpl/lapack/lapack/dsyrfsx.f, revision 1.1
1.1 ! bertrand 1: SUBROUTINE DSYRFSX( UPLO, EQUED, N, NRHS, A, LDA, AF, LDAF, IPIV,
! 2: $ S, B, LDB, X, LDX, RCOND, BERR, N_ERR_BNDS,
! 3: $ ERR_BNDS_NORM, ERR_BNDS_COMP, NPARAMS, PARAMS,
! 4: $ WORK, IWORK, INFO )
! 5: *
! 6: * -- LAPACK routine (version 3.2.2) --
! 7: * -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
! 8: * -- Jason Riedy of Univ. of California Berkeley. --
! 9: * -- June 2010 --
! 10: *
! 11: * -- LAPACK is a software package provided by Univ. of Tennessee, --
! 12: * -- Univ. of California Berkeley and NAG Ltd. --
! 13: *
! 14: IMPLICIT NONE
! 15: * ..
! 16: * .. Scalar Arguments ..
! 17: CHARACTER UPLO, EQUED
! 18: INTEGER INFO, LDA, LDAF, LDB, LDX, N, NRHS, NPARAMS,
! 19: $ N_ERR_BNDS
! 20: DOUBLE PRECISION RCOND
! 21: * ..
! 22: * .. Array Arguments ..
! 23: INTEGER IPIV( * ), IWORK( * )
! 24: DOUBLE PRECISION A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
! 25: $ X( LDX, * ), WORK( * )
! 26: DOUBLE PRECISION S( * ), PARAMS( * ), BERR( * ),
! 27: $ ERR_BNDS_NORM( NRHS, * ),
! 28: $ ERR_BNDS_COMP( NRHS, * )
! 29: * ..
! 30: *
! 31: * Purpose
! 32: * =======
! 33: *
! 34: * DSYRFSX improves the computed solution to a system of linear
! 35: * equations when the coefficient matrix is symmetric indefinite, and
! 36: * provides error bounds and backward error estimates for the
! 37: * solution. In addition to normwise error bound, the code provides
! 38: * maximum componentwise error bound if possible. See comments for
! 39: * ERR_BNDS_NORM and ERR_BNDS_COMP for details of the error bounds.
! 40: *
! 41: * The original system of linear equations may have been equilibrated
! 42: * before calling this routine, as described by arguments EQUED and S
! 43: * below. In this case, the solution and error bounds returned are
! 44: * for the original unequilibrated system.
! 45: *
! 46: * Arguments
! 47: * =========
! 48: *
! 49: * Some optional parameters are bundled in the PARAMS array. These
! 50: * settings determine how refinement is performed, but often the
! 51: * defaults are acceptable. If the defaults are acceptable, users
! 52: * can pass NPARAMS = 0 which prevents the source code from accessing
! 53: * the PARAMS argument.
! 54: *
! 55: * UPLO (input) CHARACTER*1
! 56: * = 'U': Upper triangle of A is stored;
! 57: * = 'L': Lower triangle of A is stored.
! 58: *
! 59: * EQUED (input) CHARACTER*1
! 60: * Specifies the form of equilibration that was done to A
! 61: * before calling this routine. This is needed to compute
! 62: * the solution and error bounds correctly.
! 63: * = 'N': No equilibration
! 64: * = 'Y': Both row and column equilibration, i.e., A has been
! 65: * replaced by diag(S) * A * diag(S).
! 66: * The right hand side B has been changed accordingly.
! 67: *
! 68: * N (input) INTEGER
! 69: * The order of the matrix A. N >= 0.
! 70: *
! 71: * NRHS (input) INTEGER
! 72: * The number of right hand sides, i.e., the number of columns
! 73: * of the matrices B and X. NRHS >= 0.
! 74: *
! 75: * A (input) DOUBLE PRECISION array, dimension (LDA,N)
! 76: * The symmetric matrix A. If UPLO = 'U', the leading N-by-N
! 77: * upper triangular part of A contains the upper triangular
! 78: * part of the matrix A, and the strictly lower triangular
! 79: * part of A is not referenced. If UPLO = 'L', the leading
! 80: * N-by-N lower triangular part of A contains the lower
! 81: * triangular part of the matrix A, and the strictly upper
! 82: * triangular part of A is not referenced.
! 83: *
! 84: * LDA (input) INTEGER
! 85: * The leading dimension of the array A. LDA >= max(1,N).
! 86: *
! 87: * AF (input) DOUBLE PRECISION array, dimension (LDAF,N)
! 88: * The factored form of the matrix A. AF contains the block
! 89: * diagonal matrix D and the multipliers used to obtain the
! 90: * factor U or L from the factorization A = U*D*U**T or A =
! 91: * L*D*L**T as computed by DSYTRF.
! 92: *
! 93: * LDAF (input) INTEGER
! 94: * The leading dimension of the array AF. LDAF >= max(1,N).
! 95: *
! 96: * IPIV (input) INTEGER array, dimension (N)
! 97: * Details of the interchanges and the block structure of D
! 98: * as determined by DSYTRF.
! 99: *
! 100: * S (input or output) DOUBLE PRECISION array, dimension (N)
! 101: * The scale factors for A. If EQUED = 'Y', A is multiplied on
! 102: * the left and right by diag(S). S is an input argument if FACT =
! 103: * 'F'; otherwise, S is an output argument. If FACT = 'F' and EQUED
! 104: * = 'Y', each element of S must be positive. If S is output, each
! 105: * element of S is a power of the radix. If S is input, each element
! 106: * of S should be a power of the radix to ensure a reliable solution
! 107: * and error estimates. Scaling by powers of the radix does not cause
! 108: * rounding errors unless the result underflows or overflows.
! 109: * Rounding errors during scaling lead to refining with a matrix that
! 110: * is not equivalent to the input matrix, producing error estimates
! 111: * that may not be reliable.
! 112: *
! 113: * B (input) DOUBLE PRECISION array, dimension (LDB,NRHS)
! 114: * The right hand side matrix B.
! 115: *
! 116: * LDB (input) INTEGER
! 117: * The leading dimension of the array B. LDB >= max(1,N).
! 118: *
! 119: * X (input/output) DOUBLE PRECISION array, dimension (LDX,NRHS)
! 120: * On entry, the solution matrix X, as computed by DGETRS.
! 121: * On exit, the improved solution matrix X.
! 122: *
! 123: * LDX (input) INTEGER
! 124: * The leading dimension of the array X. LDX >= max(1,N).
! 125: *
! 126: * RCOND (output) DOUBLE PRECISION
! 127: * Reciprocal scaled condition number. This is an estimate of the
! 128: * reciprocal Skeel condition number of the matrix A after
! 129: * equilibration (if done). If this is less than the machine
! 130: * precision (in particular, if it is zero), the matrix is singular
! 131: * to working precision. Note that the error may still be small even
! 132: * if this number is very small and the matrix appears ill-
! 133: * conditioned.
! 134: *
! 135: * BERR (output) DOUBLE PRECISION array, dimension (NRHS)
! 136: * Componentwise relative backward error. This is the
! 137: * componentwise relative backward error of each solution vector X(j)
! 138: * (i.e., the smallest relative change in any element of A or B that
! 139: * makes X(j) an exact solution).
! 140: *
! 141: * N_ERR_BNDS (input) INTEGER
! 142: * Number of error bounds to return for each right hand side
! 143: * and each type (normwise or componentwise). See ERR_BNDS_NORM and
! 144: * ERR_BNDS_COMP below.
! 145: *
! 146: * ERR_BNDS_NORM (output) DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
! 147: * For each right-hand side, this array contains information about
! 148: * various error bounds and condition numbers corresponding to the
! 149: * normwise relative error, which is defined as follows:
! 150: *
! 151: * Normwise relative error in the ith solution vector:
! 152: * max_j (abs(XTRUE(j,i) - X(j,i)))
! 153: * ------------------------------
! 154: * max_j abs(X(j,i))
! 155: *
! 156: * The array is indexed by the type of error information as described
! 157: * below. There currently are up to three pieces of information
! 158: * returned.
! 159: *
! 160: * The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
! 161: * right-hand side.
! 162: *
! 163: * The second index in ERR_BNDS_NORM(:,err) contains the following
! 164: * three fields:
! 165: * err = 1 "Trust/don't trust" boolean. Trust the answer if the
! 166: * reciprocal condition number is less than the threshold
! 167: * sqrt(n) * dlamch('Epsilon').
! 168: *
! 169: * err = 2 "Guaranteed" error bound: The estimated forward error,
! 170: * almost certainly within a factor of 10 of the true error
! 171: * so long as the next entry is greater than the threshold
! 172: * sqrt(n) * dlamch('Epsilon'). This error bound should only
! 173: * be trusted if the previous boolean is true.
! 174: *
! 175: * err = 3 Reciprocal condition number: Estimated normwise
! 176: * reciprocal condition number. Compared with the threshold
! 177: * sqrt(n) * dlamch('Epsilon') to determine if the error
! 178: * estimate is "guaranteed". These reciprocal condition
! 179: * numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
! 180: * appropriately scaled matrix Z.
! 181: * Let Z = S*A, where S scales each row by a power of the
! 182: * radix so all absolute row sums of Z are approximately 1.
! 183: *
! 184: * See Lapack Working Note 165 for further details and extra
! 185: * cautions.
! 186: *
! 187: * ERR_BNDS_COMP (output) DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
! 188: * For each right-hand side, this array contains information about
! 189: * various error bounds and condition numbers corresponding to the
! 190: * componentwise relative error, which is defined as follows:
! 191: *
! 192: * Componentwise relative error in the ith solution vector:
! 193: * abs(XTRUE(j,i) - X(j,i))
! 194: * max_j ----------------------
! 195: * abs(X(j,i))
! 196: *
! 197: * The array is indexed by the right-hand side i (on which the
! 198: * componentwise relative error depends), and the type of error
! 199: * information as described below. There currently are up to three
! 200: * pieces of information returned for each right-hand side. If
! 201: * componentwise accuracy is not requested (PARAMS(3) = 0.0), then
! 202: * ERR_BNDS_COMP is not accessed. If N_ERR_BNDS .LT. 3, then at most
! 203: * the first (:,N_ERR_BNDS) entries are returned.
! 204: *
! 205: * The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
! 206: * right-hand side.
! 207: *
! 208: * The second index in ERR_BNDS_COMP(:,err) contains the following
! 209: * three fields:
! 210: * err = 1 "Trust/don't trust" boolean. Trust the answer if the
! 211: * reciprocal condition number is less than the threshold
! 212: * sqrt(n) * dlamch('Epsilon').
! 213: *
! 214: * err = 2 "Guaranteed" error bound: The estimated forward error,
! 215: * almost certainly within a factor of 10 of the true error
! 216: * so long as the next entry is greater than the threshold
! 217: * sqrt(n) * dlamch('Epsilon'). This error bound should only
! 218: * be trusted if the previous boolean is true.
! 219: *
! 220: * err = 3 Reciprocal condition number: Estimated componentwise
! 221: * reciprocal condition number. Compared with the threshold
! 222: * sqrt(n) * dlamch('Epsilon') to determine if the error
! 223: * estimate is "guaranteed". These reciprocal condition
! 224: * numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
! 225: * appropriately scaled matrix Z.
! 226: * Let Z = S*(A*diag(x)), where x is the solution for the
! 227: * current right-hand side and S scales each row of
! 228: * A*diag(x) by a power of the radix so all absolute row
! 229: * sums of Z are approximately 1.
! 230: *
! 231: * See Lapack Working Note 165 for further details and extra
! 232: * cautions.
! 233: *
! 234: * NPARAMS (input) INTEGER
! 235: * Specifies the number of parameters set in PARAMS. If .LE. 0, the
! 236: * PARAMS array is never referenced and default values are used.
! 237: *
! 238: * PARAMS (input / output) DOUBLE PRECISION array, dimension (NPARAMS)
! 239: * Specifies algorithm parameters. If an entry is .LT. 0.0, then
! 240: * that entry will be filled with default value used for that
! 241: * parameter. Only positions up to NPARAMS are accessed; defaults
! 242: * are used for higher-numbered parameters.
! 243: *
! 244: * PARAMS(LA_LINRX_ITREF_I = 1) : Whether to perform iterative
! 245: * refinement or not.
! 246: * Default: 1.0D+0
! 247: * = 0.0 : No refinement is performed, and no error bounds are
! 248: * computed.
! 249: * = 1.0 : Use the double-precision refinement algorithm,
! 250: * possibly with doubled-single computations if the
! 251: * compilation environment does not support DOUBLE
! 252: * PRECISION.
! 253: * (other values are reserved for future use)
! 254: *
! 255: * PARAMS(LA_LINRX_ITHRESH_I = 2) : Maximum number of residual
! 256: * computations allowed for refinement.
! 257: * Default: 10
! 258: * Aggressive: Set to 100 to permit convergence using approximate
! 259: * factorizations or factorizations other than LU. If
! 260: * the factorization uses a technique other than
! 261: * Gaussian elimination, the guarantees in
! 262: * err_bnds_norm and err_bnds_comp may no longer be
! 263: * trustworthy.
! 264: *
! 265: * PARAMS(LA_LINRX_CWISE_I = 3) : Flag determining if the code
! 266: * will attempt to find a solution with small componentwise
! 267: * relative error in the double-precision algorithm. Positive
! 268: * is true, 0.0 is false.
! 269: * Default: 1.0 (attempt componentwise convergence)
! 270: *
! 271: * WORK (workspace) DOUBLE PRECISION array, dimension (4*N)
! 272: *
! 273: * IWORK (workspace) INTEGER array, dimension (N)
! 274: *
! 275: * INFO (output) INTEGER
! 276: * = 0: Successful exit. The solution to every right-hand side is
! 277: * guaranteed.
! 278: * < 0: If INFO = -i, the i-th argument had an illegal value
! 279: * > 0 and <= N: U(INFO,INFO) is exactly zero. The factorization
! 280: * has been completed, but the factor U is exactly singular, so
! 281: * the solution and error bounds could not be computed. RCOND = 0
! 282: * is returned.
! 283: * = N+J: The solution corresponding to the Jth right-hand side is
! 284: * not guaranteed. The solutions corresponding to other right-
! 285: * hand sides K with K > J may not be guaranteed as well, but
! 286: * only the first such right-hand side is reported. If a small
! 287: * componentwise error is not requested (PARAMS(3) = 0.0) then
! 288: * the Jth right-hand side is the first with a normwise error
! 289: * bound that is not guaranteed (the smallest J such
! 290: * that ERR_BNDS_NORM(J,1) = 0.0). By default (PARAMS(3) = 1.0)
! 291: * the Jth right-hand side is the first with either a normwise or
! 292: * componentwise error bound that is not guaranteed (the smallest
! 293: * J such that either ERR_BNDS_NORM(J,1) = 0.0 or
! 294: * ERR_BNDS_COMP(J,1) = 0.0). See the definition of
! 295: * ERR_BNDS_NORM(:,1) and ERR_BNDS_COMP(:,1). To get information
! 296: * about all of the right-hand sides check ERR_BNDS_NORM or
! 297: * ERR_BNDS_COMP.
! 298: *
! 299: * ==================================================================
! 300: *
! 301: * .. Parameters ..
! 302: DOUBLE PRECISION ZERO, ONE
! 303: PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
! 304: DOUBLE PRECISION ITREF_DEFAULT, ITHRESH_DEFAULT
! 305: DOUBLE PRECISION COMPONENTWISE_DEFAULT, RTHRESH_DEFAULT
! 306: DOUBLE PRECISION DZTHRESH_DEFAULT
! 307: PARAMETER ( ITREF_DEFAULT = 1.0D+0 )
! 308: PARAMETER ( ITHRESH_DEFAULT = 10.0D+0 )
! 309: PARAMETER ( COMPONENTWISE_DEFAULT = 1.0D+0 )
! 310: PARAMETER ( RTHRESH_DEFAULT = 0.5D+0 )
! 311: PARAMETER ( DZTHRESH_DEFAULT = 0.25D+0 )
! 312: INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
! 313: $ LA_LINRX_CWISE_I
! 314: PARAMETER ( LA_LINRX_ITREF_I = 1,
! 315: $ LA_LINRX_ITHRESH_I = 2 )
! 316: PARAMETER ( LA_LINRX_CWISE_I = 3 )
! 317: INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
! 318: $ LA_LINRX_RCOND_I
! 319: PARAMETER ( LA_LINRX_TRUST_I = 1, LA_LINRX_ERR_I = 2 )
! 320: PARAMETER ( LA_LINRX_RCOND_I = 3 )
! 321: * ..
! 322: * .. Local Scalars ..
! 323: CHARACTER(1) NORM
! 324: LOGICAL RCEQU
! 325: INTEGER J, PREC_TYPE, REF_TYPE, N_NORMS
! 326: DOUBLE PRECISION ANORM, RCOND_TMP
! 327: DOUBLE PRECISION ILLRCOND_THRESH, ERR_LBND, CWISE_WRONG
! 328: LOGICAL IGNORE_CWISE
! 329: INTEGER ITHRESH
! 330: DOUBLE PRECISION RTHRESH, UNSTABLE_THRESH
! 331: * ..
! 332: * .. External Subroutines ..
! 333: EXTERNAL XERBLA, DSYCON, DLA_SYRFSX_EXTENDED
! 334: * ..
! 335: * .. Intrinsic Functions ..
! 336: INTRINSIC MAX, SQRT
! 337: * ..
! 338: * .. External Functions ..
! 339: EXTERNAL LSAME, BLAS_FPINFO_X, ILATRANS, ILAPREC
! 340: EXTERNAL DLAMCH, DLANSY, DLA_SYRCOND
! 341: DOUBLE PRECISION DLAMCH, DLANSY, DLA_SYRCOND
! 342: LOGICAL LSAME
! 343: INTEGER BLAS_FPINFO_X
! 344: INTEGER ILATRANS, ILAPREC
! 345: * ..
! 346: * .. Executable Statements ..
! 347: *
! 348: * Check the input parameters.
! 349: *
! 350: INFO = 0
! 351: REF_TYPE = INT( ITREF_DEFAULT )
! 352: IF ( NPARAMS .GE. LA_LINRX_ITREF_I ) THEN
! 353: IF ( PARAMS( LA_LINRX_ITREF_I ) .LT. 0.0D+0 ) THEN
! 354: PARAMS( LA_LINRX_ITREF_I ) = ITREF_DEFAULT
! 355: ELSE
! 356: REF_TYPE = PARAMS( LA_LINRX_ITREF_I )
! 357: END IF
! 358: END IF
! 359: *
! 360: * Set default parameters.
! 361: *
! 362: ILLRCOND_THRESH = DBLE( N )*DLAMCH( 'Epsilon' )
! 363: ITHRESH = INT( ITHRESH_DEFAULT )
! 364: RTHRESH = RTHRESH_DEFAULT
! 365: UNSTABLE_THRESH = DZTHRESH_DEFAULT
! 366: IGNORE_CWISE = COMPONENTWISE_DEFAULT .EQ. 0.0D+0
! 367: *
! 368: IF ( NPARAMS.GE.LA_LINRX_ITHRESH_I ) THEN
! 369: IF ( PARAMS( LA_LINRX_ITHRESH_I ).LT.0.0D+0 ) THEN
! 370: PARAMS( LA_LINRX_ITHRESH_I ) = ITHRESH
! 371: ELSE
! 372: ITHRESH = INT( PARAMS( LA_LINRX_ITHRESH_I ) )
! 373: END IF
! 374: END IF
! 375: IF ( NPARAMS.GE.LA_LINRX_CWISE_I ) THEN
! 376: IF ( PARAMS( LA_LINRX_CWISE_I ).LT.0.0D+0 ) THEN
! 377: IF ( IGNORE_CWISE ) THEN
! 378: PARAMS( LA_LINRX_CWISE_I ) = 0.0D+0
! 379: ELSE
! 380: PARAMS( LA_LINRX_CWISE_I ) = 1.0D+0
! 381: END IF
! 382: ELSE
! 383: IGNORE_CWISE = PARAMS( LA_LINRX_CWISE_I ) .EQ. 0.0D+0
! 384: END IF
! 385: END IF
! 386: IF ( REF_TYPE .EQ. 0 .OR. N_ERR_BNDS .EQ. 0 ) THEN
! 387: N_NORMS = 0
! 388: ELSE IF ( IGNORE_CWISE ) THEN
! 389: N_NORMS = 1
! 390: ELSE
! 391: N_NORMS = 2
! 392: END IF
! 393: *
! 394: RCEQU = LSAME( EQUED, 'Y' )
! 395: *
! 396: * Test input parameters.
! 397: *
! 398: IF ( .NOT.LSAME( UPLO, 'U' ) .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
! 399: INFO = -1
! 400: ELSE IF( .NOT.RCEQU .AND. .NOT.LSAME( EQUED, 'N' ) ) THEN
! 401: INFO = -2
! 402: ELSE IF( N.LT.0 ) THEN
! 403: INFO = -3
! 404: ELSE IF( NRHS.LT.0 ) THEN
! 405: INFO = -4
! 406: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
! 407: INFO = -6
! 408: ELSE IF( LDAF.LT.MAX( 1, N ) ) THEN
! 409: INFO = -8
! 410: ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
! 411: INFO = -11
! 412: ELSE IF( LDX.LT.MAX( 1, N ) ) THEN
! 413: INFO = -13
! 414: END IF
! 415: IF( INFO.NE.0 ) THEN
! 416: CALL XERBLA( 'DSYRFSX', -INFO )
! 417: RETURN
! 418: END IF
! 419: *
! 420: * Quick return if possible.
! 421: *
! 422: IF( N.EQ.0 .OR. NRHS.EQ.0 ) THEN
! 423: RCOND = 1.0D+0
! 424: DO J = 1, NRHS
! 425: BERR( J ) = 0.0D+0
! 426: IF ( N_ERR_BNDS .GE. 1 ) THEN
! 427: ERR_BNDS_NORM( J, LA_LINRX_TRUST_I ) = 1.0D+0
! 428: ERR_BNDS_COMP( J, LA_LINRX_TRUST_I ) = 1.0D+0
! 429: END IF
! 430: IF ( N_ERR_BNDS .GE. 2 ) THEN
! 431: ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) = 0.0D+0
! 432: ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) = 0.0D+0
! 433: END IF
! 434: IF ( N_ERR_BNDS .GE. 3 ) THEN
! 435: ERR_BNDS_NORM( J, LA_LINRX_RCOND_I ) = 1.0D+0
! 436: ERR_BNDS_COMP( J, LA_LINRX_RCOND_I ) = 1.0D+0
! 437: END IF
! 438: END DO
! 439: RETURN
! 440: END IF
! 441: *
! 442: * Default to failure.
! 443: *
! 444: RCOND = 0.0D+0
! 445: DO J = 1, NRHS
! 446: BERR( J ) = 1.0D+0
! 447: IF ( N_ERR_BNDS .GE. 1 ) THEN
! 448: ERR_BNDS_NORM( J, LA_LINRX_TRUST_I ) = 1.0D+0
! 449: ERR_BNDS_COMP( J, LA_LINRX_TRUST_I ) = 1.0D+0
! 450: END IF
! 451: IF ( N_ERR_BNDS .GE. 2 ) THEN
! 452: ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) = 1.0D+0
! 453: ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) = 1.0D+0
! 454: END IF
! 455: IF ( N_ERR_BNDS .GE. 3 ) THEN
! 456: ERR_BNDS_NORM( J, LA_LINRX_RCOND_I ) = 0.0D+0
! 457: ERR_BNDS_COMP( J, LA_LINRX_RCOND_I ) = 0.0D+0
! 458: END IF
! 459: END DO
! 460: *
! 461: * Compute the norm of A and the reciprocal of the condition
! 462: * number of A.
! 463: *
! 464: NORM = 'I'
! 465: ANORM = DLANSY( NORM, UPLO, N, A, LDA, WORK )
! 466: CALL DSYCON( UPLO, N, AF, LDAF, IPIV, ANORM, RCOND, WORK,
! 467: $ IWORK, INFO )
! 468: *
! 469: * Perform refinement on each right-hand side
! 470: *
! 471: IF ( REF_TYPE .NE. 0 ) THEN
! 472:
! 473: PREC_TYPE = ILAPREC( 'E' )
! 474:
! 475: CALL DLA_SYRFSX_EXTENDED( PREC_TYPE, UPLO, N,
! 476: $ NRHS, A, LDA, AF, LDAF, IPIV, RCEQU, S, B,
! 477: $ LDB, X, LDX, BERR, N_NORMS, ERR_BNDS_NORM, ERR_BNDS_COMP,
! 478: $ WORK( N+1 ), WORK( 1 ), WORK( 2*N+1 ), WORK( 1 ), RCOND,
! 479: $ ITHRESH, RTHRESH, UNSTABLE_THRESH, IGNORE_CWISE,
! 480: $ INFO )
! 481: END IF
! 482:
! 483: ERR_LBND = MAX( 10.0D+0, SQRT( DBLE( N ) ) )*DLAMCH( 'Epsilon' )
! 484: IF (N_ERR_BNDS .GE. 1 .AND. N_NORMS .GE. 1) THEN
! 485: *
! 486: * Compute scaled normwise condition number cond(A*C).
! 487: *
! 488: IF ( RCEQU ) THEN
! 489: RCOND_TMP = DLA_SYRCOND( UPLO, N, A, LDA, AF, LDAF, IPIV,
! 490: $ -1, S, INFO, WORK, IWORK )
! 491: ELSE
! 492: RCOND_TMP = DLA_SYRCOND( UPLO, N, A, LDA, AF, LDAF, IPIV,
! 493: $ 0, S, INFO, WORK, IWORK )
! 494: END IF
! 495: DO J = 1, NRHS
! 496: *
! 497: * Cap the error at 1.0.
! 498: *
! 499: IF (N_ERR_BNDS .GE. LA_LINRX_ERR_I
! 500: $ .AND. ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) .GT. 1.0D+0)
! 501: $ ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) = 1.0D+0
! 502: *
! 503: * Threshold the error (see LAWN).
! 504: *
! 505: IF ( RCOND_TMP .LT. ILLRCOND_THRESH ) THEN
! 506: ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) = 1.0D+0
! 507: ERR_BNDS_NORM( J, LA_LINRX_TRUST_I ) = 0.0D+0
! 508: IF ( INFO .LE. N ) INFO = N + J
! 509: ELSE IF (ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) .LT. ERR_LBND)
! 510: $ THEN
! 511: ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) = ERR_LBND
! 512: ERR_BNDS_NORM( J, LA_LINRX_TRUST_I ) = 1.0D+0
! 513: END IF
! 514: *
! 515: * Save the condition number.
! 516: *
! 517: IF (N_ERR_BNDS .GE. LA_LINRX_RCOND_I) THEN
! 518: ERR_BNDS_NORM( J, LA_LINRX_RCOND_I ) = RCOND_TMP
! 519: END IF
! 520: END DO
! 521: END IF
! 522:
! 523: IF ( N_ERR_BNDS .GE. 1 .AND. N_NORMS .GE. 2 ) THEN
! 524: *
! 525: * Compute componentwise condition number cond(A*diag(Y(:,J))) for
! 526: * each right-hand side using the current solution as an estimate of
! 527: * the true solution. If the componentwise error estimate is too
! 528: * large, then the solution is a lousy estimate of truth and the
! 529: * estimated RCOND may be too optimistic. To avoid misleading users,
! 530: * the inverse condition number is set to 0.0 when the estimated
! 531: * cwise error is at least CWISE_WRONG.
! 532: *
! 533: CWISE_WRONG = SQRT( DLAMCH( 'Epsilon' ) )
! 534: DO J = 1, NRHS
! 535: IF ( ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) .LT. CWISE_WRONG )
! 536: $ THEN
! 537: RCOND_TMP = DLA_SYRCOND( UPLO, N, A, LDA, AF, LDAF, IPIV,
! 538: $ 1, X(1,J), INFO, WORK, IWORK )
! 539: ELSE
! 540: RCOND_TMP = 0.0D+0
! 541: END IF
! 542: *
! 543: * Cap the error at 1.0.
! 544: *
! 545: IF ( N_ERR_BNDS .GE. LA_LINRX_ERR_I
! 546: $ .AND. ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) .GT. 1.0D+0 )
! 547: $ ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) = 1.0D+0
! 548: *
! 549: * Threshold the error (see LAWN).
! 550: *
! 551: IF ( RCOND_TMP .LT. ILLRCOND_THRESH ) THEN
! 552: ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) = 1.0D+0
! 553: ERR_BNDS_COMP( J, LA_LINRX_TRUST_I ) = 0.0D+0
! 554: IF ( PARAMS( LA_LINRX_CWISE_I ) .EQ. 1.0D+0
! 555: $ .AND. INFO.LT.N + J ) INFO = N + J
! 556: ELSE IF ( ERR_BNDS_COMP( J, LA_LINRX_ERR_I )
! 557: $ .LT. ERR_LBND ) THEN
! 558: ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) = ERR_LBND
! 559: ERR_BNDS_COMP( J, LA_LINRX_TRUST_I ) = 1.0D+0
! 560: END IF
! 561: *
! 562: * Save the condition number.
! 563: *
! 564: IF ( N_ERR_BNDS .GE. LA_LINRX_RCOND_I ) THEN
! 565: ERR_BNDS_COMP( J, LA_LINRX_RCOND_I ) = RCOND_TMP
! 566: END IF
! 567:
! 568: END DO
! 569: END IF
! 570: *
! 571: RETURN
! 572: *
! 573: * End of DSYRFSX
! 574: *
! 575: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dsyrfsx.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack