Annotation of rpl/lapack/lapack/dlantb.f, revision 1.8
1.8 ! bertrand 1: *> \brief \b DLANTB
! 2: *
! 3: * =========== DOCUMENTATION ===========
! 4: *
! 5: * Online html documentation available at
! 6: * http://www.netlib.org/lapack/explore-html/
! 7: *
! 8: *> \htmlonly
! 9: *> Download DLANTB + dependencies
! 10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlantb.f">
! 11: *> [TGZ]</a>
! 12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlantb.f">
! 13: *> [ZIP]</a>
! 14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlantb.f">
! 15: *> [TXT]</a>
! 16: *> \endhtmlonly
! 17: *
! 18: * Definition:
! 19: * ===========
! 20: *
! 21: * DOUBLE PRECISION FUNCTION DLANTB( NORM, UPLO, DIAG, N, K, AB,
! 22: * LDAB, WORK )
! 23: *
! 24: * .. Scalar Arguments ..
! 25: * CHARACTER DIAG, NORM, UPLO
! 26: * INTEGER K, LDAB, N
! 27: * ..
! 28: * .. Array Arguments ..
! 29: * DOUBLE PRECISION AB( LDAB, * ), WORK( * )
! 30: * ..
! 31: *
! 32: *
! 33: *> \par Purpose:
! 34: * =============
! 35: *>
! 36: *> \verbatim
! 37: *>
! 38: *> DLANTB returns the value of the one norm, or the Frobenius norm, or
! 39: *> the infinity norm, or the element of largest absolute value of an
! 40: *> n by n triangular band matrix A, with ( k + 1 ) diagonals.
! 41: *> \endverbatim
! 42: *>
! 43: *> \return DLANTB
! 44: *> \verbatim
! 45: *>
! 46: *> DLANTB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
! 47: *> (
! 48: *> ( norm1(A), NORM = '1', 'O' or 'o'
! 49: *> (
! 50: *> ( normI(A), NORM = 'I' or 'i'
! 51: *> (
! 52: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
! 53: *>
! 54: *> where norm1 denotes the one norm of a matrix (maximum column sum),
! 55: *> normI denotes the infinity norm of a matrix (maximum row sum) and
! 56: *> normF denotes the Frobenius norm of a matrix (square root of sum of
! 57: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
! 58: *> \endverbatim
! 59: *
! 60: * Arguments:
! 61: * ==========
! 62: *
! 63: *> \param[in] NORM
! 64: *> \verbatim
! 65: *> NORM is CHARACTER*1
! 66: *> Specifies the value to be returned in DLANTB as described
! 67: *> above.
! 68: *> \endverbatim
! 69: *>
! 70: *> \param[in] UPLO
! 71: *> \verbatim
! 72: *> UPLO is CHARACTER*1
! 73: *> Specifies whether the matrix A is upper or lower triangular.
! 74: *> = 'U': Upper triangular
! 75: *> = 'L': Lower triangular
! 76: *> \endverbatim
! 77: *>
! 78: *> \param[in] DIAG
! 79: *> \verbatim
! 80: *> DIAG is CHARACTER*1
! 81: *> Specifies whether or not the matrix A is unit triangular.
! 82: *> = 'N': Non-unit triangular
! 83: *> = 'U': Unit triangular
! 84: *> \endverbatim
! 85: *>
! 86: *> \param[in] N
! 87: *> \verbatim
! 88: *> N is INTEGER
! 89: *> The order of the matrix A. N >= 0. When N = 0, DLANTB is
! 90: *> set to zero.
! 91: *> \endverbatim
! 92: *>
! 93: *> \param[in] K
! 94: *> \verbatim
! 95: *> K is INTEGER
! 96: *> The number of super-diagonals of the matrix A if UPLO = 'U',
! 97: *> or the number of sub-diagonals of the matrix A if UPLO = 'L'.
! 98: *> K >= 0.
! 99: *> \endverbatim
! 100: *>
! 101: *> \param[in] AB
! 102: *> \verbatim
! 103: *> AB is DOUBLE PRECISION array, dimension (LDAB,N)
! 104: *> The upper or lower triangular band matrix A, stored in the
! 105: *> first k+1 rows of AB. The j-th column of A is stored
! 106: *> in the j-th column of the array AB as follows:
! 107: *> if UPLO = 'U', AB(k+1+i-j,j) = A(i,j) for max(1,j-k)<=i<=j;
! 108: *> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+k).
! 109: *> Note that when DIAG = 'U', the elements of the array AB
! 110: *> corresponding to the diagonal elements of the matrix A are
! 111: *> not referenced, but are assumed to be one.
! 112: *> \endverbatim
! 113: *>
! 114: *> \param[in] LDAB
! 115: *> \verbatim
! 116: *> LDAB is INTEGER
! 117: *> The leading dimension of the array AB. LDAB >= K+1.
! 118: *> \endverbatim
! 119: *>
! 120: *> \param[out] WORK
! 121: *> \verbatim
! 122: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
! 123: *> where LWORK >= N when NORM = 'I'; otherwise, WORK is not
! 124: *> referenced.
! 125: *> \endverbatim
! 126: *
! 127: * Authors:
! 128: * ========
! 129: *
! 130: *> \author Univ. of Tennessee
! 131: *> \author Univ. of California Berkeley
! 132: *> \author Univ. of Colorado Denver
! 133: *> \author NAG Ltd.
! 134: *
! 135: *> \date November 2011
! 136: *
! 137: *> \ingroup doubleOTHERauxiliary
! 138: *
! 139: * =====================================================================
1.1 bertrand 140: DOUBLE PRECISION FUNCTION DLANTB( NORM, UPLO, DIAG, N, K, AB,
141: $ LDAB, WORK )
142: *
1.8 ! bertrand 143: * -- LAPACK auxiliary routine (version 3.4.0) --
1.1 bertrand 144: * -- LAPACK is a software package provided by Univ. of Tennessee, --
145: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
1.8 ! bertrand 146: * November 2011
1.1 bertrand 147: *
148: * .. Scalar Arguments ..
149: CHARACTER DIAG, NORM, UPLO
150: INTEGER K, LDAB, N
151: * ..
152: * .. Array Arguments ..
153: DOUBLE PRECISION AB( LDAB, * ), WORK( * )
154: * ..
155: *
156: * =====================================================================
157: *
158: * .. Parameters ..
159: DOUBLE PRECISION ONE, ZERO
160: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
161: * ..
162: * .. Local Scalars ..
163: LOGICAL UDIAG
164: INTEGER I, J, L
165: DOUBLE PRECISION SCALE, SUM, VALUE
166: * ..
167: * .. External Subroutines ..
168: EXTERNAL DLASSQ
169: * ..
170: * .. External Functions ..
171: LOGICAL LSAME
172: EXTERNAL LSAME
173: * ..
174: * .. Intrinsic Functions ..
175: INTRINSIC ABS, MAX, MIN, SQRT
176: * ..
177: * .. Executable Statements ..
178: *
179: IF( N.EQ.0 ) THEN
180: VALUE = ZERO
181: ELSE IF( LSAME( NORM, 'M' ) ) THEN
182: *
183: * Find max(abs(A(i,j))).
184: *
185: IF( LSAME( DIAG, 'U' ) ) THEN
186: VALUE = ONE
187: IF( LSAME( UPLO, 'U' ) ) THEN
188: DO 20 J = 1, N
189: DO 10 I = MAX( K+2-J, 1 ), K
190: VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
191: 10 CONTINUE
192: 20 CONTINUE
193: ELSE
194: DO 40 J = 1, N
195: DO 30 I = 2, MIN( N+1-J, K+1 )
196: VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
197: 30 CONTINUE
198: 40 CONTINUE
199: END IF
200: ELSE
201: VALUE = ZERO
202: IF( LSAME( UPLO, 'U' ) ) THEN
203: DO 60 J = 1, N
204: DO 50 I = MAX( K+2-J, 1 ), K + 1
205: VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
206: 50 CONTINUE
207: 60 CONTINUE
208: ELSE
209: DO 80 J = 1, N
210: DO 70 I = 1, MIN( N+1-J, K+1 )
211: VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
212: 70 CONTINUE
213: 80 CONTINUE
214: END IF
215: END IF
216: ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
217: *
218: * Find norm1(A).
219: *
220: VALUE = ZERO
221: UDIAG = LSAME( DIAG, 'U' )
222: IF( LSAME( UPLO, 'U' ) ) THEN
223: DO 110 J = 1, N
224: IF( UDIAG ) THEN
225: SUM = ONE
226: DO 90 I = MAX( K+2-J, 1 ), K
227: SUM = SUM + ABS( AB( I, J ) )
228: 90 CONTINUE
229: ELSE
230: SUM = ZERO
231: DO 100 I = MAX( K+2-J, 1 ), K + 1
232: SUM = SUM + ABS( AB( I, J ) )
233: 100 CONTINUE
234: END IF
235: VALUE = MAX( VALUE, SUM )
236: 110 CONTINUE
237: ELSE
238: DO 140 J = 1, N
239: IF( UDIAG ) THEN
240: SUM = ONE
241: DO 120 I = 2, MIN( N+1-J, K+1 )
242: SUM = SUM + ABS( AB( I, J ) )
243: 120 CONTINUE
244: ELSE
245: SUM = ZERO
246: DO 130 I = 1, MIN( N+1-J, K+1 )
247: SUM = SUM + ABS( AB( I, J ) )
248: 130 CONTINUE
249: END IF
250: VALUE = MAX( VALUE, SUM )
251: 140 CONTINUE
252: END IF
253: ELSE IF( LSAME( NORM, 'I' ) ) THEN
254: *
255: * Find normI(A).
256: *
257: VALUE = ZERO
258: IF( LSAME( UPLO, 'U' ) ) THEN
259: IF( LSAME( DIAG, 'U' ) ) THEN
260: DO 150 I = 1, N
261: WORK( I ) = ONE
262: 150 CONTINUE
263: DO 170 J = 1, N
264: L = K + 1 - J
265: DO 160 I = MAX( 1, J-K ), J - 1
266: WORK( I ) = WORK( I ) + ABS( AB( L+I, J ) )
267: 160 CONTINUE
268: 170 CONTINUE
269: ELSE
270: DO 180 I = 1, N
271: WORK( I ) = ZERO
272: 180 CONTINUE
273: DO 200 J = 1, N
274: L = K + 1 - J
275: DO 190 I = MAX( 1, J-K ), J
276: WORK( I ) = WORK( I ) + ABS( AB( L+I, J ) )
277: 190 CONTINUE
278: 200 CONTINUE
279: END IF
280: ELSE
281: IF( LSAME( DIAG, 'U' ) ) THEN
282: DO 210 I = 1, N
283: WORK( I ) = ONE
284: 210 CONTINUE
285: DO 230 J = 1, N
286: L = 1 - J
287: DO 220 I = J + 1, MIN( N, J+K )
288: WORK( I ) = WORK( I ) + ABS( AB( L+I, J ) )
289: 220 CONTINUE
290: 230 CONTINUE
291: ELSE
292: DO 240 I = 1, N
293: WORK( I ) = ZERO
294: 240 CONTINUE
295: DO 260 J = 1, N
296: L = 1 - J
297: DO 250 I = J, MIN( N, J+K )
298: WORK( I ) = WORK( I ) + ABS( AB( L+I, J ) )
299: 250 CONTINUE
300: 260 CONTINUE
301: END IF
302: END IF
303: DO 270 I = 1, N
304: VALUE = MAX( VALUE, WORK( I ) )
305: 270 CONTINUE
306: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
307: *
308: * Find normF(A).
309: *
310: IF( LSAME( UPLO, 'U' ) ) THEN
311: IF( LSAME( DIAG, 'U' ) ) THEN
312: SCALE = ONE
313: SUM = N
314: IF( K.GT.0 ) THEN
315: DO 280 J = 2, N
316: CALL DLASSQ( MIN( J-1, K ),
317: $ AB( MAX( K+2-J, 1 ), J ), 1, SCALE,
318: $ SUM )
319: 280 CONTINUE
320: END IF
321: ELSE
322: SCALE = ZERO
323: SUM = ONE
324: DO 290 J = 1, N
325: CALL DLASSQ( MIN( J, K+1 ), AB( MAX( K+2-J, 1 ), J ),
326: $ 1, SCALE, SUM )
327: 290 CONTINUE
328: END IF
329: ELSE
330: IF( LSAME( DIAG, 'U' ) ) THEN
331: SCALE = ONE
332: SUM = N
333: IF( K.GT.0 ) THEN
334: DO 300 J = 1, N - 1
335: CALL DLASSQ( MIN( N-J, K ), AB( 2, J ), 1, SCALE,
336: $ SUM )
337: 300 CONTINUE
338: END IF
339: ELSE
340: SCALE = ZERO
341: SUM = ONE
342: DO 310 J = 1, N
343: CALL DLASSQ( MIN( N-J+1, K+1 ), AB( 1, J ), 1, SCALE,
344: $ SUM )
345: 310 CONTINUE
346: END IF
347: END IF
348: VALUE = SCALE*SQRT( SUM )
349: END IF
350: *
351: DLANTB = VALUE
352: RETURN
353: *
354: * End of DLANTB
355: *
356: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dlantb.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack