1: *> \brief \b DORGQR
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DORGQR + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dorgqr.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dorgqr.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dorgqr.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DORGQR( M, N, K, A, LDA, TAU, WORK, LWORK, INFO )
22: *
23: * .. Scalar Arguments ..
24: * INTEGER INFO, K, LDA, LWORK, M, N
25: * ..
26: * .. Array Arguments ..
27: * DOUBLE PRECISION A( LDA, * ), TAU( * ), WORK( * )
28: * ..
29: *
30: *
31: *> \par Purpose:
32: * =============
33: *>
34: *> \verbatim
35: *>
36: *> DORGQR generates an M-by-N real matrix Q with orthonormal columns,
37: *> which is defined as the first N columns of a product of K elementary
38: *> reflectors of order M
39: *>
40: *> Q = H(1) H(2) . . . H(k)
41: *>
42: *> as returned by DGEQRF.
43: *> \endverbatim
44: *
45: * Arguments:
46: * ==========
47: *
48: *> \param[in] M
49: *> \verbatim
50: *> M is INTEGER
51: *> The number of rows of the matrix Q. M >= 0.
52: *> \endverbatim
53: *>
54: *> \param[in] N
55: *> \verbatim
56: *> N is INTEGER
57: *> The number of columns of the matrix Q. M >= N >= 0.
58: *> \endverbatim
59: *>
60: *> \param[in] K
61: *> \verbatim
62: *> K is INTEGER
63: *> The number of elementary reflectors whose product defines the
64: *> matrix Q. N >= K >= 0.
65: *> \endverbatim
66: *>
67: *> \param[in,out] A
68: *> \verbatim
69: *> A is DOUBLE PRECISION array, dimension (LDA,N)
70: *> On entry, the i-th column must contain the vector which
71: *> defines the elementary reflector H(i), for i = 1,2,...,k, as
72: *> returned by DGEQRF in the first k columns of its array
73: *> argument A.
74: *> On exit, the M-by-N matrix Q.
75: *> \endverbatim
76: *>
77: *> \param[in] LDA
78: *> \verbatim
79: *> LDA is INTEGER
80: *> The first dimension of the array A. LDA >= max(1,M).
81: *> \endverbatim
82: *>
83: *> \param[in] TAU
84: *> \verbatim
85: *> TAU is DOUBLE PRECISION array, dimension (K)
86: *> TAU(i) must contain the scalar factor of the elementary
87: *> reflector H(i), as returned by DGEQRF.
88: *> \endverbatim
89: *>
90: *> \param[out] WORK
91: *> \verbatim
92: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK))
93: *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
94: *> \endverbatim
95: *>
96: *> \param[in] LWORK
97: *> \verbatim
98: *> LWORK is INTEGER
99: *> The dimension of the array WORK. LWORK >= max(1,N).
100: *> For optimum performance LWORK >= N*NB, where NB is the
101: *> optimal blocksize.
102: *>
103: *> If LWORK = -1, then a workspace query is assumed; the routine
104: *> only calculates the optimal size of the WORK array, returns
105: *> this value as the first entry of the WORK array, and no error
106: *> message related to LWORK is issued by XERBLA.
107: *> \endverbatim
108: *>
109: *> \param[out] INFO
110: *> \verbatim
111: *> INFO is INTEGER
112: *> = 0: successful exit
113: *> < 0: if INFO = -i, the i-th argument has an illegal value
114: *> \endverbatim
115: *
116: * Authors:
117: * ========
118: *
119: *> \author Univ. of Tennessee
120: *> \author Univ. of California Berkeley
121: *> \author Univ. of Colorado Denver
122: *> \author NAG Ltd.
123: *
124: *> \ingroup doubleOTHERcomputational
125: *
126: * =====================================================================
127: SUBROUTINE DORGQR( M, N, K, A, LDA, TAU, WORK, LWORK, INFO )
128: *
129: * -- LAPACK computational routine --
130: * -- LAPACK is a software package provided by Univ. of Tennessee, --
131: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
132: *
133: * .. Scalar Arguments ..
134: INTEGER INFO, K, LDA, LWORK, M, N
135: * ..
136: * .. Array Arguments ..
137: DOUBLE PRECISION A( LDA, * ), TAU( * ), WORK( * )
138: * ..
139: *
140: * =====================================================================
141: *
142: * .. Parameters ..
143: DOUBLE PRECISION ZERO
144: PARAMETER ( ZERO = 0.0D+0 )
145: * ..
146: * .. Local Scalars ..
147: LOGICAL LQUERY
148: INTEGER I, IB, IINFO, IWS, J, KI, KK, L, LDWORK,
149: $ LWKOPT, NB, NBMIN, NX
150: * ..
151: * .. External Subroutines ..
152: EXTERNAL DLARFB, DLARFT, DORG2R, XERBLA
153: * ..
154: * .. Intrinsic Functions ..
155: INTRINSIC MAX, MIN
156: * ..
157: * .. External Functions ..
158: INTEGER ILAENV
159: EXTERNAL ILAENV
160: * ..
161: * .. Executable Statements ..
162: *
163: * Test the input arguments
164: *
165: INFO = 0
166: NB = ILAENV( 1, 'DORGQR', ' ', M, N, K, -1 )
167: LWKOPT = MAX( 1, N )*NB
168: WORK( 1 ) = LWKOPT
169: LQUERY = ( LWORK.EQ.-1 )
170: IF( M.LT.0 ) THEN
171: INFO = -1
172: ELSE IF( N.LT.0 .OR. N.GT.M ) THEN
173: INFO = -2
174: ELSE IF( K.LT.0 .OR. K.GT.N ) THEN
175: INFO = -3
176: ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
177: INFO = -5
178: ELSE IF( LWORK.LT.MAX( 1, N ) .AND. .NOT.LQUERY ) THEN
179: INFO = -8
180: END IF
181: IF( INFO.NE.0 ) THEN
182: CALL XERBLA( 'DORGQR', -INFO )
183: RETURN
184: ELSE IF( LQUERY ) THEN
185: RETURN
186: END IF
187: *
188: * Quick return if possible
189: *
190: IF( N.LE.0 ) THEN
191: WORK( 1 ) = 1
192: RETURN
193: END IF
194: *
195: NBMIN = 2
196: NX = 0
197: IWS = N
198: IF( NB.GT.1 .AND. NB.LT.K ) THEN
199: *
200: * Determine when to cross over from blocked to unblocked code.
201: *
202: NX = MAX( 0, ILAENV( 3, 'DORGQR', ' ', M, N, K, -1 ) )
203: IF( NX.LT.K ) THEN
204: *
205: * Determine if workspace is large enough for blocked code.
206: *
207: LDWORK = N
208: IWS = LDWORK*NB
209: IF( LWORK.LT.IWS ) THEN
210: *
211: * Not enough workspace to use optimal NB: reduce NB and
212: * determine the minimum value of NB.
213: *
214: NB = LWORK / LDWORK
215: NBMIN = MAX( 2, ILAENV( 2, 'DORGQR', ' ', M, N, K, -1 ) )
216: END IF
217: END IF
218: END IF
219: *
220: IF( NB.GE.NBMIN .AND. NB.LT.K .AND. NX.LT.K ) THEN
221: *
222: * Use blocked code after the last block.
223: * The first kk columns are handled by the block method.
224: *
225: KI = ( ( K-NX-1 ) / NB )*NB
226: KK = MIN( K, KI+NB )
227: *
228: * Set A(1:kk,kk+1:n) to zero.
229: *
230: DO 20 J = KK + 1, N
231: DO 10 I = 1, KK
232: A( I, J ) = ZERO
233: 10 CONTINUE
234: 20 CONTINUE
235: ELSE
236: KK = 0
237: END IF
238: *
239: * Use unblocked code for the last or only block.
240: *
241: IF( KK.LT.N )
242: $ CALL DORG2R( M-KK, N-KK, K-KK, A( KK+1, KK+1 ), LDA,
243: $ TAU( KK+1 ), WORK, IINFO )
244: *
245: IF( KK.GT.0 ) THEN
246: *
247: * Use blocked code
248: *
249: DO 50 I = KI + 1, 1, -NB
250: IB = MIN( NB, K-I+1 )
251: IF( I+IB.LE.N ) THEN
252: *
253: * Form the triangular factor of the block reflector
254: * H = H(i) H(i+1) . . . H(i+ib-1)
255: *
256: CALL DLARFT( 'Forward', 'Columnwise', M-I+1, IB,
257: $ A( I, I ), LDA, TAU( I ), WORK, LDWORK )
258: *
259: * Apply H to A(i:m,i+ib:n) from the left
260: *
261: CALL DLARFB( 'Left', 'No transpose', 'Forward',
262: $ 'Columnwise', M-I+1, N-I-IB+1, IB,
263: $ A( I, I ), LDA, WORK, LDWORK, A( I, I+IB ),
264: $ LDA, WORK( IB+1 ), LDWORK )
265: END IF
266: *
267: * Apply H to rows i:m of current block
268: *
269: CALL DORG2R( M-I+1, IB, IB, A( I, I ), LDA, TAU( I ), WORK,
270: $ IINFO )
271: *
272: * Set rows 1:i-1 of current block to zero
273: *
274: DO 40 J = I, I + IB - 1
275: DO 30 L = 1, I - 1
276: A( L, J ) = ZERO
277: 30 CONTINUE
278: 40 CONTINUE
279: 50 CONTINUE
280: END IF
281: *
282: WORK( 1 ) = IWS
283: RETURN
284: *
285: * End of DORGQR
286: *
287: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dorgqr.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack