1: *> \brief \b DLANTR
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DLANTR + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlantr.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlantr.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlantr.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION DLANTR( NORM, UPLO, DIAG, M, N, A, LDA,
22: * WORK )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER DIAG, NORM, UPLO
26: * INTEGER LDA, M, N
27: * ..
28: * .. Array Arguments ..
29: * DOUBLE PRECISION A( LDA, * ), WORK( * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> DLANTR returns the value of the one norm, or the Frobenius norm, or
39: *> the infinity norm, or the element of largest absolute value of a
40: *> trapezoidal or triangular matrix A.
41: *> \endverbatim
42: *>
43: *> \return DLANTR
44: *> \verbatim
45: *>
46: *> DLANTR = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47: *> (
48: *> ( norm1(A), NORM = '1', 'O' or 'o'
49: *> (
50: *> ( normI(A), NORM = 'I' or 'i'
51: *> (
52: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53: *>
54: *> where norm1 denotes the one norm of a matrix (maximum column sum),
55: *> normI denotes the infinity norm of a matrix (maximum row sum) and
56: *> normF denotes the Frobenius norm of a matrix (square root of sum of
57: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58: *> \endverbatim
59: *
60: * Arguments:
61: * ==========
62: *
63: *> \param[in] NORM
64: *> \verbatim
65: *> NORM is CHARACTER*1
66: *> Specifies the value to be returned in DLANTR as described
67: *> above.
68: *> \endverbatim
69: *>
70: *> \param[in] UPLO
71: *> \verbatim
72: *> UPLO is CHARACTER*1
73: *> Specifies whether the matrix A is upper or lower trapezoidal.
74: *> = 'U': Upper trapezoidal
75: *> = 'L': Lower trapezoidal
76: *> Note that A is triangular instead of trapezoidal if M = N.
77: *> \endverbatim
78: *>
79: *> \param[in] DIAG
80: *> \verbatim
81: *> DIAG is CHARACTER*1
82: *> Specifies whether or not the matrix A has unit diagonal.
83: *> = 'N': Non-unit diagonal
84: *> = 'U': Unit diagonal
85: *> \endverbatim
86: *>
87: *> \param[in] M
88: *> \verbatim
89: *> M is INTEGER
90: *> The number of rows of the matrix A. M >= 0, and if
91: *> UPLO = 'U', M <= N. When M = 0, DLANTR is set to zero.
92: *> \endverbatim
93: *>
94: *> \param[in] N
95: *> \verbatim
96: *> N is INTEGER
97: *> The number of columns of the matrix A. N >= 0, and if
98: *> UPLO = 'L', N <= M. When N = 0, DLANTR is set to zero.
99: *> \endverbatim
100: *>
101: *> \param[in] A
102: *> \verbatim
103: *> A is DOUBLE PRECISION array, dimension (LDA,N)
104: *> The trapezoidal matrix A (A is triangular if M = N).
105: *> If UPLO = 'U', the leading m by n upper trapezoidal part of
106: *> the array A contains the upper trapezoidal matrix, and the
107: *> strictly lower triangular part of A is not referenced.
108: *> If UPLO = 'L', the leading m by n lower trapezoidal part of
109: *> the array A contains the lower trapezoidal matrix, and the
110: *> strictly upper triangular part of A is not referenced. Note
111: *> that when DIAG = 'U', the diagonal elements of A are not
112: *> referenced and are assumed to be one.
113: *> \endverbatim
114: *>
115: *> \param[in] LDA
116: *> \verbatim
117: *> LDA is INTEGER
118: *> The leading dimension of the array A. LDA >= max(M,1).
119: *> \endverbatim
120: *>
121: *> \param[out] WORK
122: *> \verbatim
123: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
124: *> where LWORK >= M when NORM = 'I'; otherwise, WORK is not
125: *> referenced.
126: *> \endverbatim
127: *
128: * Authors:
129: * ========
130: *
131: *> \author Univ. of Tennessee
132: *> \author Univ. of California Berkeley
133: *> \author Univ. of Colorado Denver
134: *> \author NAG Ltd.
135: *
136: *> \date November 2011
137: *
138: *> \ingroup doubleOTHERauxiliary
139: *
140: * =====================================================================
141: DOUBLE PRECISION FUNCTION DLANTR( NORM, UPLO, DIAG, M, N, A, LDA,
142: $ WORK )
143: *
144: * -- LAPACK auxiliary routine (version 3.4.0) --
145: * -- LAPACK is a software package provided by Univ. of Tennessee, --
146: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
147: * November 2011
148: *
149: * .. Scalar Arguments ..
150: CHARACTER DIAG, NORM, UPLO
151: INTEGER LDA, M, N
152: * ..
153: * .. Array Arguments ..
154: DOUBLE PRECISION A( LDA, * ), WORK( * )
155: * ..
156: *
157: * =====================================================================
158: *
159: * .. Parameters ..
160: DOUBLE PRECISION ONE, ZERO
161: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
162: * ..
163: * .. Local Scalars ..
164: LOGICAL UDIAG
165: INTEGER I, J
166: DOUBLE PRECISION SCALE, SUM, VALUE
167: * ..
168: * .. External Subroutines ..
169: EXTERNAL DLASSQ
170: * ..
171: * .. External Functions ..
172: LOGICAL LSAME
173: EXTERNAL LSAME
174: * ..
175: * .. Intrinsic Functions ..
176: INTRINSIC ABS, MAX, MIN, SQRT
177: * ..
178: * .. Executable Statements ..
179: *
180: IF( MIN( M, N ).EQ.0 ) THEN
181: VALUE = ZERO
182: ELSE IF( LSAME( NORM, 'M' ) ) THEN
183: *
184: * Find max(abs(A(i,j))).
185: *
186: IF( LSAME( DIAG, 'U' ) ) THEN
187: VALUE = ONE
188: IF( LSAME( UPLO, 'U' ) ) THEN
189: DO 20 J = 1, N
190: DO 10 I = 1, MIN( M, J-1 )
191: VALUE = MAX( VALUE, ABS( A( I, J ) ) )
192: 10 CONTINUE
193: 20 CONTINUE
194: ELSE
195: DO 40 J = 1, N
196: DO 30 I = J + 1, M
197: VALUE = MAX( VALUE, ABS( A( I, J ) ) )
198: 30 CONTINUE
199: 40 CONTINUE
200: END IF
201: ELSE
202: VALUE = ZERO
203: IF( LSAME( UPLO, 'U' ) ) THEN
204: DO 60 J = 1, N
205: DO 50 I = 1, MIN( M, J )
206: VALUE = MAX( VALUE, ABS( A( I, J ) ) )
207: 50 CONTINUE
208: 60 CONTINUE
209: ELSE
210: DO 80 J = 1, N
211: DO 70 I = J, M
212: VALUE = MAX( VALUE, ABS( A( I, J ) ) )
213: 70 CONTINUE
214: 80 CONTINUE
215: END IF
216: END IF
217: ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
218: *
219: * Find norm1(A).
220: *
221: VALUE = ZERO
222: UDIAG = LSAME( DIAG, 'U' )
223: IF( LSAME( UPLO, 'U' ) ) THEN
224: DO 110 J = 1, N
225: IF( ( UDIAG ) .AND. ( J.LE.M ) ) THEN
226: SUM = ONE
227: DO 90 I = 1, J - 1
228: SUM = SUM + ABS( A( I, J ) )
229: 90 CONTINUE
230: ELSE
231: SUM = ZERO
232: DO 100 I = 1, MIN( M, J )
233: SUM = SUM + ABS( A( I, J ) )
234: 100 CONTINUE
235: END IF
236: VALUE = MAX( VALUE, SUM )
237: 110 CONTINUE
238: ELSE
239: DO 140 J = 1, N
240: IF( UDIAG ) THEN
241: SUM = ONE
242: DO 120 I = J + 1, M
243: SUM = SUM + ABS( A( I, J ) )
244: 120 CONTINUE
245: ELSE
246: SUM = ZERO
247: DO 130 I = J, M
248: SUM = SUM + ABS( A( I, J ) )
249: 130 CONTINUE
250: END IF
251: VALUE = MAX( VALUE, SUM )
252: 140 CONTINUE
253: END IF
254: ELSE IF( LSAME( NORM, 'I' ) ) THEN
255: *
256: * Find normI(A).
257: *
258: IF( LSAME( UPLO, 'U' ) ) THEN
259: IF( LSAME( DIAG, 'U' ) ) THEN
260: DO 150 I = 1, M
261: WORK( I ) = ONE
262: 150 CONTINUE
263: DO 170 J = 1, N
264: DO 160 I = 1, MIN( M, J-1 )
265: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
266: 160 CONTINUE
267: 170 CONTINUE
268: ELSE
269: DO 180 I = 1, M
270: WORK( I ) = ZERO
271: 180 CONTINUE
272: DO 200 J = 1, N
273: DO 190 I = 1, MIN( M, J )
274: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
275: 190 CONTINUE
276: 200 CONTINUE
277: END IF
278: ELSE
279: IF( LSAME( DIAG, 'U' ) ) THEN
280: DO 210 I = 1, N
281: WORK( I ) = ONE
282: 210 CONTINUE
283: DO 220 I = N + 1, M
284: WORK( I ) = ZERO
285: 220 CONTINUE
286: DO 240 J = 1, N
287: DO 230 I = J + 1, M
288: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
289: 230 CONTINUE
290: 240 CONTINUE
291: ELSE
292: DO 250 I = 1, M
293: WORK( I ) = ZERO
294: 250 CONTINUE
295: DO 270 J = 1, N
296: DO 260 I = J, M
297: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
298: 260 CONTINUE
299: 270 CONTINUE
300: END IF
301: END IF
302: VALUE = ZERO
303: DO 280 I = 1, M
304: VALUE = MAX( VALUE, WORK( I ) )
305: 280 CONTINUE
306: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
307: *
308: * Find normF(A).
309: *
310: IF( LSAME( UPLO, 'U' ) ) THEN
311: IF( LSAME( DIAG, 'U' ) ) THEN
312: SCALE = ONE
313: SUM = MIN( M, N )
314: DO 290 J = 2, N
315: CALL DLASSQ( MIN( M, J-1 ), A( 1, J ), 1, SCALE, SUM )
316: 290 CONTINUE
317: ELSE
318: SCALE = ZERO
319: SUM = ONE
320: DO 300 J = 1, N
321: CALL DLASSQ( MIN( M, J ), A( 1, J ), 1, SCALE, SUM )
322: 300 CONTINUE
323: END IF
324: ELSE
325: IF( LSAME( DIAG, 'U' ) ) THEN
326: SCALE = ONE
327: SUM = MIN( M, N )
328: DO 310 J = 1, N
329: CALL DLASSQ( M-J, A( MIN( M, J+1 ), J ), 1, SCALE,
330: $ SUM )
331: 310 CONTINUE
332: ELSE
333: SCALE = ZERO
334: SUM = ONE
335: DO 320 J = 1, N
336: CALL DLASSQ( M-J+1, A( J, J ), 1, SCALE, SUM )
337: 320 CONTINUE
338: END IF
339: END IF
340: VALUE = SCALE*SQRT( SUM )
341: END IF
342: *
343: DLANTR = VALUE
344: RETURN
345: *
346: * End of DLANTR
347: *
348: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dlantr.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack