1: *> \brief \b DORGR2 generates all or part of the orthogonal matrix Q from an RQ factorization determined by sgerqf (unblocked algorithm).
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DORGR2 + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dorgr2.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dorgr2.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dorgr2.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DORGR2( M, N, K, A, LDA, TAU, WORK, INFO )
22: *
23: * .. Scalar Arguments ..
24: * INTEGER INFO, K, LDA, M, N
25: * ..
26: * .. Array Arguments ..
27: * DOUBLE PRECISION A( LDA, * ), TAU( * ), WORK( * )
28: * ..
29: *
30: *
31: *> \par Purpose:
32: * =============
33: *>
34: *> \verbatim
35: *>
36: *> DORGR2 generates an m by n real matrix Q with orthonormal rows,
37: *> which is defined as the last m rows of a product of k elementary
38: *> reflectors of order n
39: *>
40: *> Q = H(1) H(2) . . . H(k)
41: *>
42: *> as returned by DGERQF.
43: *> \endverbatim
44: *
45: * Arguments:
46: * ==========
47: *
48: *> \param[in] M
49: *> \verbatim
50: *> M is INTEGER
51: *> The number of rows of the matrix Q. M >= 0.
52: *> \endverbatim
53: *>
54: *> \param[in] N
55: *> \verbatim
56: *> N is INTEGER
57: *> The number of columns of the matrix Q. N >= M.
58: *> \endverbatim
59: *>
60: *> \param[in] K
61: *> \verbatim
62: *> K is INTEGER
63: *> The number of elementary reflectors whose product defines the
64: *> matrix Q. M >= K >= 0.
65: *> \endverbatim
66: *>
67: *> \param[in,out] A
68: *> \verbatim
69: *> A is DOUBLE PRECISION array, dimension (LDA,N)
70: *> On entry, the (m-k+i)-th row must contain the vector which
71: *> defines the elementary reflector H(i), for i = 1,2,...,k, as
72: *> returned by DGERQF in the last k rows of its array argument
73: *> A.
74: *> On exit, the m by n matrix Q.
75: *> \endverbatim
76: *>
77: *> \param[in] LDA
78: *> \verbatim
79: *> LDA is INTEGER
80: *> The first dimension of the array A. LDA >= max(1,M).
81: *> \endverbatim
82: *>
83: *> \param[in] TAU
84: *> \verbatim
85: *> TAU is DOUBLE PRECISION array, dimension (K)
86: *> TAU(i) must contain the scalar factor of the elementary
87: *> reflector H(i), as returned by DGERQF.
88: *> \endverbatim
89: *>
90: *> \param[out] WORK
91: *> \verbatim
92: *> WORK is DOUBLE PRECISION array, dimension (M)
93: *> \endverbatim
94: *>
95: *> \param[out] INFO
96: *> \verbatim
97: *> INFO is INTEGER
98: *> = 0: successful exit
99: *> < 0: if INFO = -i, the i-th argument has an illegal value
100: *> \endverbatim
101: *
102: * Authors:
103: * ========
104: *
105: *> \author Univ. of Tennessee
106: *> \author Univ. of California Berkeley
107: *> \author Univ. of Colorado Denver
108: *> \author NAG Ltd.
109: *
110: *> \ingroup doubleOTHERcomputational
111: *
112: * =====================================================================
113: SUBROUTINE DORGR2( M, N, K, A, LDA, TAU, WORK, INFO )
114: *
115: * -- LAPACK computational routine --
116: * -- LAPACK is a software package provided by Univ. of Tennessee, --
117: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
118: *
119: * .. Scalar Arguments ..
120: INTEGER INFO, K, LDA, M, N
121: * ..
122: * .. Array Arguments ..
123: DOUBLE PRECISION A( LDA, * ), TAU( * ), WORK( * )
124: * ..
125: *
126: * =====================================================================
127: *
128: * .. Parameters ..
129: DOUBLE PRECISION ONE, ZERO
130: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
131: * ..
132: * .. Local Scalars ..
133: INTEGER I, II, J, L
134: * ..
135: * .. External Subroutines ..
136: EXTERNAL DLARF, DSCAL, XERBLA
137: * ..
138: * .. Intrinsic Functions ..
139: INTRINSIC MAX
140: * ..
141: * .. Executable Statements ..
142: *
143: * Test the input arguments
144: *
145: INFO = 0
146: IF( M.LT.0 ) THEN
147: INFO = -1
148: ELSE IF( N.LT.M ) THEN
149: INFO = -2
150: ELSE IF( K.LT.0 .OR. K.GT.M ) THEN
151: INFO = -3
152: ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
153: INFO = -5
154: END IF
155: IF( INFO.NE.0 ) THEN
156: CALL XERBLA( 'DORGR2', -INFO )
157: RETURN
158: END IF
159: *
160: * Quick return if possible
161: *
162: IF( M.LE.0 )
163: $ RETURN
164: *
165: IF( K.LT.M ) THEN
166: *
167: * Initialise rows 1:m-k to rows of the unit matrix
168: *
169: DO 20 J = 1, N
170: DO 10 L = 1, M - K
171: A( L, J ) = ZERO
172: 10 CONTINUE
173: IF( J.GT.N-M .AND. J.LE.N-K )
174: $ A( M-N+J, J ) = ONE
175: 20 CONTINUE
176: END IF
177: *
178: DO 40 I = 1, K
179: II = M - K + I
180: *
181: * Apply H(i) to A(1:m-k+i,1:n-k+i) from the right
182: *
183: A( II, N-M+II ) = ONE
184: CALL DLARF( 'Right', II-1, N-M+II, A( II, 1 ), LDA, TAU( I ),
185: $ A, LDA, WORK )
186: CALL DSCAL( N-M+II-1, -TAU( I ), A( II, 1 ), LDA )
187: A( II, N-M+II ) = ONE - TAU( I )
188: *
189: * Set A(m-k+i,n-k+i+1:n) to zero
190: *
191: DO 30 L = N - M + II + 1, N
192: A( II, L ) = ZERO
193: 30 CONTINUE
194: 40 CONTINUE
195: RETURN
196: *
197: * End of DORGR2
198: *
199: END
CVSweb interface <joel.bertrand@systella.fr>