1: *> \brief <b> DSBEVX computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrices</b>
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DSBEVX + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dsbevx.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dsbevx.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dsbevx.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DSBEVX( JOBZ, RANGE, UPLO, N, KD, AB, LDAB, Q, LDQ, VL,
22: * VU, IL, IU, ABSTOL, M, W, Z, LDZ, WORK, IWORK,
23: * IFAIL, INFO )
24: *
25: * .. Scalar Arguments ..
26: * CHARACTER JOBZ, RANGE, UPLO
27: * INTEGER IL, INFO, IU, KD, LDAB, LDQ, LDZ, M, N
28: * DOUBLE PRECISION ABSTOL, VL, VU
29: * ..
30: * .. Array Arguments ..
31: * INTEGER IFAIL( * ), IWORK( * )
32: * DOUBLE PRECISION AB( LDAB, * ), Q( LDQ, * ), W( * ), WORK( * ),
33: * $ Z( LDZ, * )
34: * ..
35: *
36: *
37: *> \par Purpose:
38: * =============
39: *>
40: *> \verbatim
41: *>
42: *> DSBEVX computes selected eigenvalues and, optionally, eigenvectors
43: *> of a real symmetric band matrix A. Eigenvalues and eigenvectors can
44: *> be selected by specifying either a range of values or a range of
45: *> indices for the desired eigenvalues.
46: *> \endverbatim
47: *
48: * Arguments:
49: * ==========
50: *
51: *> \param[in] JOBZ
52: *> \verbatim
53: *> JOBZ is CHARACTER*1
54: *> = 'N': Compute eigenvalues only;
55: *> = 'V': Compute eigenvalues and eigenvectors.
56: *> \endverbatim
57: *>
58: *> \param[in] RANGE
59: *> \verbatim
60: *> RANGE is CHARACTER*1
61: *> = 'A': all eigenvalues will be found;
62: *> = 'V': all eigenvalues in the half-open interval (VL,VU]
63: *> will be found;
64: *> = 'I': the IL-th through IU-th eigenvalues will be found.
65: *> \endverbatim
66: *>
67: *> \param[in] UPLO
68: *> \verbatim
69: *> UPLO is CHARACTER*1
70: *> = 'U': Upper triangle of A is stored;
71: *> = 'L': Lower triangle of A is stored.
72: *> \endverbatim
73: *>
74: *> \param[in] N
75: *> \verbatim
76: *> N is INTEGER
77: *> The order of the matrix A. N >= 0.
78: *> \endverbatim
79: *>
80: *> \param[in] KD
81: *> \verbatim
82: *> KD is INTEGER
83: *> The number of superdiagonals of the matrix A if UPLO = 'U',
84: *> or the number of subdiagonals if UPLO = 'L'. KD >= 0.
85: *> \endverbatim
86: *>
87: *> \param[in,out] AB
88: *> \verbatim
89: *> AB is DOUBLE PRECISION array, dimension (LDAB, N)
90: *> On entry, the upper or lower triangle of the symmetric band
91: *> matrix A, stored in the first KD+1 rows of the array. The
92: *> j-th column of A is stored in the j-th column of the array AB
93: *> as follows:
94: *> if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j;
95: *> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd).
96: *>
97: *> On exit, AB is overwritten by values generated during the
98: *> reduction to tridiagonal form. If UPLO = 'U', the first
99: *> superdiagonal and the diagonal of the tridiagonal matrix T
100: *> are returned in rows KD and KD+1 of AB, and if UPLO = 'L',
101: *> the diagonal and first subdiagonal of T are returned in the
102: *> first two rows of AB.
103: *> \endverbatim
104: *>
105: *> \param[in] LDAB
106: *> \verbatim
107: *> LDAB is INTEGER
108: *> The leading dimension of the array AB. LDAB >= KD + 1.
109: *> \endverbatim
110: *>
111: *> \param[out] Q
112: *> \verbatim
113: *> Q is DOUBLE PRECISION array, dimension (LDQ, N)
114: *> If JOBZ = 'V', the N-by-N orthogonal matrix used in the
115: *> reduction to tridiagonal form.
116: *> If JOBZ = 'N', the array Q is not referenced.
117: *> \endverbatim
118: *>
119: *> \param[in] LDQ
120: *> \verbatim
121: *> LDQ is INTEGER
122: *> The leading dimension of the array Q. If JOBZ = 'V', then
123: *> LDQ >= max(1,N).
124: *> \endverbatim
125: *>
126: *> \param[in] VL
127: *> \verbatim
128: *> VL is DOUBLE PRECISION
129: *> If RANGE='V', the lower bound of the interval to
130: *> be searched for eigenvalues. VL < VU.
131: *> Not referenced if RANGE = 'A' or 'I'.
132: *> \endverbatim
133: *>
134: *> \param[in] VU
135: *> \verbatim
136: *> VU is DOUBLE PRECISION
137: *> If RANGE='V', the upper bound of the interval to
138: *> be searched for eigenvalues. VL < VU.
139: *> Not referenced if RANGE = 'A' or 'I'.
140: *> \endverbatim
141: *>
142: *> \param[in] IL
143: *> \verbatim
144: *> IL is INTEGER
145: *> If RANGE='I', the index of the
146: *> smallest eigenvalue to be returned.
147: *> 1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
148: *> Not referenced if RANGE = 'A' or 'V'.
149: *> \endverbatim
150: *>
151: *> \param[in] IU
152: *> \verbatim
153: *> IU is INTEGER
154: *> If RANGE='I', the index of the
155: *> largest eigenvalue to be returned.
156: *> 1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
157: *> Not referenced if RANGE = 'A' or 'V'.
158: *> \endverbatim
159: *>
160: *> \param[in] ABSTOL
161: *> \verbatim
162: *> ABSTOL is DOUBLE PRECISION
163: *> The absolute error tolerance for the eigenvalues.
164: *> An approximate eigenvalue is accepted as converged
165: *> when it is determined to lie in an interval [a,b]
166: *> of width less than or equal to
167: *>
168: *> ABSTOL + EPS * max( |a|,|b| ) ,
169: *>
170: *> where EPS is the machine precision. If ABSTOL is less than
171: *> or equal to zero, then EPS*|T| will be used in its place,
172: *> where |T| is the 1-norm of the tridiagonal matrix obtained
173: *> by reducing AB to tridiagonal form.
174: *>
175: *> Eigenvalues will be computed most accurately when ABSTOL is
176: *> set to twice the underflow threshold 2*DLAMCH('S'), not zero.
177: *> If this routine returns with INFO>0, indicating that some
178: *> eigenvectors did not converge, try setting ABSTOL to
179: *> 2*DLAMCH('S').
180: *>
181: *> See "Computing Small Singular Values of Bidiagonal Matrices
182: *> with Guaranteed High Relative Accuracy," by Demmel and
183: *> Kahan, LAPACK Working Note #3.
184: *> \endverbatim
185: *>
186: *> \param[out] M
187: *> \verbatim
188: *> M is INTEGER
189: *> The total number of eigenvalues found. 0 <= M <= N.
190: *> If RANGE = 'A', M = N, and if RANGE = 'I', M = IU-IL+1.
191: *> \endverbatim
192: *>
193: *> \param[out] W
194: *> \verbatim
195: *> W is DOUBLE PRECISION array, dimension (N)
196: *> The first M elements contain the selected eigenvalues in
197: *> ascending order.
198: *> \endverbatim
199: *>
200: *> \param[out] Z
201: *> \verbatim
202: *> Z is DOUBLE PRECISION array, dimension (LDZ, max(1,M))
203: *> If JOBZ = 'V', then if INFO = 0, the first M columns of Z
204: *> contain the orthonormal eigenvectors of the matrix A
205: *> corresponding to the selected eigenvalues, with the i-th
206: *> column of Z holding the eigenvector associated with W(i).
207: *> If an eigenvector fails to converge, then that column of Z
208: *> contains the latest approximation to the eigenvector, and the
209: *> index of the eigenvector is returned in IFAIL.
210: *> If JOBZ = 'N', then Z is not referenced.
211: *> Note: the user must ensure that at least max(1,M) columns are
212: *> supplied in the array Z; if RANGE = 'V', the exact value of M
213: *> is not known in advance and an upper bound must be used.
214: *> \endverbatim
215: *>
216: *> \param[in] LDZ
217: *> \verbatim
218: *> LDZ is INTEGER
219: *> The leading dimension of the array Z. LDZ >= 1, and if
220: *> JOBZ = 'V', LDZ >= max(1,N).
221: *> \endverbatim
222: *>
223: *> \param[out] WORK
224: *> \verbatim
225: *> WORK is DOUBLE PRECISION array, dimension (7*N)
226: *> \endverbatim
227: *>
228: *> \param[out] IWORK
229: *> \verbatim
230: *> IWORK is INTEGER array, dimension (5*N)
231: *> \endverbatim
232: *>
233: *> \param[out] IFAIL
234: *> \verbatim
235: *> IFAIL is INTEGER array, dimension (N)
236: *> If JOBZ = 'V', then if INFO = 0, the first M elements of
237: *> IFAIL are zero. If INFO > 0, then IFAIL contains the
238: *> indices of the eigenvectors that failed to converge.
239: *> If JOBZ = 'N', then IFAIL is not referenced.
240: *> \endverbatim
241: *>
242: *> \param[out] INFO
243: *> \verbatim
244: *> INFO is INTEGER
245: *> = 0: successful exit.
246: *> < 0: if INFO = -i, the i-th argument had an illegal value.
247: *> > 0: if INFO = i, then i eigenvectors failed to converge.
248: *> Their indices are stored in array IFAIL.
249: *> \endverbatim
250: *
251: * Authors:
252: * ========
253: *
254: *> \author Univ. of Tennessee
255: *> \author Univ. of California Berkeley
256: *> \author Univ. of Colorado Denver
257: *> \author NAG Ltd.
258: *
259: *> \ingroup doubleOTHEReigen
260: *
261: * =====================================================================
262: SUBROUTINE DSBEVX( JOBZ, RANGE, UPLO, N, KD, AB, LDAB, Q, LDQ, VL,
263: $ VU, IL, IU, ABSTOL, M, W, Z, LDZ, WORK, IWORK,
264: $ IFAIL, INFO )
265: *
266: * -- LAPACK driver routine --
267: * -- LAPACK is a software package provided by Univ. of Tennessee, --
268: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
269: *
270: * .. Scalar Arguments ..
271: CHARACTER JOBZ, RANGE, UPLO
272: INTEGER IL, INFO, IU, KD, LDAB, LDQ, LDZ, M, N
273: DOUBLE PRECISION ABSTOL, VL, VU
274: * ..
275: * .. Array Arguments ..
276: INTEGER IFAIL( * ), IWORK( * )
277: DOUBLE PRECISION AB( LDAB, * ), Q( LDQ, * ), W( * ), WORK( * ),
278: $ Z( LDZ, * )
279: * ..
280: *
281: * =====================================================================
282: *
283: * .. Parameters ..
284: DOUBLE PRECISION ZERO, ONE
285: PARAMETER ( ZERO = 0.0D0, ONE = 1.0D0 )
286: * ..
287: * .. Local Scalars ..
288: LOGICAL ALLEIG, INDEIG, LOWER, TEST, VALEIG, WANTZ
289: CHARACTER ORDER
290: INTEGER I, IINFO, IMAX, INDD, INDE, INDEE, INDIBL,
291: $ INDISP, INDIWO, INDWRK, ISCALE, ITMP1, J, JJ,
292: $ NSPLIT
293: DOUBLE PRECISION ABSTLL, ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN,
294: $ SIGMA, SMLNUM, TMP1, VLL, VUU
295: * ..
296: * .. External Functions ..
297: LOGICAL LSAME
298: DOUBLE PRECISION DLAMCH, DLANSB
299: EXTERNAL LSAME, DLAMCH, DLANSB
300: * ..
301: * .. External Subroutines ..
302: EXTERNAL DCOPY, DGEMV, DLACPY, DLASCL, DSBTRD, DSCAL,
303: $ DSTEBZ, DSTEIN, DSTEQR, DSTERF, DSWAP, XERBLA
304: * ..
305: * .. Intrinsic Functions ..
306: INTRINSIC MAX, MIN, SQRT
307: * ..
308: * .. Executable Statements ..
309: *
310: * Test the input parameters.
311: *
312: WANTZ = LSAME( JOBZ, 'V' )
313: ALLEIG = LSAME( RANGE, 'A' )
314: VALEIG = LSAME( RANGE, 'V' )
315: INDEIG = LSAME( RANGE, 'I' )
316: LOWER = LSAME( UPLO, 'L' )
317: *
318: INFO = 0
319: IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
320: INFO = -1
321: ELSE IF( .NOT.( ALLEIG .OR. VALEIG .OR. INDEIG ) ) THEN
322: INFO = -2
323: ELSE IF( .NOT.( LOWER .OR. LSAME( UPLO, 'U' ) ) ) THEN
324: INFO = -3
325: ELSE IF( N.LT.0 ) THEN
326: INFO = -4
327: ELSE IF( KD.LT.0 ) THEN
328: INFO = -5
329: ELSE IF( LDAB.LT.KD+1 ) THEN
330: INFO = -7
331: ELSE IF( WANTZ .AND. LDQ.LT.MAX( 1, N ) ) THEN
332: INFO = -9
333: ELSE
334: IF( VALEIG ) THEN
335: IF( N.GT.0 .AND. VU.LE.VL )
336: $ INFO = -11
337: ELSE IF( INDEIG ) THEN
338: IF( IL.LT.1 .OR. IL.GT.MAX( 1, N ) ) THEN
339: INFO = -12
340: ELSE IF( IU.LT.MIN( N, IL ) .OR. IU.GT.N ) THEN
341: INFO = -13
342: END IF
343: END IF
344: END IF
345: IF( INFO.EQ.0 ) THEN
346: IF( LDZ.LT.1 .OR. ( WANTZ .AND. LDZ.LT.N ) )
347: $ INFO = -18
348: END IF
349: *
350: IF( INFO.NE.0 ) THEN
351: CALL XERBLA( 'DSBEVX', -INFO )
352: RETURN
353: END IF
354: *
355: * Quick return if possible
356: *
357: M = 0
358: IF( N.EQ.0 )
359: $ RETURN
360: *
361: IF( N.EQ.1 ) THEN
362: M = 1
363: IF( LOWER ) THEN
364: TMP1 = AB( 1, 1 )
365: ELSE
366: TMP1 = AB( KD+1, 1 )
367: END IF
368: IF( VALEIG ) THEN
369: IF( .NOT.( VL.LT.TMP1 .AND. VU.GE.TMP1 ) )
370: $ M = 0
371: END IF
372: IF( M.EQ.1 ) THEN
373: W( 1 ) = TMP1
374: IF( WANTZ )
375: $ Z( 1, 1 ) = ONE
376: END IF
377: RETURN
378: END IF
379: *
380: * Get machine constants.
381: *
382: SAFMIN = DLAMCH( 'Safe minimum' )
383: EPS = DLAMCH( 'Precision' )
384: SMLNUM = SAFMIN / EPS
385: BIGNUM = ONE / SMLNUM
386: RMIN = SQRT( SMLNUM )
387: RMAX = MIN( SQRT( BIGNUM ), ONE / SQRT( SQRT( SAFMIN ) ) )
388: *
389: * Scale matrix to allowable range, if necessary.
390: *
391: ISCALE = 0
392: ABSTLL = ABSTOL
393: IF( VALEIG ) THEN
394: VLL = VL
395: VUU = VU
396: ELSE
397: VLL = ZERO
398: VUU = ZERO
399: END IF
400: ANRM = DLANSB( 'M', UPLO, N, KD, AB, LDAB, WORK )
401: IF( ANRM.GT.ZERO .AND. ANRM.LT.RMIN ) THEN
402: ISCALE = 1
403: SIGMA = RMIN / ANRM
404: ELSE IF( ANRM.GT.RMAX ) THEN
405: ISCALE = 1
406: SIGMA = RMAX / ANRM
407: END IF
408: IF( ISCALE.EQ.1 ) THEN
409: IF( LOWER ) THEN
410: CALL DLASCL( 'B', KD, KD, ONE, SIGMA, N, N, AB, LDAB, INFO )
411: ELSE
412: CALL DLASCL( 'Q', KD, KD, ONE, SIGMA, N, N, AB, LDAB, INFO )
413: END IF
414: IF( ABSTOL.GT.0 )
415: $ ABSTLL = ABSTOL*SIGMA
416: IF( VALEIG ) THEN
417: VLL = VL*SIGMA
418: VUU = VU*SIGMA
419: END IF
420: END IF
421: *
422: * Call DSBTRD to reduce symmetric band matrix to tridiagonal form.
423: *
424: INDD = 1
425: INDE = INDD + N
426: INDWRK = INDE + N
427: CALL DSBTRD( JOBZ, UPLO, N, KD, AB, LDAB, WORK( INDD ),
428: $ WORK( INDE ), Q, LDQ, WORK( INDWRK ), IINFO )
429: *
430: * If all eigenvalues are desired and ABSTOL is less than or equal
431: * to zero, then call DSTERF or SSTEQR. If this fails for some
432: * eigenvalue, then try DSTEBZ.
433: *
434: TEST = .FALSE.
435: IF (INDEIG) THEN
436: IF (IL.EQ.1 .AND. IU.EQ.N) THEN
437: TEST = .TRUE.
438: END IF
439: END IF
440: IF ((ALLEIG .OR. TEST) .AND. (ABSTOL.LE.ZERO)) THEN
441: CALL DCOPY( N, WORK( INDD ), 1, W, 1 )
442: INDEE = INDWRK + 2*N
443: IF( .NOT.WANTZ ) THEN
444: CALL DCOPY( N-1, WORK( INDE ), 1, WORK( INDEE ), 1 )
445: CALL DSTERF( N, W, WORK( INDEE ), INFO )
446: ELSE
447: CALL DLACPY( 'A', N, N, Q, LDQ, Z, LDZ )
448: CALL DCOPY( N-1, WORK( INDE ), 1, WORK( INDEE ), 1 )
449: CALL DSTEQR( JOBZ, N, W, WORK( INDEE ), Z, LDZ,
450: $ WORK( INDWRK ), INFO )
451: IF( INFO.EQ.0 ) THEN
452: DO 10 I = 1, N
453: IFAIL( I ) = 0
454: 10 CONTINUE
455: END IF
456: END IF
457: IF( INFO.EQ.0 ) THEN
458: M = N
459: GO TO 30
460: END IF
461: INFO = 0
462: END IF
463: *
464: * Otherwise, call DSTEBZ and, if eigenvectors are desired, SSTEIN.
465: *
466: IF( WANTZ ) THEN
467: ORDER = 'B'
468: ELSE
469: ORDER = 'E'
470: END IF
471: INDIBL = 1
472: INDISP = INDIBL + N
473: INDIWO = INDISP + N
474: CALL DSTEBZ( RANGE, ORDER, N, VLL, VUU, IL, IU, ABSTLL,
475: $ WORK( INDD ), WORK( INDE ), M, NSPLIT, W,
476: $ IWORK( INDIBL ), IWORK( INDISP ), WORK( INDWRK ),
477: $ IWORK( INDIWO ), INFO )
478: *
479: IF( WANTZ ) THEN
480: CALL DSTEIN( N, WORK( INDD ), WORK( INDE ), M, W,
481: $ IWORK( INDIBL ), IWORK( INDISP ), Z, LDZ,
482: $ WORK( INDWRK ), IWORK( INDIWO ), IFAIL, INFO )
483: *
484: * Apply orthogonal matrix used in reduction to tridiagonal
485: * form to eigenvectors returned by DSTEIN.
486: *
487: DO 20 J = 1, M
488: CALL DCOPY( N, Z( 1, J ), 1, WORK( 1 ), 1 )
489: CALL DGEMV( 'N', N, N, ONE, Q, LDQ, WORK, 1, ZERO,
490: $ Z( 1, J ), 1 )
491: 20 CONTINUE
492: END IF
493: *
494: * If matrix was scaled, then rescale eigenvalues appropriately.
495: *
496: 30 CONTINUE
497: IF( ISCALE.EQ.1 ) THEN
498: IF( INFO.EQ.0 ) THEN
499: IMAX = M
500: ELSE
501: IMAX = INFO - 1
502: END IF
503: CALL DSCAL( IMAX, ONE / SIGMA, W, 1 )
504: END IF
505: *
506: * If eigenvalues are not in order, then sort them, along with
507: * eigenvectors.
508: *
509: IF( WANTZ ) THEN
510: DO 50 J = 1, M - 1
511: I = 0
512: TMP1 = W( J )
513: DO 40 JJ = J + 1, M
514: IF( W( JJ ).LT.TMP1 ) THEN
515: I = JJ
516: TMP1 = W( JJ )
517: END IF
518: 40 CONTINUE
519: *
520: IF( I.NE.0 ) THEN
521: ITMP1 = IWORK( INDIBL+I-1 )
522: W( I ) = W( J )
523: IWORK( INDIBL+I-1 ) = IWORK( INDIBL+J-1 )
524: W( J ) = TMP1
525: IWORK( INDIBL+J-1 ) = ITMP1
526: CALL DSWAP( N, Z( 1, I ), 1, Z( 1, J ), 1 )
527: IF( INFO.NE.0 ) THEN
528: ITMP1 = IFAIL( I )
529: IFAIL( I ) = IFAIL( J )
530: IFAIL( J ) = ITMP1
531: END IF
532: END IF
533: 50 CONTINUE
534: END IF
535: *
536: RETURN
537: *
538: * End of DSBEVX
539: *
540: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dsbevx.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack