Annotation of rpl/lapack/lapack/dporfs.f, revision 1.18
1.9 bertrand 1: *> \brief \b DPORFS
2: *
3: * =========== DOCUMENTATION ===========
4: *
1.15 bertrand 5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
1.9 bertrand 7: *
8: *> \htmlonly
1.15 bertrand 9: *> Download DPORFS + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dporfs.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dporfs.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dporfs.f">
1.9 bertrand 15: *> [TXT]</a>
1.15 bertrand 16: *> \endhtmlonly
1.9 bertrand 17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DPORFS( UPLO, N, NRHS, A, LDA, AF, LDAF, B, LDB, X,
22: * LDX, FERR, BERR, WORK, IWORK, INFO )
1.15 bertrand 23: *
1.9 bertrand 24: * .. Scalar Arguments ..
25: * CHARACTER UPLO
26: * INTEGER INFO, LDA, LDAF, LDB, LDX, N, NRHS
27: * ..
28: * .. Array Arguments ..
29: * INTEGER IWORK( * )
30: * DOUBLE PRECISION A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
31: * $ BERR( * ), FERR( * ), WORK( * ), X( LDX, * )
32: * ..
1.15 bertrand 33: *
1.9 bertrand 34: *
35: *> \par Purpose:
36: * =============
37: *>
38: *> \verbatim
39: *>
40: *> DPORFS improves the computed solution to a system of linear
41: *> equations when the coefficient matrix is symmetric positive definite,
42: *> and provides error bounds and backward error estimates for the
43: *> solution.
44: *> \endverbatim
45: *
46: * Arguments:
47: * ==========
48: *
49: *> \param[in] UPLO
50: *> \verbatim
51: *> UPLO is CHARACTER*1
52: *> = 'U': Upper triangle of A is stored;
53: *> = 'L': Lower triangle of A is stored.
54: *> \endverbatim
55: *>
56: *> \param[in] N
57: *> \verbatim
58: *> N is INTEGER
59: *> The order of the matrix A. N >= 0.
60: *> \endverbatim
61: *>
62: *> \param[in] NRHS
63: *> \verbatim
64: *> NRHS is INTEGER
65: *> The number of right hand sides, i.e., the number of columns
66: *> of the matrices B and X. NRHS >= 0.
67: *> \endverbatim
68: *>
69: *> \param[in] A
70: *> \verbatim
71: *> A is DOUBLE PRECISION array, dimension (LDA,N)
72: *> The symmetric matrix A. If UPLO = 'U', the leading N-by-N
73: *> upper triangular part of A contains the upper triangular part
74: *> of the matrix A, and the strictly lower triangular part of A
75: *> is not referenced. If UPLO = 'L', the leading N-by-N lower
76: *> triangular part of A contains the lower triangular part of
77: *> the matrix A, and the strictly upper triangular part of A is
78: *> not referenced.
79: *> \endverbatim
80: *>
81: *> \param[in] LDA
82: *> \verbatim
83: *> LDA is INTEGER
84: *> The leading dimension of the array A. LDA >= max(1,N).
85: *> \endverbatim
86: *>
87: *> \param[in] AF
88: *> \verbatim
89: *> AF is DOUBLE PRECISION array, dimension (LDAF,N)
90: *> The triangular factor U or L from the Cholesky factorization
91: *> A = U**T*U or A = L*L**T, as computed by DPOTRF.
92: *> \endverbatim
93: *>
94: *> \param[in] LDAF
95: *> \verbatim
96: *> LDAF is INTEGER
97: *> The leading dimension of the array AF. LDAF >= max(1,N).
98: *> \endverbatim
99: *>
100: *> \param[in] B
101: *> \verbatim
102: *> B is DOUBLE PRECISION array, dimension (LDB,NRHS)
103: *> The right hand side matrix B.
104: *> \endverbatim
105: *>
106: *> \param[in] LDB
107: *> \verbatim
108: *> LDB is INTEGER
109: *> The leading dimension of the array B. LDB >= max(1,N).
110: *> \endverbatim
111: *>
112: *> \param[in,out] X
113: *> \verbatim
114: *> X is DOUBLE PRECISION array, dimension (LDX,NRHS)
115: *> On entry, the solution matrix X, as computed by DPOTRS.
116: *> On exit, the improved solution matrix X.
117: *> \endverbatim
118: *>
119: *> \param[in] LDX
120: *> \verbatim
121: *> LDX is INTEGER
122: *> The leading dimension of the array X. LDX >= max(1,N).
123: *> \endverbatim
124: *>
125: *> \param[out] FERR
126: *> \verbatim
127: *> FERR is DOUBLE PRECISION array, dimension (NRHS)
128: *> The estimated forward error bound for each solution vector
129: *> X(j) (the j-th column of the solution matrix X).
130: *> If XTRUE is the true solution corresponding to X(j), FERR(j)
131: *> is an estimated upper bound for the magnitude of the largest
132: *> element in (X(j) - XTRUE) divided by the magnitude of the
133: *> largest element in X(j). The estimate is as reliable as
134: *> the estimate for RCOND, and is almost always a slight
135: *> overestimate of the true error.
136: *> \endverbatim
137: *>
138: *> \param[out] BERR
139: *> \verbatim
140: *> BERR is DOUBLE PRECISION array, dimension (NRHS)
141: *> The componentwise relative backward error of each solution
142: *> vector X(j) (i.e., the smallest relative change in
143: *> any element of A or B that makes X(j) an exact solution).
144: *> \endverbatim
145: *>
146: *> \param[out] WORK
147: *> \verbatim
148: *> WORK is DOUBLE PRECISION array, dimension (3*N)
149: *> \endverbatim
150: *>
151: *> \param[out] IWORK
152: *> \verbatim
153: *> IWORK is INTEGER array, dimension (N)
154: *> \endverbatim
155: *>
156: *> \param[out] INFO
157: *> \verbatim
158: *> INFO is INTEGER
159: *> = 0: successful exit
160: *> < 0: if INFO = -i, the i-th argument had an illegal value
161: *> \endverbatim
162: *
163: *> \par Internal Parameters:
164: * =========================
165: *>
166: *> \verbatim
167: *> ITMAX is the maximum number of steps of iterative refinement.
168: *> \endverbatim
169: *
170: * Authors:
171: * ========
172: *
1.15 bertrand 173: *> \author Univ. of Tennessee
174: *> \author Univ. of California Berkeley
175: *> \author Univ. of Colorado Denver
176: *> \author NAG Ltd.
1.9 bertrand 177: *
178: *> \ingroup doublePOcomputational
179: *
180: * =====================================================================
1.1 bertrand 181: SUBROUTINE DPORFS( UPLO, N, NRHS, A, LDA, AF, LDAF, B, LDB, X,
182: $ LDX, FERR, BERR, WORK, IWORK, INFO )
183: *
1.18 ! bertrand 184: * -- LAPACK computational routine --
1.1 bertrand 185: * -- LAPACK is a software package provided by Univ. of Tennessee, --
186: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
187: *
188: * .. Scalar Arguments ..
189: CHARACTER UPLO
190: INTEGER INFO, LDA, LDAF, LDB, LDX, N, NRHS
191: * ..
192: * .. Array Arguments ..
193: INTEGER IWORK( * )
194: DOUBLE PRECISION A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
195: $ BERR( * ), FERR( * ), WORK( * ), X( LDX, * )
196: * ..
197: *
198: * =====================================================================
199: *
200: * .. Parameters ..
201: INTEGER ITMAX
202: PARAMETER ( ITMAX = 5 )
203: DOUBLE PRECISION ZERO
204: PARAMETER ( ZERO = 0.0D+0 )
205: DOUBLE PRECISION ONE
206: PARAMETER ( ONE = 1.0D+0 )
207: DOUBLE PRECISION TWO
208: PARAMETER ( TWO = 2.0D+0 )
209: DOUBLE PRECISION THREE
210: PARAMETER ( THREE = 3.0D+0 )
211: * ..
212: * .. Local Scalars ..
213: LOGICAL UPPER
214: INTEGER COUNT, I, J, K, KASE, NZ
215: DOUBLE PRECISION EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN, XK
216: * ..
217: * .. Local Arrays ..
218: INTEGER ISAVE( 3 )
219: * ..
220: * .. External Subroutines ..
221: EXTERNAL DAXPY, DCOPY, DLACN2, DPOTRS, DSYMV, XERBLA
222: * ..
223: * .. Intrinsic Functions ..
224: INTRINSIC ABS, MAX
225: * ..
226: * .. External Functions ..
227: LOGICAL LSAME
228: DOUBLE PRECISION DLAMCH
229: EXTERNAL LSAME, DLAMCH
230: * ..
231: * .. Executable Statements ..
232: *
233: * Test the input parameters.
234: *
235: INFO = 0
236: UPPER = LSAME( UPLO, 'U' )
237: IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
238: INFO = -1
239: ELSE IF( N.LT.0 ) THEN
240: INFO = -2
241: ELSE IF( NRHS.LT.0 ) THEN
242: INFO = -3
243: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
244: INFO = -5
245: ELSE IF( LDAF.LT.MAX( 1, N ) ) THEN
246: INFO = -7
247: ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
248: INFO = -9
249: ELSE IF( LDX.LT.MAX( 1, N ) ) THEN
250: INFO = -11
251: END IF
252: IF( INFO.NE.0 ) THEN
253: CALL XERBLA( 'DPORFS', -INFO )
254: RETURN
255: END IF
256: *
257: * Quick return if possible
258: *
259: IF( N.EQ.0 .OR. NRHS.EQ.0 ) THEN
260: DO 10 J = 1, NRHS
261: FERR( J ) = ZERO
262: BERR( J ) = ZERO
263: 10 CONTINUE
264: RETURN
265: END IF
266: *
267: * NZ = maximum number of nonzero elements in each row of A, plus 1
268: *
269: NZ = N + 1
270: EPS = DLAMCH( 'Epsilon' )
271: SAFMIN = DLAMCH( 'Safe minimum' )
272: SAFE1 = NZ*SAFMIN
273: SAFE2 = SAFE1 / EPS
274: *
275: * Do for each right hand side
276: *
277: DO 140 J = 1, NRHS
278: *
279: COUNT = 1
280: LSTRES = THREE
281: 20 CONTINUE
282: *
283: * Loop until stopping criterion is satisfied.
284: *
285: * Compute residual R = B - A * X
286: *
287: CALL DCOPY( N, B( 1, J ), 1, WORK( N+1 ), 1 )
288: CALL DSYMV( UPLO, N, -ONE, A, LDA, X( 1, J ), 1, ONE,
289: $ WORK( N+1 ), 1 )
290: *
291: * Compute componentwise relative backward error from formula
292: *
293: * max(i) ( abs(R(i)) / ( abs(A)*abs(X) + abs(B) )(i) )
294: *
295: * where abs(Z) is the componentwise absolute value of the matrix
296: * or vector Z. If the i-th component of the denominator is less
297: * than SAFE2, then SAFE1 is added to the i-th components of the
298: * numerator and denominator before dividing.
299: *
300: DO 30 I = 1, N
301: WORK( I ) = ABS( B( I, J ) )
302: 30 CONTINUE
303: *
304: * Compute abs(A)*abs(X) + abs(B).
305: *
306: IF( UPPER ) THEN
307: DO 50 K = 1, N
308: S = ZERO
309: XK = ABS( X( K, J ) )
310: DO 40 I = 1, K - 1
311: WORK( I ) = WORK( I ) + ABS( A( I, K ) )*XK
312: S = S + ABS( A( I, K ) )*ABS( X( I, J ) )
313: 40 CONTINUE
314: WORK( K ) = WORK( K ) + ABS( A( K, K ) )*XK + S
315: 50 CONTINUE
316: ELSE
317: DO 70 K = 1, N
318: S = ZERO
319: XK = ABS( X( K, J ) )
320: WORK( K ) = WORK( K ) + ABS( A( K, K ) )*XK
321: DO 60 I = K + 1, N
322: WORK( I ) = WORK( I ) + ABS( A( I, K ) )*XK
323: S = S + ABS( A( I, K ) )*ABS( X( I, J ) )
324: 60 CONTINUE
325: WORK( K ) = WORK( K ) + S
326: 70 CONTINUE
327: END IF
328: S = ZERO
329: DO 80 I = 1, N
330: IF( WORK( I ).GT.SAFE2 ) THEN
331: S = MAX( S, ABS( WORK( N+I ) ) / WORK( I ) )
332: ELSE
333: S = MAX( S, ( ABS( WORK( N+I ) )+SAFE1 ) /
334: $ ( WORK( I )+SAFE1 ) )
335: END IF
336: 80 CONTINUE
337: BERR( J ) = S
338: *
339: * Test stopping criterion. Continue iterating if
340: * 1) The residual BERR(J) is larger than machine epsilon, and
341: * 2) BERR(J) decreased by at least a factor of 2 during the
342: * last iteration, and
343: * 3) At most ITMAX iterations tried.
344: *
345: IF( BERR( J ).GT.EPS .AND. TWO*BERR( J ).LE.LSTRES .AND.
346: $ COUNT.LE.ITMAX ) THEN
347: *
348: * Update solution and try again.
349: *
350: CALL DPOTRS( UPLO, N, 1, AF, LDAF, WORK( N+1 ), N, INFO )
351: CALL DAXPY( N, ONE, WORK( N+1 ), 1, X( 1, J ), 1 )
352: LSTRES = BERR( J )
353: COUNT = COUNT + 1
354: GO TO 20
355: END IF
356: *
357: * Bound error from formula
358: *
359: * norm(X - XTRUE) / norm(X) .le. FERR =
360: * norm( abs(inv(A))*
361: * ( abs(R) + NZ*EPS*( abs(A)*abs(X)+abs(B) ))) / norm(X)
362: *
363: * where
364: * norm(Z) is the magnitude of the largest component of Z
365: * inv(A) is the inverse of A
366: * abs(Z) is the componentwise absolute value of the matrix or
367: * vector Z
368: * NZ is the maximum number of nonzeros in any row of A, plus 1
369: * EPS is machine epsilon
370: *
371: * The i-th component of abs(R)+NZ*EPS*(abs(A)*abs(X)+abs(B))
372: * is incremented by SAFE1 if the i-th component of
373: * abs(A)*abs(X) + abs(B) is less than SAFE2.
374: *
375: * Use DLACN2 to estimate the infinity-norm of the matrix
376: * inv(A) * diag(W),
377: * where W = abs(R) + NZ*EPS*( abs(A)*abs(X)+abs(B) )))
378: *
379: DO 90 I = 1, N
380: IF( WORK( I ).GT.SAFE2 ) THEN
381: WORK( I ) = ABS( WORK( N+I ) ) + NZ*EPS*WORK( I )
382: ELSE
383: WORK( I ) = ABS( WORK( N+I ) ) + NZ*EPS*WORK( I ) + SAFE1
384: END IF
385: 90 CONTINUE
386: *
387: KASE = 0
388: 100 CONTINUE
389: CALL DLACN2( N, WORK( 2*N+1 ), WORK( N+1 ), IWORK, FERR( J ),
390: $ KASE, ISAVE )
391: IF( KASE.NE.0 ) THEN
392: IF( KASE.EQ.1 ) THEN
393: *
1.8 bertrand 394: * Multiply by diag(W)*inv(A**T).
1.1 bertrand 395: *
396: CALL DPOTRS( UPLO, N, 1, AF, LDAF, WORK( N+1 ), N, INFO )
397: DO 110 I = 1, N
398: WORK( N+I ) = WORK( I )*WORK( N+I )
399: 110 CONTINUE
400: ELSE IF( KASE.EQ.2 ) THEN
401: *
402: * Multiply by inv(A)*diag(W).
403: *
404: DO 120 I = 1, N
405: WORK( N+I ) = WORK( I )*WORK( N+I )
406: 120 CONTINUE
407: CALL DPOTRS( UPLO, N, 1, AF, LDAF, WORK( N+1 ), N, INFO )
408: END IF
409: GO TO 100
410: END IF
411: *
412: * Normalize error.
413: *
414: LSTRES = ZERO
415: DO 130 I = 1, N
416: LSTRES = MAX( LSTRES, ABS( X( I, J ) ) )
417: 130 CONTINUE
418: IF( LSTRES.NE.ZERO )
419: $ FERR( J ) = FERR( J ) / LSTRES
420: *
421: 140 CONTINUE
422: *
423: RETURN
424: *
425: * End of DPORFS
426: *
427: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dporfs.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack