Annotation of rpl/lapack/lapack/dorgl2.f, revision 1.8
1.8 ! bertrand 1: *> \brief \b DORGL2
! 2: *
! 3: * =========== DOCUMENTATION ===========
! 4: *
! 5: * Online html documentation available at
! 6: * http://www.netlib.org/lapack/explore-html/
! 7: *
! 8: *> \htmlonly
! 9: *> Download DORGL2 + dependencies
! 10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dorgl2.f">
! 11: *> [TGZ]</a>
! 12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dorgl2.f">
! 13: *> [ZIP]</a>
! 14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dorgl2.f">
! 15: *> [TXT]</a>
! 16: *> \endhtmlonly
! 17: *
! 18: * Definition:
! 19: * ===========
! 20: *
! 21: * SUBROUTINE DORGL2( M, N, K, A, LDA, TAU, WORK, INFO )
! 22: *
! 23: * .. Scalar Arguments ..
! 24: * INTEGER INFO, K, LDA, M, N
! 25: * ..
! 26: * .. Array Arguments ..
! 27: * DOUBLE PRECISION A( LDA, * ), TAU( * ), WORK( * )
! 28: * ..
! 29: *
! 30: *
! 31: *> \par Purpose:
! 32: * =============
! 33: *>
! 34: *> \verbatim
! 35: *>
! 36: *> DORGL2 generates an m by n real matrix Q with orthonormal rows,
! 37: *> which is defined as the first m rows of a product of k elementary
! 38: *> reflectors of order n
! 39: *>
! 40: *> Q = H(k) . . . H(2) H(1)
! 41: *>
! 42: *> as returned by DGELQF.
! 43: *> \endverbatim
! 44: *
! 45: * Arguments:
! 46: * ==========
! 47: *
! 48: *> \param[in] M
! 49: *> \verbatim
! 50: *> M is INTEGER
! 51: *> The number of rows of the matrix Q. M >= 0.
! 52: *> \endverbatim
! 53: *>
! 54: *> \param[in] N
! 55: *> \verbatim
! 56: *> N is INTEGER
! 57: *> The number of columns of the matrix Q. N >= M.
! 58: *> \endverbatim
! 59: *>
! 60: *> \param[in] K
! 61: *> \verbatim
! 62: *> K is INTEGER
! 63: *> The number of elementary reflectors whose product defines the
! 64: *> matrix Q. M >= K >= 0.
! 65: *> \endverbatim
! 66: *>
! 67: *> \param[in,out] A
! 68: *> \verbatim
! 69: *> A is DOUBLE PRECISION array, dimension (LDA,N)
! 70: *> On entry, the i-th row must contain the vector which defines
! 71: *> the elementary reflector H(i), for i = 1,2,...,k, as returned
! 72: *> by DGELQF in the first k rows of its array argument A.
! 73: *> On exit, the m-by-n matrix Q.
! 74: *> \endverbatim
! 75: *>
! 76: *> \param[in] LDA
! 77: *> \verbatim
! 78: *> LDA is INTEGER
! 79: *> The first dimension of the array A. LDA >= max(1,M).
! 80: *> \endverbatim
! 81: *>
! 82: *> \param[in] TAU
! 83: *> \verbatim
! 84: *> TAU is DOUBLE PRECISION array, dimension (K)
! 85: *> TAU(i) must contain the scalar factor of the elementary
! 86: *> reflector H(i), as returned by DGELQF.
! 87: *> \endverbatim
! 88: *>
! 89: *> \param[out] WORK
! 90: *> \verbatim
! 91: *> WORK is DOUBLE PRECISION array, dimension (M)
! 92: *> \endverbatim
! 93: *>
! 94: *> \param[out] INFO
! 95: *> \verbatim
! 96: *> INFO is INTEGER
! 97: *> = 0: successful exit
! 98: *> < 0: if INFO = -i, the i-th argument has an illegal value
! 99: *> \endverbatim
! 100: *
! 101: * Authors:
! 102: * ========
! 103: *
! 104: *> \author Univ. of Tennessee
! 105: *> \author Univ. of California Berkeley
! 106: *> \author Univ. of Colorado Denver
! 107: *> \author NAG Ltd.
! 108: *
! 109: *> \date November 2011
! 110: *
! 111: *> \ingroup doubleOTHERcomputational
! 112: *
! 113: * =====================================================================
1.1 bertrand 114: SUBROUTINE DORGL2( M, N, K, A, LDA, TAU, WORK, INFO )
115: *
1.8 ! bertrand 116: * -- LAPACK computational routine (version 3.4.0) --
1.1 bertrand 117: * -- LAPACK is a software package provided by Univ. of Tennessee, --
118: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
1.8 ! bertrand 119: * November 2011
1.1 bertrand 120: *
121: * .. Scalar Arguments ..
122: INTEGER INFO, K, LDA, M, N
123: * ..
124: * .. Array Arguments ..
125: DOUBLE PRECISION A( LDA, * ), TAU( * ), WORK( * )
126: * ..
127: *
128: * =====================================================================
129: *
130: * .. Parameters ..
131: DOUBLE PRECISION ONE, ZERO
132: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
133: * ..
134: * .. Local Scalars ..
135: INTEGER I, J, L
136: * ..
137: * .. External Subroutines ..
138: EXTERNAL DLARF, DSCAL, XERBLA
139: * ..
140: * .. Intrinsic Functions ..
141: INTRINSIC MAX
142: * ..
143: * .. Executable Statements ..
144: *
145: * Test the input arguments
146: *
147: INFO = 0
148: IF( M.LT.0 ) THEN
149: INFO = -1
150: ELSE IF( N.LT.M ) THEN
151: INFO = -2
152: ELSE IF( K.LT.0 .OR. K.GT.M ) THEN
153: INFO = -3
154: ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
155: INFO = -5
156: END IF
157: IF( INFO.NE.0 ) THEN
158: CALL XERBLA( 'DORGL2', -INFO )
159: RETURN
160: END IF
161: *
162: * Quick return if possible
163: *
164: IF( M.LE.0 )
165: $ RETURN
166: *
167: IF( K.LT.M ) THEN
168: *
169: * Initialise rows k+1:m to rows of the unit matrix
170: *
171: DO 20 J = 1, N
172: DO 10 L = K + 1, M
173: A( L, J ) = ZERO
174: 10 CONTINUE
175: IF( J.GT.K .AND. J.LE.M )
176: $ A( J, J ) = ONE
177: 20 CONTINUE
178: END IF
179: *
180: DO 40 I = K, 1, -1
181: *
182: * Apply H(i) to A(i:m,i:n) from the right
183: *
184: IF( I.LT.N ) THEN
185: IF( I.LT.M ) THEN
186: A( I, I ) = ONE
187: CALL DLARF( 'Right', M-I, N-I+1, A( I, I ), LDA,
188: $ TAU( I ), A( I+1, I ), LDA, WORK )
189: END IF
190: CALL DSCAL( N-I, -TAU( I ), A( I, I+1 ), LDA )
191: END IF
192: A( I, I ) = ONE - TAU( I )
193: *
194: * Set A(i,1:i-1) to zero
195: *
196: DO 30 L = 1, I - 1
197: A( I, L ) = ZERO
198: 30 CONTINUE
199: 40 CONTINUE
200: RETURN
201: *
202: * End of DORGL2
203: *
204: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dorgl2.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack