1: *> \brief \b DORBDB
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DORBDB + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dorbdb.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dorbdb.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dorbdb.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DORBDB( TRANS, SIGNS, M, P, Q, X11, LDX11, X12, LDX12,
22: * X21, LDX21, X22, LDX22, THETA, PHI, TAUP1,
23: * TAUP2, TAUQ1, TAUQ2, WORK, LWORK, INFO )
24: *
25: * .. Scalar Arguments ..
26: * CHARACTER SIGNS, TRANS
27: * INTEGER INFO, LDX11, LDX12, LDX21, LDX22, LWORK, M, P,
28: * $ Q
29: * ..
30: * .. Array Arguments ..
31: * DOUBLE PRECISION PHI( * ), THETA( * )
32: * DOUBLE PRECISION TAUP1( * ), TAUP2( * ), TAUQ1( * ), TAUQ2( * ),
33: * $ WORK( * ), X11( LDX11, * ), X12( LDX12, * ),
34: * $ X21( LDX21, * ), X22( LDX22, * )
35: * ..
36: *
37: *
38: *> \par Purpose:
39: * =============
40: *>
41: *> \verbatim
42: *>
43: *> DORBDB simultaneously bidiagonalizes the blocks of an M-by-M
44: *> partitioned orthogonal matrix X:
45: *>
46: *> [ B11 | B12 0 0 ]
47: *> [ X11 | X12 ] [ P1 | ] [ 0 | 0 -I 0 ] [ Q1 | ]**T
48: *> X = [-----------] = [---------] [----------------] [---------] .
49: *> [ X21 | X22 ] [ | P2 ] [ B21 | B22 0 0 ] [ | Q2 ]
50: *> [ 0 | 0 0 I ]
51: *>
52: *> X11 is P-by-Q. Q must be no larger than P, M-P, or M-Q. (If this is
53: *> not the case, then X must be transposed and/or permuted. This can be
54: *> done in constant time using the TRANS and SIGNS options. See DORCSD
55: *> for details.)
56: *>
57: *> The orthogonal matrices P1, P2, Q1, and Q2 are P-by-P, (M-P)-by-
58: *> (M-P), Q-by-Q, and (M-Q)-by-(M-Q), respectively. They are
59: *> represented implicitly by Householder vectors.
60: *>
61: *> B11, B12, B21, and B22 are Q-by-Q bidiagonal matrices represented
62: *> implicitly by angles THETA, PHI.
63: *> \endverbatim
64: *
65: * Arguments:
66: * ==========
67: *
68: *> \param[in] TRANS
69: *> \verbatim
70: *> TRANS is CHARACTER
71: *> = 'T': X, U1, U2, V1T, and V2T are stored in row-major
72: *> order;
73: *> otherwise: X, U1, U2, V1T, and V2T are stored in column-
74: *> major order.
75: *> \endverbatim
76: *>
77: *> \param[in] SIGNS
78: *> \verbatim
79: *> SIGNS is CHARACTER
80: *> = 'O': The lower-left block is made nonpositive (the
81: *> "other" convention);
82: *> otherwise: The upper-right block is made nonpositive (the
83: *> "default" convention).
84: *> \endverbatim
85: *>
86: *> \param[in] M
87: *> \verbatim
88: *> M is INTEGER
89: *> The number of rows and columns in X.
90: *> \endverbatim
91: *>
92: *> \param[in] P
93: *> \verbatim
94: *> P is INTEGER
95: *> The number of rows in X11 and X12. 0 <= P <= M.
96: *> \endverbatim
97: *>
98: *> \param[in] Q
99: *> \verbatim
100: *> Q is INTEGER
101: *> The number of columns in X11 and X21. 0 <= Q <=
102: *> MIN(P,M-P,M-Q).
103: *> \endverbatim
104: *>
105: *> \param[in,out] X11
106: *> \verbatim
107: *> X11 is DOUBLE PRECISION array, dimension (LDX11,Q)
108: *> On entry, the top-left block of the orthogonal matrix to be
109: *> reduced. On exit, the form depends on TRANS:
110: *> If TRANS = 'N', then
111: *> the columns of tril(X11) specify reflectors for P1,
112: *> the rows of triu(X11,1) specify reflectors for Q1;
113: *> else TRANS = 'T', and
114: *> the rows of triu(X11) specify reflectors for P1,
115: *> the columns of tril(X11,-1) specify reflectors for Q1.
116: *> \endverbatim
117: *>
118: *> \param[in] LDX11
119: *> \verbatim
120: *> LDX11 is INTEGER
121: *> The leading dimension of X11. If TRANS = 'N', then LDX11 >=
122: *> P; else LDX11 >= Q.
123: *> \endverbatim
124: *>
125: *> \param[in,out] X12
126: *> \verbatim
127: *> X12 is DOUBLE PRECISION array, dimension (LDX12,M-Q)
128: *> On entry, the top-right block of the orthogonal matrix to
129: *> be reduced. On exit, the form depends on TRANS:
130: *> If TRANS = 'N', then
131: *> the rows of triu(X12) specify the first P reflectors for
132: *> Q2;
133: *> else TRANS = 'T', and
134: *> the columns of tril(X12) specify the first P reflectors
135: *> for Q2.
136: *> \endverbatim
137: *>
138: *> \param[in] LDX12
139: *> \verbatim
140: *> LDX12 is INTEGER
141: *> The leading dimension of X12. If TRANS = 'N', then LDX12 >=
142: *> P; else LDX11 >= M-Q.
143: *> \endverbatim
144: *>
145: *> \param[in,out] X21
146: *> \verbatim
147: *> X21 is DOUBLE PRECISION array, dimension (LDX21,Q)
148: *> On entry, the bottom-left block of the orthogonal matrix to
149: *> be reduced. On exit, the form depends on TRANS:
150: *> If TRANS = 'N', then
151: *> the columns of tril(X21) specify reflectors for P2;
152: *> else TRANS = 'T', and
153: *> the rows of triu(X21) specify reflectors for P2.
154: *> \endverbatim
155: *>
156: *> \param[in] LDX21
157: *> \verbatim
158: *> LDX21 is INTEGER
159: *> The leading dimension of X21. If TRANS = 'N', then LDX21 >=
160: *> M-P; else LDX21 >= Q.
161: *> \endverbatim
162: *>
163: *> \param[in,out] X22
164: *> \verbatim
165: *> X22 is DOUBLE PRECISION array, dimension (LDX22,M-Q)
166: *> On entry, the bottom-right block of the orthogonal matrix to
167: *> be reduced. On exit, the form depends on TRANS:
168: *> If TRANS = 'N', then
169: *> the rows of triu(X22(Q+1:M-P,P+1:M-Q)) specify the last
170: *> M-P-Q reflectors for Q2,
171: *> else TRANS = 'T', and
172: *> the columns of tril(X22(P+1:M-Q,Q+1:M-P)) specify the last
173: *> M-P-Q reflectors for P2.
174: *> \endverbatim
175: *>
176: *> \param[in] LDX22
177: *> \verbatim
178: *> LDX22 is INTEGER
179: *> The leading dimension of X22. If TRANS = 'N', then LDX22 >=
180: *> M-P; else LDX22 >= M-Q.
181: *> \endverbatim
182: *>
183: *> \param[out] THETA
184: *> \verbatim
185: *> THETA is DOUBLE PRECISION array, dimension (Q)
186: *> The entries of the bidiagonal blocks B11, B12, B21, B22 can
187: *> be computed from the angles THETA and PHI. See Further
188: *> Details.
189: *> \endverbatim
190: *>
191: *> \param[out] PHI
192: *> \verbatim
193: *> PHI is DOUBLE PRECISION array, dimension (Q-1)
194: *> The entries of the bidiagonal blocks B11, B12, B21, B22 can
195: *> be computed from the angles THETA and PHI. See Further
196: *> Details.
197: *> \endverbatim
198: *>
199: *> \param[out] TAUP1
200: *> \verbatim
201: *> TAUP1 is DOUBLE PRECISION array, dimension (P)
202: *> The scalar factors of the elementary reflectors that define
203: *> P1.
204: *> \endverbatim
205: *>
206: *> \param[out] TAUP2
207: *> \verbatim
208: *> TAUP2 is DOUBLE PRECISION array, dimension (M-P)
209: *> The scalar factors of the elementary reflectors that define
210: *> P2.
211: *> \endverbatim
212: *>
213: *> \param[out] TAUQ1
214: *> \verbatim
215: *> TAUQ1 is DOUBLE PRECISION array, dimension (Q)
216: *> The scalar factors of the elementary reflectors that define
217: *> Q1.
218: *> \endverbatim
219: *>
220: *> \param[out] TAUQ2
221: *> \verbatim
222: *> TAUQ2 is DOUBLE PRECISION array, dimension (M-Q)
223: *> The scalar factors of the elementary reflectors that define
224: *> Q2.
225: *> \endverbatim
226: *>
227: *> \param[out] WORK
228: *> \verbatim
229: *> WORK is DOUBLE PRECISION array, dimension (LWORK)
230: *> \endverbatim
231: *>
232: *> \param[in] LWORK
233: *> \verbatim
234: *> LWORK is INTEGER
235: *> The dimension of the array WORK. LWORK >= M-Q.
236: *>
237: *> If LWORK = -1, then a workspace query is assumed; the routine
238: *> only calculates the optimal size of the WORK array, returns
239: *> this value as the first entry of the WORK array, and no error
240: *> message related to LWORK is issued by XERBLA.
241: *> \endverbatim
242: *>
243: *> \param[out] INFO
244: *> \verbatim
245: *> INFO is INTEGER
246: *> = 0: successful exit.
247: *> < 0: if INFO = -i, the i-th argument had an illegal value.
248: *> \endverbatim
249: *
250: * Authors:
251: * ========
252: *
253: *> \author Univ. of Tennessee
254: *> \author Univ. of California Berkeley
255: *> \author Univ. of Colorado Denver
256: *> \author NAG Ltd.
257: *
258: *> \ingroup doubleOTHERcomputational
259: *
260: *> \par Further Details:
261: * =====================
262: *>
263: *> \verbatim
264: *>
265: *> The bidiagonal blocks B11, B12, B21, and B22 are represented
266: *> implicitly by angles THETA(1), ..., THETA(Q) and PHI(1), ...,
267: *> PHI(Q-1). B11 and B21 are upper bidiagonal, while B21 and B22 are
268: *> lower bidiagonal. Every entry in each bidiagonal band is a product
269: *> of a sine or cosine of a THETA with a sine or cosine of a PHI. See
270: *> [1] or DORCSD for details.
271: *>
272: *> P1, P2, Q1, and Q2 are represented as products of elementary
273: *> reflectors. See DORCSD for details on generating P1, P2, Q1, and Q2
274: *> using DORGQR and DORGLQ.
275: *> \endverbatim
276: *
277: *> \par References:
278: * ================
279: *>
280: *> [1] Brian D. Sutton. Computing the complete CS decomposition. Numer.
281: *> Algorithms, 50(1):33-65, 2009.
282: *>
283: * =====================================================================
284: SUBROUTINE DORBDB( TRANS, SIGNS, M, P, Q, X11, LDX11, X12, LDX12,
285: $ X21, LDX21, X22, LDX22, THETA, PHI, TAUP1,
286: $ TAUP2, TAUQ1, TAUQ2, WORK, LWORK, INFO )
287: *
288: * -- LAPACK computational routine --
289: * -- LAPACK is a software package provided by Univ. of Tennessee, --
290: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
291: *
292: * .. Scalar Arguments ..
293: CHARACTER SIGNS, TRANS
294: INTEGER INFO, LDX11, LDX12, LDX21, LDX22, LWORK, M, P,
295: $ Q
296: * ..
297: * .. Array Arguments ..
298: DOUBLE PRECISION PHI( * ), THETA( * )
299: DOUBLE PRECISION TAUP1( * ), TAUP2( * ), TAUQ1( * ), TAUQ2( * ),
300: $ WORK( * ), X11( LDX11, * ), X12( LDX12, * ),
301: $ X21( LDX21, * ), X22( LDX22, * )
302: * ..
303: *
304: * ====================================================================
305: *
306: * .. Parameters ..
307: DOUBLE PRECISION REALONE
308: PARAMETER ( REALONE = 1.0D0 )
309: DOUBLE PRECISION ONE
310: PARAMETER ( ONE = 1.0D0 )
311: * ..
312: * .. Local Scalars ..
313: LOGICAL COLMAJOR, LQUERY
314: INTEGER I, LWORKMIN, LWORKOPT
315: DOUBLE PRECISION Z1, Z2, Z3, Z4
316: * ..
317: * .. External Subroutines ..
318: EXTERNAL DAXPY, DLARF, DLARFGP, DSCAL, XERBLA
319: * ..
320: * .. External Functions ..
321: DOUBLE PRECISION DNRM2
322: LOGICAL LSAME
323: EXTERNAL DNRM2, LSAME
324: * ..
325: * .. Intrinsic Functions
326: INTRINSIC ATAN2, COS, MAX, SIN
327: * ..
328: * .. Executable Statements ..
329: *
330: * Test input arguments
331: *
332: INFO = 0
333: COLMAJOR = .NOT. LSAME( TRANS, 'T' )
334: IF( .NOT. LSAME( SIGNS, 'O' ) ) THEN
335: Z1 = REALONE
336: Z2 = REALONE
337: Z3 = REALONE
338: Z4 = REALONE
339: ELSE
340: Z1 = REALONE
341: Z2 = -REALONE
342: Z3 = REALONE
343: Z4 = -REALONE
344: END IF
345: LQUERY = LWORK .EQ. -1
346: *
347: IF( M .LT. 0 ) THEN
348: INFO = -3
349: ELSE IF( P .LT. 0 .OR. P .GT. M ) THEN
350: INFO = -4
351: ELSE IF( Q .LT. 0 .OR. Q .GT. P .OR. Q .GT. M-P .OR.
352: $ Q .GT. M-Q ) THEN
353: INFO = -5
354: ELSE IF( COLMAJOR .AND. LDX11 .LT. MAX( 1, P ) ) THEN
355: INFO = -7
356: ELSE IF( .NOT.COLMAJOR .AND. LDX11 .LT. MAX( 1, Q ) ) THEN
357: INFO = -7
358: ELSE IF( COLMAJOR .AND. LDX12 .LT. MAX( 1, P ) ) THEN
359: INFO = -9
360: ELSE IF( .NOT.COLMAJOR .AND. LDX12 .LT. MAX( 1, M-Q ) ) THEN
361: INFO = -9
362: ELSE IF( COLMAJOR .AND. LDX21 .LT. MAX( 1, M-P ) ) THEN
363: INFO = -11
364: ELSE IF( .NOT.COLMAJOR .AND. LDX21 .LT. MAX( 1, Q ) ) THEN
365: INFO = -11
366: ELSE IF( COLMAJOR .AND. LDX22 .LT. MAX( 1, M-P ) ) THEN
367: INFO = -13
368: ELSE IF( .NOT.COLMAJOR .AND. LDX22 .LT. MAX( 1, M-Q ) ) THEN
369: INFO = -13
370: END IF
371: *
372: * Compute workspace
373: *
374: IF( INFO .EQ. 0 ) THEN
375: LWORKOPT = M - Q
376: LWORKMIN = M - Q
377: WORK(1) = LWORKOPT
378: IF( LWORK .LT. LWORKMIN .AND. .NOT. LQUERY ) THEN
379: INFO = -21
380: END IF
381: END IF
382: IF( INFO .NE. 0 ) THEN
383: CALL XERBLA( 'xORBDB', -INFO )
384: RETURN
385: ELSE IF( LQUERY ) THEN
386: RETURN
387: END IF
388: *
389: * Handle column-major and row-major separately
390: *
391: IF( COLMAJOR ) THEN
392: *
393: * Reduce columns 1, ..., Q of X11, X12, X21, and X22
394: *
395: DO I = 1, Q
396: *
397: IF( I .EQ. 1 ) THEN
398: CALL DSCAL( P-I+1, Z1, X11(I,I), 1 )
399: ELSE
400: CALL DSCAL( P-I+1, Z1*COS(PHI(I-1)), X11(I,I), 1 )
401: CALL DAXPY( P-I+1, -Z1*Z3*Z4*SIN(PHI(I-1)), X12(I,I-1),
402: $ 1, X11(I,I), 1 )
403: END IF
404: IF( I .EQ. 1 ) THEN
405: CALL DSCAL( M-P-I+1, Z2, X21(I,I), 1 )
406: ELSE
407: CALL DSCAL( M-P-I+1, Z2*COS(PHI(I-1)), X21(I,I), 1 )
408: CALL DAXPY( M-P-I+1, -Z2*Z3*Z4*SIN(PHI(I-1)), X22(I,I-1),
409: $ 1, X21(I,I), 1 )
410: END IF
411: *
412: THETA(I) = ATAN2( DNRM2( M-P-I+1, X21(I,I), 1 ),
413: $ DNRM2( P-I+1, X11(I,I), 1 ) )
414: *
415: IF( P .GT. I ) THEN
416: CALL DLARFGP( P-I+1, X11(I,I), X11(I+1,I), 1, TAUP1(I) )
417: ELSE IF( P .EQ. I ) THEN
418: CALL DLARFGP( P-I+1, X11(I,I), X11(I,I), 1, TAUP1(I) )
419: END IF
420: X11(I,I) = ONE
421: IF ( M-P .GT. I ) THEN
422: CALL DLARFGP( M-P-I+1, X21(I,I), X21(I+1,I), 1,
423: $ TAUP2(I) )
424: ELSE IF ( M-P .EQ. I ) THEN
425: CALL DLARFGP( M-P-I+1, X21(I,I), X21(I,I), 1, TAUP2(I) )
426: END IF
427: X21(I,I) = ONE
428: *
429: IF ( Q .GT. I ) THEN
430: CALL DLARF( 'L', P-I+1, Q-I, X11(I,I), 1, TAUP1(I),
431: $ X11(I,I+1), LDX11, WORK )
432: END IF
433: IF ( M-Q+1 .GT. I ) THEN
434: CALL DLARF( 'L', P-I+1, M-Q-I+1, X11(I,I), 1, TAUP1(I),
435: $ X12(I,I), LDX12, WORK )
436: END IF
437: IF ( Q .GT. I ) THEN
438: CALL DLARF( 'L', M-P-I+1, Q-I, X21(I,I), 1, TAUP2(I),
439: $ X21(I,I+1), LDX21, WORK )
440: END IF
441: IF ( M-Q+1 .GT. I ) THEN
442: CALL DLARF( 'L', M-P-I+1, M-Q-I+1, X21(I,I), 1, TAUP2(I),
443: $ X22(I,I), LDX22, WORK )
444: END IF
445: *
446: IF( I .LT. Q ) THEN
447: CALL DSCAL( Q-I, -Z1*Z3*SIN(THETA(I)), X11(I,I+1),
448: $ LDX11 )
449: CALL DAXPY( Q-I, Z2*Z3*COS(THETA(I)), X21(I,I+1), LDX21,
450: $ X11(I,I+1), LDX11 )
451: END IF
452: CALL DSCAL( M-Q-I+1, -Z1*Z4*SIN(THETA(I)), X12(I,I), LDX12 )
453: CALL DAXPY( M-Q-I+1, Z2*Z4*COS(THETA(I)), X22(I,I), LDX22,
454: $ X12(I,I), LDX12 )
455: *
456: IF( I .LT. Q )
457: $ PHI(I) = ATAN2( DNRM2( Q-I, X11(I,I+1), LDX11 ),
458: $ DNRM2( M-Q-I+1, X12(I,I), LDX12 ) )
459: *
460: IF( I .LT. Q ) THEN
461: IF ( Q-I .EQ. 1 ) THEN
462: CALL DLARFGP( Q-I, X11(I,I+1), X11(I,I+1), LDX11,
463: $ TAUQ1(I) )
464: ELSE
465: CALL DLARFGP( Q-I, X11(I,I+1), X11(I,I+2), LDX11,
466: $ TAUQ1(I) )
467: END IF
468: X11(I,I+1) = ONE
469: END IF
470: IF ( Q+I-1 .LT. M ) THEN
471: IF ( M-Q .EQ. I ) THEN
472: CALL DLARFGP( M-Q-I+1, X12(I,I), X12(I,I), LDX12,
473: $ TAUQ2(I) )
474: ELSE
475: CALL DLARFGP( M-Q-I+1, X12(I,I), X12(I,I+1), LDX12,
476: $ TAUQ2(I) )
477: END IF
478: END IF
479: X12(I,I) = ONE
480: *
481: IF( I .LT. Q ) THEN
482: CALL DLARF( 'R', P-I, Q-I, X11(I,I+1), LDX11, TAUQ1(I),
483: $ X11(I+1,I+1), LDX11, WORK )
484: CALL DLARF( 'R', M-P-I, Q-I, X11(I,I+1), LDX11, TAUQ1(I),
485: $ X21(I+1,I+1), LDX21, WORK )
486: END IF
487: IF ( P .GT. I ) THEN
488: CALL DLARF( 'R', P-I, M-Q-I+1, X12(I,I), LDX12, TAUQ2(I),
489: $ X12(I+1,I), LDX12, WORK )
490: END IF
491: IF ( M-P .GT. I ) THEN
492: CALL DLARF( 'R', M-P-I, M-Q-I+1, X12(I,I), LDX12,
493: $ TAUQ2(I), X22(I+1,I), LDX22, WORK )
494: END IF
495: *
496: END DO
497: *
498: * Reduce columns Q + 1, ..., P of X12, X22
499: *
500: DO I = Q + 1, P
501: *
502: CALL DSCAL( M-Q-I+1, -Z1*Z4, X12(I,I), LDX12 )
503: IF ( I .GE. M-Q ) THEN
504: CALL DLARFGP( M-Q-I+1, X12(I,I), X12(I,I), LDX12,
505: $ TAUQ2(I) )
506: ELSE
507: CALL DLARFGP( M-Q-I+1, X12(I,I), X12(I,I+1), LDX12,
508: $ TAUQ2(I) )
509: END IF
510: X12(I,I) = ONE
511: *
512: IF ( P .GT. I ) THEN
513: CALL DLARF( 'R', P-I, M-Q-I+1, X12(I,I), LDX12, TAUQ2(I),
514: $ X12(I+1,I), LDX12, WORK )
515: END IF
516: IF( M-P-Q .GE. 1 )
517: $ CALL DLARF( 'R', M-P-Q, M-Q-I+1, X12(I,I), LDX12,
518: $ TAUQ2(I), X22(Q+1,I), LDX22, WORK )
519: *
520: END DO
521: *
522: * Reduce columns P + 1, ..., M - Q of X12, X22
523: *
524: DO I = 1, M - P - Q
525: *
526: CALL DSCAL( M-P-Q-I+1, Z2*Z4, X22(Q+I,P+I), LDX22 )
527: IF ( I .EQ. M-P-Q ) THEN
528: CALL DLARFGP( M-P-Q-I+1, X22(Q+I,P+I), X22(Q+I,P+I),
529: $ LDX22, TAUQ2(P+I) )
530: ELSE
531: CALL DLARFGP( M-P-Q-I+1, X22(Q+I,P+I), X22(Q+I,P+I+1),
532: $ LDX22, TAUQ2(P+I) )
533: END IF
534: X22(Q+I,P+I) = ONE
535: IF ( I .LT. M-P-Q ) THEN
536: CALL DLARF( 'R', M-P-Q-I, M-P-Q-I+1, X22(Q+I,P+I), LDX22,
537: $ TAUQ2(P+I), X22(Q+I+1,P+I), LDX22, WORK )
538: END IF
539: *
540: END DO
541: *
542: ELSE
543: *
544: * Reduce columns 1, ..., Q of X11, X12, X21, X22
545: *
546: DO I = 1, Q
547: *
548: IF( I .EQ. 1 ) THEN
549: CALL DSCAL( P-I+1, Z1, X11(I,I), LDX11 )
550: ELSE
551: CALL DSCAL( P-I+1, Z1*COS(PHI(I-1)), X11(I,I), LDX11 )
552: CALL DAXPY( P-I+1, -Z1*Z3*Z4*SIN(PHI(I-1)), X12(I-1,I),
553: $ LDX12, X11(I,I), LDX11 )
554: END IF
555: IF( I .EQ. 1 ) THEN
556: CALL DSCAL( M-P-I+1, Z2, X21(I,I), LDX21 )
557: ELSE
558: CALL DSCAL( M-P-I+1, Z2*COS(PHI(I-1)), X21(I,I), LDX21 )
559: CALL DAXPY( M-P-I+1, -Z2*Z3*Z4*SIN(PHI(I-1)), X22(I-1,I),
560: $ LDX22, X21(I,I), LDX21 )
561: END IF
562: *
563: THETA(I) = ATAN2( DNRM2( M-P-I+1, X21(I,I), LDX21 ),
564: $ DNRM2( P-I+1, X11(I,I), LDX11 ) )
565: *
566: CALL DLARFGP( P-I+1, X11(I,I), X11(I,I+1), LDX11, TAUP1(I) )
567: X11(I,I) = ONE
568: IF ( I .EQ. M-P ) THEN
569: CALL DLARFGP( M-P-I+1, X21(I,I), X21(I,I), LDX21,
570: $ TAUP2(I) )
571: ELSE
572: CALL DLARFGP( M-P-I+1, X21(I,I), X21(I,I+1), LDX21,
573: $ TAUP2(I) )
574: END IF
575: X21(I,I) = ONE
576: *
577: IF ( Q .GT. I ) THEN
578: CALL DLARF( 'R', Q-I, P-I+1, X11(I,I), LDX11, TAUP1(I),
579: $ X11(I+1,I), LDX11, WORK )
580: END IF
581: IF ( M-Q+1 .GT. I ) THEN
582: CALL DLARF( 'R', M-Q-I+1, P-I+1, X11(I,I), LDX11,
583: $ TAUP1(I), X12(I,I), LDX12, WORK )
584: END IF
585: IF ( Q .GT. I ) THEN
586: CALL DLARF( 'R', Q-I, M-P-I+1, X21(I,I), LDX21, TAUP2(I),
587: $ X21(I+1,I), LDX21, WORK )
588: END IF
589: IF ( M-Q+1 .GT. I ) THEN
590: CALL DLARF( 'R', M-Q-I+1, M-P-I+1, X21(I,I), LDX21,
591: $ TAUP2(I), X22(I,I), LDX22, WORK )
592: END IF
593: *
594: IF( I .LT. Q ) THEN
595: CALL DSCAL( Q-I, -Z1*Z3*SIN(THETA(I)), X11(I+1,I), 1 )
596: CALL DAXPY( Q-I, Z2*Z3*COS(THETA(I)), X21(I+1,I), 1,
597: $ X11(I+1,I), 1 )
598: END IF
599: CALL DSCAL( M-Q-I+1, -Z1*Z4*SIN(THETA(I)), X12(I,I), 1 )
600: CALL DAXPY( M-Q-I+1, Z2*Z4*COS(THETA(I)), X22(I,I), 1,
601: $ X12(I,I), 1 )
602: *
603: IF( I .LT. Q )
604: $ PHI(I) = ATAN2( DNRM2( Q-I, X11(I+1,I), 1 ),
605: $ DNRM2( M-Q-I+1, X12(I,I), 1 ) )
606: *
607: IF( I .LT. Q ) THEN
608: IF ( Q-I .EQ. 1) THEN
609: CALL DLARFGP( Q-I, X11(I+1,I), X11(I+1,I), 1,
610: $ TAUQ1(I) )
611: ELSE
612: CALL DLARFGP( Q-I, X11(I+1,I), X11(I+2,I), 1,
613: $ TAUQ1(I) )
614: END IF
615: X11(I+1,I) = ONE
616: END IF
617: IF ( M-Q .GT. I ) THEN
618: CALL DLARFGP( M-Q-I+1, X12(I,I), X12(I+1,I), 1,
619: $ TAUQ2(I) )
620: ELSE
621: CALL DLARFGP( M-Q-I+1, X12(I,I), X12(I,I), 1,
622: $ TAUQ2(I) )
623: END IF
624: X12(I,I) = ONE
625: *
626: IF( I .LT. Q ) THEN
627: CALL DLARF( 'L', Q-I, P-I, X11(I+1,I), 1, TAUQ1(I),
628: $ X11(I+1,I+1), LDX11, WORK )
629: CALL DLARF( 'L', Q-I, M-P-I, X11(I+1,I), 1, TAUQ1(I),
630: $ X21(I+1,I+1), LDX21, WORK )
631: END IF
632: CALL DLARF( 'L', M-Q-I+1, P-I, X12(I,I), 1, TAUQ2(I),
633: $ X12(I,I+1), LDX12, WORK )
634: IF ( M-P-I .GT. 0 ) THEN
635: CALL DLARF( 'L', M-Q-I+1, M-P-I, X12(I,I), 1, TAUQ2(I),
636: $ X22(I,I+1), LDX22, WORK )
637: END IF
638: *
639: END DO
640: *
641: * Reduce columns Q + 1, ..., P of X12, X22
642: *
643: DO I = Q + 1, P
644: *
645: CALL DSCAL( M-Q-I+1, -Z1*Z4, X12(I,I), 1 )
646: CALL DLARFGP( M-Q-I+1, X12(I,I), X12(I+1,I), 1, TAUQ2(I) )
647: X12(I,I) = ONE
648: *
649: IF ( P .GT. I ) THEN
650: CALL DLARF( 'L', M-Q-I+1, P-I, X12(I,I), 1, TAUQ2(I),
651: $ X12(I,I+1), LDX12, WORK )
652: END IF
653: IF( M-P-Q .GE. 1 )
654: $ CALL DLARF( 'L', M-Q-I+1, M-P-Q, X12(I,I), 1, TAUQ2(I),
655: $ X22(I,Q+1), LDX22, WORK )
656: *
657: END DO
658: *
659: * Reduce columns P + 1, ..., M - Q of X12, X22
660: *
661: DO I = 1, M - P - Q
662: *
663: CALL DSCAL( M-P-Q-I+1, Z2*Z4, X22(P+I,Q+I), 1 )
664: IF ( M-P-Q .EQ. I ) THEN
665: CALL DLARFGP( M-P-Q-I+1, X22(P+I,Q+I), X22(P+I,Q+I), 1,
666: $ TAUQ2(P+I) )
667: ELSE
668: CALL DLARFGP( M-P-Q-I+1, X22(P+I,Q+I), X22(P+I+1,Q+I), 1,
669: $ TAUQ2(P+I) )
670: CALL DLARF( 'L', M-P-Q-I+1, M-P-Q-I, X22(P+I,Q+I), 1,
671: $ TAUQ2(P+I), X22(P+I,Q+I+1), LDX22, WORK )
672: END IF
673: X22(P+I,Q+I) = ONE
674: *
675: END DO
676: *
677: END IF
678: *
679: RETURN
680: *
681: * End of DORBDB
682: *
683: END
684:
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dorbdb.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack