1: *> \brief \b DLARFB applies a block reflector or its transpose to a general rectangular matrix.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DLARFB + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlarfb.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlarfb.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlarfb.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DLARFB( SIDE, TRANS, DIRECT, STOREV, M, N, K, V, LDV,
22: * T, LDT, C, LDC, WORK, LDWORK )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER DIRECT, SIDE, STOREV, TRANS
26: * INTEGER K, LDC, LDT, LDV, LDWORK, M, N
27: * ..
28: * .. Array Arguments ..
29: * DOUBLE PRECISION C( LDC, * ), T( LDT, * ), V( LDV, * ),
30: * $ WORK( LDWORK, * )
31: * ..
32: *
33: *
34: *> \par Purpose:
35: * =============
36: *>
37: *> \verbatim
38: *>
39: *> DLARFB applies a real block reflector H or its transpose H**T to a
40: *> real m by n matrix C, from either the left or the right.
41: *> \endverbatim
42: *
43: * Arguments:
44: * ==========
45: *
46: *> \param[in] SIDE
47: *> \verbatim
48: *> SIDE is CHARACTER*1
49: *> = 'L': apply H or H**T from the Left
50: *> = 'R': apply H or H**T from the Right
51: *> \endverbatim
52: *>
53: *> \param[in] TRANS
54: *> \verbatim
55: *> TRANS is CHARACTER*1
56: *> = 'N': apply H (No transpose)
57: *> = 'T': apply H**T (Transpose)
58: *> \endverbatim
59: *>
60: *> \param[in] DIRECT
61: *> \verbatim
62: *> DIRECT is CHARACTER*1
63: *> Indicates how H is formed from a product of elementary
64: *> reflectors
65: *> = 'F': H = H(1) H(2) . . . H(k) (Forward)
66: *> = 'B': H = H(k) . . . H(2) H(1) (Backward)
67: *> \endverbatim
68: *>
69: *> \param[in] STOREV
70: *> \verbatim
71: *> STOREV is CHARACTER*1
72: *> Indicates how the vectors which define the elementary
73: *> reflectors are stored:
74: *> = 'C': Columnwise
75: *> = 'R': Rowwise
76: *> \endverbatim
77: *>
78: *> \param[in] M
79: *> \verbatim
80: *> M is INTEGER
81: *> The number of rows of the matrix C.
82: *> \endverbatim
83: *>
84: *> \param[in] N
85: *> \verbatim
86: *> N is INTEGER
87: *> The number of columns of the matrix C.
88: *> \endverbatim
89: *>
90: *> \param[in] K
91: *> \verbatim
92: *> K is INTEGER
93: *> The order of the matrix T (= the number of elementary
94: *> reflectors whose product defines the block reflector).
95: *> If SIDE = 'L', M >= K >= 0;
96: *> if SIDE = 'R', N >= K >= 0.
97: *> \endverbatim
98: *>
99: *> \param[in] V
100: *> \verbatim
101: *> V is DOUBLE PRECISION array, dimension
102: *> (LDV,K) if STOREV = 'C'
103: *> (LDV,M) if STOREV = 'R' and SIDE = 'L'
104: *> (LDV,N) if STOREV = 'R' and SIDE = 'R'
105: *> The matrix V. See Further Details.
106: *> \endverbatim
107: *>
108: *> \param[in] LDV
109: *> \verbatim
110: *> LDV is INTEGER
111: *> The leading dimension of the array V.
112: *> If STOREV = 'C' and SIDE = 'L', LDV >= max(1,M);
113: *> if STOREV = 'C' and SIDE = 'R', LDV >= max(1,N);
114: *> if STOREV = 'R', LDV >= K.
115: *> \endverbatim
116: *>
117: *> \param[in] T
118: *> \verbatim
119: *> T is DOUBLE PRECISION array, dimension (LDT,K)
120: *> The triangular k by k matrix T in the representation of the
121: *> block reflector.
122: *> \endverbatim
123: *>
124: *> \param[in] LDT
125: *> \verbatim
126: *> LDT is INTEGER
127: *> The leading dimension of the array T. LDT >= K.
128: *> \endverbatim
129: *>
130: *> \param[in,out] C
131: *> \verbatim
132: *> C is DOUBLE PRECISION array, dimension (LDC,N)
133: *> On entry, the m by n matrix C.
134: *> On exit, C is overwritten by H*C or H**T*C or C*H or C*H**T.
135: *> \endverbatim
136: *>
137: *> \param[in] LDC
138: *> \verbatim
139: *> LDC is INTEGER
140: *> The leading dimension of the array C. LDC >= max(1,M).
141: *> \endverbatim
142: *>
143: *> \param[out] WORK
144: *> \verbatim
145: *> WORK is DOUBLE PRECISION array, dimension (LDWORK,K)
146: *> \endverbatim
147: *>
148: *> \param[in] LDWORK
149: *> \verbatim
150: *> LDWORK is INTEGER
151: *> The leading dimension of the array WORK.
152: *> If SIDE = 'L', LDWORK >= max(1,N);
153: *> if SIDE = 'R', LDWORK >= max(1,M).
154: *> \endverbatim
155: *
156: * Authors:
157: * ========
158: *
159: *> \author Univ. of Tennessee
160: *> \author Univ. of California Berkeley
161: *> \author Univ. of Colorado Denver
162: *> \author NAG Ltd.
163: *
164: *> \date June 2013
165: *
166: *> \ingroup doubleOTHERauxiliary
167: *
168: *> \par Further Details:
169: * =====================
170: *>
171: *> \verbatim
172: *>
173: *> The shape of the matrix V and the storage of the vectors which define
174: *> the H(i) is best illustrated by the following example with n = 5 and
175: *> k = 3. The elements equal to 1 are not stored; the corresponding
176: *> array elements are modified but restored on exit. The rest of the
177: *> array is not used.
178: *>
179: *> DIRECT = 'F' and STOREV = 'C': DIRECT = 'F' and STOREV = 'R':
180: *>
181: *> V = ( 1 ) V = ( 1 v1 v1 v1 v1 )
182: *> ( v1 1 ) ( 1 v2 v2 v2 )
183: *> ( v1 v2 1 ) ( 1 v3 v3 )
184: *> ( v1 v2 v3 )
185: *> ( v1 v2 v3 )
186: *>
187: *> DIRECT = 'B' and STOREV = 'C': DIRECT = 'B' and STOREV = 'R':
188: *>
189: *> V = ( v1 v2 v3 ) V = ( v1 v1 1 )
190: *> ( v1 v2 v3 ) ( v2 v2 v2 1 )
191: *> ( 1 v2 v3 ) ( v3 v3 v3 v3 1 )
192: *> ( 1 v3 )
193: *> ( 1 )
194: *> \endverbatim
195: *>
196: * =====================================================================
197: SUBROUTINE DLARFB( SIDE, TRANS, DIRECT, STOREV, M, N, K, V, LDV,
198: $ T, LDT, C, LDC, WORK, LDWORK )
199: *
200: * -- LAPACK auxiliary routine (version 3.7.0) --
201: * -- LAPACK is a software package provided by Univ. of Tennessee, --
202: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
203: * June 2013
204: *
205: * .. Scalar Arguments ..
206: CHARACTER DIRECT, SIDE, STOREV, TRANS
207: INTEGER K, LDC, LDT, LDV, LDWORK, M, N
208: * ..
209: * .. Array Arguments ..
210: DOUBLE PRECISION C( LDC, * ), T( LDT, * ), V( LDV, * ),
211: $ WORK( LDWORK, * )
212: * ..
213: *
214: * =====================================================================
215: *
216: * .. Parameters ..
217: DOUBLE PRECISION ONE
218: PARAMETER ( ONE = 1.0D+0 )
219: * ..
220: * .. Local Scalars ..
221: CHARACTER TRANST
222: INTEGER I, J
223: * ..
224: * .. External Functions ..
225: LOGICAL LSAME
226: EXTERNAL LSAME
227: * ..
228: * .. External Subroutines ..
229: EXTERNAL DCOPY, DGEMM, DTRMM
230: * ..
231: * .. Executable Statements ..
232: *
233: * Quick return if possible
234: *
235: IF( M.LE.0 .OR. N.LE.0 )
236: $ RETURN
237: *
238: IF( LSAME( TRANS, 'N' ) ) THEN
239: TRANST = 'T'
240: ELSE
241: TRANST = 'N'
242: END IF
243: *
244: IF( LSAME( STOREV, 'C' ) ) THEN
245: *
246: IF( LSAME( DIRECT, 'F' ) ) THEN
247: *
248: * Let V = ( V1 ) (first K rows)
249: * ( V2 )
250: * where V1 is unit lower triangular.
251: *
252: IF( LSAME( SIDE, 'L' ) ) THEN
253: *
254: * Form H * C or H**T * C where C = ( C1 )
255: * ( C2 )
256: *
257: * W := C**T * V = (C1**T * V1 + C2**T * V2) (stored in WORK)
258: *
259: * W := C1**T
260: *
261: DO 10 J = 1, K
262: CALL DCOPY( N, C( J, 1 ), LDC, WORK( 1, J ), 1 )
263: 10 CONTINUE
264: *
265: * W := W * V1
266: *
267: CALL DTRMM( 'Right', 'Lower', 'No transpose', 'Unit', N,
268: $ K, ONE, V, LDV, WORK, LDWORK )
269: IF( M.GT.K ) THEN
270: *
271: * W := W + C2**T * V2
272: *
273: CALL DGEMM( 'Transpose', 'No transpose', N, K, M-K,
274: $ ONE, C( K+1, 1 ), LDC, V( K+1, 1 ), LDV,
275: $ ONE, WORK, LDWORK )
276: END IF
277: *
278: * W := W * T**T or W * T
279: *
280: CALL DTRMM( 'Right', 'Upper', TRANST, 'Non-unit', N, K,
281: $ ONE, T, LDT, WORK, LDWORK )
282: *
283: * C := C - V * W**T
284: *
285: IF( M.GT.K ) THEN
286: *
287: * C2 := C2 - V2 * W**T
288: *
289: CALL DGEMM( 'No transpose', 'Transpose', M-K, N, K,
290: $ -ONE, V( K+1, 1 ), LDV, WORK, LDWORK, ONE,
291: $ C( K+1, 1 ), LDC )
292: END IF
293: *
294: * W := W * V1**T
295: *
296: CALL DTRMM( 'Right', 'Lower', 'Transpose', 'Unit', N, K,
297: $ ONE, V, LDV, WORK, LDWORK )
298: *
299: * C1 := C1 - W**T
300: *
301: DO 30 J = 1, K
302: DO 20 I = 1, N
303: C( J, I ) = C( J, I ) - WORK( I, J )
304: 20 CONTINUE
305: 30 CONTINUE
306: *
307: ELSE IF( LSAME( SIDE, 'R' ) ) THEN
308: *
309: * Form C * H or C * H**T where C = ( C1 C2 )
310: *
311: * W := C * V = (C1*V1 + C2*V2) (stored in WORK)
312: *
313: * W := C1
314: *
315: DO 40 J = 1, K
316: CALL DCOPY( M, C( 1, J ), 1, WORK( 1, J ), 1 )
317: 40 CONTINUE
318: *
319: * W := W * V1
320: *
321: CALL DTRMM( 'Right', 'Lower', 'No transpose', 'Unit', M,
322: $ K, ONE, V, LDV, WORK, LDWORK )
323: IF( N.GT.K ) THEN
324: *
325: * W := W + C2 * V2
326: *
327: CALL DGEMM( 'No transpose', 'No transpose', M, K, N-K,
328: $ ONE, C( 1, K+1 ), LDC, V( K+1, 1 ), LDV,
329: $ ONE, WORK, LDWORK )
330: END IF
331: *
332: * W := W * T or W * T**T
333: *
334: CALL DTRMM( 'Right', 'Upper', TRANS, 'Non-unit', M, K,
335: $ ONE, T, LDT, WORK, LDWORK )
336: *
337: * C := C - W * V**T
338: *
339: IF( N.GT.K ) THEN
340: *
341: * C2 := C2 - W * V2**T
342: *
343: CALL DGEMM( 'No transpose', 'Transpose', M, N-K, K,
344: $ -ONE, WORK, LDWORK, V( K+1, 1 ), LDV, ONE,
345: $ C( 1, K+1 ), LDC )
346: END IF
347: *
348: * W := W * V1**T
349: *
350: CALL DTRMM( 'Right', 'Lower', 'Transpose', 'Unit', M, K,
351: $ ONE, V, LDV, WORK, LDWORK )
352: *
353: * C1 := C1 - W
354: *
355: DO 60 J = 1, K
356: DO 50 I = 1, M
357: C( I, J ) = C( I, J ) - WORK( I, J )
358: 50 CONTINUE
359: 60 CONTINUE
360: END IF
361: *
362: ELSE
363: *
364: * Let V = ( V1 )
365: * ( V2 ) (last K rows)
366: * where V2 is unit upper triangular.
367: *
368: IF( LSAME( SIDE, 'L' ) ) THEN
369: *
370: * Form H * C or H**T * C where C = ( C1 )
371: * ( C2 )
372: *
373: * W := C**T * V = (C1**T * V1 + C2**T * V2) (stored in WORK)
374: *
375: * W := C2**T
376: *
377: DO 70 J = 1, K
378: CALL DCOPY( N, C( M-K+J, 1 ), LDC, WORK( 1, J ), 1 )
379: 70 CONTINUE
380: *
381: * W := W * V2
382: *
383: CALL DTRMM( 'Right', 'Upper', 'No transpose', 'Unit', N,
384: $ K, ONE, V( M-K+1, 1 ), LDV, WORK, LDWORK )
385: IF( M.GT.K ) THEN
386: *
387: * W := W + C1**T * V1
388: *
389: CALL DGEMM( 'Transpose', 'No transpose', N, K, M-K,
390: $ ONE, C, LDC, V, LDV, ONE, WORK, LDWORK )
391: END IF
392: *
393: * W := W * T**T or W * T
394: *
395: CALL DTRMM( 'Right', 'Lower', TRANST, 'Non-unit', N, K,
396: $ ONE, T, LDT, WORK, LDWORK )
397: *
398: * C := C - V * W**T
399: *
400: IF( M.GT.K ) THEN
401: *
402: * C1 := C1 - V1 * W**T
403: *
404: CALL DGEMM( 'No transpose', 'Transpose', M-K, N, K,
405: $ -ONE, V, LDV, WORK, LDWORK, ONE, C, LDC )
406: END IF
407: *
408: * W := W * V2**T
409: *
410: CALL DTRMM( 'Right', 'Upper', 'Transpose', 'Unit', N, K,
411: $ ONE, V( M-K+1, 1 ), LDV, WORK, LDWORK )
412: *
413: * C2 := C2 - W**T
414: *
415: DO 90 J = 1, K
416: DO 80 I = 1, N
417: C( M-K+J, I ) = C( M-K+J, I ) - WORK( I, J )
418: 80 CONTINUE
419: 90 CONTINUE
420: *
421: ELSE IF( LSAME( SIDE, 'R' ) ) THEN
422: *
423: * Form C * H or C * H**T where C = ( C1 C2 )
424: *
425: * W := C * V = (C1*V1 + C2*V2) (stored in WORK)
426: *
427: * W := C2
428: *
429: DO 100 J = 1, K
430: CALL DCOPY( M, C( 1, N-K+J ), 1, WORK( 1, J ), 1 )
431: 100 CONTINUE
432: *
433: * W := W * V2
434: *
435: CALL DTRMM( 'Right', 'Upper', 'No transpose', 'Unit', M,
436: $ K, ONE, V( N-K+1, 1 ), LDV, WORK, LDWORK )
437: IF( N.GT.K ) THEN
438: *
439: * W := W + C1 * V1
440: *
441: CALL DGEMM( 'No transpose', 'No transpose', M, K, N-K,
442: $ ONE, C, LDC, V, LDV, ONE, WORK, LDWORK )
443: END IF
444: *
445: * W := W * T or W * T**T
446: *
447: CALL DTRMM( 'Right', 'Lower', TRANS, 'Non-unit', M, K,
448: $ ONE, T, LDT, WORK, LDWORK )
449: *
450: * C := C - W * V**T
451: *
452: IF( N.GT.K ) THEN
453: *
454: * C1 := C1 - W * V1**T
455: *
456: CALL DGEMM( 'No transpose', 'Transpose', M, N-K, K,
457: $ -ONE, WORK, LDWORK, V, LDV, ONE, C, LDC )
458: END IF
459: *
460: * W := W * V2**T
461: *
462: CALL DTRMM( 'Right', 'Upper', 'Transpose', 'Unit', M, K,
463: $ ONE, V( N-K+1, 1 ), LDV, WORK, LDWORK )
464: *
465: * C2 := C2 - W
466: *
467: DO 120 J = 1, K
468: DO 110 I = 1, M
469: C( I, N-K+J ) = C( I, N-K+J ) - WORK( I, J )
470: 110 CONTINUE
471: 120 CONTINUE
472: END IF
473: END IF
474: *
475: ELSE IF( LSAME( STOREV, 'R' ) ) THEN
476: *
477: IF( LSAME( DIRECT, 'F' ) ) THEN
478: *
479: * Let V = ( V1 V2 ) (V1: first K columns)
480: * where V1 is unit upper triangular.
481: *
482: IF( LSAME( SIDE, 'L' ) ) THEN
483: *
484: * Form H * C or H**T * C where C = ( C1 )
485: * ( C2 )
486: *
487: * W := C**T * V**T = (C1**T * V1**T + C2**T * V2**T) (stored in WORK)
488: *
489: * W := C1**T
490: *
491: DO 130 J = 1, K
492: CALL DCOPY( N, C( J, 1 ), LDC, WORK( 1, J ), 1 )
493: 130 CONTINUE
494: *
495: * W := W * V1**T
496: *
497: CALL DTRMM( 'Right', 'Upper', 'Transpose', 'Unit', N, K,
498: $ ONE, V, LDV, WORK, LDWORK )
499: IF( M.GT.K ) THEN
500: *
501: * W := W + C2**T * V2**T
502: *
503: CALL DGEMM( 'Transpose', 'Transpose', N, K, M-K, ONE,
504: $ C( K+1, 1 ), LDC, V( 1, K+1 ), LDV, ONE,
505: $ WORK, LDWORK )
506: END IF
507: *
508: * W := W * T**T or W * T
509: *
510: CALL DTRMM( 'Right', 'Upper', TRANST, 'Non-unit', N, K,
511: $ ONE, T, LDT, WORK, LDWORK )
512: *
513: * C := C - V**T * W**T
514: *
515: IF( M.GT.K ) THEN
516: *
517: * C2 := C2 - V2**T * W**T
518: *
519: CALL DGEMM( 'Transpose', 'Transpose', M-K, N, K, -ONE,
520: $ V( 1, K+1 ), LDV, WORK, LDWORK, ONE,
521: $ C( K+1, 1 ), LDC )
522: END IF
523: *
524: * W := W * V1
525: *
526: CALL DTRMM( 'Right', 'Upper', 'No transpose', 'Unit', N,
527: $ K, ONE, V, LDV, WORK, LDWORK )
528: *
529: * C1 := C1 - W**T
530: *
531: DO 150 J = 1, K
532: DO 140 I = 1, N
533: C( J, I ) = C( J, I ) - WORK( I, J )
534: 140 CONTINUE
535: 150 CONTINUE
536: *
537: ELSE IF( LSAME( SIDE, 'R' ) ) THEN
538: *
539: * Form C * H or C * H**T where C = ( C1 C2 )
540: *
541: * W := C * V**T = (C1*V1**T + C2*V2**T) (stored in WORK)
542: *
543: * W := C1
544: *
545: DO 160 J = 1, K
546: CALL DCOPY( M, C( 1, J ), 1, WORK( 1, J ), 1 )
547: 160 CONTINUE
548: *
549: * W := W * V1**T
550: *
551: CALL DTRMM( 'Right', 'Upper', 'Transpose', 'Unit', M, K,
552: $ ONE, V, LDV, WORK, LDWORK )
553: IF( N.GT.K ) THEN
554: *
555: * W := W + C2 * V2**T
556: *
557: CALL DGEMM( 'No transpose', 'Transpose', M, K, N-K,
558: $ ONE, C( 1, K+1 ), LDC, V( 1, K+1 ), LDV,
559: $ ONE, WORK, LDWORK )
560: END IF
561: *
562: * W := W * T or W * T**T
563: *
564: CALL DTRMM( 'Right', 'Upper', TRANS, 'Non-unit', M, K,
565: $ ONE, T, LDT, WORK, LDWORK )
566: *
567: * C := C - W * V
568: *
569: IF( N.GT.K ) THEN
570: *
571: * C2 := C2 - W * V2
572: *
573: CALL DGEMM( 'No transpose', 'No transpose', M, N-K, K,
574: $ -ONE, WORK, LDWORK, V( 1, K+1 ), LDV, ONE,
575: $ C( 1, K+1 ), LDC )
576: END IF
577: *
578: * W := W * V1
579: *
580: CALL DTRMM( 'Right', 'Upper', 'No transpose', 'Unit', M,
581: $ K, ONE, V, LDV, WORK, LDWORK )
582: *
583: * C1 := C1 - W
584: *
585: DO 180 J = 1, K
586: DO 170 I = 1, M
587: C( I, J ) = C( I, J ) - WORK( I, J )
588: 170 CONTINUE
589: 180 CONTINUE
590: *
591: END IF
592: *
593: ELSE
594: *
595: * Let V = ( V1 V2 ) (V2: last K columns)
596: * where V2 is unit lower triangular.
597: *
598: IF( LSAME( SIDE, 'L' ) ) THEN
599: *
600: * Form H * C or H**T * C where C = ( C1 )
601: * ( C2 )
602: *
603: * W := C**T * V**T = (C1**T * V1**T + C2**T * V2**T) (stored in WORK)
604: *
605: * W := C2**T
606: *
607: DO 190 J = 1, K
608: CALL DCOPY( N, C( M-K+J, 1 ), LDC, WORK( 1, J ), 1 )
609: 190 CONTINUE
610: *
611: * W := W * V2**T
612: *
613: CALL DTRMM( 'Right', 'Lower', 'Transpose', 'Unit', N, K,
614: $ ONE, V( 1, M-K+1 ), LDV, WORK, LDWORK )
615: IF( M.GT.K ) THEN
616: *
617: * W := W + C1**T * V1**T
618: *
619: CALL DGEMM( 'Transpose', 'Transpose', N, K, M-K, ONE,
620: $ C, LDC, V, LDV, ONE, WORK, LDWORK )
621: END IF
622: *
623: * W := W * T**T or W * T
624: *
625: CALL DTRMM( 'Right', 'Lower', TRANST, 'Non-unit', N, K,
626: $ ONE, T, LDT, WORK, LDWORK )
627: *
628: * C := C - V**T * W**T
629: *
630: IF( M.GT.K ) THEN
631: *
632: * C1 := C1 - V1**T * W**T
633: *
634: CALL DGEMM( 'Transpose', 'Transpose', M-K, N, K, -ONE,
635: $ V, LDV, WORK, LDWORK, ONE, C, LDC )
636: END IF
637: *
638: * W := W * V2
639: *
640: CALL DTRMM( 'Right', 'Lower', 'No transpose', 'Unit', N,
641: $ K, ONE, V( 1, M-K+1 ), LDV, WORK, LDWORK )
642: *
643: * C2 := C2 - W**T
644: *
645: DO 210 J = 1, K
646: DO 200 I = 1, N
647: C( M-K+J, I ) = C( M-K+J, I ) - WORK( I, J )
648: 200 CONTINUE
649: 210 CONTINUE
650: *
651: ELSE IF( LSAME( SIDE, 'R' ) ) THEN
652: *
653: * Form C * H or C * H' where C = ( C1 C2 )
654: *
655: * W := C * V**T = (C1*V1**T + C2*V2**T) (stored in WORK)
656: *
657: * W := C2
658: *
659: DO 220 J = 1, K
660: CALL DCOPY( M, C( 1, N-K+J ), 1, WORK( 1, J ), 1 )
661: 220 CONTINUE
662: *
663: * W := W * V2**T
664: *
665: CALL DTRMM( 'Right', 'Lower', 'Transpose', 'Unit', M, K,
666: $ ONE, V( 1, N-K+1 ), LDV, WORK, LDWORK )
667: IF( N.GT.K ) THEN
668: *
669: * W := W + C1 * V1**T
670: *
671: CALL DGEMM( 'No transpose', 'Transpose', M, K, N-K,
672: $ ONE, C, LDC, V, LDV, ONE, WORK, LDWORK )
673: END IF
674: *
675: * W := W * T or W * T**T
676: *
677: CALL DTRMM( 'Right', 'Lower', TRANS, 'Non-unit', M, K,
678: $ ONE, T, LDT, WORK, LDWORK )
679: *
680: * C := C - W * V
681: *
682: IF( N.GT.K ) THEN
683: *
684: * C1 := C1 - W * V1
685: *
686: CALL DGEMM( 'No transpose', 'No transpose', M, N-K, K,
687: $ -ONE, WORK, LDWORK, V, LDV, ONE, C, LDC )
688: END IF
689: *
690: * W := W * V2
691: *
692: CALL DTRMM( 'Right', 'Lower', 'No transpose', 'Unit', M,
693: $ K, ONE, V( 1, N-K+1 ), LDV, WORK, LDWORK )
694: *
695: * C1 := C1 - W
696: *
697: DO 240 J = 1, K
698: DO 230 I = 1, M
699: C( I, N-K+J ) = C( I, N-K+J ) - WORK( I, J )
700: 230 CONTINUE
701: 240 CONTINUE
702: *
703: END IF
704: *
705: END IF
706: END IF
707: *
708: RETURN
709: *
710: * End of DLARFB
711: *
712: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dlarfb.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack