Return to dorgl2.f CVS log

Up to [local] / rpl / lapack / lapack

Première mise à jour de lapack et blas.

    1: *> \brief \b DORGL2
    2: *
    3: *  =========== DOCUMENTATION ===========
    4: *
    5: * Online html documentation available at
    6: *            http://www.netlib.org/lapack/explore-html/
    7: *
    8: *> \htmlonly
    9: *> Download DORGL2 + dependencies
   10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dorgl2.f">
   11: *> [TGZ]</a>
   12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dorgl2.f">
   13: *> [ZIP]</a>
   14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dorgl2.f">
   15: *> [TXT]</a>
   16: *> \endhtmlonly
   17: *
   18: *  Definition:
   19: *  ===========
   20: *
   21: *       SUBROUTINE DORGL2( M, N, K, A, LDA, TAU, WORK, INFO )
   22: *
   23: *       .. Scalar Arguments ..
   24: *       INTEGER            INFO, K, LDA, M, N
   25: *       ..
   26: *       .. Array Arguments ..
   27: *       DOUBLE PRECISION   A( LDA, * ), TAU( * ), WORK( * )
   28: *       ..
   29: *
   30: *
   31: *> \par Purpose:
   32: *  =============
   33: *>
   34: *> \verbatim
   35: *>
   36: *> DORGL2 generates an m by n real matrix Q with orthonormal rows,
   37: *> which is defined as the first m rows of a product of k elementary
   38: *> reflectors of order n
   39: *>
   40: *>       Q  =  H(k) . . . H(2) H(1)
   41: *>
   42: *> as returned by DGELQF.
   43: *> \endverbatim
   44: *
   45: *  Arguments:
   46: *  ==========
   47: *
   48: *> \param[in] M
   49: *> \verbatim
   50: *>          M is INTEGER
   51: *>          The number of rows of the matrix Q. M >= 0.
   52: *> \endverbatim
   53: *>
   54: *> \param[in] N
   55: *> \verbatim
   56: *>          N is INTEGER
   57: *>          The number of columns of the matrix Q. N >= M.
   58: *> \endverbatim
   59: *>
   60: *> \param[in] K
   61: *> \verbatim
   62: *>          K is INTEGER
   63: *>          The number of elementary reflectors whose product defines the
   64: *>          matrix Q. M >= K >= 0.
   65: *> \endverbatim
   66: *>
   67: *> \param[in,out] A
   68: *> \verbatim
   69: *>          A is DOUBLE PRECISION array, dimension (LDA,N)
   70: *>          On entry, the i-th row must contain the vector which defines
   71: *>          the elementary reflector H(i), for i = 1,2,...,k, as returned
   72: *>          by DGELQF in the first k rows of its array argument A.
   73: *>          On exit, the m-by-n matrix Q.
   74: *> \endverbatim
   75: *>
   76: *> \param[in] LDA
   77: *> \verbatim
   78: *>          LDA is INTEGER
   79: *>          The first dimension of the array A. LDA >= max(1,M).
   80: *> \endverbatim
   81: *>
   82: *> \param[in] TAU
   83: *> \verbatim
   84: *>          TAU is DOUBLE PRECISION array, dimension (K)
   85: *>          TAU(i) must contain the scalar factor of the elementary
   86: *>          reflector H(i), as returned by DGELQF.
   87: *> \endverbatim
   88: *>
   89: *> \param[out] WORK
   90: *> \verbatim
   91: *>          WORK is DOUBLE PRECISION array, dimension (M)
   92: *> \endverbatim
   93: *>
   94: *> \param[out] INFO
   95: *> \verbatim
   96: *>          INFO is INTEGER
   97: *>          = 0: successful exit
   98: *>          < 0: if INFO = -i, the i-th argument has an illegal value
   99: *> \endverbatim
  100: *
  101: *  Authors:
  102: *  ========
  103: *
  104: *> \author Univ. of Tennessee
  105: *> \author Univ. of California Berkeley
  106: *> \author Univ. of Colorado Denver
  107: *> \author NAG Ltd.
  108: *
  109: *> \ingroup doubleOTHERcomputational
  110: *
  111: *  =====================================================================
  112:       SUBROUTINE DORGL2( M, N, K, A, LDA, TAU, WORK, INFO )
  113: *
  114: *  -- LAPACK computational routine --
  115: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
  116: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
  117: *
  118: *     .. Scalar Arguments ..
  119:       INTEGER            INFO, K, LDA, M, N
  120: *     ..
  121: *     .. Array Arguments ..
  122:       DOUBLE PRECISION   A( LDA, * ), TAU( * ), WORK( * )
  123: *     ..
  124: *
  125: *  =====================================================================
  126: *
  127: *     .. Parameters ..
  128:       DOUBLE PRECISION   ONE, ZERO
  129:       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
  130: *     ..
  131: *     .. Local Scalars ..
  132:       INTEGER            I, J, L
  133: *     ..
  134: *     .. External Subroutines ..
  135:       EXTERNAL           DLARF, DSCAL, XERBLA
  136: *     ..
  137: *     .. Intrinsic Functions ..
  138:       INTRINSIC          MAX
  139: *     ..
  140: *     .. Executable Statements ..
  141: *
  142: *     Test the input arguments
  143: *
  144:       INFO = 0
  145:       IF( M.LT.0 ) THEN
  146:          INFO = -1
  147:       ELSE IF( N.LT.M ) THEN
  148:          INFO = -2
  149:       ELSE IF( K.LT.0 .OR. K.GT.M ) THEN
  150:          INFO = -3
  151:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
  152:          INFO = -5
  153:       END IF
  154:       IF( INFO.NE.0 ) THEN
  155:          CALL XERBLA( 'DORGL2', -INFO )
  156:          RETURN
  157:       END IF
  158: *
  159: *     Quick return if possible
  160: *
  161:       IF( M.LE.0 )
  162:      $   RETURN
  163: *
  164:       IF( K.LT.M ) THEN
  165: *
  166: *        Initialise rows k+1:m to rows of the unit matrix
  167: *
  168:          DO 20 J = 1, N
  169:             DO 10 L = K + 1, M
  170:                A( L, J ) = ZERO
  171:    10       CONTINUE
  172:             IF( J.GT.K .AND. J.LE.M )
  173:      $         A( J, J ) = ONE
  174:    20    CONTINUE
  175:       END IF
  176: *
  177:       DO 40 I = K, 1, -1
  178: *
  179: *        Apply H(i) to A(i:m,i:n) from the right
  180: *
  181:          IF( I.LT.N ) THEN
  182:             IF( I.LT.M ) THEN
  183:                A( I, I ) = ONE
  184:                CALL DLARF( 'Right', M-I, N-I+1, A( I, I ), LDA,
  185:      $                     TAU( I ), A( I+1, I ), LDA, WORK )
  186:             END IF
  187:             CALL DSCAL( N-I, -TAU( I ), A( I, I+1 ), LDA )
  188:          END IF
  189:          A( I, I ) = ONE - TAU( I )
  190: *
  191: *        Set A(i,1:i-1) to zero
  192: *
  193:          DO 30 L = 1, I - 1
  194:             A( I, L ) = ZERO
  195:    30    CONTINUE
  196:    40 CONTINUE
  197:       RETURN
  198: *
  199: *     End of DORGL2
  200: *
  201:       END