Annotation of rpl/lapack/lapack/dlange.f, revision 1.18
1.11 bertrand 1: *> \brief \b DLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of a general rectangular matrix.
1.8 bertrand 2: *
3: * =========== DOCUMENTATION ===========
4: *
1.15 bertrand 5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
1.8 bertrand 7: *
8: *> \htmlonly
1.15 bertrand 9: *> Download DLANGE + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlange.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlange.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlange.f">
1.8 bertrand 15: *> [TXT]</a>
1.15 bertrand 16: *> \endhtmlonly
1.8 bertrand 17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION DLANGE( NORM, M, N, A, LDA, WORK )
1.15 bertrand 22: *
1.8 bertrand 23: * .. Scalar Arguments ..
24: * CHARACTER NORM
25: * INTEGER LDA, M, N
26: * ..
27: * .. Array Arguments ..
28: * DOUBLE PRECISION A( LDA, * ), WORK( * )
29: * ..
1.15 bertrand 30: *
1.8 bertrand 31: *
32: *> \par Purpose:
33: * =============
34: *>
35: *> \verbatim
36: *>
37: *> DLANGE returns the value of the one norm, or the Frobenius norm, or
38: *> the infinity norm, or the element of largest absolute value of a
39: *> real matrix A.
40: *> \endverbatim
41: *>
42: *> \return DLANGE
43: *> \verbatim
44: *>
45: *> DLANGE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
46: *> (
47: *> ( norm1(A), NORM = '1', 'O' or 'o'
48: *> (
49: *> ( normI(A), NORM = 'I' or 'i'
50: *> (
51: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
52: *>
53: *> where norm1 denotes the one norm of a matrix (maximum column sum),
54: *> normI denotes the infinity norm of a matrix (maximum row sum) and
55: *> normF denotes the Frobenius norm of a matrix (square root of sum of
56: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
57: *> \endverbatim
58: *
59: * Arguments:
60: * ==========
61: *
62: *> \param[in] NORM
63: *> \verbatim
64: *> NORM is CHARACTER*1
65: *> Specifies the value to be returned in DLANGE as described
66: *> above.
67: *> \endverbatim
68: *>
69: *> \param[in] M
70: *> \verbatim
71: *> M is INTEGER
72: *> The number of rows of the matrix A. M >= 0. When M = 0,
73: *> DLANGE is set to zero.
74: *> \endverbatim
75: *>
76: *> \param[in] N
77: *> \verbatim
78: *> N is INTEGER
79: *> The number of columns of the matrix A. N >= 0. When N = 0,
80: *> DLANGE is set to zero.
81: *> \endverbatim
82: *>
83: *> \param[in] A
84: *> \verbatim
85: *> A is DOUBLE PRECISION array, dimension (LDA,N)
86: *> The m by n matrix A.
87: *> \endverbatim
88: *>
89: *> \param[in] LDA
90: *> \verbatim
91: *> LDA is INTEGER
92: *> The leading dimension of the array A. LDA >= max(M,1).
93: *> \endverbatim
94: *>
95: *> \param[out] WORK
96: *> \verbatim
97: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
98: *> where LWORK >= M when NORM = 'I'; otherwise, WORK is not
99: *> referenced.
100: *> \endverbatim
101: *
102: * Authors:
103: * ========
104: *
1.15 bertrand 105: *> \author Univ. of Tennessee
106: *> \author Univ. of California Berkeley
107: *> \author Univ. of Colorado Denver
108: *> \author NAG Ltd.
1.8 bertrand 109: *
1.15 bertrand 110: *> \date December 2016
1.8 bertrand 111: *
112: *> \ingroup doubleGEauxiliary
113: *
114: * =====================================================================
1.1 bertrand 115: DOUBLE PRECISION FUNCTION DLANGE( NORM, M, N, A, LDA, WORK )
116: *
1.15 bertrand 117: * -- LAPACK auxiliary routine (version 3.7.0) --
1.1 bertrand 118: * -- LAPACK is a software package provided by Univ. of Tennessee, --
119: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
1.15 bertrand 120: * December 2016
1.1 bertrand 121: *
1.18 ! bertrand 122: IMPLICIT NONE
1.1 bertrand 123: * .. Scalar Arguments ..
124: CHARACTER NORM
125: INTEGER LDA, M, N
126: * ..
127: * .. Array Arguments ..
128: DOUBLE PRECISION A( LDA, * ), WORK( * )
129: * ..
130: *
131: * =====================================================================
132: *
133: * .. Parameters ..
134: DOUBLE PRECISION ONE, ZERO
135: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
136: * ..
137: * .. Local Scalars ..
138: INTEGER I, J
1.18 ! bertrand 139: DOUBLE PRECISION SUM, VALUE, TEMP
! 140: * ..
! 141: * .. Local Arrays ..
! 142: DOUBLE PRECISION SSQ( 2 ), COLSSQ( 2 )
1.1 bertrand 143: * ..
144: * .. External Subroutines ..
1.18 ! bertrand 145: EXTERNAL DLASSQ, DCOMBSSQ
1.1 bertrand 146: * ..
147: * .. External Functions ..
1.11 bertrand 148: LOGICAL LSAME, DISNAN
149: EXTERNAL LSAME, DISNAN
1.1 bertrand 150: * ..
151: * .. Intrinsic Functions ..
1.11 bertrand 152: INTRINSIC ABS, MIN, SQRT
1.1 bertrand 153: * ..
154: * .. Executable Statements ..
155: *
156: IF( MIN( M, N ).EQ.0 ) THEN
157: VALUE = ZERO
158: ELSE IF( LSAME( NORM, 'M' ) ) THEN
159: *
160: * Find max(abs(A(i,j))).
161: *
162: VALUE = ZERO
163: DO 20 J = 1, N
164: DO 10 I = 1, M
1.11 bertrand 165: TEMP = ABS( A( I, J ) )
166: IF( VALUE.LT.TEMP .OR. DISNAN( TEMP ) ) VALUE = TEMP
1.1 bertrand 167: 10 CONTINUE
168: 20 CONTINUE
169: ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
170: *
171: * Find norm1(A).
172: *
173: VALUE = ZERO
174: DO 40 J = 1, N
175: SUM = ZERO
176: DO 30 I = 1, M
177: SUM = SUM + ABS( A( I, J ) )
178: 30 CONTINUE
1.11 bertrand 179: IF( VALUE.LT.SUM .OR. DISNAN( SUM ) ) VALUE = SUM
1.1 bertrand 180: 40 CONTINUE
181: ELSE IF( LSAME( NORM, 'I' ) ) THEN
182: *
183: * Find normI(A).
184: *
185: DO 50 I = 1, M
186: WORK( I ) = ZERO
187: 50 CONTINUE
188: DO 70 J = 1, N
189: DO 60 I = 1, M
190: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
191: 60 CONTINUE
192: 70 CONTINUE
193: VALUE = ZERO
194: DO 80 I = 1, M
1.11 bertrand 195: TEMP = WORK( I )
196: IF( VALUE.LT.TEMP .OR. DISNAN( TEMP ) ) VALUE = TEMP
1.1 bertrand 197: 80 CONTINUE
198: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
199: *
200: * Find normF(A).
1.18 ! bertrand 201: * SSQ(1) is scale
! 202: * SSQ(2) is sum-of-squares
! 203: * For better accuracy, sum each column separately.
1.1 bertrand 204: *
1.18 ! bertrand 205: SSQ( 1 ) = ZERO
! 206: SSQ( 2 ) = ONE
1.1 bertrand 207: DO 90 J = 1, N
1.18 ! bertrand 208: COLSSQ( 1 ) = ZERO
! 209: COLSSQ( 2 ) = ONE
! 210: CALL DLASSQ( M, A( 1, J ), 1, COLSSQ( 1 ), COLSSQ( 2 ) )
! 211: CALL DCOMBSSQ( SSQ, COLSSQ )
1.1 bertrand 212: 90 CONTINUE
1.18 ! bertrand 213: VALUE = SSQ( 1 )*SQRT( SSQ( 2 ) )
1.1 bertrand 214: END IF
215: *
216: DLANGE = VALUE
217: RETURN
218: *
219: * End of DLANGE
220: *
221: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dlange.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack