Annotation of rpl/lapack/lapack/dormql.f, revision 1.1
1.1 ! bertrand 1: SUBROUTINE DORMQL( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
! 2: $ WORK, LWORK, INFO )
! 3: *
! 4: * -- LAPACK routine (version 3.2) --
! 5: * -- LAPACK is a software package provided by Univ. of Tennessee, --
! 6: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
! 7: * November 2006
! 8: *
! 9: * .. Scalar Arguments ..
! 10: CHARACTER SIDE, TRANS
! 11: INTEGER INFO, K, LDA, LDC, LWORK, M, N
! 12: * ..
! 13: * .. Array Arguments ..
! 14: DOUBLE PRECISION A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
! 15: * ..
! 16: *
! 17: * Purpose
! 18: * =======
! 19: *
! 20: * DORMQL overwrites the general real M-by-N matrix C with
! 21: *
! 22: * SIDE = 'L' SIDE = 'R'
! 23: * TRANS = 'N': Q * C C * Q
! 24: * TRANS = 'T': Q**T * C C * Q**T
! 25: *
! 26: * where Q is a real orthogonal matrix defined as the product of k
! 27: * elementary reflectors
! 28: *
! 29: * Q = H(k) . . . H(2) H(1)
! 30: *
! 31: * as returned by DGEQLF. Q is of order M if SIDE = 'L' and of order N
! 32: * if SIDE = 'R'.
! 33: *
! 34: * Arguments
! 35: * =========
! 36: *
! 37: * SIDE (input) CHARACTER*1
! 38: * = 'L': apply Q or Q**T from the Left;
! 39: * = 'R': apply Q or Q**T from the Right.
! 40: *
! 41: * TRANS (input) CHARACTER*1
! 42: * = 'N': No transpose, apply Q;
! 43: * = 'T': Transpose, apply Q**T.
! 44: *
! 45: * M (input) INTEGER
! 46: * The number of rows of the matrix C. M >= 0.
! 47: *
! 48: * N (input) INTEGER
! 49: * The number of columns of the matrix C. N >= 0.
! 50: *
! 51: * K (input) INTEGER
! 52: * The number of elementary reflectors whose product defines
! 53: * the matrix Q.
! 54: * If SIDE = 'L', M >= K >= 0;
! 55: * if SIDE = 'R', N >= K >= 0.
! 56: *
! 57: * A (input) DOUBLE PRECISION array, dimension (LDA,K)
! 58: * The i-th column must contain the vector which defines the
! 59: * elementary reflector H(i), for i = 1,2,...,k, as returned by
! 60: * DGEQLF in the last k columns of its array argument A.
! 61: * A is modified by the routine but restored on exit.
! 62: *
! 63: * LDA (input) INTEGER
! 64: * The leading dimension of the array A.
! 65: * If SIDE = 'L', LDA >= max(1,M);
! 66: * if SIDE = 'R', LDA >= max(1,N).
! 67: *
! 68: * TAU (input) DOUBLE PRECISION array, dimension (K)
! 69: * TAU(i) must contain the scalar factor of the elementary
! 70: * reflector H(i), as returned by DGEQLF.
! 71: *
! 72: * C (input/output) DOUBLE PRECISION array, dimension (LDC,N)
! 73: * On entry, the M-by-N matrix C.
! 74: * On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
! 75: *
! 76: * LDC (input) INTEGER
! 77: * The leading dimension of the array C. LDC >= max(1,M).
! 78: *
! 79: * WORK (workspace/output) DOUBLE PRECISION array, dimension (MAX(1,LWORK))
! 80: * On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
! 81: *
! 82: * LWORK (input) INTEGER
! 83: * The dimension of the array WORK.
! 84: * If SIDE = 'L', LWORK >= max(1,N);
! 85: * if SIDE = 'R', LWORK >= max(1,M).
! 86: * For optimum performance LWORK >= N*NB if SIDE = 'L', and
! 87: * LWORK >= M*NB if SIDE = 'R', where NB is the optimal
! 88: * blocksize.
! 89: *
! 90: * If LWORK = -1, then a workspace query is assumed; the routine
! 91: * only calculates the optimal size of the WORK array, returns
! 92: * this value as the first entry of the WORK array, and no error
! 93: * message related to LWORK is issued by XERBLA.
! 94: *
! 95: * INFO (output) INTEGER
! 96: * = 0: successful exit
! 97: * < 0: if INFO = -i, the i-th argument had an illegal value
! 98: *
! 99: * =====================================================================
! 100: *
! 101: * .. Parameters ..
! 102: INTEGER NBMAX, LDT
! 103: PARAMETER ( NBMAX = 64, LDT = NBMAX+1 )
! 104: * ..
! 105: * .. Local Scalars ..
! 106: LOGICAL LEFT, LQUERY, NOTRAN
! 107: INTEGER I, I1, I2, I3, IB, IINFO, IWS, LDWORK, LWKOPT,
! 108: $ MI, NB, NBMIN, NI, NQ, NW
! 109: * ..
! 110: * .. Local Arrays ..
! 111: DOUBLE PRECISION T( LDT, NBMAX )
! 112: * ..
! 113: * .. External Functions ..
! 114: LOGICAL LSAME
! 115: INTEGER ILAENV
! 116: EXTERNAL LSAME, ILAENV
! 117: * ..
! 118: * .. External Subroutines ..
! 119: EXTERNAL DLARFB, DLARFT, DORM2L, XERBLA
! 120: * ..
! 121: * .. Intrinsic Functions ..
! 122: INTRINSIC MAX, MIN
! 123: * ..
! 124: * .. Executable Statements ..
! 125: *
! 126: * Test the input arguments
! 127: *
! 128: INFO = 0
! 129: LEFT = LSAME( SIDE, 'L' )
! 130: NOTRAN = LSAME( TRANS, 'N' )
! 131: LQUERY = ( LWORK.EQ.-1 )
! 132: *
! 133: * NQ is the order of Q and NW is the minimum dimension of WORK
! 134: *
! 135: IF( LEFT ) THEN
! 136: NQ = M
! 137: NW = MAX( 1, N )
! 138: ELSE
! 139: NQ = N
! 140: NW = MAX( 1, M )
! 141: END IF
! 142: IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
! 143: INFO = -1
! 144: ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) ) THEN
! 145: INFO = -2
! 146: ELSE IF( M.LT.0 ) THEN
! 147: INFO = -3
! 148: ELSE IF( N.LT.0 ) THEN
! 149: INFO = -4
! 150: ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
! 151: INFO = -5
! 152: ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
! 153: INFO = -7
! 154: ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
! 155: INFO = -10
! 156: END IF
! 157: *
! 158: IF( INFO.EQ.0 ) THEN
! 159: IF( M.EQ.0 .OR. N.EQ.0 ) THEN
! 160: LWKOPT = 1
! 161: ELSE
! 162: *
! 163: * Determine the block size. NB may be at most NBMAX, where
! 164: * NBMAX is used to define the local array T.
! 165: *
! 166: NB = MIN( NBMAX, ILAENV( 1, 'DORMQL', SIDE // TRANS, M, N,
! 167: $ K, -1 ) )
! 168: LWKOPT = NW*NB
! 169: END IF
! 170: WORK( 1 ) = LWKOPT
! 171: *
! 172: IF( LWORK.LT.NW .AND. .NOT.LQUERY ) THEN
! 173: INFO = -12
! 174: END IF
! 175: END IF
! 176: *
! 177: IF( INFO.NE.0 ) THEN
! 178: CALL XERBLA( 'DORMQL', -INFO )
! 179: RETURN
! 180: ELSE IF( LQUERY ) THEN
! 181: RETURN
! 182: END IF
! 183: *
! 184: * Quick return if possible
! 185: *
! 186: IF( M.EQ.0 .OR. N.EQ.0 ) THEN
! 187: RETURN
! 188: END IF
! 189: *
! 190: NBMIN = 2
! 191: LDWORK = NW
! 192: IF( NB.GT.1 .AND. NB.LT.K ) THEN
! 193: IWS = NW*NB
! 194: IF( LWORK.LT.IWS ) THEN
! 195: NB = LWORK / LDWORK
! 196: NBMIN = MAX( 2, ILAENV( 2, 'DORMQL', SIDE // TRANS, M, N, K,
! 197: $ -1 ) )
! 198: END IF
! 199: ELSE
! 200: IWS = NW
! 201: END IF
! 202: *
! 203: IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
! 204: *
! 205: * Use unblocked code
! 206: *
! 207: CALL DORM2L( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
! 208: $ IINFO )
! 209: ELSE
! 210: *
! 211: * Use blocked code
! 212: *
! 213: IF( ( LEFT .AND. NOTRAN ) .OR.
! 214: $ ( .NOT.LEFT .AND. .NOT.NOTRAN ) ) THEN
! 215: I1 = 1
! 216: I2 = K
! 217: I3 = NB
! 218: ELSE
! 219: I1 = ( ( K-1 ) / NB )*NB + 1
! 220: I2 = 1
! 221: I3 = -NB
! 222: END IF
! 223: *
! 224: IF( LEFT ) THEN
! 225: NI = N
! 226: ELSE
! 227: MI = M
! 228: END IF
! 229: *
! 230: DO 10 I = I1, I2, I3
! 231: IB = MIN( NB, K-I+1 )
! 232: *
! 233: * Form the triangular factor of the block reflector
! 234: * H = H(i+ib-1) . . . H(i+1) H(i)
! 235: *
! 236: CALL DLARFT( 'Backward', 'Columnwise', NQ-K+I+IB-1, IB,
! 237: $ A( 1, I ), LDA, TAU( I ), T, LDT )
! 238: IF( LEFT ) THEN
! 239: *
! 240: * H or H' is applied to C(1:m-k+i+ib-1,1:n)
! 241: *
! 242: MI = M - K + I + IB - 1
! 243: ELSE
! 244: *
! 245: * H or H' is applied to C(1:m,1:n-k+i+ib-1)
! 246: *
! 247: NI = N - K + I + IB - 1
! 248: END IF
! 249: *
! 250: * Apply H or H'
! 251: *
! 252: CALL DLARFB( SIDE, TRANS, 'Backward', 'Columnwise', MI, NI,
! 253: $ IB, A( 1, I ), LDA, T, LDT, C, LDC, WORK,
! 254: $ LDWORK )
! 255: 10 CONTINUE
! 256: END IF
! 257: WORK( 1 ) = LWKOPT
! 258: RETURN
! 259: *
! 260: * End of DORMQL
! 261: *
! 262: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dormql.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack