Annotation of rpl/lapack/lapack/dlagtm.f, revision 1.19
1.12 bertrand 1: *> \brief \b DLAGTM performs a matrix-matrix product of the form C = αAB+βC, where A is a tridiagonal matrix, B and C are rectangular matrices, and α and β are scalars, which may be 0, 1, or -1.
1.9 bertrand 2: *
3: * =========== DOCUMENTATION ===========
4: *
1.16 bertrand 5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
1.9 bertrand 7: *
8: *> \htmlonly
1.16 bertrand 9: *> Download DLAGTM + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlagtm.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlagtm.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlagtm.f">
1.9 bertrand 15: *> [TXT]</a>
1.16 bertrand 16: *> \endhtmlonly
1.9 bertrand 17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DLAGTM( TRANS, N, NRHS, ALPHA, DL, D, DU, X, LDX, BETA,
22: * B, LDB )
1.16 bertrand 23: *
1.9 bertrand 24: * .. Scalar Arguments ..
25: * CHARACTER TRANS
26: * INTEGER LDB, LDX, N, NRHS
27: * DOUBLE PRECISION ALPHA, BETA
28: * ..
29: * .. Array Arguments ..
30: * DOUBLE PRECISION B( LDB, * ), D( * ), DL( * ), DU( * ),
31: * $ X( LDX, * )
32: * ..
1.16 bertrand 33: *
1.9 bertrand 34: *
35: *> \par Purpose:
36: * =============
37: *>
38: *> \verbatim
39: *>
40: *> DLAGTM performs a matrix-vector product of the form
41: *>
42: *> B := alpha * A * X + beta * B
43: *>
44: *> where A is a tridiagonal matrix of order N, B and X are N by NRHS
45: *> matrices, and alpha and beta are real scalars, each of which may be
46: *> 0., 1., or -1.
47: *> \endverbatim
48: *
49: * Arguments:
50: * ==========
51: *
52: *> \param[in] TRANS
53: *> \verbatim
54: *> TRANS is CHARACTER*1
55: *> Specifies the operation applied to A.
56: *> = 'N': No transpose, B := alpha * A * X + beta * B
57: *> = 'T': Transpose, B := alpha * A'* X + beta * B
58: *> = 'C': Conjugate transpose = Transpose
59: *> \endverbatim
60: *>
61: *> \param[in] N
62: *> \verbatim
63: *> N is INTEGER
64: *> The order of the matrix A. N >= 0.
65: *> \endverbatim
66: *>
67: *> \param[in] NRHS
68: *> \verbatim
69: *> NRHS is INTEGER
70: *> The number of right hand sides, i.e., the number of columns
71: *> of the matrices X and B.
72: *> \endverbatim
73: *>
74: *> \param[in] ALPHA
75: *> \verbatim
76: *> ALPHA is DOUBLE PRECISION
77: *> The scalar alpha. ALPHA must be 0., 1., or -1.; otherwise,
78: *> it is assumed to be 0.
79: *> \endverbatim
80: *>
81: *> \param[in] DL
82: *> \verbatim
83: *> DL is DOUBLE PRECISION array, dimension (N-1)
84: *> The (n-1) sub-diagonal elements of T.
85: *> \endverbatim
86: *>
87: *> \param[in] D
88: *> \verbatim
89: *> D is DOUBLE PRECISION array, dimension (N)
90: *> The diagonal elements of T.
91: *> \endverbatim
92: *>
93: *> \param[in] DU
94: *> \verbatim
95: *> DU is DOUBLE PRECISION array, dimension (N-1)
96: *> The (n-1) super-diagonal elements of T.
97: *> \endverbatim
98: *>
99: *> \param[in] X
100: *> \verbatim
101: *> X is DOUBLE PRECISION array, dimension (LDX,NRHS)
102: *> The N by NRHS matrix X.
103: *> \endverbatim
104: *>
105: *> \param[in] LDX
106: *> \verbatim
107: *> LDX is INTEGER
108: *> The leading dimension of the array X. LDX >= max(N,1).
109: *> \endverbatim
110: *>
111: *> \param[in] BETA
112: *> \verbatim
113: *> BETA is DOUBLE PRECISION
114: *> The scalar beta. BETA must be 0., 1., or -1.; otherwise,
115: *> it is assumed to be 1.
116: *> \endverbatim
117: *>
118: *> \param[in,out] B
119: *> \verbatim
120: *> B is DOUBLE PRECISION array, dimension (LDB,NRHS)
121: *> On entry, the N by NRHS matrix B.
122: *> On exit, B is overwritten by the matrix expression
123: *> B := alpha * A * X + beta * B.
124: *> \endverbatim
125: *>
126: *> \param[in] LDB
127: *> \verbatim
128: *> LDB is INTEGER
129: *> The leading dimension of the array B. LDB >= max(N,1).
130: *> \endverbatim
131: *
132: * Authors:
133: * ========
134: *
1.16 bertrand 135: *> \author Univ. of Tennessee
136: *> \author Univ. of California Berkeley
137: *> \author Univ. of Colorado Denver
138: *> \author NAG Ltd.
1.9 bertrand 139: *
140: *> \ingroup doubleOTHERauxiliary
141: *
142: * =====================================================================
1.1 bertrand 143: SUBROUTINE DLAGTM( TRANS, N, NRHS, ALPHA, DL, D, DU, X, LDX, BETA,
144: $ B, LDB )
145: *
1.19 ! bertrand 146: * -- LAPACK auxiliary routine --
1.1 bertrand 147: * -- LAPACK is a software package provided by Univ. of Tennessee, --
148: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
149: *
150: * .. Scalar Arguments ..
151: CHARACTER TRANS
152: INTEGER LDB, LDX, N, NRHS
153: DOUBLE PRECISION ALPHA, BETA
154: * ..
155: * .. Array Arguments ..
156: DOUBLE PRECISION B( LDB, * ), D( * ), DL( * ), DU( * ),
157: $ X( LDX, * )
158: * ..
159: *
160: * =====================================================================
161: *
162: * .. Parameters ..
163: DOUBLE PRECISION ONE, ZERO
164: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
165: * ..
166: * .. Local Scalars ..
167: INTEGER I, J
168: * ..
169: * .. External Functions ..
170: LOGICAL LSAME
171: EXTERNAL LSAME
172: * ..
173: * .. Executable Statements ..
174: *
175: IF( N.EQ.0 )
176: $ RETURN
177: *
178: * Multiply B by BETA if BETA.NE.1.
179: *
180: IF( BETA.EQ.ZERO ) THEN
181: DO 20 J = 1, NRHS
182: DO 10 I = 1, N
183: B( I, J ) = ZERO
184: 10 CONTINUE
185: 20 CONTINUE
186: ELSE IF( BETA.EQ.-ONE ) THEN
187: DO 40 J = 1, NRHS
188: DO 30 I = 1, N
189: B( I, J ) = -B( I, J )
190: 30 CONTINUE
191: 40 CONTINUE
192: END IF
193: *
194: IF( ALPHA.EQ.ONE ) THEN
195: IF( LSAME( TRANS, 'N' ) ) THEN
196: *
197: * Compute B := B + A*X
198: *
199: DO 60 J = 1, NRHS
200: IF( N.EQ.1 ) THEN
201: B( 1, J ) = B( 1, J ) + D( 1 )*X( 1, J )
202: ELSE
203: B( 1, J ) = B( 1, J ) + D( 1 )*X( 1, J ) +
204: $ DU( 1 )*X( 2, J )
205: B( N, J ) = B( N, J ) + DL( N-1 )*X( N-1, J ) +
206: $ D( N )*X( N, J )
207: DO 50 I = 2, N - 1
208: B( I, J ) = B( I, J ) + DL( I-1 )*X( I-1, J ) +
209: $ D( I )*X( I, J ) + DU( I )*X( I+1, J )
210: 50 CONTINUE
211: END IF
212: 60 CONTINUE
213: ELSE
214: *
1.8 bertrand 215: * Compute B := B + A**T*X
1.1 bertrand 216: *
217: DO 80 J = 1, NRHS
218: IF( N.EQ.1 ) THEN
219: B( 1, J ) = B( 1, J ) + D( 1 )*X( 1, J )
220: ELSE
221: B( 1, J ) = B( 1, J ) + D( 1 )*X( 1, J ) +
222: $ DL( 1 )*X( 2, J )
223: B( N, J ) = B( N, J ) + DU( N-1 )*X( N-1, J ) +
224: $ D( N )*X( N, J )
225: DO 70 I = 2, N - 1
226: B( I, J ) = B( I, J ) + DU( I-1 )*X( I-1, J ) +
227: $ D( I )*X( I, J ) + DL( I )*X( I+1, J )
228: 70 CONTINUE
229: END IF
230: 80 CONTINUE
231: END IF
232: ELSE IF( ALPHA.EQ.-ONE ) THEN
233: IF( LSAME( TRANS, 'N' ) ) THEN
234: *
235: * Compute B := B - A*X
236: *
237: DO 100 J = 1, NRHS
238: IF( N.EQ.1 ) THEN
239: B( 1, J ) = B( 1, J ) - D( 1 )*X( 1, J )
240: ELSE
241: B( 1, J ) = B( 1, J ) - D( 1 )*X( 1, J ) -
242: $ DU( 1 )*X( 2, J )
243: B( N, J ) = B( N, J ) - DL( N-1 )*X( N-1, J ) -
244: $ D( N )*X( N, J )
245: DO 90 I = 2, N - 1
246: B( I, J ) = B( I, J ) - DL( I-1 )*X( I-1, J ) -
247: $ D( I )*X( I, J ) - DU( I )*X( I+1, J )
248: 90 CONTINUE
249: END IF
250: 100 CONTINUE
251: ELSE
252: *
1.8 bertrand 253: * Compute B := B - A**T*X
1.1 bertrand 254: *
255: DO 120 J = 1, NRHS
256: IF( N.EQ.1 ) THEN
257: B( 1, J ) = B( 1, J ) - D( 1 )*X( 1, J )
258: ELSE
259: B( 1, J ) = B( 1, J ) - D( 1 )*X( 1, J ) -
260: $ DL( 1 )*X( 2, J )
261: B( N, J ) = B( N, J ) - DU( N-1 )*X( N-1, J ) -
262: $ D( N )*X( N, J )
263: DO 110 I = 2, N - 1
264: B( I, J ) = B( I, J ) - DU( I-1 )*X( I-1, J ) -
265: $ D( I )*X( I, J ) - DL( I )*X( I+1, J )
266: 110 CONTINUE
267: END IF
268: 120 CONTINUE
269: END IF
270: END IF
271: RETURN
272: *
273: * End of DLAGTM
274: *
275: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dlagtm.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack