1: *> \brief \b DLANHS returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of an upper Hessenberg matrix.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DLANHS + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlanhs.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlanhs.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlanhs.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION DLANHS( NORM, N, A, LDA, WORK )
22: *
23: * .. Scalar Arguments ..
24: * CHARACTER NORM
25: * INTEGER LDA, N
26: * ..
27: * .. Array Arguments ..
28: * DOUBLE PRECISION A( LDA, * ), WORK( * )
29: * ..
30: *
31: *
32: *> \par Purpose:
33: * =============
34: *>
35: *> \verbatim
36: *>
37: *> DLANHS returns the value of the one norm, or the Frobenius norm, or
38: *> the infinity norm, or the element of largest absolute value of a
39: *> Hessenberg matrix A.
40: *> \endverbatim
41: *>
42: *> \return DLANHS
43: *> \verbatim
44: *>
45: *> DLANHS = ( max(abs(A(i,j))), NORM = 'M' or 'm'
46: *> (
47: *> ( norm1(A), NORM = '1', 'O' or 'o'
48: *> (
49: *> ( normI(A), NORM = 'I' or 'i'
50: *> (
51: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
52: *>
53: *> where norm1 denotes the one norm of a matrix (maximum column sum),
54: *> normI denotes the infinity norm of a matrix (maximum row sum) and
55: *> normF denotes the Frobenius norm of a matrix (square root of sum of
56: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
57: *> \endverbatim
58: *
59: * Arguments:
60: * ==========
61: *
62: *> \param[in] NORM
63: *> \verbatim
64: *> NORM is CHARACTER*1
65: *> Specifies the value to be returned in DLANHS as described
66: *> above.
67: *> \endverbatim
68: *>
69: *> \param[in] N
70: *> \verbatim
71: *> N is INTEGER
72: *> The order of the matrix A. N >= 0. When N = 0, DLANHS is
73: *> set to zero.
74: *> \endverbatim
75: *>
76: *> \param[in] A
77: *> \verbatim
78: *> A is DOUBLE PRECISION array, dimension (LDA,N)
79: *> The n by n upper Hessenberg matrix A; the part of A below the
80: *> first sub-diagonal is not referenced.
81: *> \endverbatim
82: *>
83: *> \param[in] LDA
84: *> \verbatim
85: *> LDA is INTEGER
86: *> The leading dimension of the array A. LDA >= max(N,1).
87: *> \endverbatim
88: *>
89: *> \param[out] WORK
90: *> \verbatim
91: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
92: *> where LWORK >= N when NORM = 'I'; otherwise, WORK is not
93: *> referenced.
94: *> \endverbatim
95: *
96: * Authors:
97: * ========
98: *
99: *> \author Univ. of Tennessee
100: *> \author Univ. of California Berkeley
101: *> \author Univ. of Colorado Denver
102: *> \author NAG Ltd.
103: *
104: *> \ingroup doubleOTHERauxiliary
105: *
106: * =====================================================================
107: DOUBLE PRECISION FUNCTION DLANHS( NORM, N, A, LDA, WORK )
108: *
109: * -- LAPACK auxiliary routine --
110: * -- LAPACK is a software package provided by Univ. of Tennessee, --
111: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
112: *
113: * .. Scalar Arguments ..
114: CHARACTER NORM
115: INTEGER LDA, N
116: * ..
117: * .. Array Arguments ..
118: DOUBLE PRECISION A( LDA, * ), WORK( * )
119: * ..
120: *
121: * =====================================================================
122: *
123: * .. Parameters ..
124: DOUBLE PRECISION ONE, ZERO
125: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
126: * ..
127: * .. Local Scalars ..
128: INTEGER I, J
129: DOUBLE PRECISION SCALE, SUM, VALUE
130: * ..
131: * .. External Subroutines ..
132: EXTERNAL DLASSQ
133: * ..
134: * .. External Functions ..
135: LOGICAL LSAME, DISNAN
136: EXTERNAL LSAME, DISNAN
137: * ..
138: * .. Intrinsic Functions ..
139: INTRINSIC ABS, MIN, SQRT
140: * ..
141: * .. Executable Statements ..
142: *
143: IF( N.EQ.0 ) THEN
144: VALUE = ZERO
145: ELSE IF( LSAME( NORM, 'M' ) ) THEN
146: *
147: * Find max(abs(A(i,j))).
148: *
149: VALUE = ZERO
150: DO 20 J = 1, N
151: DO 10 I = 1, MIN( N, J+1 )
152: SUM = ABS( A( I, J ) )
153: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
154: 10 CONTINUE
155: 20 CONTINUE
156: ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
157: *
158: * Find norm1(A).
159: *
160: VALUE = ZERO
161: DO 40 J = 1, N
162: SUM = ZERO
163: DO 30 I = 1, MIN( N, J+1 )
164: SUM = SUM + ABS( A( I, J ) )
165: 30 CONTINUE
166: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
167: 40 CONTINUE
168: ELSE IF( LSAME( NORM, 'I' ) ) THEN
169: *
170: * Find normI(A).
171: *
172: DO 50 I = 1, N
173: WORK( I ) = ZERO
174: 50 CONTINUE
175: DO 70 J = 1, N
176: DO 60 I = 1, MIN( N, J+1 )
177: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
178: 60 CONTINUE
179: 70 CONTINUE
180: VALUE = ZERO
181: DO 80 I = 1, N
182: SUM = WORK( I )
183: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
184: 80 CONTINUE
185: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
186: *
187: * Find normF(A).
188: *
189: SCALE = ZERO
190: SUM = ONE
191: DO 90 J = 1, N
192: CALL DLASSQ( MIN( N, J+1 ), A( 1, J ), 1, SCALE, SUM )
193: 90 CONTINUE
194: VALUE = SCALE*SQRT( SUM )
195: END IF
196: *
197: DLANHS = VALUE
198: RETURN
199: *
200: * End of DLANHS
201: *
202: END
CVSweb interface <joel.bertrand@systella.fr>