Annotation of rpl/lapack/lapack/dormql.f, revision 1.10
1.9 bertrand 1: *> \brief \b DORMQL
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DORMQL + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dormql.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dormql.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dormql.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DORMQL( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
22: * WORK, LWORK, INFO )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER SIDE, TRANS
26: * INTEGER INFO, K, LDA, LDC, LWORK, M, N
27: * ..
28: * .. Array Arguments ..
29: * DOUBLE PRECISION A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> DORMQL overwrites the general real M-by-N matrix C with
39: *>
40: *> SIDE = 'L' SIDE = 'R'
41: *> TRANS = 'N': Q * C C * Q
42: *> TRANS = 'T': Q**T * C C * Q**T
43: *>
44: *> where Q is a real orthogonal matrix defined as the product of k
45: *> elementary reflectors
46: *>
47: *> Q = H(k) . . . H(2) H(1)
48: *>
49: *> as returned by DGEQLF. Q is of order M if SIDE = 'L' and of order N
50: *> if SIDE = 'R'.
51: *> \endverbatim
52: *
53: * Arguments:
54: * ==========
55: *
56: *> \param[in] SIDE
57: *> \verbatim
58: *> SIDE is CHARACTER*1
59: *> = 'L': apply Q or Q**T from the Left;
60: *> = 'R': apply Q or Q**T from the Right.
61: *> \endverbatim
62: *>
63: *> \param[in] TRANS
64: *> \verbatim
65: *> TRANS is CHARACTER*1
66: *> = 'N': No transpose, apply Q;
67: *> = 'T': Transpose, apply Q**T.
68: *> \endverbatim
69: *>
70: *> \param[in] M
71: *> \verbatim
72: *> M is INTEGER
73: *> The number of rows of the matrix C. M >= 0.
74: *> \endverbatim
75: *>
76: *> \param[in] N
77: *> \verbatim
78: *> N is INTEGER
79: *> The number of columns of the matrix C. N >= 0.
80: *> \endverbatim
81: *>
82: *> \param[in] K
83: *> \verbatim
84: *> K is INTEGER
85: *> The number of elementary reflectors whose product defines
86: *> the matrix Q.
87: *> If SIDE = 'L', M >= K >= 0;
88: *> if SIDE = 'R', N >= K >= 0.
89: *> \endverbatim
90: *>
91: *> \param[in] A
92: *> \verbatim
93: *> A is DOUBLE PRECISION array, dimension (LDA,K)
94: *> The i-th column must contain the vector which defines the
95: *> elementary reflector H(i), for i = 1,2,...,k, as returned by
96: *> DGEQLF in the last k columns of its array argument A.
97: *> A is modified by the routine but restored on exit.
98: *> \endverbatim
99: *>
100: *> \param[in] LDA
101: *> \verbatim
102: *> LDA is INTEGER
103: *> The leading dimension of the array A.
104: *> If SIDE = 'L', LDA >= max(1,M);
105: *> if SIDE = 'R', LDA >= max(1,N).
106: *> \endverbatim
107: *>
108: *> \param[in] TAU
109: *> \verbatim
110: *> TAU is DOUBLE PRECISION array, dimension (K)
111: *> TAU(i) must contain the scalar factor of the elementary
112: *> reflector H(i), as returned by DGEQLF.
113: *> \endverbatim
114: *>
115: *> \param[in,out] C
116: *> \verbatim
117: *> C is DOUBLE PRECISION array, dimension (LDC,N)
118: *> On entry, the M-by-N matrix C.
119: *> On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
120: *> \endverbatim
121: *>
122: *> \param[in] LDC
123: *> \verbatim
124: *> LDC is INTEGER
125: *> The leading dimension of the array C. LDC >= max(1,M).
126: *> \endverbatim
127: *>
128: *> \param[out] WORK
129: *> \verbatim
130: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK))
131: *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
132: *> \endverbatim
133: *>
134: *> \param[in] LWORK
135: *> \verbatim
136: *> LWORK is INTEGER
137: *> The dimension of the array WORK.
138: *> If SIDE = 'L', LWORK >= max(1,N);
139: *> if SIDE = 'R', LWORK >= max(1,M).
140: *> For optimum performance LWORK >= N*NB if SIDE = 'L', and
141: *> LWORK >= M*NB if SIDE = 'R', where NB is the optimal
142: *> blocksize.
143: *>
144: *> If LWORK = -1, then a workspace query is assumed; the routine
145: *> only calculates the optimal size of the WORK array, returns
146: *> this value as the first entry of the WORK array, and no error
147: *> message related to LWORK is issued by XERBLA.
148: *> \endverbatim
149: *>
150: *> \param[out] INFO
151: *> \verbatim
152: *> INFO is INTEGER
153: *> = 0: successful exit
154: *> < 0: if INFO = -i, the i-th argument had an illegal value
155: *> \endverbatim
156: *
157: * Authors:
158: * ========
159: *
160: *> \author Univ. of Tennessee
161: *> \author Univ. of California Berkeley
162: *> \author Univ. of Colorado Denver
163: *> \author NAG Ltd.
164: *
165: *> \date November 2011
166: *
167: *> \ingroup doubleOTHERcomputational
168: *
169: * =====================================================================
1.1 bertrand 170: SUBROUTINE DORMQL( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
171: $ WORK, LWORK, INFO )
172: *
1.9 bertrand 173: * -- LAPACK computational routine (version 3.4.0) --
1.1 bertrand 174: * -- LAPACK is a software package provided by Univ. of Tennessee, --
175: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
1.9 bertrand 176: * November 2011
1.1 bertrand 177: *
178: * .. Scalar Arguments ..
179: CHARACTER SIDE, TRANS
180: INTEGER INFO, K, LDA, LDC, LWORK, M, N
181: * ..
182: * .. Array Arguments ..
183: DOUBLE PRECISION A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
184: * ..
185: *
186: * =====================================================================
187: *
188: * .. Parameters ..
189: INTEGER NBMAX, LDT
190: PARAMETER ( NBMAX = 64, LDT = NBMAX+1 )
191: * ..
192: * .. Local Scalars ..
193: LOGICAL LEFT, LQUERY, NOTRAN
194: INTEGER I, I1, I2, I3, IB, IINFO, IWS, LDWORK, LWKOPT,
195: $ MI, NB, NBMIN, NI, NQ, NW
196: * ..
197: * .. Local Arrays ..
198: DOUBLE PRECISION T( LDT, NBMAX )
199: * ..
200: * .. External Functions ..
201: LOGICAL LSAME
202: INTEGER ILAENV
203: EXTERNAL LSAME, ILAENV
204: * ..
205: * .. External Subroutines ..
206: EXTERNAL DLARFB, DLARFT, DORM2L, XERBLA
207: * ..
208: * .. Intrinsic Functions ..
209: INTRINSIC MAX, MIN
210: * ..
211: * .. Executable Statements ..
212: *
213: * Test the input arguments
214: *
215: INFO = 0
216: LEFT = LSAME( SIDE, 'L' )
217: NOTRAN = LSAME( TRANS, 'N' )
218: LQUERY = ( LWORK.EQ.-1 )
219: *
220: * NQ is the order of Q and NW is the minimum dimension of WORK
221: *
222: IF( LEFT ) THEN
223: NQ = M
224: NW = MAX( 1, N )
225: ELSE
226: NQ = N
227: NW = MAX( 1, M )
228: END IF
229: IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
230: INFO = -1
231: ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) ) THEN
232: INFO = -2
233: ELSE IF( M.LT.0 ) THEN
234: INFO = -3
235: ELSE IF( N.LT.0 ) THEN
236: INFO = -4
237: ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
238: INFO = -5
239: ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
240: INFO = -7
241: ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
242: INFO = -10
243: END IF
244: *
245: IF( INFO.EQ.0 ) THEN
246: IF( M.EQ.0 .OR. N.EQ.0 ) THEN
247: LWKOPT = 1
248: ELSE
249: *
250: * Determine the block size. NB may be at most NBMAX, where
251: * NBMAX is used to define the local array T.
252: *
253: NB = MIN( NBMAX, ILAENV( 1, 'DORMQL', SIDE // TRANS, M, N,
254: $ K, -1 ) )
255: LWKOPT = NW*NB
256: END IF
257: WORK( 1 ) = LWKOPT
258: *
259: IF( LWORK.LT.NW .AND. .NOT.LQUERY ) THEN
260: INFO = -12
261: END IF
262: END IF
263: *
264: IF( INFO.NE.0 ) THEN
265: CALL XERBLA( 'DORMQL', -INFO )
266: RETURN
267: ELSE IF( LQUERY ) THEN
268: RETURN
269: END IF
270: *
271: * Quick return if possible
272: *
273: IF( M.EQ.0 .OR. N.EQ.0 ) THEN
274: RETURN
275: END IF
276: *
277: NBMIN = 2
278: LDWORK = NW
279: IF( NB.GT.1 .AND. NB.LT.K ) THEN
280: IWS = NW*NB
281: IF( LWORK.LT.IWS ) THEN
282: NB = LWORK / LDWORK
283: NBMIN = MAX( 2, ILAENV( 2, 'DORMQL', SIDE // TRANS, M, N, K,
284: $ -1 ) )
285: END IF
286: ELSE
287: IWS = NW
288: END IF
289: *
290: IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
291: *
292: * Use unblocked code
293: *
294: CALL DORM2L( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
295: $ IINFO )
296: ELSE
297: *
298: * Use blocked code
299: *
300: IF( ( LEFT .AND. NOTRAN ) .OR.
301: $ ( .NOT.LEFT .AND. .NOT.NOTRAN ) ) THEN
302: I1 = 1
303: I2 = K
304: I3 = NB
305: ELSE
306: I1 = ( ( K-1 ) / NB )*NB + 1
307: I2 = 1
308: I3 = -NB
309: END IF
310: *
311: IF( LEFT ) THEN
312: NI = N
313: ELSE
314: MI = M
315: END IF
316: *
317: DO 10 I = I1, I2, I3
318: IB = MIN( NB, K-I+1 )
319: *
320: * Form the triangular factor of the block reflector
321: * H = H(i+ib-1) . . . H(i+1) H(i)
322: *
323: CALL DLARFT( 'Backward', 'Columnwise', NQ-K+I+IB-1, IB,
324: $ A( 1, I ), LDA, TAU( I ), T, LDT )
325: IF( LEFT ) THEN
326: *
1.8 bertrand 327: * H or H**T is applied to C(1:m-k+i+ib-1,1:n)
1.1 bertrand 328: *
329: MI = M - K + I + IB - 1
330: ELSE
331: *
1.8 bertrand 332: * H or H**T is applied to C(1:m,1:n-k+i+ib-1)
1.1 bertrand 333: *
334: NI = N - K + I + IB - 1
335: END IF
336: *
1.8 bertrand 337: * Apply H or H**T
1.1 bertrand 338: *
339: CALL DLARFB( SIDE, TRANS, 'Backward', 'Columnwise', MI, NI,
340: $ IB, A( 1, I ), LDA, T, LDT, C, LDC, WORK,
341: $ LDWORK )
342: 10 CONTINUE
343: END IF
344: WORK( 1 ) = LWKOPT
345: RETURN
346: *
347: * End of DORMQL
348: *
349: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dormql.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack