1: *> \brief \b DLANHS returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of an upper Hessenberg matrix.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DLANHS + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlanhs.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlanhs.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlanhs.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION DLANHS( NORM, N, A, LDA, WORK )
22: *
23: * .. Scalar Arguments ..
24: * CHARACTER NORM
25: * INTEGER LDA, N
26: * ..
27: * .. Array Arguments ..
28: * DOUBLE PRECISION A( LDA, * ), WORK( * )
29: * ..
30: *
31: *
32: *> \par Purpose:
33: * =============
34: *>
35: *> \verbatim
36: *>
37: *> DLANHS returns the value of the one norm, or the Frobenius norm, or
38: *> the infinity norm, or the element of largest absolute value of a
39: *> Hessenberg matrix A.
40: *> \endverbatim
41: *>
42: *> \return DLANHS
43: *> \verbatim
44: *>
45: *> DLANHS = ( max(abs(A(i,j))), NORM = 'M' or 'm'
46: *> (
47: *> ( norm1(A), NORM = '1', 'O' or 'o'
48: *> (
49: *> ( normI(A), NORM = 'I' or 'i'
50: *> (
51: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
52: *>
53: *> where norm1 denotes the one norm of a matrix (maximum column sum),
54: *> normI denotes the infinity norm of a matrix (maximum row sum) and
55: *> normF denotes the Frobenius norm of a matrix (square root of sum of
56: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
57: *> \endverbatim
58: *
59: * Arguments:
60: * ==========
61: *
62: *> \param[in] NORM
63: *> \verbatim
64: *> NORM is CHARACTER*1
65: *> Specifies the value to be returned in DLANHS as described
66: *> above.
67: *> \endverbatim
68: *>
69: *> \param[in] N
70: *> \verbatim
71: *> N is INTEGER
72: *> The order of the matrix A. N >= 0. When N = 0, DLANHS is
73: *> set to zero.
74: *> \endverbatim
75: *>
76: *> \param[in] A
77: *> \verbatim
78: *> A is DOUBLE PRECISION array, dimension (LDA,N)
79: *> The n by n upper Hessenberg matrix A; the part of A below the
80: *> first sub-diagonal is not referenced.
81: *> \endverbatim
82: *>
83: *> \param[in] LDA
84: *> \verbatim
85: *> LDA is INTEGER
86: *> The leading dimension of the array A. LDA >= max(N,1).
87: *> \endverbatim
88: *>
89: *> \param[out] WORK
90: *> \verbatim
91: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
92: *> where LWORK >= N when NORM = 'I'; otherwise, WORK is not
93: *> referenced.
94: *> \endverbatim
95: *
96: * Authors:
97: * ========
98: *
99: *> \author Univ. of Tennessee
100: *> \author Univ. of California Berkeley
101: *> \author Univ. of Colorado Denver
102: *> \author NAG Ltd.
103: *
104: *> \date December 2016
105: *
106: *> \ingroup doubleOTHERauxiliary
107: *
108: * =====================================================================
109: DOUBLE PRECISION FUNCTION DLANHS( NORM, N, A, LDA, WORK )
110: *
111: * -- LAPACK auxiliary routine (version 3.7.0) --
112: * -- LAPACK is a software package provided by Univ. of Tennessee, --
113: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
114: * December 2016
115: *
116: IMPLICIT NONE
117: * .. Scalar Arguments ..
118: CHARACTER NORM
119: INTEGER LDA, N
120: * ..
121: * .. Array Arguments ..
122: DOUBLE PRECISION A( LDA, * ), WORK( * )
123: * ..
124: *
125: * =====================================================================
126: *
127: * .. Parameters ..
128: DOUBLE PRECISION ONE, ZERO
129: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
130: * ..
131: * .. Local Scalars ..
132: INTEGER I, J
133: DOUBLE PRECISION SUM, VALUE
134: * ..
135: * .. Local Arrays ..
136: DOUBLE PRECISION SSQ( 2 ), COLSSQ( 2 )
137: * ..
138: * .. External Functions ..
139: LOGICAL LSAME, DISNAN
140: EXTERNAL LSAME, DISNAN
141: * ..
142: * .. External Subroutines ..
143: EXTERNAL DLASSQ, DCOMBSSQ
144: * ..
145: * .. Intrinsic Functions ..
146: INTRINSIC ABS, MIN, SQRT
147: * ..
148: * .. Executable Statements ..
149: *
150: IF( N.EQ.0 ) THEN
151: VALUE = ZERO
152: ELSE IF( LSAME( NORM, 'M' ) ) THEN
153: *
154: * Find max(abs(A(i,j))).
155: *
156: VALUE = ZERO
157: DO 20 J = 1, N
158: DO 10 I = 1, MIN( N, J+1 )
159: SUM = ABS( A( I, J ) )
160: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
161: 10 CONTINUE
162: 20 CONTINUE
163: ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
164: *
165: * Find norm1(A).
166: *
167: VALUE = ZERO
168: DO 40 J = 1, N
169: SUM = ZERO
170: DO 30 I = 1, MIN( N, J+1 )
171: SUM = SUM + ABS( A( I, J ) )
172: 30 CONTINUE
173: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
174: 40 CONTINUE
175: ELSE IF( LSAME( NORM, 'I' ) ) THEN
176: *
177: * Find normI(A).
178: *
179: DO 50 I = 1, N
180: WORK( I ) = ZERO
181: 50 CONTINUE
182: DO 70 J = 1, N
183: DO 60 I = 1, MIN( N, J+1 )
184: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
185: 60 CONTINUE
186: 70 CONTINUE
187: VALUE = ZERO
188: DO 80 I = 1, N
189: SUM = WORK( I )
190: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
191: 80 CONTINUE
192: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
193: *
194: * Find normF(A).
195: * SSQ(1) is scale
196: * SSQ(2) is sum-of-squares
197: * For better accuracy, sum each column separately.
198: *
199: SSQ( 1 ) = ZERO
200: SSQ( 2 ) = ONE
201: DO 90 J = 1, N
202: COLSSQ( 1 ) = ZERO
203: COLSSQ( 2 ) = ONE
204: CALL DLASSQ( MIN( N, J+1 ), A( 1, J ), 1,
205: $ COLSSQ( 1 ), COLSSQ( 2 ) )
206: CALL DCOMBSSQ( SSQ, COLSSQ )
207: 90 CONTINUE
208: VALUE = SSQ( 1 )*SQRT( SSQ( 2 ) )
209: END IF
210: *
211: DLANHS = VALUE
212: RETURN
213: *
214: * End of DLANHS
215: *
216: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dlanhs.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack