1: *> \brief <b> DSYEVR computes the eigenvalues and, optionally, the left and/or right eigenvectors for SY matrices</b>
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DSYEVR + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dsyevr.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dsyevr.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dsyevr.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DSYEVR( JOBZ, RANGE, UPLO, N, A, LDA, VL, VU, IL, IU,
22: * ABSTOL, M, W, Z, LDZ, ISUPPZ, WORK, LWORK,
23: * IWORK, LIWORK, INFO )
24: *
25: * .. Scalar Arguments ..
26: * CHARACTER JOBZ, RANGE, UPLO
27: * INTEGER IL, INFO, IU, LDA, LDZ, LIWORK, LWORK, M, N
28: * DOUBLE PRECISION ABSTOL, VL, VU
29: * ..
30: * .. Array Arguments ..
31: * INTEGER ISUPPZ( * ), IWORK( * )
32: * DOUBLE PRECISION A( LDA, * ), W( * ), WORK( * ), Z( LDZ, * )
33: * ..
34: *
35: *
36: *> \par Purpose:
37: * =============
38: *>
39: *> \verbatim
40: *>
41: *> DSYEVR computes selected eigenvalues and, optionally, eigenvectors
42: *> of a real symmetric matrix A. Eigenvalues and eigenvectors can be
43: *> selected by specifying either a range of values or a range of
44: *> indices for the desired eigenvalues.
45: *>
46: *> DSYEVR first reduces the matrix A to tridiagonal form T with a call
47: *> to DSYTRD. Then, whenever possible, DSYEVR calls DSTEMR to compute
48: *> the eigenspectrum using Relatively Robust Representations. DSTEMR
49: *> computes eigenvalues by the dqds algorithm, while orthogonal
50: *> eigenvectors are computed from various "good" L D L^T representations
51: *> (also known as Relatively Robust Representations). Gram-Schmidt
52: *> orthogonalization is avoided as far as possible. More specifically,
53: *> the various steps of the algorithm are as follows.
54: *>
55: *> For each unreduced block (submatrix) of T,
56: *> (a) Compute T - sigma I = L D L^T, so that L and D
57: *> define all the wanted eigenvalues to high relative accuracy.
58: *> This means that small relative changes in the entries of D and L
59: *> cause only small relative changes in the eigenvalues and
60: *> eigenvectors. The standard (unfactored) representation of the
61: *> tridiagonal matrix T does not have this property in general.
62: *> (b) Compute the eigenvalues to suitable accuracy.
63: *> If the eigenvectors are desired, the algorithm attains full
64: *> accuracy of the computed eigenvalues only right before
65: *> the corresponding vectors have to be computed, see steps c) and d).
66: *> (c) For each cluster of close eigenvalues, select a new
67: *> shift close to the cluster, find a new factorization, and refine
68: *> the shifted eigenvalues to suitable accuracy.
69: *> (d) For each eigenvalue with a large enough relative separation compute
70: *> the corresponding eigenvector by forming a rank revealing twisted
71: *> factorization. Go back to (c) for any clusters that remain.
72: *>
73: *> The desired accuracy of the output can be specified by the input
74: *> parameter ABSTOL.
75: *>
76: *> For more details, see DSTEMR's documentation and:
77: *> - Inderjit S. Dhillon and Beresford N. Parlett: "Multiple representations
78: *> to compute orthogonal eigenvectors of symmetric tridiagonal matrices,"
79: *> Linear Algebra and its Applications, 387(1), pp. 1-28, August 2004.
80: *> - Inderjit Dhillon and Beresford Parlett: "Orthogonal Eigenvectors and
81: *> Relative Gaps," SIAM Journal on Matrix Analysis and Applications, Vol. 25,
82: *> 2004. Also LAPACK Working Note 154.
83: *> - Inderjit Dhillon: "A new O(n^2) algorithm for the symmetric
84: *> tridiagonal eigenvalue/eigenvector problem",
85: *> Computer Science Division Technical Report No. UCB/CSD-97-971,
86: *> UC Berkeley, May 1997.
87: *>
88: *>
89: *> Note 1 : DSYEVR calls DSTEMR when the full spectrum is requested
90: *> on machines which conform to the ieee-754 floating point standard.
91: *> DSYEVR calls DSTEBZ and DSTEIN on non-ieee machines and
92: *> when partial spectrum requests are made.
93: *>
94: *> Normal execution of DSTEMR may create NaNs and infinities and
95: *> hence may abort due to a floating point exception in environments
96: *> which do not handle NaNs and infinities in the ieee standard default
97: *> manner.
98: *> \endverbatim
99: *
100: * Arguments:
101: * ==========
102: *
103: *> \param[in] JOBZ
104: *> \verbatim
105: *> JOBZ is CHARACTER*1
106: *> = 'N': Compute eigenvalues only;
107: *> = 'V': Compute eigenvalues and eigenvectors.
108: *> \endverbatim
109: *>
110: *> \param[in] RANGE
111: *> \verbatim
112: *> RANGE is CHARACTER*1
113: *> = 'A': all eigenvalues will be found.
114: *> = 'V': all eigenvalues in the half-open interval (VL,VU]
115: *> will be found.
116: *> = 'I': the IL-th through IU-th eigenvalues will be found.
117: *> For RANGE = 'V' or 'I' and IU - IL < N - 1, DSTEBZ and
118: *> DSTEIN are called
119: *> \endverbatim
120: *>
121: *> \param[in] UPLO
122: *> \verbatim
123: *> UPLO is CHARACTER*1
124: *> = 'U': Upper triangle of A is stored;
125: *> = 'L': Lower triangle of A is stored.
126: *> \endverbatim
127: *>
128: *> \param[in] N
129: *> \verbatim
130: *> N is INTEGER
131: *> The order of the matrix A. N >= 0.
132: *> \endverbatim
133: *>
134: *> \param[in,out] A
135: *> \verbatim
136: *> A is DOUBLE PRECISION array, dimension (LDA, N)
137: *> On entry, the symmetric matrix A. If UPLO = 'U', the
138: *> leading N-by-N upper triangular part of A contains the
139: *> upper triangular part of the matrix A. If UPLO = 'L',
140: *> the leading N-by-N lower triangular part of A contains
141: *> the lower triangular part of the matrix A.
142: *> On exit, the lower triangle (if UPLO='L') or the upper
143: *> triangle (if UPLO='U') of A, including the diagonal, is
144: *> destroyed.
145: *> \endverbatim
146: *>
147: *> \param[in] LDA
148: *> \verbatim
149: *> LDA is INTEGER
150: *> The leading dimension of the array A. LDA >= max(1,N).
151: *> \endverbatim
152: *>
153: *> \param[in] VL
154: *> \verbatim
155: *> VL is DOUBLE PRECISION
156: *> If RANGE='V', the lower bound of the interval to
157: *> be searched for eigenvalues. VL < VU.
158: *> Not referenced if RANGE = 'A' or 'I'.
159: *> \endverbatim
160: *>
161: *> \param[in] VU
162: *> \verbatim
163: *> VU is DOUBLE PRECISION
164: *> If RANGE='V', the upper bound of the interval to
165: *> be searched for eigenvalues. VL < VU.
166: *> Not referenced if RANGE = 'A' or 'I'.
167: *> \endverbatim
168: *>
169: *> \param[in] IL
170: *> \verbatim
171: *> IL is INTEGER
172: *> If RANGE='I', the index of the
173: *> smallest eigenvalue to be returned.
174: *> 1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
175: *> Not referenced if RANGE = 'A' or 'V'.
176: *> \endverbatim
177: *>
178: *> \param[in] IU
179: *> \verbatim
180: *> IU is INTEGER
181: *> If RANGE='I', the index of the
182: *> largest eigenvalue to be returned.
183: *> 1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
184: *> Not referenced if RANGE = 'A' or 'V'.
185: *> \endverbatim
186: *>
187: *> \param[in] ABSTOL
188: *> \verbatim
189: *> ABSTOL is DOUBLE PRECISION
190: *> The absolute error tolerance for the eigenvalues.
191: *> An approximate eigenvalue is accepted as converged
192: *> when it is determined to lie in an interval [a,b]
193: *> of width less than or equal to
194: *>
195: *> ABSTOL + EPS * max( |a|,|b| ) ,
196: *>
197: *> where EPS is the machine precision. If ABSTOL is less than
198: *> or equal to zero, then EPS*|T| will be used in its place,
199: *> where |T| is the 1-norm of the tridiagonal matrix obtained
200: *> by reducing A to tridiagonal form.
201: *>
202: *> See "Computing Small Singular Values of Bidiagonal Matrices
203: *> with Guaranteed High Relative Accuracy," by Demmel and
204: *> Kahan, LAPACK Working Note #3.
205: *>
206: *> If high relative accuracy is important, set ABSTOL to
207: *> DLAMCH( 'Safe minimum' ). Doing so will guarantee that
208: *> eigenvalues are computed to high relative accuracy when
209: *> possible in future releases. The current code does not
210: *> make any guarantees about high relative accuracy, but
211: *> future releases will. See J. Barlow and J. Demmel,
212: *> "Computing Accurate Eigensystems of Scaled Diagonally
213: *> Dominant Matrices", LAPACK Working Note #7, for a discussion
214: *> of which matrices define their eigenvalues to high relative
215: *> accuracy.
216: *> \endverbatim
217: *>
218: *> \param[out] M
219: *> \verbatim
220: *> M is INTEGER
221: *> The total number of eigenvalues found. 0 <= M <= N.
222: *> If RANGE = 'A', M = N, and if RANGE = 'I', M = IU-IL+1.
223: *> \endverbatim
224: *>
225: *> \param[out] W
226: *> \verbatim
227: *> W is DOUBLE PRECISION array, dimension (N)
228: *> The first M elements contain the selected eigenvalues in
229: *> ascending order.
230: *> \endverbatim
231: *>
232: *> \param[out] Z
233: *> \verbatim
234: *> Z is DOUBLE PRECISION array, dimension (LDZ, max(1,M))
235: *> If JOBZ = 'V', then if INFO = 0, the first M columns of Z
236: *> contain the orthonormal eigenvectors of the matrix A
237: *> corresponding to the selected eigenvalues, with the i-th
238: *> column of Z holding the eigenvector associated with W(i).
239: *> If JOBZ = 'N', then Z is not referenced.
240: *> Note: the user must ensure that at least max(1,M) columns are
241: *> supplied in the array Z; if RANGE = 'V', the exact value of M
242: *> is not known in advance and an upper bound must be used.
243: *> Supplying N columns is always safe.
244: *> \endverbatim
245: *>
246: *> \param[in] LDZ
247: *> \verbatim
248: *> LDZ is INTEGER
249: *> The leading dimension of the array Z. LDZ >= 1, and if
250: *> JOBZ = 'V', LDZ >= max(1,N).
251: *> \endverbatim
252: *>
253: *> \param[out] ISUPPZ
254: *> \verbatim
255: *> ISUPPZ is INTEGER array, dimension ( 2*max(1,M) )
256: *> The support of the eigenvectors in Z, i.e., the indices
257: *> indicating the nonzero elements in Z. The i-th eigenvector
258: *> is nonzero only in elements ISUPPZ( 2*i-1 ) through
259: *> ISUPPZ( 2*i ). This is an output of DSTEMR (tridiagonal
260: *> matrix). The support of the eigenvectors of A is typically
261: *> 1:N because of the orthogonal transformations applied by DORMTR.
262: *> Implemented only for RANGE = 'A' or 'I' and IU - IL = N - 1
263: *> \endverbatim
264: *>
265: *> \param[out] WORK
266: *> \verbatim
267: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK))
268: *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
269: *> \endverbatim
270: *>
271: *> \param[in] LWORK
272: *> \verbatim
273: *> LWORK is INTEGER
274: *> The dimension of the array WORK. LWORK >= max(1,26*N).
275: *> For optimal efficiency, LWORK >= (NB+6)*N,
276: *> where NB is the max of the blocksize for DSYTRD and DORMTR
277: *> returned by ILAENV.
278: *>
279: *> If LWORK = -1, then a workspace query is assumed; the routine
280: *> only calculates the optimal size of the WORK array, returns
281: *> this value as the first entry of the WORK array, and no error
282: *> message related to LWORK is issued by XERBLA.
283: *> \endverbatim
284: *>
285: *> \param[out] IWORK
286: *> \verbatim
287: *> IWORK is INTEGER array, dimension (MAX(1,LIWORK))
288: *> On exit, if INFO = 0, IWORK(1) returns the optimal LWORK.
289: *> \endverbatim
290: *>
291: *> \param[in] LIWORK
292: *> \verbatim
293: *> LIWORK is INTEGER
294: *> The dimension of the array IWORK. LIWORK >= max(1,10*N).
295: *>
296: *> If LIWORK = -1, then a workspace query is assumed; the
297: *> routine only calculates the optimal size of the IWORK array,
298: *> returns this value as the first entry of the IWORK array, and
299: *> no error message related to LIWORK is issued by XERBLA.
300: *> \endverbatim
301: *>
302: *> \param[out] INFO
303: *> \verbatim
304: *> INFO is INTEGER
305: *> = 0: successful exit
306: *> < 0: if INFO = -i, the i-th argument had an illegal value
307: *> > 0: Internal error
308: *> \endverbatim
309: *
310: * Authors:
311: * ========
312: *
313: *> \author Univ. of Tennessee
314: *> \author Univ. of California Berkeley
315: *> \author Univ. of Colorado Denver
316: *> \author NAG Ltd.
317: *
318: *> \ingroup doubleSYeigen
319: *
320: *> \par Contributors:
321: * ==================
322: *>
323: *> Inderjit Dhillon, IBM Almaden, USA \n
324: *> Osni Marques, LBNL/NERSC, USA \n
325: *> Ken Stanley, Computer Science Division, University of
326: *> California at Berkeley, USA \n
327: *> Jason Riedy, Computer Science Division, University of
328: *> California at Berkeley, USA \n
329: *>
330: * =====================================================================
331: SUBROUTINE DSYEVR( JOBZ, RANGE, UPLO, N, A, LDA, VL, VU, IL, IU,
332: $ ABSTOL, M, W, Z, LDZ, ISUPPZ, WORK, LWORK,
333: $ IWORK, LIWORK, INFO )
334: *
335: * -- LAPACK driver routine --
336: * -- LAPACK is a software package provided by Univ. of Tennessee, --
337: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
338: *
339: * .. Scalar Arguments ..
340: CHARACTER JOBZ, RANGE, UPLO
341: INTEGER IL, INFO, IU, LDA, LDZ, LIWORK, LWORK, M, N
342: DOUBLE PRECISION ABSTOL, VL, VU
343: * ..
344: * .. Array Arguments ..
345: INTEGER ISUPPZ( * ), IWORK( * )
346: DOUBLE PRECISION A( LDA, * ), W( * ), WORK( * ), Z( LDZ, * )
347: * ..
348: *
349: * =====================================================================
350: *
351: * .. Parameters ..
352: DOUBLE PRECISION ZERO, ONE, TWO
353: PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0, TWO = 2.0D+0 )
354: * ..
355: * .. Local Scalars ..
356: LOGICAL ALLEIG, INDEIG, LOWER, LQUERY, VALEIG, WANTZ,
357: $ TRYRAC
358: CHARACTER ORDER
359: INTEGER I, IEEEOK, IINFO, IMAX, INDD, INDDD, INDE,
360: $ INDEE, INDIBL, INDIFL, INDISP, INDIWO, INDTAU,
361: $ INDWK, INDWKN, ISCALE, J, JJ, LIWMIN,
362: $ LLWORK, LLWRKN, LWKOPT, LWMIN, NB, NSPLIT
363: DOUBLE PRECISION ABSTLL, ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN,
364: $ SIGMA, SMLNUM, TMP1, VLL, VUU
365: * ..
366: * .. External Functions ..
367: LOGICAL LSAME
368: INTEGER ILAENV
369: DOUBLE PRECISION DLAMCH, DLANSY
370: EXTERNAL LSAME, ILAENV, DLAMCH, DLANSY
371: * ..
372: * .. External Subroutines ..
373: EXTERNAL DCOPY, DORMTR, DSCAL, DSTEBZ, DSTEMR, DSTEIN,
374: $ DSTERF, DSWAP, DSYTRD, XERBLA
375: * ..
376: * .. Intrinsic Functions ..
377: INTRINSIC MAX, MIN, SQRT
378: * ..
379: * .. Executable Statements ..
380: *
381: * Test the input parameters.
382: *
383: IEEEOK = ILAENV( 10, 'DSYEVR', 'N', 1, 2, 3, 4 )
384: *
385: LOWER = LSAME( UPLO, 'L' )
386: WANTZ = LSAME( JOBZ, 'V' )
387: ALLEIG = LSAME( RANGE, 'A' )
388: VALEIG = LSAME( RANGE, 'V' )
389: INDEIG = LSAME( RANGE, 'I' )
390: *
391: LQUERY = ( ( LWORK.EQ.-1 ) .OR. ( LIWORK.EQ.-1 ) )
392: *
393: LWMIN = MAX( 1, 26*N )
394: LIWMIN = MAX( 1, 10*N )
395: *
396: INFO = 0
397: IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
398: INFO = -1
399: ELSE IF( .NOT.( ALLEIG .OR. VALEIG .OR. INDEIG ) ) THEN
400: INFO = -2
401: ELSE IF( .NOT.( LOWER .OR. LSAME( UPLO, 'U' ) ) ) THEN
402: INFO = -3
403: ELSE IF( N.LT.0 ) THEN
404: INFO = -4
405: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
406: INFO = -6
407: ELSE
408: IF( VALEIG ) THEN
409: IF( N.GT.0 .AND. VU.LE.VL )
410: $ INFO = -8
411: ELSE IF( INDEIG ) THEN
412: IF( IL.LT.1 .OR. IL.GT.MAX( 1, N ) ) THEN
413: INFO = -9
414: ELSE IF( IU.LT.MIN( N, IL ) .OR. IU.GT.N ) THEN
415: INFO = -10
416: END IF
417: END IF
418: END IF
419: IF( INFO.EQ.0 ) THEN
420: IF( LDZ.LT.1 .OR. ( WANTZ .AND. LDZ.LT.N ) ) THEN
421: INFO = -15
422: ELSE IF( LWORK.LT.LWMIN .AND. .NOT.LQUERY ) THEN
423: INFO = -18
424: ELSE IF( LIWORK.LT.LIWMIN .AND. .NOT.LQUERY ) THEN
425: INFO = -20
426: END IF
427: END IF
428: *
429: IF( INFO.EQ.0 ) THEN
430: NB = ILAENV( 1, 'DSYTRD', UPLO, N, -1, -1, -1 )
431: NB = MAX( NB, ILAENV( 1, 'DORMTR', UPLO, N, -1, -1, -1 ) )
432: LWKOPT = MAX( ( NB+1 )*N, LWMIN )
433: WORK( 1 ) = LWKOPT
434: IWORK( 1 ) = LIWMIN
435: END IF
436: *
437: IF( INFO.NE.0 ) THEN
438: CALL XERBLA( 'DSYEVR', -INFO )
439: RETURN
440: ELSE IF( LQUERY ) THEN
441: RETURN
442: END IF
443: *
444: * Quick return if possible
445: *
446: M = 0
447: IF( N.EQ.0 ) THEN
448: WORK( 1 ) = 1
449: RETURN
450: END IF
451: *
452: IF( N.EQ.1 ) THEN
453: WORK( 1 ) = 7
454: IF( ALLEIG .OR. INDEIG ) THEN
455: M = 1
456: W( 1 ) = A( 1, 1 )
457: ELSE
458: IF( VL.LT.A( 1, 1 ) .AND. VU.GE.A( 1, 1 ) ) THEN
459: M = 1
460: W( 1 ) = A( 1, 1 )
461: END IF
462: END IF
463: IF( WANTZ ) THEN
464: Z( 1, 1 ) = ONE
465: ISUPPZ( 1 ) = 1
466: ISUPPZ( 2 ) = 1
467: END IF
468: RETURN
469: END IF
470: *
471: * Get machine constants.
472: *
473: SAFMIN = DLAMCH( 'Safe minimum' )
474: EPS = DLAMCH( 'Precision' )
475: SMLNUM = SAFMIN / EPS
476: BIGNUM = ONE / SMLNUM
477: RMIN = SQRT( SMLNUM )
478: RMAX = MIN( SQRT( BIGNUM ), ONE / SQRT( SQRT( SAFMIN ) ) )
479: *
480: * Scale matrix to allowable range, if necessary.
481: *
482: ISCALE = 0
483: ABSTLL = ABSTOL
484: IF (VALEIG) THEN
485: VLL = VL
486: VUU = VU
487: END IF
488: ANRM = DLANSY( 'M', UPLO, N, A, LDA, WORK )
489: IF( ANRM.GT.ZERO .AND. ANRM.LT.RMIN ) THEN
490: ISCALE = 1
491: SIGMA = RMIN / ANRM
492: ELSE IF( ANRM.GT.RMAX ) THEN
493: ISCALE = 1
494: SIGMA = RMAX / ANRM
495: END IF
496: IF( ISCALE.EQ.1 ) THEN
497: IF( LOWER ) THEN
498: DO 10 J = 1, N
499: CALL DSCAL( N-J+1, SIGMA, A( J, J ), 1 )
500: 10 CONTINUE
501: ELSE
502: DO 20 J = 1, N
503: CALL DSCAL( J, SIGMA, A( 1, J ), 1 )
504: 20 CONTINUE
505: END IF
506: IF( ABSTOL.GT.0 )
507: $ ABSTLL = ABSTOL*SIGMA
508: IF( VALEIG ) THEN
509: VLL = VL*SIGMA
510: VUU = VU*SIGMA
511: END IF
512: END IF
513:
514: * Initialize indices into workspaces. Note: The IWORK indices are
515: * used only if DSTERF or DSTEMR fail.
516:
517: * WORK(INDTAU:INDTAU+N-1) stores the scalar factors of the
518: * elementary reflectors used in DSYTRD.
519: INDTAU = 1
520: * WORK(INDD:INDD+N-1) stores the tridiagonal's diagonal entries.
521: INDD = INDTAU + N
522: * WORK(INDE:INDE+N-1) stores the off-diagonal entries of the
523: * tridiagonal matrix from DSYTRD.
524: INDE = INDD + N
525: * WORK(INDDD:INDDD+N-1) is a copy of the diagonal entries over
526: * -written by DSTEMR (the DSTERF path copies the diagonal to W).
527: INDDD = INDE + N
528: * WORK(INDEE:INDEE+N-1) is a copy of the off-diagonal entries over
529: * -written while computing the eigenvalues in DSTERF and DSTEMR.
530: INDEE = INDDD + N
531: * INDWK is the starting offset of the left-over workspace, and
532: * LLWORK is the remaining workspace size.
533: INDWK = INDEE + N
534: LLWORK = LWORK - INDWK + 1
535:
536: * IWORK(INDIBL:INDIBL+M-1) corresponds to IBLOCK in DSTEBZ and
537: * stores the block indices of each of the M<=N eigenvalues.
538: INDIBL = 1
539: * IWORK(INDISP:INDISP+NSPLIT-1) corresponds to ISPLIT in DSTEBZ and
540: * stores the starting and finishing indices of each block.
541: INDISP = INDIBL + N
542: * IWORK(INDIFL:INDIFL+N-1) stores the indices of eigenvectors
543: * that corresponding to eigenvectors that fail to converge in
544: * DSTEIN. This information is discarded; if any fail, the driver
545: * returns INFO > 0.
546: INDIFL = INDISP + N
547: * INDIWO is the offset of the remaining integer workspace.
548: INDIWO = INDIFL + N
549:
550: *
551: * Call DSYTRD to reduce symmetric matrix to tridiagonal form.
552: *
553: CALL DSYTRD( UPLO, N, A, LDA, WORK( INDD ), WORK( INDE ),
554: $ WORK( INDTAU ), WORK( INDWK ), LLWORK, IINFO )
555: *
556: * If all eigenvalues are desired
557: * then call DSTERF or DSTEMR and DORMTR.
558: *
559: IF( ( ALLEIG .OR. ( INDEIG .AND. IL.EQ.1 .AND. IU.EQ.N ) ) .AND.
560: $ IEEEOK.EQ.1 ) THEN
561: IF( .NOT.WANTZ ) THEN
562: CALL DCOPY( N, WORK( INDD ), 1, W, 1 )
563: CALL DCOPY( N-1, WORK( INDE ), 1, WORK( INDEE ), 1 )
564: CALL DSTERF( N, W, WORK( INDEE ), INFO )
565: ELSE
566: CALL DCOPY( N-1, WORK( INDE ), 1, WORK( INDEE ), 1 )
567: CALL DCOPY( N, WORK( INDD ), 1, WORK( INDDD ), 1 )
568: *
569: IF (ABSTOL .LE. TWO*N*EPS) THEN
570: TRYRAC = .TRUE.
571: ELSE
572: TRYRAC = .FALSE.
573: END IF
574: CALL DSTEMR( JOBZ, 'A', N, WORK( INDDD ), WORK( INDEE ),
575: $ VL, VU, IL, IU, M, W, Z, LDZ, N, ISUPPZ,
576: $ TRYRAC, WORK( INDWK ), LWORK, IWORK, LIWORK,
577: $ INFO )
578: *
579: *
580: *
581: * Apply orthogonal matrix used in reduction to tridiagonal
582: * form to eigenvectors returned by DSTEMR.
583: *
584: IF( WANTZ .AND. INFO.EQ.0 ) THEN
585: INDWKN = INDE
586: LLWRKN = LWORK - INDWKN + 1
587: CALL DORMTR( 'L', UPLO, 'N', N, M, A, LDA,
588: $ WORK( INDTAU ), Z, LDZ, WORK( INDWKN ),
589: $ LLWRKN, IINFO )
590: END IF
591: END IF
592: *
593: *
594: IF( INFO.EQ.0 ) THEN
595: * Everything worked. Skip DSTEBZ/DSTEIN. IWORK(:) are
596: * undefined.
597: M = N
598: GO TO 30
599: END IF
600: INFO = 0
601: END IF
602: *
603: * Otherwise, call DSTEBZ and, if eigenvectors are desired, DSTEIN.
604: * Also call DSTEBZ and DSTEIN if DSTEMR fails.
605: *
606: IF( WANTZ ) THEN
607: ORDER = 'B'
608: ELSE
609: ORDER = 'E'
610: END IF
611:
612: CALL DSTEBZ( RANGE, ORDER, N, VLL, VUU, IL, IU, ABSTLL,
613: $ WORK( INDD ), WORK( INDE ), M, NSPLIT, W,
614: $ IWORK( INDIBL ), IWORK( INDISP ), WORK( INDWK ),
615: $ IWORK( INDIWO ), INFO )
616: *
617: IF( WANTZ ) THEN
618: CALL DSTEIN( N, WORK( INDD ), WORK( INDE ), M, W,
619: $ IWORK( INDIBL ), IWORK( INDISP ), Z, LDZ,
620: $ WORK( INDWK ), IWORK( INDIWO ), IWORK( INDIFL ),
621: $ INFO )
622: *
623: * Apply orthogonal matrix used in reduction to tridiagonal
624: * form to eigenvectors returned by DSTEIN.
625: *
626: INDWKN = INDE
627: LLWRKN = LWORK - INDWKN + 1
628: CALL DORMTR( 'L', UPLO, 'N', N, M, A, LDA, WORK( INDTAU ), Z,
629: $ LDZ, WORK( INDWKN ), LLWRKN, IINFO )
630: END IF
631: *
632: * If matrix was scaled, then rescale eigenvalues appropriately.
633: *
634: * Jump here if DSTEMR/DSTEIN succeeded.
635: 30 CONTINUE
636: IF( ISCALE.EQ.1 ) THEN
637: IF( INFO.EQ.0 ) THEN
638: IMAX = M
639: ELSE
640: IMAX = INFO - 1
641: END IF
642: CALL DSCAL( IMAX, ONE / SIGMA, W, 1 )
643: END IF
644: *
645: * If eigenvalues are not in order, then sort them, along with
646: * eigenvectors. Note: We do not sort the IFAIL portion of IWORK.
647: * It may not be initialized (if DSTEMR/DSTEIN succeeded), and we do
648: * not return this detailed information to the user.
649: *
650: IF( WANTZ ) THEN
651: DO 50 J = 1, M - 1
652: I = 0
653: TMP1 = W( J )
654: DO 40 JJ = J + 1, M
655: IF( W( JJ ).LT.TMP1 ) THEN
656: I = JJ
657: TMP1 = W( JJ )
658: END IF
659: 40 CONTINUE
660: *
661: IF( I.NE.0 ) THEN
662: W( I ) = W( J )
663: W( J ) = TMP1
664: CALL DSWAP( N, Z( 1, I ), 1, Z( 1, J ), 1 )
665: END IF
666: 50 CONTINUE
667: END IF
668: *
669: * Set WORK(1) to optimal workspace size.
670: *
671: WORK( 1 ) = LWKOPT
672: IWORK( 1 ) = LIWMIN
673: *
674: RETURN
675: *
676: * End of DSYEVR
677: *
678: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dsyevr.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack