1: *> \brief \b DLANTR returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a trapezoidal or triangular matrix.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DLANTR + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlantr.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlantr.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlantr.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION DLANTR( NORM, UPLO, DIAG, M, N, A, LDA,
22: * WORK )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER DIAG, NORM, UPLO
26: * INTEGER LDA, M, N
27: * ..
28: * .. Array Arguments ..
29: * DOUBLE PRECISION A( LDA, * ), WORK( * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> DLANTR returns the value of the one norm, or the Frobenius norm, or
39: *> the infinity norm, or the element of largest absolute value of a
40: *> trapezoidal or triangular matrix A.
41: *> \endverbatim
42: *>
43: *> \return DLANTR
44: *> \verbatim
45: *>
46: *> DLANTR = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47: *> (
48: *> ( norm1(A), NORM = '1', 'O' or 'o'
49: *> (
50: *> ( normI(A), NORM = 'I' or 'i'
51: *> (
52: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53: *>
54: *> where norm1 denotes the one norm of a matrix (maximum column sum),
55: *> normI denotes the infinity norm of a matrix (maximum row sum) and
56: *> normF denotes the Frobenius norm of a matrix (square root of sum of
57: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58: *> \endverbatim
59: *
60: * Arguments:
61: * ==========
62: *
63: *> \param[in] NORM
64: *> \verbatim
65: *> NORM is CHARACTER*1
66: *> Specifies the value to be returned in DLANTR as described
67: *> above.
68: *> \endverbatim
69: *>
70: *> \param[in] UPLO
71: *> \verbatim
72: *> UPLO is CHARACTER*1
73: *> Specifies whether the matrix A is upper or lower trapezoidal.
74: *> = 'U': Upper trapezoidal
75: *> = 'L': Lower trapezoidal
76: *> Note that A is triangular instead of trapezoidal if M = N.
77: *> \endverbatim
78: *>
79: *> \param[in] DIAG
80: *> \verbatim
81: *> DIAG is CHARACTER*1
82: *> Specifies whether or not the matrix A has unit diagonal.
83: *> = 'N': Non-unit diagonal
84: *> = 'U': Unit diagonal
85: *> \endverbatim
86: *>
87: *> \param[in] M
88: *> \verbatim
89: *> M is INTEGER
90: *> The number of rows of the matrix A. M >= 0, and if
91: *> UPLO = 'U', M <= N. When M = 0, DLANTR is set to zero.
92: *> \endverbatim
93: *>
94: *> \param[in] N
95: *> \verbatim
96: *> N is INTEGER
97: *> The number of columns of the matrix A. N >= 0, and if
98: *> UPLO = 'L', N <= M. When N = 0, DLANTR is set to zero.
99: *> \endverbatim
100: *>
101: *> \param[in] A
102: *> \verbatim
103: *> A is DOUBLE PRECISION array, dimension (LDA,N)
104: *> The trapezoidal matrix A (A is triangular if M = N).
105: *> If UPLO = 'U', the leading m by n upper trapezoidal part of
106: *> the array A contains the upper trapezoidal matrix, and the
107: *> strictly lower triangular part of A is not referenced.
108: *> If UPLO = 'L', the leading m by n lower trapezoidal part of
109: *> the array A contains the lower trapezoidal matrix, and the
110: *> strictly upper triangular part of A is not referenced. Note
111: *> that when DIAG = 'U', the diagonal elements of A are not
112: *> referenced and are assumed to be one.
113: *> \endverbatim
114: *>
115: *> \param[in] LDA
116: *> \verbatim
117: *> LDA is INTEGER
118: *> The leading dimension of the array A. LDA >= max(M,1).
119: *> \endverbatim
120: *>
121: *> \param[out] WORK
122: *> \verbatim
123: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
124: *> where LWORK >= M when NORM = 'I'; otherwise, WORK is not
125: *> referenced.
126: *> \endverbatim
127: *
128: * Authors:
129: * ========
130: *
131: *> \author Univ. of Tennessee
132: *> \author Univ. of California Berkeley
133: *> \author Univ. of Colorado Denver
134: *> \author NAG Ltd.
135: *
136: *> \date December 2016
137: *
138: *> \ingroup doubleOTHERauxiliary
139: *
140: * =====================================================================
141: DOUBLE PRECISION FUNCTION DLANTR( NORM, UPLO, DIAG, M, N, A, LDA,
142: $ WORK )
143: *
144: * -- LAPACK auxiliary routine (version 3.7.0) --
145: * -- LAPACK is a software package provided by Univ. of Tennessee, --
146: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
147: * December 2016
148: *
149: IMPLICIT NONE
150: * .. Scalar Arguments ..
151: CHARACTER DIAG, NORM, UPLO
152: INTEGER LDA, M, N
153: * ..
154: * .. Array Arguments ..
155: DOUBLE PRECISION A( LDA, * ), WORK( * )
156: * ..
157: *
158: * =====================================================================
159: *
160: * .. Parameters ..
161: DOUBLE PRECISION ONE, ZERO
162: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
163: * ..
164: * .. Local Scalars ..
165: LOGICAL UDIAG
166: INTEGER I, J
167: DOUBLE PRECISION SUM, VALUE
168: * ..
169: * .. Local Arrays ..
170: DOUBLE PRECISION SSQ( 2 ), COLSSQ( 2 )
171: * ..
172: * .. External Functions ..
173: LOGICAL LSAME, DISNAN
174: EXTERNAL LSAME, DISNAN
175: * ..
176: * .. External Subroutines ..
177: EXTERNAL DLASSQ, DCOMBSSQ
178: * ..
179: * .. Intrinsic Functions ..
180: INTRINSIC ABS, MIN, SQRT
181: * ..
182: * .. Executable Statements ..
183: *
184: IF( MIN( M, N ).EQ.0 ) THEN
185: VALUE = ZERO
186: ELSE IF( LSAME( NORM, 'M' ) ) THEN
187: *
188: * Find max(abs(A(i,j))).
189: *
190: IF( LSAME( DIAG, 'U' ) ) THEN
191: VALUE = ONE
192: IF( LSAME( UPLO, 'U' ) ) THEN
193: DO 20 J = 1, N
194: DO 10 I = 1, MIN( M, J-1 )
195: SUM = ABS( A( I, J ) )
196: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
197: 10 CONTINUE
198: 20 CONTINUE
199: ELSE
200: DO 40 J = 1, N
201: DO 30 I = J + 1, M
202: SUM = ABS( A( I, J ) )
203: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
204: 30 CONTINUE
205: 40 CONTINUE
206: END IF
207: ELSE
208: VALUE = ZERO
209: IF( LSAME( UPLO, 'U' ) ) THEN
210: DO 60 J = 1, N
211: DO 50 I = 1, MIN( M, J )
212: SUM = ABS( A( I, J ) )
213: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
214: 50 CONTINUE
215: 60 CONTINUE
216: ELSE
217: DO 80 J = 1, N
218: DO 70 I = J, M
219: SUM = ABS( A( I, J ) )
220: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
221: 70 CONTINUE
222: 80 CONTINUE
223: END IF
224: END IF
225: ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
226: *
227: * Find norm1(A).
228: *
229: VALUE = ZERO
230: UDIAG = LSAME( DIAG, 'U' )
231: IF( LSAME( UPLO, 'U' ) ) THEN
232: DO 110 J = 1, N
233: IF( ( UDIAG ) .AND. ( J.LE.M ) ) THEN
234: SUM = ONE
235: DO 90 I = 1, J - 1
236: SUM = SUM + ABS( A( I, J ) )
237: 90 CONTINUE
238: ELSE
239: SUM = ZERO
240: DO 100 I = 1, MIN( M, J )
241: SUM = SUM + ABS( A( I, J ) )
242: 100 CONTINUE
243: END IF
244: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
245: 110 CONTINUE
246: ELSE
247: DO 140 J = 1, N
248: IF( UDIAG ) THEN
249: SUM = ONE
250: DO 120 I = J + 1, M
251: SUM = SUM + ABS( A( I, J ) )
252: 120 CONTINUE
253: ELSE
254: SUM = ZERO
255: DO 130 I = J, M
256: SUM = SUM + ABS( A( I, J ) )
257: 130 CONTINUE
258: END IF
259: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
260: 140 CONTINUE
261: END IF
262: ELSE IF( LSAME( NORM, 'I' ) ) THEN
263: *
264: * Find normI(A).
265: *
266: IF( LSAME( UPLO, 'U' ) ) THEN
267: IF( LSAME( DIAG, 'U' ) ) THEN
268: DO 150 I = 1, M
269: WORK( I ) = ONE
270: 150 CONTINUE
271: DO 170 J = 1, N
272: DO 160 I = 1, MIN( M, J-1 )
273: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
274: 160 CONTINUE
275: 170 CONTINUE
276: ELSE
277: DO 180 I = 1, M
278: WORK( I ) = ZERO
279: 180 CONTINUE
280: DO 200 J = 1, N
281: DO 190 I = 1, MIN( M, J )
282: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
283: 190 CONTINUE
284: 200 CONTINUE
285: END IF
286: ELSE
287: IF( LSAME( DIAG, 'U' ) ) THEN
288: DO 210 I = 1, N
289: WORK( I ) = ONE
290: 210 CONTINUE
291: DO 220 I = N + 1, M
292: WORK( I ) = ZERO
293: 220 CONTINUE
294: DO 240 J = 1, N
295: DO 230 I = J + 1, M
296: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
297: 230 CONTINUE
298: 240 CONTINUE
299: ELSE
300: DO 250 I = 1, M
301: WORK( I ) = ZERO
302: 250 CONTINUE
303: DO 270 J = 1, N
304: DO 260 I = J, M
305: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
306: 260 CONTINUE
307: 270 CONTINUE
308: END IF
309: END IF
310: VALUE = ZERO
311: DO 280 I = 1, M
312: SUM = WORK( I )
313: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
314: 280 CONTINUE
315: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
316: *
317: * Find normF(A).
318: * SSQ(1) is scale
319: * SSQ(2) is sum-of-squares
320: * For better accuracy, sum each column separately.
321: *
322: IF( LSAME( UPLO, 'U' ) ) THEN
323: IF( LSAME( DIAG, 'U' ) ) THEN
324: SSQ( 1 ) = ONE
325: SSQ( 2 ) = MIN( M, N )
326: DO 290 J = 2, N
327: COLSSQ( 1 ) = ZERO
328: COLSSQ( 2 ) = ONE
329: CALL DLASSQ( MIN( M, J-1 ), A( 1, J ), 1,
330: $ COLSSQ( 1 ), COLSSQ( 2 ) )
331: CALL DCOMBSSQ( SSQ, COLSSQ )
332: 290 CONTINUE
333: ELSE
334: SSQ( 1 ) = ZERO
335: SSQ( 2 ) = ONE
336: DO 300 J = 1, N
337: COLSSQ( 1 ) = ZERO
338: COLSSQ( 2 ) = ONE
339: CALL DLASSQ( MIN( M, J ), A( 1, J ), 1,
340: $ COLSSQ( 1 ), COLSSQ( 2 ) )
341: CALL DCOMBSSQ( SSQ, COLSSQ )
342: 300 CONTINUE
343: END IF
344: ELSE
345: IF( LSAME( DIAG, 'U' ) ) THEN
346: SSQ( 1 ) = ONE
347: SSQ( 2 ) = MIN( M, N )
348: DO 310 J = 1, N
349: COLSSQ( 1 ) = ZERO
350: COLSSQ( 2 ) = ONE
351: CALL DLASSQ( M-J, A( MIN( M, J+1 ), J ), 1,
352: $ COLSSQ( 1 ), COLSSQ( 2 ) )
353: CALL DCOMBSSQ( SSQ, COLSSQ )
354: 310 CONTINUE
355: ELSE
356: SSQ( 1 ) = ZERO
357: SSQ( 2 ) = ONE
358: DO 320 J = 1, N
359: COLSSQ( 1 ) = ZERO
360: COLSSQ( 2 ) = ONE
361: CALL DLASSQ( M-J+1, A( J, J ), 1,
362: $ COLSSQ( 1 ), COLSSQ( 2 ) )
363: CALL DCOMBSSQ( SSQ, COLSSQ )
364: 320 CONTINUE
365: END IF
366: END IF
367: VALUE = SSQ( 1 )*SQRT( SSQ( 2 ) )
368: END IF
369: *
370: DLANTR = VALUE
371: RETURN
372: *
373: * End of DLANTR
374: *
375: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dlantr.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack