1: *> \brief \b DORBDB3
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DORBDB3 + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dorbdb3.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dorbdb3.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dorbdb3.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DORBDB3( M, P, Q, X11, LDX11, X21, LDX21, THETA, PHI,
22: * TAUP1, TAUP2, TAUQ1, WORK, LWORK, INFO )
23: *
24: * .. Scalar Arguments ..
25: * INTEGER INFO, LWORK, M, P, Q, LDX11, LDX21
26: * ..
27: * .. Array Arguments ..
28: * DOUBLE PRECISION PHI(*), THETA(*)
29: * DOUBLE PRECISION TAUP1(*), TAUP2(*), TAUQ1(*), WORK(*),
30: * $ X11(LDX11,*), X21(LDX21,*)
31: * ..
32: *
33: *
34: *> \par Purpose:
35: * =============
36: *>
37: *>\verbatim
38: *>
39: *> DORBDB3 simultaneously bidiagonalizes the blocks of a tall and skinny
40: *> matrix X with orthonomal columns:
41: *>
42: *> [ B11 ]
43: *> [ X11 ] [ P1 | ] [ 0 ]
44: *> [-----] = [---------] [-----] Q1**T .
45: *> [ X21 ] [ | P2 ] [ B21 ]
46: *> [ 0 ]
47: *>
48: *> X11 is P-by-Q, and X21 is (M-P)-by-Q. M-P must be no larger than P,
49: *> Q, or M-Q. Routines DORBDB1, DORBDB2, and DORBDB4 handle cases in
50: *> which M-P is not the minimum dimension.
51: *>
52: *> The orthogonal matrices P1, P2, and Q1 are P-by-P, (M-P)-by-(M-P),
53: *> and (M-Q)-by-(M-Q), respectively. They are represented implicitly by
54: *> Householder vectors.
55: *>
56: *> B11 and B12 are (M-P)-by-(M-P) bidiagonal matrices represented
57: *> implicitly by angles THETA, PHI.
58: *>
59: *>\endverbatim
60: *
61: * Arguments:
62: * ==========
63: *
64: *> \param[in] M
65: *> \verbatim
66: *> M is INTEGER
67: *> The number of rows X11 plus the number of rows in X21.
68: *> \endverbatim
69: *>
70: *> \param[in] P
71: *> \verbatim
72: *> P is INTEGER
73: *> The number of rows in X11. 0 <= P <= M. M-P <= min(P,Q,M-Q).
74: *> \endverbatim
75: *>
76: *> \param[in] Q
77: *> \verbatim
78: *> Q is INTEGER
79: *> The number of columns in X11 and X21. 0 <= Q <= M.
80: *> \endverbatim
81: *>
82: *> \param[in,out] X11
83: *> \verbatim
84: *> X11 is DOUBLE PRECISION array, dimension (LDX11,Q)
85: *> On entry, the top block of the matrix X to be reduced. On
86: *> exit, the columns of tril(X11) specify reflectors for P1 and
87: *> the rows of triu(X11,1) specify reflectors for Q1.
88: *> \endverbatim
89: *>
90: *> \param[in] LDX11
91: *> \verbatim
92: *> LDX11 is INTEGER
93: *> The leading dimension of X11. LDX11 >= P.
94: *> \endverbatim
95: *>
96: *> \param[in,out] X21
97: *> \verbatim
98: *> X21 is DOUBLE PRECISION array, dimension (LDX21,Q)
99: *> On entry, the bottom block of the matrix X to be reduced. On
100: *> exit, the columns of tril(X21) specify reflectors for P2.
101: *> \endverbatim
102: *>
103: *> \param[in] LDX21
104: *> \verbatim
105: *> LDX21 is INTEGER
106: *> The leading dimension of X21. LDX21 >= M-P.
107: *> \endverbatim
108: *>
109: *> \param[out] THETA
110: *> \verbatim
111: *> THETA is DOUBLE PRECISION array, dimension (Q)
112: *> The entries of the bidiagonal blocks B11, B21 are defined by
113: *> THETA and PHI. See Further Details.
114: *> \endverbatim
115: *>
116: *> \param[out] PHI
117: *> \verbatim
118: *> PHI is DOUBLE PRECISION array, dimension (Q-1)
119: *> The entries of the bidiagonal blocks B11, B21 are defined by
120: *> THETA and PHI. See Further Details.
121: *> \endverbatim
122: *>
123: *> \param[out] TAUP1
124: *> \verbatim
125: *> TAUP1 is DOUBLE PRECISION array, dimension (P)
126: *> The scalar factors of the elementary reflectors that define
127: *> P1.
128: *> \endverbatim
129: *>
130: *> \param[out] TAUP2
131: *> \verbatim
132: *> TAUP2 is DOUBLE PRECISION array, dimension (M-P)
133: *> The scalar factors of the elementary reflectors that define
134: *> P2.
135: *> \endverbatim
136: *>
137: *> \param[out] TAUQ1
138: *> \verbatim
139: *> TAUQ1 is DOUBLE PRECISION array, dimension (Q)
140: *> The scalar factors of the elementary reflectors that define
141: *> Q1.
142: *> \endverbatim
143: *>
144: *> \param[out] WORK
145: *> \verbatim
146: *> WORK is DOUBLE PRECISION array, dimension (LWORK)
147: *> \endverbatim
148: *>
149: *> \param[in] LWORK
150: *> \verbatim
151: *> LWORK is INTEGER
152: *> The dimension of the array WORK. LWORK >= M-Q.
153: *>
154: *> If LWORK = -1, then a workspace query is assumed; the routine
155: *> only calculates the optimal size of the WORK array, returns
156: *> this value as the first entry of the WORK array, and no error
157: *> message related to LWORK is issued by XERBLA.
158: *> \endverbatim
159: *>
160: *> \param[out] INFO
161: *> \verbatim
162: *> INFO is INTEGER
163: *> = 0: successful exit.
164: *> < 0: if INFO = -i, the i-th argument had an illegal value.
165: *> \endverbatim
166: *
167: * Authors:
168: * ========
169: *
170: *> \author Univ. of Tennessee
171: *> \author Univ. of California Berkeley
172: *> \author Univ. of Colorado Denver
173: *> \author NAG Ltd.
174: *
175: *> \ingroup doubleOTHERcomputational
176: *
177: *> \par Further Details:
178: * =====================
179: *>
180: *> \verbatim
181: *>
182: *> The upper-bidiagonal blocks B11, B21 are represented implicitly by
183: *> angles THETA(1), ..., THETA(Q) and PHI(1), ..., PHI(Q-1). Every entry
184: *> in each bidiagonal band is a product of a sine or cosine of a THETA
185: *> with a sine or cosine of a PHI. See [1] or DORCSD for details.
186: *>
187: *> P1, P2, and Q1 are represented as products of elementary reflectors.
188: *> See DORCSD2BY1 for details on generating P1, P2, and Q1 using DORGQR
189: *> and DORGLQ.
190: *> \endverbatim
191: *
192: *> \par References:
193: * ================
194: *>
195: *> [1] Brian D. Sutton. Computing the complete CS decomposition. Numer.
196: *> Algorithms, 50(1):33-65, 2009.
197: *>
198: * =====================================================================
199: SUBROUTINE DORBDB3( M, P, Q, X11, LDX11, X21, LDX21, THETA, PHI,
200: $ TAUP1, TAUP2, TAUQ1, WORK, LWORK, INFO )
201: *
202: * -- LAPACK computational routine --
203: * -- LAPACK is a software package provided by Univ. of Tennessee, --
204: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
205: *
206: * .. Scalar Arguments ..
207: INTEGER INFO, LWORK, M, P, Q, LDX11, LDX21
208: * ..
209: * .. Array Arguments ..
210: DOUBLE PRECISION PHI(*), THETA(*)
211: DOUBLE PRECISION TAUP1(*), TAUP2(*), TAUQ1(*), WORK(*),
212: $ X11(LDX11,*), X21(LDX21,*)
213: * ..
214: *
215: * ====================================================================
216: *
217: * .. Parameters ..
218: DOUBLE PRECISION ONE
219: PARAMETER ( ONE = 1.0D0 )
220: * ..
221: * .. Local Scalars ..
222: DOUBLE PRECISION C, S
223: INTEGER CHILDINFO, I, ILARF, IORBDB5, LLARF, LORBDB5,
224: $ LWORKMIN, LWORKOPT
225: LOGICAL LQUERY
226: * ..
227: * .. External Subroutines ..
228: EXTERNAL DLARF, DLARFGP, DORBDB5, DROT, XERBLA
229: * ..
230: * .. External Functions ..
231: DOUBLE PRECISION DNRM2
232: EXTERNAL DNRM2
233: * ..
234: * .. Intrinsic Function ..
235: INTRINSIC ATAN2, COS, MAX, SIN, SQRT
236: * ..
237: * .. Executable Statements ..
238: *
239: * Test input arguments
240: *
241: INFO = 0
242: LQUERY = LWORK .EQ. -1
243: *
244: IF( M .LT. 0 ) THEN
245: INFO = -1
246: ELSE IF( 2*P .LT. M .OR. P .GT. M ) THEN
247: INFO = -2
248: ELSE IF( Q .LT. M-P .OR. M-Q .LT. M-P ) THEN
249: INFO = -3
250: ELSE IF( LDX11 .LT. MAX( 1, P ) ) THEN
251: INFO = -5
252: ELSE IF( LDX21 .LT. MAX( 1, M-P ) ) THEN
253: INFO = -7
254: END IF
255: *
256: * Compute workspace
257: *
258: IF( INFO .EQ. 0 ) THEN
259: ILARF = 2
260: LLARF = MAX( P, M-P-1, Q-1 )
261: IORBDB5 = 2
262: LORBDB5 = Q-1
263: LWORKOPT = MAX( ILARF+LLARF-1, IORBDB5+LORBDB5-1 )
264: LWORKMIN = LWORKOPT
265: WORK(1) = LWORKOPT
266: IF( LWORK .LT. LWORKMIN .AND. .NOT.LQUERY ) THEN
267: INFO = -14
268: END IF
269: END IF
270: IF( INFO .NE. 0 ) THEN
271: CALL XERBLA( 'DORBDB3', -INFO )
272: RETURN
273: ELSE IF( LQUERY ) THEN
274: RETURN
275: END IF
276: *
277: * Reduce rows 1, ..., M-P of X11 and X21
278: *
279: DO I = 1, M-P
280: *
281: IF( I .GT. 1 ) THEN
282: CALL DROT( Q-I+1, X11(I-1,I), LDX11, X21(I,I), LDX11, C, S )
283: END IF
284: *
285: CALL DLARFGP( Q-I+1, X21(I,I), X21(I,I+1), LDX21, TAUQ1(I) )
286: S = X21(I,I)
287: X21(I,I) = ONE
288: CALL DLARF( 'R', P-I+1, Q-I+1, X21(I,I), LDX21, TAUQ1(I),
289: $ X11(I,I), LDX11, WORK(ILARF) )
290: CALL DLARF( 'R', M-P-I, Q-I+1, X21(I,I), LDX21, TAUQ1(I),
291: $ X21(I+1,I), LDX21, WORK(ILARF) )
292: C = SQRT( DNRM2( P-I+1, X11(I,I), 1 )**2
293: $ + DNRM2( M-P-I, X21(I+1,I), 1 )**2 )
294: THETA(I) = ATAN2( S, C )
295: *
296: CALL DORBDB5( P-I+1, M-P-I, Q-I, X11(I,I), 1, X21(I+1,I), 1,
297: $ X11(I,I+1), LDX11, X21(I+1,I+1), LDX21,
298: $ WORK(IORBDB5), LORBDB5, CHILDINFO )
299: CALL DLARFGP( P-I+1, X11(I,I), X11(I+1,I), 1, TAUP1(I) )
300: IF( I .LT. M-P ) THEN
301: CALL DLARFGP( M-P-I, X21(I+1,I), X21(I+2,I), 1, TAUP2(I) )
302: PHI(I) = ATAN2( X21(I+1,I), X11(I,I) )
303: C = COS( PHI(I) )
304: S = SIN( PHI(I) )
305: X21(I+1,I) = ONE
306: CALL DLARF( 'L', M-P-I, Q-I, X21(I+1,I), 1, TAUP2(I),
307: $ X21(I+1,I+1), LDX21, WORK(ILARF) )
308: END IF
309: X11(I,I) = ONE
310: CALL DLARF( 'L', P-I+1, Q-I, X11(I,I), 1, TAUP1(I), X11(I,I+1),
311: $ LDX11, WORK(ILARF) )
312: *
313: END DO
314: *
315: * Reduce the bottom-right portion of X11 to the identity matrix
316: *
317: DO I = M-P + 1, Q
318: CALL DLARFGP( P-I+1, X11(I,I), X11(I+1,I), 1, TAUP1(I) )
319: X11(I,I) = ONE
320: CALL DLARF( 'L', P-I+1, Q-I, X11(I,I), 1, TAUP1(I), X11(I,I+1),
321: $ LDX11, WORK(ILARF) )
322: END DO
323: *
324: RETURN
325: *
326: * End of DORBDB3
327: *
328: END
329:
CVSweb interface <joel.bertrand@systella.fr>