1: DOUBLE PRECISION FUNCTION DLANGB( NORM, N, KL, KU, AB, LDAB,
2: $ WORK )
3: *
4: * -- LAPACK auxiliary routine (version 3.2) --
5: * -- LAPACK is a software package provided by Univ. of Tennessee, --
6: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
7: * November 2006
8: *
9: * .. Scalar Arguments ..
10: CHARACTER NORM
11: INTEGER KL, KU, LDAB, N
12: * ..
13: * .. Array Arguments ..
14: DOUBLE PRECISION AB( LDAB, * ), WORK( * )
15: * ..
16: *
17: * Purpose
18: * =======
19: *
20: * DLANGB returns the value of the one norm, or the Frobenius norm, or
21: * the infinity norm, or the element of largest absolute value of an
22: * n by n band matrix A, with kl sub-diagonals and ku super-diagonals.
23: *
24: * Description
25: * ===========
26: *
27: * DLANGB returns the value
28: *
29: * DLANGB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
30: * (
31: * ( norm1(A), NORM = '1', 'O' or 'o'
32: * (
33: * ( normI(A), NORM = 'I' or 'i'
34: * (
35: * ( normF(A), NORM = 'F', 'f', 'E' or 'e'
36: *
37: * where norm1 denotes the one norm of a matrix (maximum column sum),
38: * normI denotes the infinity norm of a matrix (maximum row sum) and
39: * normF denotes the Frobenius norm of a matrix (square root of sum of
40: * squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
41: *
42: * Arguments
43: * =========
44: *
45: * NORM (input) CHARACTER*1
46: * Specifies the value to be returned in DLANGB as described
47: * above.
48: *
49: * N (input) INTEGER
50: * The order of the matrix A. N >= 0. When N = 0, DLANGB is
51: * set to zero.
52: *
53: * KL (input) INTEGER
54: * The number of sub-diagonals of the matrix A. KL >= 0.
55: *
56: * KU (input) INTEGER
57: * The number of super-diagonals of the matrix A. KU >= 0.
58: *
59: * AB (input) DOUBLE PRECISION array, dimension (LDAB,N)
60: * The band matrix A, stored in rows 1 to KL+KU+1. The j-th
61: * column of A is stored in the j-th column of the array AB as
62: * follows:
63: * AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(n,j+kl).
64: *
65: * LDAB (input) INTEGER
66: * The leading dimension of the array AB. LDAB >= KL+KU+1.
67: *
68: * WORK (workspace) DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
69: * where LWORK >= N when NORM = 'I'; otherwise, WORK is not
70: * referenced.
71: *
72: * =====================================================================
73: *
74: *
75: * .. Parameters ..
76: DOUBLE PRECISION ONE, ZERO
77: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
78: * ..
79: * .. Local Scalars ..
80: INTEGER I, J, K, L
81: DOUBLE PRECISION SCALE, SUM, VALUE
82: * ..
83: * .. External Subroutines ..
84: EXTERNAL DLASSQ
85: * ..
86: * .. External Functions ..
87: LOGICAL LSAME
88: EXTERNAL LSAME
89: * ..
90: * .. Intrinsic Functions ..
91: INTRINSIC ABS, MAX, MIN, SQRT
92: * ..
93: * .. Executable Statements ..
94: *
95: IF( N.EQ.0 ) THEN
96: VALUE = ZERO
97: ELSE IF( LSAME( NORM, 'M' ) ) THEN
98: *
99: * Find max(abs(A(i,j))).
100: *
101: VALUE = ZERO
102: DO 20 J = 1, N
103: DO 10 I = MAX( KU+2-J, 1 ), MIN( N+KU+1-J, KL+KU+1 )
104: VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
105: 10 CONTINUE
106: 20 CONTINUE
107: ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
108: *
109: * Find norm1(A).
110: *
111: VALUE = ZERO
112: DO 40 J = 1, N
113: SUM = ZERO
114: DO 30 I = MAX( KU+2-J, 1 ), MIN( N+KU+1-J, KL+KU+1 )
115: SUM = SUM + ABS( AB( I, J ) )
116: 30 CONTINUE
117: VALUE = MAX( VALUE, SUM )
118: 40 CONTINUE
119: ELSE IF( LSAME( NORM, 'I' ) ) THEN
120: *
121: * Find normI(A).
122: *
123: DO 50 I = 1, N
124: WORK( I ) = ZERO
125: 50 CONTINUE
126: DO 70 J = 1, N
127: K = KU + 1 - J
128: DO 60 I = MAX( 1, J-KU ), MIN( N, J+KL )
129: WORK( I ) = WORK( I ) + ABS( AB( K+I, J ) )
130: 60 CONTINUE
131: 70 CONTINUE
132: VALUE = ZERO
133: DO 80 I = 1, N
134: VALUE = MAX( VALUE, WORK( I ) )
135: 80 CONTINUE
136: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
137: *
138: * Find normF(A).
139: *
140: SCALE = ZERO
141: SUM = ONE
142: DO 90 J = 1, N
143: L = MAX( 1, J-KU )
144: K = KU + 1 - J + L
145: CALL DLASSQ( MIN( N, J+KL )-L+1, AB( K, J ), 1, SCALE, SUM )
146: 90 CONTINUE
147: VALUE = SCALE*SQRT( SUM )
148: END IF
149: *
150: DLANGB = VALUE
151: RETURN
152: *
153: * End of DLANGB
154: *
155: END
CVSweb interface <joel.bertrand@systella.fr>