1: *> \brief \b DORBDB
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DORBDB + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dorbdb.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dorbdb.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dorbdb.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DORBDB( TRANS, SIGNS, M, P, Q, X11, LDX11, X12, LDX12,
22: * X21, LDX21, X22, LDX22, THETA, PHI, TAUP1,
23: * TAUP2, TAUQ1, TAUQ2, WORK, LWORK, INFO )
24: *
25: * .. Scalar Arguments ..
26: * CHARACTER SIGNS, TRANS
27: * INTEGER INFO, LDX11, LDX12, LDX21, LDX22, LWORK, M, P,
28: * $ Q
29: * ..
30: * .. Array Arguments ..
31: * DOUBLE PRECISION PHI( * ), THETA( * )
32: * DOUBLE PRECISION TAUP1( * ), TAUP2( * ), TAUQ1( * ), TAUQ2( * ),
33: * $ WORK( * ), X11( LDX11, * ), X12( LDX12, * ),
34: * $ X21( LDX21, * ), X22( LDX22, * )
35: * ..
36: *
37: *
38: *> \par Purpose:
39: * =============
40: *>
41: *> \verbatim
42: *>
43: *> DORBDB simultaneously bidiagonalizes the blocks of an M-by-M
44: *> partitioned orthogonal matrix X:
45: *>
46: *> [ B11 | B12 0 0 ]
47: *> [ X11 | X12 ] [ P1 | ] [ 0 | 0 -I 0 ] [ Q1 | ]**T
48: *> X = [-----------] = [---------] [----------------] [---------] .
49: *> [ X21 | X22 ] [ | P2 ] [ B21 | B22 0 0 ] [ | Q2 ]
50: *> [ 0 | 0 0 I ]
51: *>
52: *> X11 is P-by-Q. Q must be no larger than P, M-P, or M-Q. (If this is
53: *> not the case, then X must be transposed and/or permuted. This can be
54: *> done in constant time using the TRANS and SIGNS options. See DORCSD
55: *> for details.)
56: *>
57: *> The orthogonal matrices P1, P2, Q1, and Q2 are P-by-P, (M-P)-by-
58: *> (M-P), Q-by-Q, and (M-Q)-by-(M-Q), respectively. They are
59: *> represented implicitly by Householder vectors.
60: *>
61: *> B11, B12, B21, and B22 are Q-by-Q bidiagonal matrices represented
62: *> implicitly by angles THETA, PHI.
63: *> \endverbatim
64: *
65: * Arguments:
66: * ==========
67: *
68: *> \param[in] TRANS
69: *> \verbatim
70: *> TRANS is CHARACTER
71: *> = 'T': X, U1, U2, V1T, and V2T are stored in row-major
72: *> order;
73: *> otherwise: X, U1, U2, V1T, and V2T are stored in column-
74: *> major order.
75: *> \endverbatim
76: *>
77: *> \param[in] SIGNS
78: *> \verbatim
79: *> SIGNS is CHARACTER
80: *> = 'O': The lower-left block is made nonpositive (the
81: *> "other" convention);
82: *> otherwise: The upper-right block is made nonpositive (the
83: *> "default" convention).
84: *> \endverbatim
85: *>
86: *> \param[in] M
87: *> \verbatim
88: *> M is INTEGER
89: *> The number of rows and columns in X.
90: *> \endverbatim
91: *>
92: *> \param[in] P
93: *> \verbatim
94: *> P is INTEGER
95: *> The number of rows in X11 and X12. 0 <= P <= M.
96: *> \endverbatim
97: *>
98: *> \param[in] Q
99: *> \verbatim
100: *> Q is INTEGER
101: *> The number of columns in X11 and X21. 0 <= Q <=
102: *> MIN(P,M-P,M-Q).
103: *> \endverbatim
104: *>
105: *> \param[in,out] X11
106: *> \verbatim
107: *> X11 is DOUBLE PRECISION array, dimension (LDX11,Q)
108: *> On entry, the top-left block of the orthogonal matrix to be
109: *> reduced. On exit, the form depends on TRANS:
110: *> If TRANS = 'N', then
111: *> the columns of tril(X11) specify reflectors for P1,
112: *> the rows of triu(X11,1) specify reflectors for Q1;
113: *> else TRANS = 'T', and
114: *> the rows of triu(X11) specify reflectors for P1,
115: *> the columns of tril(X11,-1) specify reflectors for Q1.
116: *> \endverbatim
117: *>
118: *> \param[in] LDX11
119: *> \verbatim
120: *> LDX11 is INTEGER
121: *> The leading dimension of X11. If TRANS = 'N', then LDX11 >=
122: *> P; else LDX11 >= Q.
123: *> \endverbatim
124: *>
125: *> \param[in,out] X12
126: *> \verbatim
127: *> X12 is DOUBLE PRECISION array, dimension (LDX12,M-Q)
128: *> On entry, the top-right block of the orthogonal matrix to
129: *> be reduced. On exit, the form depends on TRANS:
130: *> If TRANS = 'N', then
131: *> the rows of triu(X12) specify the first P reflectors for
132: *> Q2;
133: *> else TRANS = 'T', and
134: *> the columns of tril(X12) specify the first P reflectors
135: *> for Q2.
136: *> \endverbatim
137: *>
138: *> \param[in] LDX12
139: *> \verbatim
140: *> LDX12 is INTEGER
141: *> The leading dimension of X12. If TRANS = 'N', then LDX12 >=
142: *> P; else LDX11 >= M-Q.
143: *> \endverbatim
144: *>
145: *> \param[in,out] X21
146: *> \verbatim
147: *> X21 is DOUBLE PRECISION array, dimension (LDX21,Q)
148: *> On entry, the bottom-left block of the orthogonal matrix to
149: *> be reduced. On exit, the form depends on TRANS:
150: *> If TRANS = 'N', then
151: *> the columns of tril(X21) specify reflectors for P2;
152: *> else TRANS = 'T', and
153: *> the rows of triu(X21) specify reflectors for P2.
154: *> \endverbatim
155: *>
156: *> \param[in] LDX21
157: *> \verbatim
158: *> LDX21 is INTEGER
159: *> The leading dimension of X21. If TRANS = 'N', then LDX21 >=
160: *> M-P; else LDX21 >= Q.
161: *> \endverbatim
162: *>
163: *> \param[in,out] X22
164: *> \verbatim
165: *> X22 is DOUBLE PRECISION array, dimension (LDX22,M-Q)
166: *> On entry, the bottom-right block of the orthogonal matrix to
167: *> be reduced. On exit, the form depends on TRANS:
168: *> If TRANS = 'N', then
169: *> the rows of triu(X22(Q+1:M-P,P+1:M-Q)) specify the last
170: *> M-P-Q reflectors for Q2,
171: *> else TRANS = 'T', and
172: *> the columns of tril(X22(P+1:M-Q,Q+1:M-P)) specify the last
173: *> M-P-Q reflectors for P2.
174: *> \endverbatim
175: *>
176: *> \param[in] LDX22
177: *> \verbatim
178: *> LDX22 is INTEGER
179: *> The leading dimension of X22. If TRANS = 'N', then LDX22 >=
180: *> M-P; else LDX22 >= M-Q.
181: *> \endverbatim
182: *>
183: *> \param[out] THETA
184: *> \verbatim
185: *> THETA is DOUBLE PRECISION array, dimension (Q)
186: *> The entries of the bidiagonal blocks B11, B12, B21, B22 can
187: *> be computed from the angles THETA and PHI. See Further
188: *> Details.
189: *> \endverbatim
190: *>
191: *> \param[out] PHI
192: *> \verbatim
193: *> PHI is DOUBLE PRECISION array, dimension (Q-1)
194: *> The entries of the bidiagonal blocks B11, B12, B21, B22 can
195: *> be computed from the angles THETA and PHI. See Further
196: *> Details.
197: *> \endverbatim
198: *>
199: *> \param[out] TAUP1
200: *> \verbatim
201: *> TAUP1 is DOUBLE PRECISION array, dimension (P)
202: *> The scalar factors of the elementary reflectors that define
203: *> P1.
204: *> \endverbatim
205: *>
206: *> \param[out] TAUP2
207: *> \verbatim
208: *> TAUP2 is DOUBLE PRECISION array, dimension (M-P)
209: *> The scalar factors of the elementary reflectors that define
210: *> P2.
211: *> \endverbatim
212: *>
213: *> \param[out] TAUQ1
214: *> \verbatim
215: *> TAUQ1 is DOUBLE PRECISION array, dimension (Q)
216: *> The scalar factors of the elementary reflectors that define
217: *> Q1.
218: *> \endverbatim
219: *>
220: *> \param[out] TAUQ2
221: *> \verbatim
222: *> TAUQ2 is DOUBLE PRECISION array, dimension (M-Q)
223: *> The scalar factors of the elementary reflectors that define
224: *> Q2.
225: *> \endverbatim
226: *>
227: *> \param[out] WORK
228: *> \verbatim
229: *> WORK is DOUBLE PRECISION array, dimension (LWORK)
230: *> \endverbatim
231: *>
232: *> \param[in] LWORK
233: *> \verbatim
234: *> LWORK is INTEGER
235: *> The dimension of the array WORK. LWORK >= M-Q.
236: *>
237: *> If LWORK = -1, then a workspace query is assumed; the routine
238: *> only calculates the optimal size of the WORK array, returns
239: *> this value as the first entry of the WORK array, and no error
240: *> message related to LWORK is issued by XERBLA.
241: *> \endverbatim
242: *>
243: *> \param[out] INFO
244: *> \verbatim
245: *> INFO is INTEGER
246: *> = 0: successful exit.
247: *> < 0: if INFO = -i, the i-th argument had an illegal value.
248: *> \endverbatim
249: *
250: * Authors:
251: * ========
252: *
253: *> \author Univ. of Tennessee
254: *> \author Univ. of California Berkeley
255: *> \author Univ. of Colorado Denver
256: *> \author NAG Ltd.
257: *
258: *> \date November 2011
259: *
260: *> \ingroup doubleOTHERcomputational
261: *
262: *> \par Further Details:
263: * =====================
264: *>
265: *> \verbatim
266: *>
267: *> The bidiagonal blocks B11, B12, B21, and B22 are represented
268: *> implicitly by angles THETA(1), ..., THETA(Q) and PHI(1), ...,
269: *> PHI(Q-1). B11 and B21 are upper bidiagonal, while B21 and B22 are
270: *> lower bidiagonal. Every entry in each bidiagonal band is a product
271: *> of a sine or cosine of a THETA with a sine or cosine of a PHI. See
272: *> [1] or DORCSD for details.
273: *>
274: *> P1, P2, Q1, and Q2 are represented as products of elementary
275: *> reflectors. See DORCSD for details on generating P1, P2, Q1, and Q2
276: *> using DORGQR and DORGLQ.
277: *> \endverbatim
278: *
279: *> \par References:
280: * ================
281: *>
282: *> [1] Brian D. Sutton. Computing the complete CS decomposition. Numer.
283: *> Algorithms, 50(1):33-65, 2009.
284: *>
285: * =====================================================================
286: SUBROUTINE DORBDB( TRANS, SIGNS, M, P, Q, X11, LDX11, X12, LDX12,
287: $ X21, LDX21, X22, LDX22, THETA, PHI, TAUP1,
288: $ TAUP2, TAUQ1, TAUQ2, WORK, LWORK, INFO )
289: *
290: * -- LAPACK computational routine (version 3.4.0) --
291: * -- LAPACK is a software package provided by Univ. of Tennessee, --
292: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
293: * November 2011
294: *
295: * .. Scalar Arguments ..
296: CHARACTER SIGNS, TRANS
297: INTEGER INFO, LDX11, LDX12, LDX21, LDX22, LWORK, M, P,
298: $ Q
299: * ..
300: * .. Array Arguments ..
301: DOUBLE PRECISION PHI( * ), THETA( * )
302: DOUBLE PRECISION TAUP1( * ), TAUP2( * ), TAUQ1( * ), TAUQ2( * ),
303: $ WORK( * ), X11( LDX11, * ), X12( LDX12, * ),
304: $ X21( LDX21, * ), X22( LDX22, * )
305: * ..
306: *
307: * ====================================================================
308: *
309: * .. Parameters ..
310: DOUBLE PRECISION REALONE
311: PARAMETER ( REALONE = 1.0D0 )
312: DOUBLE PRECISION ONE
313: PARAMETER ( ONE = 1.0D0 )
314: * ..
315: * .. Local Scalars ..
316: LOGICAL COLMAJOR, LQUERY
317: INTEGER I, LWORKMIN, LWORKOPT
318: DOUBLE PRECISION Z1, Z2, Z3, Z4
319: * ..
320: * .. External Subroutines ..
321: EXTERNAL DAXPY, DLARF, DLARFGP, DSCAL, XERBLA
322: * ..
323: * .. External Functions ..
324: DOUBLE PRECISION DNRM2
325: LOGICAL LSAME
326: EXTERNAL DNRM2, LSAME
327: * ..
328: * .. Intrinsic Functions
329: INTRINSIC ATAN2, COS, MAX, SIN
330: * ..
331: * .. Executable Statements ..
332: *
333: * Test input arguments
334: *
335: INFO = 0
336: COLMAJOR = .NOT. LSAME( TRANS, 'T' )
337: IF( .NOT. LSAME( SIGNS, 'O' ) ) THEN
338: Z1 = REALONE
339: Z2 = REALONE
340: Z3 = REALONE
341: Z4 = REALONE
342: ELSE
343: Z1 = REALONE
344: Z2 = -REALONE
345: Z3 = REALONE
346: Z4 = -REALONE
347: END IF
348: LQUERY = LWORK .EQ. -1
349: *
350: IF( M .LT. 0 ) THEN
351: INFO = -3
352: ELSE IF( P .LT. 0 .OR. P .GT. M ) THEN
353: INFO = -4
354: ELSE IF( Q .LT. 0 .OR. Q .GT. P .OR. Q .GT. M-P .OR.
355: $ Q .GT. M-Q ) THEN
356: INFO = -5
357: ELSE IF( COLMAJOR .AND. LDX11 .LT. MAX( 1, P ) ) THEN
358: INFO = -7
359: ELSE IF( .NOT.COLMAJOR .AND. LDX11 .LT. MAX( 1, Q ) ) THEN
360: INFO = -7
361: ELSE IF( COLMAJOR .AND. LDX12 .LT. MAX( 1, P ) ) THEN
362: INFO = -9
363: ELSE IF( .NOT.COLMAJOR .AND. LDX12 .LT. MAX( 1, M-Q ) ) THEN
364: INFO = -9
365: ELSE IF( COLMAJOR .AND. LDX21 .LT. MAX( 1, M-P ) ) THEN
366: INFO = -11
367: ELSE IF( .NOT.COLMAJOR .AND. LDX21 .LT. MAX( 1, Q ) ) THEN
368: INFO = -11
369: ELSE IF( COLMAJOR .AND. LDX22 .LT. MAX( 1, M-P ) ) THEN
370: INFO = -13
371: ELSE IF( .NOT.COLMAJOR .AND. LDX22 .LT. MAX( 1, M-Q ) ) THEN
372: INFO = -13
373: END IF
374: *
375: * Compute workspace
376: *
377: IF( INFO .EQ. 0 ) THEN
378: LWORKOPT = M - Q
379: LWORKMIN = M - Q
380: WORK(1) = LWORKOPT
381: IF( LWORK .LT. LWORKMIN .AND. .NOT. LQUERY ) THEN
382: INFO = -21
383: END IF
384: END IF
385: IF( INFO .NE. 0 ) THEN
386: CALL XERBLA( 'xORBDB', -INFO )
387: RETURN
388: ELSE IF( LQUERY ) THEN
389: RETURN
390: END IF
391: *
392: * Handle column-major and row-major separately
393: *
394: IF( COLMAJOR ) THEN
395: *
396: * Reduce columns 1, ..., Q of X11, X12, X21, and X22
397: *
398: DO I = 1, Q
399: *
400: IF( I .EQ. 1 ) THEN
401: CALL DSCAL( P-I+1, Z1, X11(I,I), 1 )
402: ELSE
403: CALL DSCAL( P-I+1, Z1*COS(PHI(I-1)), X11(I,I), 1 )
404: CALL DAXPY( P-I+1, -Z1*Z3*Z4*SIN(PHI(I-1)), X12(I,I-1),
405: $ 1, X11(I,I), 1 )
406: END IF
407: IF( I .EQ. 1 ) THEN
408: CALL DSCAL( M-P-I+1, Z2, X21(I,I), 1 )
409: ELSE
410: CALL DSCAL( M-P-I+1, Z2*COS(PHI(I-1)), X21(I,I), 1 )
411: CALL DAXPY( M-P-I+1, -Z2*Z3*Z4*SIN(PHI(I-1)), X22(I,I-1),
412: $ 1, X21(I,I), 1 )
413: END IF
414: *
415: THETA(I) = ATAN2( DNRM2( M-P-I+1, X21(I,I), 1 ),
416: $ DNRM2( P-I+1, X11(I,I), 1 ) )
417: *
418: CALL DLARFGP( P-I+1, X11(I,I), X11(I+1,I), 1, TAUP1(I) )
419: X11(I,I) = ONE
420: CALL DLARFGP( M-P-I+1, X21(I,I), X21(I+1,I), 1, TAUP2(I) )
421: X21(I,I) = ONE
422: *
423: CALL DLARF( 'L', P-I+1, Q-I, X11(I,I), 1, TAUP1(I),
424: $ X11(I,I+1), LDX11, WORK )
425: CALL DLARF( 'L', P-I+1, M-Q-I+1, X11(I,I), 1, TAUP1(I),
426: $ X12(I,I), LDX12, WORK )
427: CALL DLARF( 'L', M-P-I+1, Q-I, X21(I,I), 1, TAUP2(I),
428: $ X21(I,I+1), LDX21, WORK )
429: CALL DLARF( 'L', M-P-I+1, M-Q-I+1, X21(I,I), 1, TAUP2(I),
430: $ X22(I,I), LDX22, WORK )
431: *
432: IF( I .LT. Q ) THEN
433: CALL DSCAL( Q-I, -Z1*Z3*SIN(THETA(I)), X11(I,I+1),
434: $ LDX11 )
435: CALL DAXPY( Q-I, Z2*Z3*COS(THETA(I)), X21(I,I+1), LDX21,
436: $ X11(I,I+1), LDX11 )
437: END IF
438: CALL DSCAL( M-Q-I+1, -Z1*Z4*SIN(THETA(I)), X12(I,I), LDX12 )
439: CALL DAXPY( M-Q-I+1, Z2*Z4*COS(THETA(I)), X22(I,I), LDX22,
440: $ X12(I,I), LDX12 )
441: *
442: IF( I .LT. Q )
443: $ PHI(I) = ATAN2( DNRM2( Q-I, X11(I,I+1), LDX11 ),
444: $ DNRM2( M-Q-I+1, X12(I,I), LDX12 ) )
445: *
446: IF( I .LT. Q ) THEN
447: CALL DLARFGP( Q-I, X11(I,I+1), X11(I,I+2), LDX11,
448: $ TAUQ1(I) )
449: X11(I,I+1) = ONE
450: END IF
451: CALL DLARFGP( M-Q-I+1, X12(I,I), X12(I,I+1), LDX12,
452: $ TAUQ2(I) )
453: X12(I,I) = ONE
454: *
455: IF( I .LT. Q ) THEN
456: CALL DLARF( 'R', P-I, Q-I, X11(I,I+1), LDX11, TAUQ1(I),
457: $ X11(I+1,I+1), LDX11, WORK )
458: CALL DLARF( 'R', M-P-I, Q-I, X11(I,I+1), LDX11, TAUQ1(I),
459: $ X21(I+1,I+1), LDX21, WORK )
460: END IF
461: CALL DLARF( 'R', P-I, M-Q-I+1, X12(I,I), LDX12, TAUQ2(I),
462: $ X12(I+1,I), LDX12, WORK )
463: CALL DLARF( 'R', M-P-I, M-Q-I+1, X12(I,I), LDX12, TAUQ2(I),
464: $ X22(I+1,I), LDX22, WORK )
465: *
466: END DO
467: *
468: * Reduce columns Q + 1, ..., P of X12, X22
469: *
470: DO I = Q + 1, P
471: *
472: CALL DSCAL( M-Q-I+1, -Z1*Z4, X12(I,I), LDX12 )
473: CALL DLARFGP( M-Q-I+1, X12(I,I), X12(I,I+1), LDX12,
474: $ TAUQ2(I) )
475: X12(I,I) = ONE
476: *
477: CALL DLARF( 'R', P-I, M-Q-I+1, X12(I,I), LDX12, TAUQ2(I),
478: $ X12(I+1,I), LDX12, WORK )
479: IF( M-P-Q .GE. 1 )
480: $ CALL DLARF( 'R', M-P-Q, M-Q-I+1, X12(I,I), LDX12,
481: $ TAUQ2(I), X22(Q+1,I), LDX22, WORK )
482: *
483: END DO
484: *
485: * Reduce columns P + 1, ..., M - Q of X12, X22
486: *
487: DO I = 1, M - P - Q
488: *
489: CALL DSCAL( M-P-Q-I+1, Z2*Z4, X22(Q+I,P+I), LDX22 )
490: CALL DLARFGP( M-P-Q-I+1, X22(Q+I,P+I), X22(Q+I,P+I+1),
491: $ LDX22, TAUQ2(P+I) )
492: X22(Q+I,P+I) = ONE
493: CALL DLARF( 'R', M-P-Q-I, M-P-Q-I+1, X22(Q+I,P+I), LDX22,
494: $ TAUQ2(P+I), X22(Q+I+1,P+I), LDX22, WORK )
495: *
496: END DO
497: *
498: ELSE
499: *
500: * Reduce columns 1, ..., Q of X11, X12, X21, X22
501: *
502: DO I = 1, Q
503: *
504: IF( I .EQ. 1 ) THEN
505: CALL DSCAL( P-I+1, Z1, X11(I,I), LDX11 )
506: ELSE
507: CALL DSCAL( P-I+1, Z1*COS(PHI(I-1)), X11(I,I), LDX11 )
508: CALL DAXPY( P-I+1, -Z1*Z3*Z4*SIN(PHI(I-1)), X12(I-1,I),
509: $ LDX12, X11(I,I), LDX11 )
510: END IF
511: IF( I .EQ. 1 ) THEN
512: CALL DSCAL( M-P-I+1, Z2, X21(I,I), LDX21 )
513: ELSE
514: CALL DSCAL( M-P-I+1, Z2*COS(PHI(I-1)), X21(I,I), LDX21 )
515: CALL DAXPY( M-P-I+1, -Z2*Z3*Z4*SIN(PHI(I-1)), X22(I-1,I),
516: $ LDX22, X21(I,I), LDX21 )
517: END IF
518: *
519: THETA(I) = ATAN2( DNRM2( M-P-I+1, X21(I,I), LDX21 ),
520: $ DNRM2( P-I+1, X11(I,I), LDX11 ) )
521: *
522: CALL DLARFGP( P-I+1, X11(I,I), X11(I,I+1), LDX11, TAUP1(I) )
523: X11(I,I) = ONE
524: CALL DLARFGP( M-P-I+1, X21(I,I), X21(I,I+1), LDX21,
525: $ TAUP2(I) )
526: X21(I,I) = ONE
527: *
528: CALL DLARF( 'R', Q-I, P-I+1, X11(I,I), LDX11, TAUP1(I),
529: $ X11(I+1,I), LDX11, WORK )
530: CALL DLARF( 'R', M-Q-I+1, P-I+1, X11(I,I), LDX11, TAUP1(I),
531: $ X12(I,I), LDX12, WORK )
532: CALL DLARF( 'R', Q-I, M-P-I+1, X21(I,I), LDX21, TAUP2(I),
533: $ X21(I+1,I), LDX21, WORK )
534: CALL DLARF( 'R', M-Q-I+1, M-P-I+1, X21(I,I), LDX21,
535: $ TAUP2(I), X22(I,I), LDX22, WORK )
536: *
537: IF( I .LT. Q ) THEN
538: CALL DSCAL( Q-I, -Z1*Z3*SIN(THETA(I)), X11(I+1,I), 1 )
539: CALL DAXPY( Q-I, Z2*Z3*COS(THETA(I)), X21(I+1,I), 1,
540: $ X11(I+1,I), 1 )
541: END IF
542: CALL DSCAL( M-Q-I+1, -Z1*Z4*SIN(THETA(I)), X12(I,I), 1 )
543: CALL DAXPY( M-Q-I+1, Z2*Z4*COS(THETA(I)), X22(I,I), 1,
544: $ X12(I,I), 1 )
545: *
546: IF( I .LT. Q )
547: $ PHI(I) = ATAN2( DNRM2( Q-I, X11(I+1,I), 1 ),
548: $ DNRM2( M-Q-I+1, X12(I,I), 1 ) )
549: *
550: IF( I .LT. Q ) THEN
551: CALL DLARFGP( Q-I, X11(I+1,I), X11(I+2,I), 1, TAUQ1(I) )
552: X11(I+1,I) = ONE
553: END IF
554: CALL DLARFGP( M-Q-I+1, X12(I,I), X12(I+1,I), 1, TAUQ2(I) )
555: X12(I,I) = ONE
556: *
557: IF( I .LT. Q ) THEN
558: CALL DLARF( 'L', Q-I, P-I, X11(I+1,I), 1, TAUQ1(I),
559: $ X11(I+1,I+1), LDX11, WORK )
560: CALL DLARF( 'L', Q-I, M-P-I, X11(I+1,I), 1, TAUQ1(I),
561: $ X21(I+1,I+1), LDX21, WORK )
562: END IF
563: CALL DLARF( 'L', M-Q-I+1, P-I, X12(I,I), 1, TAUQ2(I),
564: $ X12(I,I+1), LDX12, WORK )
565: CALL DLARF( 'L', M-Q-I+1, M-P-I, X12(I,I), 1, TAUQ2(I),
566: $ X22(I,I+1), LDX22, WORK )
567: *
568: END DO
569: *
570: * Reduce columns Q + 1, ..., P of X12, X22
571: *
572: DO I = Q + 1, P
573: *
574: CALL DSCAL( M-Q-I+1, -Z1*Z4, X12(I,I), 1 )
575: CALL DLARFGP( M-Q-I+1, X12(I,I), X12(I+1,I), 1, TAUQ2(I) )
576: X12(I,I) = ONE
577: *
578: CALL DLARF( 'L', M-Q-I+1, P-I, X12(I,I), 1, TAUQ2(I),
579: $ X12(I,I+1), LDX12, WORK )
580: IF( M-P-Q .GE. 1 )
581: $ CALL DLARF( 'L', M-Q-I+1, M-P-Q, X12(I,I), 1, TAUQ2(I),
582: $ X22(I,Q+1), LDX22, WORK )
583: *
584: END DO
585: *
586: * Reduce columns P + 1, ..., M - Q of X12, X22
587: *
588: DO I = 1, M - P - Q
589: *
590: CALL DSCAL( M-P-Q-I+1, Z2*Z4, X22(P+I,Q+I), 1 )
591: CALL DLARFGP( M-P-Q-I+1, X22(P+I,Q+I), X22(P+I+1,Q+I), 1,
592: $ TAUQ2(P+I) )
593: X22(P+I,Q+I) = ONE
594: *
595: CALL DLARF( 'L', M-P-Q-I+1, M-P-Q-I, X22(P+I,Q+I), 1,
596: $ TAUQ2(P+I), X22(P+I,Q+I+1), LDX22, WORK )
597: *
598: END DO
599: *
600: END IF
601: *
602: RETURN
603: *
604: * End of DORBDB
605: *
606: END
607:
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dorbdb.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack