1: *> \brief \b DSYEQUB
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DSYEQUB + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dsyequb.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dsyequb.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dsyequb.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DSYEQUB( UPLO, N, A, LDA, S, SCOND, AMAX, WORK, INFO )
22: *
23: * .. Scalar Arguments ..
24: * INTEGER INFO, LDA, N
25: * DOUBLE PRECISION AMAX, SCOND
26: * CHARACTER UPLO
27: * ..
28: * .. Array Arguments ..
29: * DOUBLE PRECISION A( LDA, * ), S( * ), WORK( * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> DSYEQUB computes row and column scalings intended to equilibrate a
39: *> symmetric matrix A (with respect to the Euclidean norm) and reduce
40: *> its condition number. The scale factors S are computed by the BIN
41: *> algorithm (see references) so that the scaled matrix B with elements
42: *> B(i,j) = S(i)*A(i,j)*S(j) has a condition number within a factor N of
43: *> the smallest possible condition number over all possible diagonal
44: *> scalings.
45: *> \endverbatim
46: *
47: * Arguments:
48: * ==========
49: *
50: *> \param[in] UPLO
51: *> \verbatim
52: *> UPLO is CHARACTER*1
53: *> = 'U': Upper triangle of A is stored;
54: *> = 'L': Lower triangle of A is stored.
55: *> \endverbatim
56: *>
57: *> \param[in] N
58: *> \verbatim
59: *> N is INTEGER
60: *> The order of the matrix A. N >= 0.
61: *> \endverbatim
62: *>
63: *> \param[in] A
64: *> \verbatim
65: *> A is DOUBLE PRECISION array, dimension (LDA,N)
66: *> The N-by-N symmetric matrix whose scaling factors are to be
67: *> computed.
68: *> \endverbatim
69: *>
70: *> \param[in] LDA
71: *> \verbatim
72: *> LDA is INTEGER
73: *> The leading dimension of the array A. LDA >= max(1,N).
74: *> \endverbatim
75: *>
76: *> \param[out] S
77: *> \verbatim
78: *> S is DOUBLE PRECISION array, dimension (N)
79: *> If INFO = 0, S contains the scale factors for A.
80: *> \endverbatim
81: *>
82: *> \param[out] SCOND
83: *> \verbatim
84: *> SCOND is DOUBLE PRECISION
85: *> If INFO = 0, S contains the ratio of the smallest S(i) to
86: *> the largest S(i). If SCOND >= 0.1 and AMAX is neither too
87: *> large nor too small, it is not worth scaling by S.
88: *> \endverbatim
89: *>
90: *> \param[out] AMAX
91: *> \verbatim
92: *> AMAX is DOUBLE PRECISION
93: *> Largest absolute value of any matrix element. If AMAX is
94: *> very close to overflow or very close to underflow, the
95: *> matrix should be scaled.
96: *> \endverbatim
97: *>
98: *> \param[out] WORK
99: *> \verbatim
100: *> WORK is DOUBLE PRECISION array, dimension (2*N)
101: *> \endverbatim
102: *>
103: *> \param[out] INFO
104: *> \verbatim
105: *> INFO is INTEGER
106: *> = 0: successful exit
107: *> < 0: if INFO = -i, the i-th argument had an illegal value
108: *> > 0: if INFO = i, the i-th diagonal element is nonpositive.
109: *> \endverbatim
110: *
111: * Authors:
112: * ========
113: *
114: *> \author Univ. of Tennessee
115: *> \author Univ. of California Berkeley
116: *> \author Univ. of Colorado Denver
117: *> \author NAG Ltd.
118: *
119: *> \ingroup doubleSYcomputational
120: *
121: *> \par References:
122: * ================
123: *>
124: *> Livne, O.E. and Golub, G.H., "Scaling by Binormalization", \n
125: *> Numerical Algorithms, vol. 35, no. 1, pp. 97-120, January 2004. \n
126: *> DOI 10.1023/B:NUMA.0000016606.32820.69 \n
127: *> Tech report version: http://citeseerx.ist.psu.edu/viewdoc/summary?doi=10.1.1.3.1679
128: *>
129: * =====================================================================
130: SUBROUTINE DSYEQUB( UPLO, N, A, LDA, S, SCOND, AMAX, WORK, INFO )
131: *
132: * -- LAPACK computational routine --
133: * -- LAPACK is a software package provided by Univ. of Tennessee, --
134: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
135: *
136: * .. Scalar Arguments ..
137: INTEGER INFO, LDA, N
138: DOUBLE PRECISION AMAX, SCOND
139: CHARACTER UPLO
140: * ..
141: * .. Array Arguments ..
142: DOUBLE PRECISION A( LDA, * ), S( * ), WORK( * )
143: * ..
144: *
145: * =====================================================================
146: *
147: * .. Parameters ..
148: DOUBLE PRECISION ONE, ZERO
149: PARAMETER ( ONE = 1.0D0, ZERO = 0.0D0 )
150: INTEGER MAX_ITER
151: PARAMETER ( MAX_ITER = 100 )
152: * ..
153: * .. Local Scalars ..
154: INTEGER I, J, ITER
155: DOUBLE PRECISION AVG, STD, TOL, C0, C1, C2, T, U, SI, D, BASE,
156: $ SMIN, SMAX, SMLNUM, BIGNUM, SCALE, SUMSQ
157: LOGICAL UP
158: * ..
159: * .. External Functions ..
160: DOUBLE PRECISION DLAMCH
161: LOGICAL LSAME
162: EXTERNAL DLAMCH, LSAME
163: * ..
164: * .. External Subroutines ..
165: EXTERNAL DLASSQ, XERBLA
166: * ..
167: * .. Intrinsic Functions ..
168: INTRINSIC ABS, INT, LOG, MAX, MIN, SQRT
169: * ..
170: * .. Executable Statements ..
171: *
172: * Test the input parameters.
173: *
174: INFO = 0
175: IF ( .NOT. ( LSAME( UPLO, 'U' ) .OR. LSAME( UPLO, 'L' ) ) ) THEN
176: INFO = -1
177: ELSE IF ( N .LT. 0 ) THEN
178: INFO = -2
179: ELSE IF ( LDA .LT. MAX( 1, N ) ) THEN
180: INFO = -4
181: END IF
182: IF ( INFO .NE. 0 ) THEN
183: CALL XERBLA( 'DSYEQUB', -INFO )
184: RETURN
185: END IF
186:
187: UP = LSAME( UPLO, 'U' )
188: AMAX = ZERO
189: *
190: * Quick return if possible.
191: *
192: IF ( N .EQ. 0 ) THEN
193: SCOND = ONE
194: RETURN
195: END IF
196:
197: DO I = 1, N
198: S( I ) = ZERO
199: END DO
200:
201: AMAX = ZERO
202: IF ( UP ) THEN
203: DO J = 1, N
204: DO I = 1, J-1
205: S( I ) = MAX( S( I ), ABS( A( I, J ) ) )
206: S( J ) = MAX( S( J ), ABS( A( I, J ) ) )
207: AMAX = MAX( AMAX, ABS( A( I, J ) ) )
208: END DO
209: S( J ) = MAX( S( J ), ABS( A( J, J ) ) )
210: AMAX = MAX( AMAX, ABS( A( J, J ) ) )
211: END DO
212: ELSE
213: DO J = 1, N
214: S( J ) = MAX( S( J ), ABS( A( J, J ) ) )
215: AMAX = MAX( AMAX, ABS( A( J, J ) ) )
216: DO I = J+1, N
217: S( I ) = MAX( S( I ), ABS( A( I, J ) ) )
218: S( J ) = MAX( S( J ), ABS( A( I, J ) ) )
219: AMAX = MAX( AMAX, ABS( A( I, J ) ) )
220: END DO
221: END DO
222: END IF
223: DO J = 1, N
224: S( J ) = 1.0D0 / S( J )
225: END DO
226:
227: TOL = ONE / SQRT( 2.0D0 * N )
228:
229: DO ITER = 1, MAX_ITER
230: SCALE = 0.0D0
231: SUMSQ = 0.0D0
232: * beta = |A|s
233: DO I = 1, N
234: WORK( I ) = ZERO
235: END DO
236: IF ( UP ) THEN
237: DO J = 1, N
238: DO I = 1, J-1
239: WORK( I ) = WORK( I ) + ABS( A( I, J ) ) * S( J )
240: WORK( J ) = WORK( J ) + ABS( A( I, J ) ) * S( I )
241: END DO
242: WORK( J ) = WORK( J ) + ABS( A( J, J ) ) * S( J )
243: END DO
244: ELSE
245: DO J = 1, N
246: WORK( J ) = WORK( J ) + ABS( A( J, J ) ) * S( J )
247: DO I = J+1, N
248: WORK( I ) = WORK( I ) + ABS( A( I, J ) ) * S( J )
249: WORK( J ) = WORK( J ) + ABS( A( I, J ) ) * S( I )
250: END DO
251: END DO
252: END IF
253:
254: * avg = s^T beta / n
255: AVG = 0.0D0
256: DO I = 1, N
257: AVG = AVG + S( I )*WORK( I )
258: END DO
259: AVG = AVG / N
260:
261: STD = 0.0D0
262: DO I = N+1, 2*N
263: WORK( I ) = S( I-N ) * WORK( I-N ) - AVG
264: END DO
265: CALL DLASSQ( N, WORK( N+1 ), 1, SCALE, SUMSQ )
266: STD = SCALE * SQRT( SUMSQ / N )
267:
268: IF ( STD .LT. TOL * AVG ) GOTO 999
269:
270: DO I = 1, N
271: T = ABS( A( I, I ) )
272: SI = S( I )
273: C2 = ( N-1 ) * T
274: C1 = ( N-2 ) * ( WORK( I ) - T*SI )
275: C0 = -(T*SI)*SI + 2*WORK( I )*SI - N*AVG
276: D = C1*C1 - 4*C0*C2
277:
278: IF ( D .LE. 0 ) THEN
279: INFO = -1
280: RETURN
281: END IF
282: SI = -2*C0 / ( C1 + SQRT( D ) )
283:
284: D = SI - S( I )
285: U = ZERO
286: IF ( UP ) THEN
287: DO J = 1, I
288: T = ABS( A( J, I ) )
289: U = U + S( J )*T
290: WORK( J ) = WORK( J ) + D*T
291: END DO
292: DO J = I+1,N
293: T = ABS( A( I, J ) )
294: U = U + S( J )*T
295: WORK( J ) = WORK( J ) + D*T
296: END DO
297: ELSE
298: DO J = 1, I
299: T = ABS( A( I, J ) )
300: U = U + S( J )*T
301: WORK( J ) = WORK( J ) + D*T
302: END DO
303: DO J = I+1,N
304: T = ABS( A( J, I ) )
305: U = U + S( J )*T
306: WORK( J ) = WORK( J ) + D*T
307: END DO
308: END IF
309:
310: AVG = AVG + ( U + WORK( I ) ) * D / N
311: S( I ) = SI
312: END DO
313: END DO
314:
315: 999 CONTINUE
316:
317: SMLNUM = DLAMCH( 'SAFEMIN' )
318: BIGNUM = ONE / SMLNUM
319: SMIN = BIGNUM
320: SMAX = ZERO
321: T = ONE / SQRT( AVG )
322: BASE = DLAMCH( 'B' )
323: U = ONE / LOG( BASE )
324: DO I = 1, N
325: S( I ) = BASE ** INT( U * LOG( S( I ) * T ) )
326: SMIN = MIN( SMIN, S( I ) )
327: SMAX = MAX( SMAX, S( I ) )
328: END DO
329: SCOND = MAX( SMIN, SMLNUM ) / MIN( SMAX, BIGNUM )
330: *
331: END
CVSweb interface <joel.bertrand@systella.fr>