1: *> \brief <b> DSBEV computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrices</b>
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DSBEV + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dsbev.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dsbev.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dsbev.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DSBEV( JOBZ, UPLO, N, KD, AB, LDAB, W, Z, LDZ, WORK,
22: * INFO )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER JOBZ, UPLO
26: * INTEGER INFO, KD, LDAB, LDZ, N
27: * ..
28: * .. Array Arguments ..
29: * DOUBLE PRECISION AB( LDAB, * ), W( * ), WORK( * ), Z( LDZ, * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> DSBEV computes all the eigenvalues and, optionally, eigenvectors of
39: *> a real symmetric band matrix A.
40: *> \endverbatim
41: *
42: * Arguments:
43: * ==========
44: *
45: *> \param[in] JOBZ
46: *> \verbatim
47: *> JOBZ is CHARACTER*1
48: *> = 'N': Compute eigenvalues only;
49: *> = 'V': Compute eigenvalues and eigenvectors.
50: *> \endverbatim
51: *>
52: *> \param[in] UPLO
53: *> \verbatim
54: *> UPLO is CHARACTER*1
55: *> = 'U': Upper triangle of A is stored;
56: *> = 'L': Lower triangle of A is stored.
57: *> \endverbatim
58: *>
59: *> \param[in] N
60: *> \verbatim
61: *> N is INTEGER
62: *> The order of the matrix A. N >= 0.
63: *> \endverbatim
64: *>
65: *> \param[in] KD
66: *> \verbatim
67: *> KD is INTEGER
68: *> The number of superdiagonals of the matrix A if UPLO = 'U',
69: *> or the number of subdiagonals if UPLO = 'L'. KD >= 0.
70: *> \endverbatim
71: *>
72: *> \param[in,out] AB
73: *> \verbatim
74: *> AB is DOUBLE PRECISION array, dimension (LDAB, N)
75: *> On entry, the upper or lower triangle of the symmetric band
76: *> matrix A, stored in the first KD+1 rows of the array. The
77: *> j-th column of A is stored in the j-th column of the array AB
78: *> as follows:
79: *> if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j;
80: *> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd).
81: *>
82: *> On exit, AB is overwritten by values generated during the
83: *> reduction to tridiagonal form. If UPLO = 'U', the first
84: *> superdiagonal and the diagonal of the tridiagonal matrix T
85: *> are returned in rows KD and KD+1 of AB, and if UPLO = 'L',
86: *> the diagonal and first subdiagonal of T are returned in the
87: *> first two rows of AB.
88: *> \endverbatim
89: *>
90: *> \param[in] LDAB
91: *> \verbatim
92: *> LDAB is INTEGER
93: *> The leading dimension of the array AB. LDAB >= KD + 1.
94: *> \endverbatim
95: *>
96: *> \param[out] W
97: *> \verbatim
98: *> W is DOUBLE PRECISION array, dimension (N)
99: *> If INFO = 0, the eigenvalues in ascending order.
100: *> \endverbatim
101: *>
102: *> \param[out] Z
103: *> \verbatim
104: *> Z is DOUBLE PRECISION array, dimension (LDZ, N)
105: *> If JOBZ = 'V', then if INFO = 0, Z contains the orthonormal
106: *> eigenvectors of the matrix A, with the i-th column of Z
107: *> holding the eigenvector associated with W(i).
108: *> If JOBZ = 'N', then Z is not referenced.
109: *> \endverbatim
110: *>
111: *> \param[in] LDZ
112: *> \verbatim
113: *> LDZ is INTEGER
114: *> The leading dimension of the array Z. LDZ >= 1, and if
115: *> JOBZ = 'V', LDZ >= max(1,N).
116: *> \endverbatim
117: *>
118: *> \param[out] WORK
119: *> \verbatim
120: *> WORK is DOUBLE PRECISION array, dimension (max(1,3*N-2))
121: *> \endverbatim
122: *>
123: *> \param[out] INFO
124: *> \verbatim
125: *> INFO is INTEGER
126: *> = 0: successful exit
127: *> < 0: if INFO = -i, the i-th argument had an illegal value
128: *> > 0: if INFO = i, the algorithm failed to converge; i
129: *> off-diagonal elements of an intermediate tridiagonal
130: *> form did not converge to zero.
131: *> \endverbatim
132: *
133: * Authors:
134: * ========
135: *
136: *> \author Univ. of Tennessee
137: *> \author Univ. of California Berkeley
138: *> \author Univ. of Colorado Denver
139: *> \author NAG Ltd.
140: *
141: *> \ingroup doubleOTHEReigen
142: *
143: * =====================================================================
144: SUBROUTINE DSBEV( JOBZ, UPLO, N, KD, AB, LDAB, W, Z, LDZ, WORK,
145: $ INFO )
146: *
147: * -- LAPACK driver routine --
148: * -- LAPACK is a software package provided by Univ. of Tennessee, --
149: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
150: *
151: * .. Scalar Arguments ..
152: CHARACTER JOBZ, UPLO
153: INTEGER INFO, KD, LDAB, LDZ, N
154: * ..
155: * .. Array Arguments ..
156: DOUBLE PRECISION AB( LDAB, * ), W( * ), WORK( * ), Z( LDZ, * )
157: * ..
158: *
159: * =====================================================================
160: *
161: * .. Parameters ..
162: DOUBLE PRECISION ZERO, ONE
163: PARAMETER ( ZERO = 0.0D0, ONE = 1.0D0 )
164: * ..
165: * .. Local Scalars ..
166: LOGICAL LOWER, WANTZ
167: INTEGER IINFO, IMAX, INDE, INDWRK, ISCALE
168: DOUBLE PRECISION ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN, SIGMA,
169: $ SMLNUM
170: * ..
171: * .. External Functions ..
172: LOGICAL LSAME
173: DOUBLE PRECISION DLAMCH, DLANSB
174: EXTERNAL LSAME, DLAMCH, DLANSB
175: * ..
176: * .. External Subroutines ..
177: EXTERNAL DLASCL, DSBTRD, DSCAL, DSTEQR, DSTERF, XERBLA
178: * ..
179: * .. Intrinsic Functions ..
180: INTRINSIC SQRT
181: * ..
182: * .. Executable Statements ..
183: *
184: * Test the input parameters.
185: *
186: WANTZ = LSAME( JOBZ, 'V' )
187: LOWER = LSAME( UPLO, 'L' )
188: *
189: INFO = 0
190: IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
191: INFO = -1
192: ELSE IF( .NOT.( LOWER .OR. LSAME( UPLO, 'U' ) ) ) THEN
193: INFO = -2
194: ELSE IF( N.LT.0 ) THEN
195: INFO = -3
196: ELSE IF( KD.LT.0 ) THEN
197: INFO = -4
198: ELSE IF( LDAB.LT.KD+1 ) THEN
199: INFO = -6
200: ELSE IF( LDZ.LT.1 .OR. ( WANTZ .AND. LDZ.LT.N ) ) THEN
201: INFO = -9
202: END IF
203: *
204: IF( INFO.NE.0 ) THEN
205: CALL XERBLA( 'DSBEV ', -INFO )
206: RETURN
207: END IF
208: *
209: * Quick return if possible
210: *
211: IF( N.EQ.0 )
212: $ RETURN
213: *
214: IF( N.EQ.1 ) THEN
215: IF( LOWER ) THEN
216: W( 1 ) = AB( 1, 1 )
217: ELSE
218: W( 1 ) = AB( KD+1, 1 )
219: END IF
220: IF( WANTZ )
221: $ Z( 1, 1 ) = ONE
222: RETURN
223: END IF
224: *
225: * Get machine constants.
226: *
227: SAFMIN = DLAMCH( 'Safe minimum' )
228: EPS = DLAMCH( 'Precision' )
229: SMLNUM = SAFMIN / EPS
230: BIGNUM = ONE / SMLNUM
231: RMIN = SQRT( SMLNUM )
232: RMAX = SQRT( BIGNUM )
233: *
234: * Scale matrix to allowable range, if necessary.
235: *
236: ANRM = DLANSB( 'M', UPLO, N, KD, AB, LDAB, WORK )
237: ISCALE = 0
238: IF( ANRM.GT.ZERO .AND. ANRM.LT.RMIN ) THEN
239: ISCALE = 1
240: SIGMA = RMIN / ANRM
241: ELSE IF( ANRM.GT.RMAX ) THEN
242: ISCALE = 1
243: SIGMA = RMAX / ANRM
244: END IF
245: IF( ISCALE.EQ.1 ) THEN
246: IF( LOWER ) THEN
247: CALL DLASCL( 'B', KD, KD, ONE, SIGMA, N, N, AB, LDAB, INFO )
248: ELSE
249: CALL DLASCL( 'Q', KD, KD, ONE, SIGMA, N, N, AB, LDAB, INFO )
250: END IF
251: END IF
252: *
253: * Call DSBTRD to reduce symmetric band matrix to tridiagonal form.
254: *
255: INDE = 1
256: INDWRK = INDE + N
257: CALL DSBTRD( JOBZ, UPLO, N, KD, AB, LDAB, W, WORK( INDE ), Z, LDZ,
258: $ WORK( INDWRK ), IINFO )
259: *
260: * For eigenvalues only, call DSTERF. For eigenvectors, call SSTEQR.
261: *
262: IF( .NOT.WANTZ ) THEN
263: CALL DSTERF( N, W, WORK( INDE ), INFO )
264: ELSE
265: CALL DSTEQR( JOBZ, N, W, WORK( INDE ), Z, LDZ, WORK( INDWRK ),
266: $ INFO )
267: END IF
268: *
269: * If matrix was scaled, then rescale eigenvalues appropriately.
270: *
271: IF( ISCALE.EQ.1 ) THEN
272: IF( INFO.EQ.0 ) THEN
273: IMAX = N
274: ELSE
275: IMAX = INFO - 1
276: END IF
277: CALL DSCAL( IMAX, ONE / SIGMA, W, 1 )
278: END IF
279: *
280: RETURN
281: *
282: * End of DSBEV
283: *
284: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dsbev.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack