1: *> \brief \b DLASY2 solves the Sylvester matrix equation where the matrices are of order 1 or 2.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DLASY2 + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlasy2.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlasy2.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlasy2.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DLASY2( LTRANL, LTRANR, ISGN, N1, N2, TL, LDTL, TR,
22: * LDTR, B, LDB, SCALE, X, LDX, XNORM, INFO )
23: *
24: * .. Scalar Arguments ..
25: * LOGICAL LTRANL, LTRANR
26: * INTEGER INFO, ISGN, LDB, LDTL, LDTR, LDX, N1, N2
27: * DOUBLE PRECISION SCALE, XNORM
28: * ..
29: * .. Array Arguments ..
30: * DOUBLE PRECISION B( LDB, * ), TL( LDTL, * ), TR( LDTR, * ),
31: * $ X( LDX, * )
32: * ..
33: *
34: *
35: *> \par Purpose:
36: * =============
37: *>
38: *> \verbatim
39: *>
40: *> DLASY2 solves for the N1 by N2 matrix X, 1 <= N1,N2 <= 2, in
41: *>
42: *> op(TL)*X + ISGN*X*op(TR) = SCALE*B,
43: *>
44: *> where TL is N1 by N1, TR is N2 by N2, B is N1 by N2, and ISGN = 1 or
45: *> -1. op(T) = T or T**T, where T**T denotes the transpose of T.
46: *> \endverbatim
47: *
48: * Arguments:
49: * ==========
50: *
51: *> \param[in] LTRANL
52: *> \verbatim
53: *> LTRANL is LOGICAL
54: *> On entry, LTRANL specifies the op(TL):
55: *> = .FALSE., op(TL) = TL,
56: *> = .TRUE., op(TL) = TL**T.
57: *> \endverbatim
58: *>
59: *> \param[in] LTRANR
60: *> \verbatim
61: *> LTRANR is LOGICAL
62: *> On entry, LTRANR specifies the op(TR):
63: *> = .FALSE., op(TR) = TR,
64: *> = .TRUE., op(TR) = TR**T.
65: *> \endverbatim
66: *>
67: *> \param[in] ISGN
68: *> \verbatim
69: *> ISGN is INTEGER
70: *> On entry, ISGN specifies the sign of the equation
71: *> as described before. ISGN may only be 1 or -1.
72: *> \endverbatim
73: *>
74: *> \param[in] N1
75: *> \verbatim
76: *> N1 is INTEGER
77: *> On entry, N1 specifies the order of matrix TL.
78: *> N1 may only be 0, 1 or 2.
79: *> \endverbatim
80: *>
81: *> \param[in] N2
82: *> \verbatim
83: *> N2 is INTEGER
84: *> On entry, N2 specifies the order of matrix TR.
85: *> N2 may only be 0, 1 or 2.
86: *> \endverbatim
87: *>
88: *> \param[in] TL
89: *> \verbatim
90: *> TL is DOUBLE PRECISION array, dimension (LDTL,2)
91: *> On entry, TL contains an N1 by N1 matrix.
92: *> \endverbatim
93: *>
94: *> \param[in] LDTL
95: *> \verbatim
96: *> LDTL is INTEGER
97: *> The leading dimension of the matrix TL. LDTL >= max(1,N1).
98: *> \endverbatim
99: *>
100: *> \param[in] TR
101: *> \verbatim
102: *> TR is DOUBLE PRECISION array, dimension (LDTR,2)
103: *> On entry, TR contains an N2 by N2 matrix.
104: *> \endverbatim
105: *>
106: *> \param[in] LDTR
107: *> \verbatim
108: *> LDTR is INTEGER
109: *> The leading dimension of the matrix TR. LDTR >= max(1,N2).
110: *> \endverbatim
111: *>
112: *> \param[in] B
113: *> \verbatim
114: *> B is DOUBLE PRECISION array, dimension (LDB,2)
115: *> On entry, the N1 by N2 matrix B contains the right-hand
116: *> side of the equation.
117: *> \endverbatim
118: *>
119: *> \param[in] LDB
120: *> \verbatim
121: *> LDB is INTEGER
122: *> The leading dimension of the matrix B. LDB >= max(1,N1).
123: *> \endverbatim
124: *>
125: *> \param[out] SCALE
126: *> \verbatim
127: *> SCALE is DOUBLE PRECISION
128: *> On exit, SCALE contains the scale factor. SCALE is chosen
129: *> less than or equal to 1 to prevent the solution overflowing.
130: *> \endverbatim
131: *>
132: *> \param[out] X
133: *> \verbatim
134: *> X is DOUBLE PRECISION array, dimension (LDX,2)
135: *> On exit, X contains the N1 by N2 solution.
136: *> \endverbatim
137: *>
138: *> \param[in] LDX
139: *> \verbatim
140: *> LDX is INTEGER
141: *> The leading dimension of the matrix X. LDX >= max(1,N1).
142: *> \endverbatim
143: *>
144: *> \param[out] XNORM
145: *> \verbatim
146: *> XNORM is DOUBLE PRECISION
147: *> On exit, XNORM is the infinity-norm of the solution.
148: *> \endverbatim
149: *>
150: *> \param[out] INFO
151: *> \verbatim
152: *> INFO is INTEGER
153: *> On exit, INFO is set to
154: *> 0: successful exit.
155: *> 1: TL and TR have too close eigenvalues, so TL or
156: *> TR is perturbed to get a nonsingular equation.
157: *> NOTE: In the interests of speed, this routine does not
158: *> check the inputs for errors.
159: *> \endverbatim
160: *
161: * Authors:
162: * ========
163: *
164: *> \author Univ. of Tennessee
165: *> \author Univ. of California Berkeley
166: *> \author Univ. of Colorado Denver
167: *> \author NAG Ltd.
168: *
169: *> \ingroup doubleSYauxiliary
170: *
171: * =====================================================================
172: SUBROUTINE DLASY2( LTRANL, LTRANR, ISGN, N1, N2, TL, LDTL, TR,
173: $ LDTR, B, LDB, SCALE, X, LDX, XNORM, INFO )
174: *
175: * -- LAPACK auxiliary routine --
176: * -- LAPACK is a software package provided by Univ. of Tennessee, --
177: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
178: *
179: * .. Scalar Arguments ..
180: LOGICAL LTRANL, LTRANR
181: INTEGER INFO, ISGN, LDB, LDTL, LDTR, LDX, N1, N2
182: DOUBLE PRECISION SCALE, XNORM
183: * ..
184: * .. Array Arguments ..
185: DOUBLE PRECISION B( LDB, * ), TL( LDTL, * ), TR( LDTR, * ),
186: $ X( LDX, * )
187: * ..
188: *
189: * =====================================================================
190: *
191: * .. Parameters ..
192: DOUBLE PRECISION ZERO, ONE
193: PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
194: DOUBLE PRECISION TWO, HALF, EIGHT
195: PARAMETER ( TWO = 2.0D+0, HALF = 0.5D+0, EIGHT = 8.0D+0 )
196: * ..
197: * .. Local Scalars ..
198: LOGICAL BSWAP, XSWAP
199: INTEGER I, IP, IPIV, IPSV, J, JP, JPSV, K
200: DOUBLE PRECISION BET, EPS, GAM, L21, SGN, SMIN, SMLNUM, TAU1,
201: $ TEMP, U11, U12, U22, XMAX
202: * ..
203: * .. Local Arrays ..
204: LOGICAL BSWPIV( 4 ), XSWPIV( 4 )
205: INTEGER JPIV( 4 ), LOCL21( 4 ), LOCU12( 4 ),
206: $ LOCU22( 4 )
207: DOUBLE PRECISION BTMP( 4 ), T16( 4, 4 ), TMP( 4 ), X2( 2 )
208: * ..
209: * .. External Functions ..
210: INTEGER IDAMAX
211: DOUBLE PRECISION DLAMCH
212: EXTERNAL IDAMAX, DLAMCH
213: * ..
214: * .. External Subroutines ..
215: EXTERNAL DCOPY, DSWAP
216: * ..
217: * .. Intrinsic Functions ..
218: INTRINSIC ABS, MAX
219: * ..
220: * .. Data statements ..
221: DATA LOCU12 / 3, 4, 1, 2 / , LOCL21 / 2, 1, 4, 3 / ,
222: $ LOCU22 / 4, 3, 2, 1 /
223: DATA XSWPIV / .FALSE., .FALSE., .TRUE., .TRUE. /
224: DATA BSWPIV / .FALSE., .TRUE., .FALSE., .TRUE. /
225: * ..
226: * .. Executable Statements ..
227: *
228: * Do not check the input parameters for errors
229: *
230: INFO = 0
231: *
232: * Quick return if possible
233: *
234: IF( N1.EQ.0 .OR. N2.EQ.0 )
235: $ RETURN
236: *
237: * Set constants to control overflow
238: *
239: EPS = DLAMCH( 'P' )
240: SMLNUM = DLAMCH( 'S' ) / EPS
241: SGN = ISGN
242: *
243: K = N1 + N1 + N2 - 2
244: GO TO ( 10, 20, 30, 50 )K
245: *
246: * 1 by 1: TL11*X + SGN*X*TR11 = B11
247: *
248: 10 CONTINUE
249: TAU1 = TL( 1, 1 ) + SGN*TR( 1, 1 )
250: BET = ABS( TAU1 )
251: IF( BET.LE.SMLNUM ) THEN
252: TAU1 = SMLNUM
253: BET = SMLNUM
254: INFO = 1
255: END IF
256: *
257: SCALE = ONE
258: GAM = ABS( B( 1, 1 ) )
259: IF( SMLNUM*GAM.GT.BET )
260: $ SCALE = ONE / GAM
261: *
262: X( 1, 1 ) = ( B( 1, 1 )*SCALE ) / TAU1
263: XNORM = ABS( X( 1, 1 ) )
264: RETURN
265: *
266: * 1 by 2:
267: * TL11*[X11 X12] + ISGN*[X11 X12]*op[TR11 TR12] = [B11 B12]
268: * [TR21 TR22]
269: *
270: 20 CONTINUE
271: *
272: SMIN = MAX( EPS*MAX( ABS( TL( 1, 1 ) ), ABS( TR( 1, 1 ) ),
273: $ ABS( TR( 1, 2 ) ), ABS( TR( 2, 1 ) ), ABS( TR( 2, 2 ) ) ),
274: $ SMLNUM )
275: TMP( 1 ) = TL( 1, 1 ) + SGN*TR( 1, 1 )
276: TMP( 4 ) = TL( 1, 1 ) + SGN*TR( 2, 2 )
277: IF( LTRANR ) THEN
278: TMP( 2 ) = SGN*TR( 2, 1 )
279: TMP( 3 ) = SGN*TR( 1, 2 )
280: ELSE
281: TMP( 2 ) = SGN*TR( 1, 2 )
282: TMP( 3 ) = SGN*TR( 2, 1 )
283: END IF
284: BTMP( 1 ) = B( 1, 1 )
285: BTMP( 2 ) = B( 1, 2 )
286: GO TO 40
287: *
288: * 2 by 1:
289: * op[TL11 TL12]*[X11] + ISGN* [X11]*TR11 = [B11]
290: * [TL21 TL22] [X21] [X21] [B21]
291: *
292: 30 CONTINUE
293: SMIN = MAX( EPS*MAX( ABS( TR( 1, 1 ) ), ABS( TL( 1, 1 ) ),
294: $ ABS( TL( 1, 2 ) ), ABS( TL( 2, 1 ) ), ABS( TL( 2, 2 ) ) ),
295: $ SMLNUM )
296: TMP( 1 ) = TL( 1, 1 ) + SGN*TR( 1, 1 )
297: TMP( 4 ) = TL( 2, 2 ) + SGN*TR( 1, 1 )
298: IF( LTRANL ) THEN
299: TMP( 2 ) = TL( 1, 2 )
300: TMP( 3 ) = TL( 2, 1 )
301: ELSE
302: TMP( 2 ) = TL( 2, 1 )
303: TMP( 3 ) = TL( 1, 2 )
304: END IF
305: BTMP( 1 ) = B( 1, 1 )
306: BTMP( 2 ) = B( 2, 1 )
307: 40 CONTINUE
308: *
309: * Solve 2 by 2 system using complete pivoting.
310: * Set pivots less than SMIN to SMIN.
311: *
312: IPIV = IDAMAX( 4, TMP, 1 )
313: U11 = TMP( IPIV )
314: IF( ABS( U11 ).LE.SMIN ) THEN
315: INFO = 1
316: U11 = SMIN
317: END IF
318: U12 = TMP( LOCU12( IPIV ) )
319: L21 = TMP( LOCL21( IPIV ) ) / U11
320: U22 = TMP( LOCU22( IPIV ) ) - U12*L21
321: XSWAP = XSWPIV( IPIV )
322: BSWAP = BSWPIV( IPIV )
323: IF( ABS( U22 ).LE.SMIN ) THEN
324: INFO = 1
325: U22 = SMIN
326: END IF
327: IF( BSWAP ) THEN
328: TEMP = BTMP( 2 )
329: BTMP( 2 ) = BTMP( 1 ) - L21*TEMP
330: BTMP( 1 ) = TEMP
331: ELSE
332: BTMP( 2 ) = BTMP( 2 ) - L21*BTMP( 1 )
333: END IF
334: SCALE = ONE
335: IF( ( TWO*SMLNUM )*ABS( BTMP( 2 ) ).GT.ABS( U22 ) .OR.
336: $ ( TWO*SMLNUM )*ABS( BTMP( 1 ) ).GT.ABS( U11 ) ) THEN
337: SCALE = HALF / MAX( ABS( BTMP( 1 ) ), ABS( BTMP( 2 ) ) )
338: BTMP( 1 ) = BTMP( 1 )*SCALE
339: BTMP( 2 ) = BTMP( 2 )*SCALE
340: END IF
341: X2( 2 ) = BTMP( 2 ) / U22
342: X2( 1 ) = BTMP( 1 ) / U11 - ( U12 / U11 )*X2( 2 )
343: IF( XSWAP ) THEN
344: TEMP = X2( 2 )
345: X2( 2 ) = X2( 1 )
346: X2( 1 ) = TEMP
347: END IF
348: X( 1, 1 ) = X2( 1 )
349: IF( N1.EQ.1 ) THEN
350: X( 1, 2 ) = X2( 2 )
351: XNORM = ABS( X( 1, 1 ) ) + ABS( X( 1, 2 ) )
352: ELSE
353: X( 2, 1 ) = X2( 2 )
354: XNORM = MAX( ABS( X( 1, 1 ) ), ABS( X( 2, 1 ) ) )
355: END IF
356: RETURN
357: *
358: * 2 by 2:
359: * op[TL11 TL12]*[X11 X12] +ISGN* [X11 X12]*op[TR11 TR12] = [B11 B12]
360: * [TL21 TL22] [X21 X22] [X21 X22] [TR21 TR22] [B21 B22]
361: *
362: * Solve equivalent 4 by 4 system using complete pivoting.
363: * Set pivots less than SMIN to SMIN.
364: *
365: 50 CONTINUE
366: SMIN = MAX( ABS( TR( 1, 1 ) ), ABS( TR( 1, 2 ) ),
367: $ ABS( TR( 2, 1 ) ), ABS( TR( 2, 2 ) ) )
368: SMIN = MAX( SMIN, ABS( TL( 1, 1 ) ), ABS( TL( 1, 2 ) ),
369: $ ABS( TL( 2, 1 ) ), ABS( TL( 2, 2 ) ) )
370: SMIN = MAX( EPS*SMIN, SMLNUM )
371: BTMP( 1 ) = ZERO
372: CALL DCOPY( 16, BTMP, 0, T16, 1 )
373: T16( 1, 1 ) = TL( 1, 1 ) + SGN*TR( 1, 1 )
374: T16( 2, 2 ) = TL( 2, 2 ) + SGN*TR( 1, 1 )
375: T16( 3, 3 ) = TL( 1, 1 ) + SGN*TR( 2, 2 )
376: T16( 4, 4 ) = TL( 2, 2 ) + SGN*TR( 2, 2 )
377: IF( LTRANL ) THEN
378: T16( 1, 2 ) = TL( 2, 1 )
379: T16( 2, 1 ) = TL( 1, 2 )
380: T16( 3, 4 ) = TL( 2, 1 )
381: T16( 4, 3 ) = TL( 1, 2 )
382: ELSE
383: T16( 1, 2 ) = TL( 1, 2 )
384: T16( 2, 1 ) = TL( 2, 1 )
385: T16( 3, 4 ) = TL( 1, 2 )
386: T16( 4, 3 ) = TL( 2, 1 )
387: END IF
388: IF( LTRANR ) THEN
389: T16( 1, 3 ) = SGN*TR( 1, 2 )
390: T16( 2, 4 ) = SGN*TR( 1, 2 )
391: T16( 3, 1 ) = SGN*TR( 2, 1 )
392: T16( 4, 2 ) = SGN*TR( 2, 1 )
393: ELSE
394: T16( 1, 3 ) = SGN*TR( 2, 1 )
395: T16( 2, 4 ) = SGN*TR( 2, 1 )
396: T16( 3, 1 ) = SGN*TR( 1, 2 )
397: T16( 4, 2 ) = SGN*TR( 1, 2 )
398: END IF
399: BTMP( 1 ) = B( 1, 1 )
400: BTMP( 2 ) = B( 2, 1 )
401: BTMP( 3 ) = B( 1, 2 )
402: BTMP( 4 ) = B( 2, 2 )
403: *
404: * Perform elimination
405: *
406: DO 100 I = 1, 3
407: XMAX = ZERO
408: DO 70 IP = I, 4
409: DO 60 JP = I, 4
410: IF( ABS( T16( IP, JP ) ).GE.XMAX ) THEN
411: XMAX = ABS( T16( IP, JP ) )
412: IPSV = IP
413: JPSV = JP
414: END IF
415: 60 CONTINUE
416: 70 CONTINUE
417: IF( IPSV.NE.I ) THEN
418: CALL DSWAP( 4, T16( IPSV, 1 ), 4, T16( I, 1 ), 4 )
419: TEMP = BTMP( I )
420: BTMP( I ) = BTMP( IPSV )
421: BTMP( IPSV ) = TEMP
422: END IF
423: IF( JPSV.NE.I )
424: $ CALL DSWAP( 4, T16( 1, JPSV ), 1, T16( 1, I ), 1 )
425: JPIV( I ) = JPSV
426: IF( ABS( T16( I, I ) ).LT.SMIN ) THEN
427: INFO = 1
428: T16( I, I ) = SMIN
429: END IF
430: DO 90 J = I + 1, 4
431: T16( J, I ) = T16( J, I ) / T16( I, I )
432: BTMP( J ) = BTMP( J ) - T16( J, I )*BTMP( I )
433: DO 80 K = I + 1, 4
434: T16( J, K ) = T16( J, K ) - T16( J, I )*T16( I, K )
435: 80 CONTINUE
436: 90 CONTINUE
437: 100 CONTINUE
438: IF( ABS( T16( 4, 4 ) ).LT.SMIN ) THEN
439: INFO = 1
440: T16( 4, 4 ) = SMIN
441: END IF
442: SCALE = ONE
443: IF( ( EIGHT*SMLNUM )*ABS( BTMP( 1 ) ).GT.ABS( T16( 1, 1 ) ) .OR.
444: $ ( EIGHT*SMLNUM )*ABS( BTMP( 2 ) ).GT.ABS( T16( 2, 2 ) ) .OR.
445: $ ( EIGHT*SMLNUM )*ABS( BTMP( 3 ) ).GT.ABS( T16( 3, 3 ) ) .OR.
446: $ ( EIGHT*SMLNUM )*ABS( BTMP( 4 ) ).GT.ABS( T16( 4, 4 ) ) ) THEN
447: SCALE = ( ONE / EIGHT ) / MAX( ABS( BTMP( 1 ) ),
448: $ ABS( BTMP( 2 ) ), ABS( BTMP( 3 ) ), ABS( BTMP( 4 ) ) )
449: BTMP( 1 ) = BTMP( 1 )*SCALE
450: BTMP( 2 ) = BTMP( 2 )*SCALE
451: BTMP( 3 ) = BTMP( 3 )*SCALE
452: BTMP( 4 ) = BTMP( 4 )*SCALE
453: END IF
454: DO 120 I = 1, 4
455: K = 5 - I
456: TEMP = ONE / T16( K, K )
457: TMP( K ) = BTMP( K )*TEMP
458: DO 110 J = K + 1, 4
459: TMP( K ) = TMP( K ) - ( TEMP*T16( K, J ) )*TMP( J )
460: 110 CONTINUE
461: 120 CONTINUE
462: DO 130 I = 1, 3
463: IF( JPIV( 4-I ).NE.4-I ) THEN
464: TEMP = TMP( 4-I )
465: TMP( 4-I ) = TMP( JPIV( 4-I ) )
466: TMP( JPIV( 4-I ) ) = TEMP
467: END IF
468: 130 CONTINUE
469: X( 1, 1 ) = TMP( 1 )
470: X( 2, 1 ) = TMP( 2 )
471: X( 1, 2 ) = TMP( 3 )
472: X( 2, 2 ) = TMP( 4 )
473: XNORM = MAX( ABS( TMP( 1 ) )+ABS( TMP( 3 ) ),
474: $ ABS( TMP( 2 ) )+ABS( TMP( 4 ) ) )
475: RETURN
476: *
477: * End of DLASY2
478: *
479: END
CVSweb interface <joel.bertrand@systella.fr>