Return to dorg2l.f CVS log

Up to [local] / rpl / lapack / lapack

Cohérence Lapack.

    1: *> \brief \b DORG2L generates all or part of the orthogonal matrix Q from a QL factorization determined by sgeqlf (unblocked algorithm).
    2: *
    3: *  =========== DOCUMENTATION ===========
    4: *
    5: * Online html documentation available at 
    6: *            http://www.netlib.org/lapack/explore-html/ 
    7: *
    8: *> \htmlonly
    9: *> Download DORG2L + dependencies 
   10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dorg2l.f"> 
   11: *> [TGZ]</a> 
   12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dorg2l.f"> 
   13: *> [ZIP]</a> 
   14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dorg2l.f"> 
   15: *> [TXT]</a>
   16: *> \endhtmlonly 
   17: *
   18: *  Definition:
   19: *  ===========
   20: *
   21: *       SUBROUTINE DORG2L( M, N, K, A, LDA, TAU, WORK, INFO )
   22: * 
   23: *       .. Scalar Arguments ..
   24: *       INTEGER            INFO, K, LDA, M, N
   25: *       ..
   26: *       .. Array Arguments ..
   27: *       DOUBLE PRECISION   A( LDA, * ), TAU( * ), WORK( * )
   28: *       ..
   29: *  
   30: *
   31: *> \par Purpose:
   32: *  =============
   33: *>
   34: *> \verbatim
   35: *>
   36: *> DORG2L generates an m by n real matrix Q with orthonormal columns,
   37: *> which is defined as the last n columns of a product of k elementary
   38: *> reflectors of order m
   39: *>
   40: *>       Q  =  H(k) . . . H(2) H(1)
   41: *>
   42: *> as returned by DGEQLF.
   43: *> \endverbatim
   44: *
   45: *  Arguments:
   46: *  ==========
   47: *
   48: *> \param[in] M
   49: *> \verbatim
   50: *>          M is INTEGER
   51: *>          The number of rows of the matrix Q. M >= 0.
   52: *> \endverbatim
   53: *>
   54: *> \param[in] N
   55: *> \verbatim
   56: *>          N is INTEGER
   57: *>          The number of columns of the matrix Q. M >= N >= 0.
   58: *> \endverbatim
   59: *>
   60: *> \param[in] K
   61: *> \verbatim
   62: *>          K is INTEGER
   63: *>          The number of elementary reflectors whose product defines the
   64: *>          matrix Q. N >= K >= 0.
   65: *> \endverbatim
   66: *>
   67: *> \param[in,out] A
   68: *> \verbatim
   69: *>          A is DOUBLE PRECISION array, dimension (LDA,N)
   70: *>          On entry, the (n-k+i)-th column must contain the vector which
   71: *>          defines the elementary reflector H(i), for i = 1,2,...,k, as
   72: *>          returned by DGEQLF in the last k columns of its array
   73: *>          argument A.
   74: *>          On exit, the m by n matrix Q.
   75: *> \endverbatim
   76: *>
   77: *> \param[in] LDA
   78: *> \verbatim
   79: *>          LDA is INTEGER
   80: *>          The first dimension of the array A. LDA >= max(1,M).
   81: *> \endverbatim
   82: *>
   83: *> \param[in] TAU
   84: *> \verbatim
   85: *>          TAU is DOUBLE PRECISION array, dimension (K)
   86: *>          TAU(i) must contain the scalar factor of the elementary
   87: *>          reflector H(i), as returned by DGEQLF.
   88: *> \endverbatim
   89: *>
   90: *> \param[out] WORK
   91: *> \verbatim
   92: *>          WORK is DOUBLE PRECISION array, dimension (N)
   93: *> \endverbatim
   94: *>
   95: *> \param[out] INFO
   96: *> \verbatim
   97: *>          INFO is INTEGER
   98: *>          = 0: successful exit
   99: *>          < 0: if INFO = -i, the i-th argument has an illegal value
  100: *> \endverbatim
  101: *
  102: *  Authors:
  103: *  ========
  104: *
  105: *> \author Univ. of Tennessee 
  106: *> \author Univ. of California Berkeley 
  107: *> \author Univ. of Colorado Denver 
  108: *> \author NAG Ltd. 
  109: *
  110: *> \date September 2012
  111: *
  112: *> \ingroup doubleOTHERcomputational
  113: *
  114: *  =====================================================================
  115:       SUBROUTINE DORG2L( M, N, K, A, LDA, TAU, WORK, INFO )
  116: *
  117: *  -- LAPACK computational routine (version 3.4.2) --
  118: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
  119: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
  120: *     September 2012
  121: *
  122: *     .. Scalar Arguments ..
  123:       INTEGER            INFO, K, LDA, M, N
  124: *     ..
  125: *     .. Array Arguments ..
  126:       DOUBLE PRECISION   A( LDA, * ), TAU( * ), WORK( * )
  127: *     ..
  128: *
  129: *  =====================================================================
  130: *
  131: *     .. Parameters ..
  132:       DOUBLE PRECISION   ONE, ZERO
  133:       PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
  134: *     ..
  135: *     .. Local Scalars ..
  136:       INTEGER            I, II, J, L
  137: *     ..
  138: *     .. External Subroutines ..
  139:       EXTERNAL           DLARF, DSCAL, XERBLA
  140: *     ..
  141: *     .. Intrinsic Functions ..
  142:       INTRINSIC          MAX
  143: *     ..
  144: *     .. Executable Statements ..
  145: *
  146: *     Test the input arguments
  147: *
  148:       INFO = 0
  149:       IF( M.LT.0 ) THEN
  150:          INFO = -1
  151:       ELSE IF( N.LT.0 .OR. N.GT.M ) THEN
  152:          INFO = -2
  153:       ELSE IF( K.LT.0 .OR. K.GT.N ) THEN
  154:          INFO = -3
  155:       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
  156:          INFO = -5
  157:       END IF
  158:       IF( INFO.NE.0 ) THEN
  159:          CALL XERBLA( 'DORG2L', -INFO )
  160:          RETURN
  161:       END IF
  162: *
  163: *     Quick return if possible
  164: *
  165:       IF( N.LE.0 )
  166:      $   RETURN
  167: *
  168: *     Initialise columns 1:n-k to columns of the unit matrix
  169: *
  170:       DO 20 J = 1, N - K
  171:          DO 10 L = 1, M
  172:             A( L, J ) = ZERO
  173:    10    CONTINUE
  174:          A( M-N+J, J ) = ONE
  175:    20 CONTINUE
  176: *
  177:       DO 40 I = 1, K
  178:          II = N - K + I
  179: *
  180: *        Apply H(i) to A(1:m-k+i,1:n-k+i) from the left
  181: *
  182:          A( M-N+II, II ) = ONE
  183:          CALL DLARF( 'Left', M-N+II, II-1, A( 1, II ), 1, TAU( I ), A,
  184:      $               LDA, WORK )
  185:          CALL DSCAL( M-N+II-1, -TAU( I ), A( 1, II ), 1 )
  186:          A( M-N+II, II ) = ONE - TAU( I )
  187: *
  188: *        Set A(m-k+i+1:m,n-k+i) to zero
  189: *
  190:          DO 30 L = M - N + II + 1, M
  191:             A( L, II ) = ZERO
  192:    30    CONTINUE
  193:    40 CONTINUE
  194:       RETURN
  195: *
  196: *     End of DORG2L
  197: *
  198:       END