1: *> \brief \b DLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of general band matrix.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DLANGB + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlangb.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlangb.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlangb.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION DLANGB( NORM, N, KL, KU, AB, LDAB,
22: * WORK )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER NORM
26: * INTEGER KL, KU, LDAB, N
27: * ..
28: * .. Array Arguments ..
29: * DOUBLE PRECISION AB( LDAB, * ), WORK( * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> DLANGB returns the value of the one norm, or the Frobenius norm, or
39: *> the infinity norm, or the element of largest absolute value of an
40: *> n by n band matrix A, with kl sub-diagonals and ku super-diagonals.
41: *> \endverbatim
42: *>
43: *> \return DLANGB
44: *> \verbatim
45: *>
46: *> DLANGB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47: *> (
48: *> ( norm1(A), NORM = '1', 'O' or 'o'
49: *> (
50: *> ( normI(A), NORM = 'I' or 'i'
51: *> (
52: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53: *>
54: *> where norm1 denotes the one norm of a matrix (maximum column sum),
55: *> normI denotes the infinity norm of a matrix (maximum row sum) and
56: *> normF denotes the Frobenius norm of a matrix (square root of sum of
57: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58: *> \endverbatim
59: *
60: * Arguments:
61: * ==========
62: *
63: *> \param[in] NORM
64: *> \verbatim
65: *> NORM is CHARACTER*1
66: *> Specifies the value to be returned in DLANGB as described
67: *> above.
68: *> \endverbatim
69: *>
70: *> \param[in] N
71: *> \verbatim
72: *> N is INTEGER
73: *> The order of the matrix A. N >= 0. When N = 0, DLANGB is
74: *> set to zero.
75: *> \endverbatim
76: *>
77: *> \param[in] KL
78: *> \verbatim
79: *> KL is INTEGER
80: *> The number of sub-diagonals of the matrix A. KL >= 0.
81: *> \endverbatim
82: *>
83: *> \param[in] KU
84: *> \verbatim
85: *> KU is INTEGER
86: *> The number of super-diagonals of the matrix A. KU >= 0.
87: *> \endverbatim
88: *>
89: *> \param[in] AB
90: *> \verbatim
91: *> AB is DOUBLE PRECISION array, dimension (LDAB,N)
92: *> The band matrix A, stored in rows 1 to KL+KU+1. The j-th
93: *> column of A is stored in the j-th column of the array AB as
94: *> follows:
95: *> AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(n,j+kl).
96: *> \endverbatim
97: *>
98: *> \param[in] LDAB
99: *> \verbatim
100: *> LDAB is INTEGER
101: *> The leading dimension of the array AB. LDAB >= KL+KU+1.
102: *> \endverbatim
103: *>
104: *> \param[out] WORK
105: *> \verbatim
106: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
107: *> where LWORK >= N when NORM = 'I'; otherwise, WORK is not
108: *> referenced.
109: *> \endverbatim
110: *
111: * Authors:
112: * ========
113: *
114: *> \author Univ. of Tennessee
115: *> \author Univ. of California Berkeley
116: *> \author Univ. of Colorado Denver
117: *> \author NAG Ltd.
118: *
119: *> \date December 2016
120: *
121: *> \ingroup doubleGBauxiliary
122: *
123: * =====================================================================
124: DOUBLE PRECISION FUNCTION DLANGB( NORM, N, KL, KU, AB, LDAB,
125: $ WORK )
126: *
127: * -- LAPACK auxiliary routine (version 3.7.0) --
128: * -- LAPACK is a software package provided by Univ. of Tennessee, --
129: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
130: * December 2016
131: *
132: IMPLICIT NONE
133: * .. Scalar Arguments ..
134: CHARACTER NORM
135: INTEGER KL, KU, LDAB, N
136: * ..
137: * .. Array Arguments ..
138: DOUBLE PRECISION AB( LDAB, * ), WORK( * )
139: * ..
140: *
141: * =====================================================================
142: *
143: * .. Parameters ..
144: DOUBLE PRECISION ONE, ZERO
145: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
146: * ..
147: * .. Local Scalars ..
148: INTEGER I, J, K, L
149: DOUBLE PRECISION SUM, VALUE, TEMP
150: * ..
151: * .. Local Arrays ..
152: DOUBLE PRECISION SSQ( 2 ), COLSSQ( 2 )
153: * ..
154: * .. External Functions ..
155: LOGICAL LSAME, DISNAN
156: EXTERNAL LSAME, DISNAN
157: * ..
158: * .. External Subroutines ..
159: EXTERNAL DLASSQ, DCOMBSSQ
160: * ..
161: * .. Intrinsic Functions ..
162: INTRINSIC ABS, MAX, MIN, SQRT
163: * ..
164: * .. Executable Statements ..
165: *
166: IF( N.EQ.0 ) THEN
167: VALUE = ZERO
168: ELSE IF( LSAME( NORM, 'M' ) ) THEN
169: *
170: * Find max(abs(A(i,j))).
171: *
172: VALUE = ZERO
173: DO 20 J = 1, N
174: DO 10 I = MAX( KU+2-J, 1 ), MIN( N+KU+1-J, KL+KU+1 )
175: TEMP = ABS( AB( I, J ) )
176: IF( VALUE.LT.TEMP .OR. DISNAN( TEMP ) ) VALUE = TEMP
177: 10 CONTINUE
178: 20 CONTINUE
179: ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
180: *
181: * Find norm1(A).
182: *
183: VALUE = ZERO
184: DO 40 J = 1, N
185: SUM = ZERO
186: DO 30 I = MAX( KU+2-J, 1 ), MIN( N+KU+1-J, KL+KU+1 )
187: SUM = SUM + ABS( AB( I, J ) )
188: 30 CONTINUE
189: IF( VALUE.LT.SUM .OR. DISNAN( SUM ) ) VALUE = SUM
190: 40 CONTINUE
191: ELSE IF( LSAME( NORM, 'I' ) ) THEN
192: *
193: * Find normI(A).
194: *
195: DO 50 I = 1, N
196: WORK( I ) = ZERO
197: 50 CONTINUE
198: DO 70 J = 1, N
199: K = KU + 1 - J
200: DO 60 I = MAX( 1, J-KU ), MIN( N, J+KL )
201: WORK( I ) = WORK( I ) + ABS( AB( K+I, J ) )
202: 60 CONTINUE
203: 70 CONTINUE
204: VALUE = ZERO
205: DO 80 I = 1, N
206: TEMP = WORK( I )
207: IF( VALUE.LT.TEMP .OR. DISNAN( TEMP ) ) VALUE = TEMP
208: 80 CONTINUE
209: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
210: *
211: * Find normF(A).
212: * SSQ(1) is scale
213: * SSQ(2) is sum-of-squares
214: * For better accuracy, sum each column separately.
215: *
216: SSQ( 1 ) = ZERO
217: SSQ( 2 ) = ONE
218: DO 90 J = 1, N
219: L = MAX( 1, J-KU )
220: K = KU + 1 - J + L
221: COLSSQ( 1 ) = ZERO
222: COLSSQ( 2 ) = ONE
223: CALL DLASSQ( MIN( N, J+KL )-L+1, AB( K, J ), 1,
224: $ COLSSQ( 1 ), COLSSQ( 2 ) )
225: CALL DCOMBSSQ( SSQ, COLSSQ )
226: 90 CONTINUE
227: VALUE = SSQ( 1 )*SQRT( SSQ( 2 ) )
228: END IF
229: *
230: DLANGB = VALUE
231: RETURN
232: *
233: * End of DLANGB
234: *
235: END
CVSweb interface <joel.bertrand@systella.fr>