Return to dpoequb.f CVS log

Up to [local] / rpl / lapack / lapack

Première mise à jour de lapack et blas.

    1: *> \brief \b DPOEQUB
    2: *
    3: *  =========== DOCUMENTATION ===========
    4: *
    5: * Online html documentation available at
    6: *            http://www.netlib.org/lapack/explore-html/
    7: *
    8: *> \htmlonly
    9: *> Download DPOEQUB + dependencies
   10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dpoequb.f">
   11: *> [TGZ]</a>
   12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dpoequb.f">
   13: *> [ZIP]</a>
   14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dpoequb.f">
   15: *> [TXT]</a>
   16: *> \endhtmlonly
   17: *
   18: *  Definition:
   19: *  ===========
   20: *
   21: *       SUBROUTINE DPOEQUB( N, A, LDA, S, SCOND, AMAX, INFO )
   22: *
   23: *       .. Scalar Arguments ..
   24: *       INTEGER            INFO, LDA, N
   25: *       DOUBLE PRECISION   AMAX, SCOND
   26: *       ..
   27: *       .. Array Arguments ..
   28: *       DOUBLE PRECISION   A( LDA, * ), S( * )
   29: *       ..
   30: *
   31: *
   32: *> \par Purpose:
   33: *  =============
   34: *>
   35: *> \verbatim
   36: *>
   37: *> DPOEQUB computes row and column scalings intended to equilibrate a
   38: *> symmetric positive definite matrix A and reduce its condition number
   39: *> (with respect to the two-norm).  S contains the scale factors,
   40: *> S(i) = 1/sqrt(A(i,i)), chosen so that the scaled matrix B with
   41: *> elements B(i,j) = S(i)*A(i,j)*S(j) has ones on the diagonal.  This
   42: *> choice of S puts the condition number of B within a factor N of the
   43: *> smallest possible condition number over all possible diagonal
   44: *> scalings.
   45: *>
   46: *> This routine differs from DPOEQU by restricting the scaling factors
   47: *> to a power of the radix.  Barring over- and underflow, scaling by
   48: *> these factors introduces no additional rounding errors.  However, the
   49: *> scaled diagonal entries are no longer approximately 1 but lie
   50: *> between sqrt(radix) and 1/sqrt(radix).
   51: *> \endverbatim
   52: *
   53: *  Arguments:
   54: *  ==========
   55: *
   56: *> \param[in] N
   57: *> \verbatim
   58: *>          N is INTEGER
   59: *>          The order of the matrix A.  N >= 0.
   60: *> \endverbatim
   61: *>
   62: *> \param[in] A
   63: *> \verbatim
   64: *>          A is DOUBLE PRECISION array, dimension (LDA,N)
   65: *>          The N-by-N symmetric positive definite matrix whose scaling
   66: *>          factors are to be computed.  Only the diagonal elements of A
   67: *>          are referenced.
   68: *> \endverbatim
   69: *>
   70: *> \param[in] LDA
   71: *> \verbatim
   72: *>          LDA is INTEGER
   73: *>          The leading dimension of the array A.  LDA >= max(1,N).
   74: *> \endverbatim
   75: *>
   76: *> \param[out] S
   77: *> \verbatim
   78: *>          S is DOUBLE PRECISION array, dimension (N)
   79: *>          If INFO = 0, S contains the scale factors for A.
   80: *> \endverbatim
   81: *>
   82: *> \param[out] SCOND
   83: *> \verbatim
   84: *>          SCOND is DOUBLE PRECISION
   85: *>          If INFO = 0, S contains the ratio of the smallest S(i) to
   86: *>          the largest S(i).  If SCOND >= 0.1 and AMAX is neither too
   87: *>          large nor too small, it is not worth scaling by S.
   88: *> \endverbatim
   89: *>
   90: *> \param[out] AMAX
   91: *> \verbatim
   92: *>          AMAX is DOUBLE PRECISION
   93: *>          Absolute value of largest matrix element.  If AMAX is very
   94: *>          close to overflow or very close to underflow, the matrix
   95: *>          should be scaled.
   96: *> \endverbatim
   97: *>
   98: *> \param[out] INFO
   99: *> \verbatim
  100: *>          INFO is INTEGER
  101: *>          = 0:  successful exit
  102: *>          < 0:  if INFO = -i, the i-th argument had an illegal value
  103: *>          > 0:  if INFO = i, the i-th diagonal element is nonpositive.
  104: *> \endverbatim
  105: *
  106: *  Authors:
  107: *  ========
  108: *
  109: *> \author Univ. of Tennessee
  110: *> \author Univ. of California Berkeley
  111: *> \author Univ. of Colorado Denver
  112: *> \author NAG Ltd.
  113: *
  114: *> \ingroup doublePOcomputational
  115: *
  116: *  =====================================================================
  117:       SUBROUTINE DPOEQUB( N, A, LDA, S, SCOND, AMAX, INFO )
  118: *
  119: *  -- LAPACK computational routine --
  120: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
  121: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
  122: *
  123: *     .. Scalar Arguments ..
  124:       INTEGER            INFO, LDA, N
  125:       DOUBLE PRECISION   AMAX, SCOND
  126: *     ..
  127: *     .. Array Arguments ..
  128:       DOUBLE PRECISION   A( LDA, * ), S( * )
  129: *     ..
  130: *
  131: *  =====================================================================
  132: *
  133: *     .. Parameters ..
  134:       DOUBLE PRECISION   ZERO, ONE
  135:       PARAMETER          ( ZERO = 0.0D+0, ONE = 1.0D+0 )
  136: *     ..
  137: *     .. Local Scalars ..
  138:       INTEGER            I
  139:       DOUBLE PRECISION   SMIN, BASE, TMP
  140: *     ..
  141: *     .. External Functions ..
  142:       DOUBLE PRECISION   DLAMCH
  143:       EXTERNAL           DLAMCH
  144: *     ..
  145: *     .. External Subroutines ..
  146:       EXTERNAL           XERBLA
  147: *     ..
  148: *     .. Intrinsic Functions ..
  149:       INTRINSIC          MAX, MIN, SQRT, LOG, INT
  150: *     ..
  151: *     .. Executable Statements ..
  152: *
  153: *     Test the input parameters.
  154: *
  155: *     Positive definite only performs 1 pass of equilibration.
  156: *
  157:       INFO = 0
  158:       IF( N.LT.0 ) THEN
  159:          INFO = -1
  160:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
  161:          INFO = -3
  162:       END IF
  163:       IF( INFO.NE.0 ) THEN
  164:          CALL XERBLA( 'DPOEQUB', -INFO )
  165:          RETURN
  166:       END IF
  167: *
  168: *     Quick return if possible.
  169: *
  170:       IF( N.EQ.0 ) THEN
  171:          SCOND = ONE
  172:          AMAX = ZERO
  173:          RETURN
  174:       END IF
  175: 
  176:       BASE = DLAMCH( 'B' )
  177:       TMP = -0.5D+0 / LOG ( BASE )
  178: *
  179: *     Find the minimum and maximum diagonal elements.
  180: *
  181:       S( 1 ) = A( 1, 1 )
  182:       SMIN = S( 1 )
  183:       AMAX = S( 1 )
  184:       DO 10 I = 2, N
  185:          S( I ) = A( I, I )
  186:          SMIN = MIN( SMIN, S( I ) )
  187:          AMAX = MAX( AMAX, S( I ) )
  188:    10 CONTINUE
  189: *
  190:       IF( SMIN.LE.ZERO ) THEN
  191: *
  192: *        Find the first non-positive diagonal element and return.
  193: *
  194:          DO 20 I = 1, N
  195:             IF( S( I ).LE.ZERO ) THEN
  196:                INFO = I
  197:                RETURN
  198:             END IF
  199:    20    CONTINUE
  200:       ELSE
  201: *
  202: *        Set the scale factors to the reciprocals
  203: *        of the diagonal elements.
  204: *
  205:          DO 30 I = 1, N
  206:             S( I ) = BASE ** INT( TMP * LOG( S( I ) ) )
  207:    30    CONTINUE
  208: *
  209: *        Compute SCOND = min(S(I)) / max(S(I)).
  210: *
  211:          SCOND = SQRT( SMIN ) / SQRT( AMAX )
  212:       END IF
  213: *
  214:       RETURN
  215: *
  216: *     End of DPOEQUB
  217: *
  218:       END