1: *> \brief \b DLA_GERFSX_EXTENDED improves the computed solution to a system of linear equations for general matrices by performing extra-precise iterative refinement and provides error bounds and backward error estimates for the solution.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DLA_GERFSX_EXTENDED + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dla_gerfsx_extended.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dla_gerfsx_extended.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dla_gerfsx_extended.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DLA_GERFSX_EXTENDED( PREC_TYPE, TRANS_TYPE, N, NRHS, A,
22: * LDA, AF, LDAF, IPIV, COLEQU, C, B,
23: * LDB, Y, LDY, BERR_OUT, N_NORMS,
24: * ERRS_N, ERRS_C, RES, AYB, DY,
25: * Y_TAIL, RCOND, ITHRESH, RTHRESH,
26: * DZ_UB, IGNORE_CWISE, INFO )
27: *
28: * .. Scalar Arguments ..
29: * INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
30: * $ TRANS_TYPE, N_NORMS, ITHRESH
31: * LOGICAL COLEQU, IGNORE_CWISE
32: * DOUBLE PRECISION RTHRESH, DZ_UB
33: * ..
34: * .. Array Arguments ..
35: * INTEGER IPIV( * )
36: * DOUBLE PRECISION A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
37: * $ Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
38: * DOUBLE PRECISION C( * ), AYB( * ), RCOND, BERR_OUT( * ),
39: * $ ERRS_N( NRHS, * ), ERRS_C( NRHS, * )
40: * ..
41: *
42: *
43: *> \par Purpose:
44: * =============
45: *>
46: *> \verbatim
47: *>
48: *>
49: *> DLA_GERFSX_EXTENDED improves the computed solution to a system of
50: *> linear equations by performing extra-precise iterative refinement
51: *> and provides error bounds and backward error estimates for the solution.
52: *> This subroutine is called by DGERFSX to perform iterative refinement.
53: *> In addition to normwise error bound, the code provides maximum
54: *> componentwise error bound if possible. See comments for ERRS_N
55: *> and ERRS_C for details of the error bounds. Note that this
56: *> subroutine is only resonsible for setting the second fields of
57: *> ERRS_N and ERRS_C.
58: *> \endverbatim
59: *
60: * Arguments:
61: * ==========
62: *
63: *> \param[in] PREC_TYPE
64: *> \verbatim
65: *> PREC_TYPE is INTEGER
66: *> Specifies the intermediate precision to be used in refinement.
67: *> The value is defined by ILAPREC(P) where P is a CHARACTER and
68: *> P = 'S': Single
69: *> = 'D': Double
70: *> = 'I': Indigenous
71: *> = 'X', 'E': Extra
72: *> \endverbatim
73: *>
74: *> \param[in] TRANS_TYPE
75: *> \verbatim
76: *> TRANS_TYPE is INTEGER
77: *> Specifies the transposition operation on A.
78: *> The value is defined by ILATRANS(T) where T is a CHARACTER and
79: *> T = 'N': No transpose
80: *> = 'T': Transpose
81: *> = 'C': Conjugate transpose
82: *> \endverbatim
83: *>
84: *> \param[in] N
85: *> \verbatim
86: *> N is INTEGER
87: *> The number of linear equations, i.e., the order of the
88: *> matrix A. N >= 0.
89: *> \endverbatim
90: *>
91: *> \param[in] NRHS
92: *> \verbatim
93: *> NRHS is INTEGER
94: *> The number of right-hand-sides, i.e., the number of columns of the
95: *> matrix B.
96: *> \endverbatim
97: *>
98: *> \param[in] A
99: *> \verbatim
100: *> A is DOUBLE PRECISION array, dimension (LDA,N)
101: *> On entry, the N-by-N matrix A.
102: *> \endverbatim
103: *>
104: *> \param[in] LDA
105: *> \verbatim
106: *> LDA is INTEGER
107: *> The leading dimension of the array A. LDA >= max(1,N).
108: *> \endverbatim
109: *>
110: *> \param[in] AF
111: *> \verbatim
112: *> AF is DOUBLE PRECISION array, dimension (LDAF,N)
113: *> The factors L and U from the factorization
114: *> A = P*L*U as computed by DGETRF.
115: *> \endverbatim
116: *>
117: *> \param[in] LDAF
118: *> \verbatim
119: *> LDAF is INTEGER
120: *> The leading dimension of the array AF. LDAF >= max(1,N).
121: *> \endverbatim
122: *>
123: *> \param[in] IPIV
124: *> \verbatim
125: *> IPIV is INTEGER array, dimension (N)
126: *> The pivot indices from the factorization A = P*L*U
127: *> as computed by DGETRF; row i of the matrix was interchanged
128: *> with row IPIV(i).
129: *> \endverbatim
130: *>
131: *> \param[in] COLEQU
132: *> \verbatim
133: *> COLEQU is LOGICAL
134: *> If .TRUE. then column equilibration was done to A before calling
135: *> this routine. This is needed to compute the solution and error
136: *> bounds correctly.
137: *> \endverbatim
138: *>
139: *> \param[in] C
140: *> \verbatim
141: *> C is DOUBLE PRECISION array, dimension (N)
142: *> The column scale factors for A. If COLEQU = .FALSE., C
143: *> is not accessed. If C is input, each element of C should be a power
144: *> of the radix to ensure a reliable solution and error estimates.
145: *> Scaling by powers of the radix does not cause rounding errors unless
146: *> the result underflows or overflows. Rounding errors during scaling
147: *> lead to refining with a matrix that is not equivalent to the
148: *> input matrix, producing error estimates that may not be
149: *> reliable.
150: *> \endverbatim
151: *>
152: *> \param[in] B
153: *> \verbatim
154: *> B is DOUBLE PRECISION array, dimension (LDB,NRHS)
155: *> The right-hand-side matrix B.
156: *> \endverbatim
157: *>
158: *> \param[in] LDB
159: *> \verbatim
160: *> LDB is INTEGER
161: *> The leading dimension of the array B. LDB >= max(1,N).
162: *> \endverbatim
163: *>
164: *> \param[in,out] Y
165: *> \verbatim
166: *> Y is DOUBLE PRECISION array, dimension
167: *> (LDY,NRHS)
168: *> On entry, the solution matrix X, as computed by DGETRS.
169: *> On exit, the improved solution matrix Y.
170: *> \endverbatim
171: *>
172: *> \param[in] LDY
173: *> \verbatim
174: *> LDY is INTEGER
175: *> The leading dimension of the array Y. LDY >= max(1,N).
176: *> \endverbatim
177: *>
178: *> \param[out] BERR_OUT
179: *> \verbatim
180: *> BERR_OUT is DOUBLE PRECISION array, dimension (NRHS)
181: *> On exit, BERR_OUT(j) contains the componentwise relative backward
182: *> error for right-hand-side j from the formula
183: *> max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
184: *> where abs(Z) is the componentwise absolute value of the matrix
185: *> or vector Z. This is computed by DLA_LIN_BERR.
186: *> \endverbatim
187: *>
188: *> \param[in] N_NORMS
189: *> \verbatim
190: *> N_NORMS is INTEGER
191: *> Determines which error bounds to return (see ERRS_N
192: *> and ERRS_C).
193: *> If N_NORMS >= 1 return normwise error bounds.
194: *> If N_NORMS >= 2 return componentwise error bounds.
195: *> \endverbatim
196: *>
197: *> \param[in,out] ERRS_N
198: *> \verbatim
199: *> ERRS_N is DOUBLE PRECISION array, dimension
200: *> (NRHS, N_ERR_BNDS)
201: *> For each right-hand side, this array contains information about
202: *> various error bounds and condition numbers corresponding to the
203: *> normwise relative error, which is defined as follows:
204: *>
205: *> Normwise relative error in the ith solution vector:
206: *> max_j (abs(XTRUE(j,i) - X(j,i)))
207: *> ------------------------------
208: *> max_j abs(X(j,i))
209: *>
210: *> The array is indexed by the type of error information as described
211: *> below. There currently are up to three pieces of information
212: *> returned.
213: *>
214: *> The first index in ERRS_N(i,:) corresponds to the ith
215: *> right-hand side.
216: *>
217: *> The second index in ERRS_N(:,err) contains the following
218: *> three fields:
219: *> err = 1 "Trust/don't trust" boolean. Trust the answer if the
220: *> reciprocal condition number is less than the threshold
221: *> sqrt(n) * slamch('Epsilon').
222: *>
223: *> err = 2 "Guaranteed" error bound: The estimated forward error,
224: *> almost certainly within a factor of 10 of the true error
225: *> so long as the next entry is greater than the threshold
226: *> sqrt(n) * slamch('Epsilon'). This error bound should only
227: *> be trusted if the previous boolean is true.
228: *>
229: *> err = 3 Reciprocal condition number: Estimated normwise
230: *> reciprocal condition number. Compared with the threshold
231: *> sqrt(n) * slamch('Epsilon') to determine if the error
232: *> estimate is "guaranteed". These reciprocal condition
233: *> numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
234: *> appropriately scaled matrix Z.
235: *> Let Z = S*A, where S scales each row by a power of the
236: *> radix so all absolute row sums of Z are approximately 1.
237: *>
238: *> This subroutine is only responsible for setting the second field
239: *> above.
240: *> See Lapack Working Note 165 for further details and extra
241: *> cautions.
242: *> \endverbatim
243: *>
244: *> \param[in,out] ERRS_C
245: *> \verbatim
246: *> ERRS_C is DOUBLE PRECISION array, dimension
247: *> (NRHS, N_ERR_BNDS)
248: *> For each right-hand side, this array contains information about
249: *> various error bounds and condition numbers corresponding to the
250: *> componentwise relative error, which is defined as follows:
251: *>
252: *> Componentwise relative error in the ith solution vector:
253: *> abs(XTRUE(j,i) - X(j,i))
254: *> max_j ----------------------
255: *> abs(X(j,i))
256: *>
257: *> The array is indexed by the right-hand side i (on which the
258: *> componentwise relative error depends), and the type of error
259: *> information as described below. There currently are up to three
260: *> pieces of information returned for each right-hand side. If
261: *> componentwise accuracy is not requested (PARAMS(3) = 0.0), then
262: *> ERRS_C is not accessed. If N_ERR_BNDS .LT. 3, then at most
263: *> the first (:,N_ERR_BNDS) entries are returned.
264: *>
265: *> The first index in ERRS_C(i,:) corresponds to the ith
266: *> right-hand side.
267: *>
268: *> The second index in ERRS_C(:,err) contains the following
269: *> three fields:
270: *> err = 1 "Trust/don't trust" boolean. Trust the answer if the
271: *> reciprocal condition number is less than the threshold
272: *> sqrt(n) * slamch('Epsilon').
273: *>
274: *> err = 2 "Guaranteed" error bound: The estimated forward error,
275: *> almost certainly within a factor of 10 of the true error
276: *> so long as the next entry is greater than the threshold
277: *> sqrt(n) * slamch('Epsilon'). This error bound should only
278: *> be trusted if the previous boolean is true.
279: *>
280: *> err = 3 Reciprocal condition number: Estimated componentwise
281: *> reciprocal condition number. Compared with the threshold
282: *> sqrt(n) * slamch('Epsilon') to determine if the error
283: *> estimate is "guaranteed". These reciprocal condition
284: *> numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
285: *> appropriately scaled matrix Z.
286: *> Let Z = S*(A*diag(x)), where x is the solution for the
287: *> current right-hand side and S scales each row of
288: *> A*diag(x) by a power of the radix so all absolute row
289: *> sums of Z are approximately 1.
290: *>
291: *> This subroutine is only responsible for setting the second field
292: *> above.
293: *> See Lapack Working Note 165 for further details and extra
294: *> cautions.
295: *> \endverbatim
296: *>
297: *> \param[in] RES
298: *> \verbatim
299: *> RES is DOUBLE PRECISION array, dimension (N)
300: *> Workspace to hold the intermediate residual.
301: *> \endverbatim
302: *>
303: *> \param[in] AYB
304: *> \verbatim
305: *> AYB is DOUBLE PRECISION array, dimension (N)
306: *> Workspace. This can be the same workspace passed for Y_TAIL.
307: *> \endverbatim
308: *>
309: *> \param[in] DY
310: *> \verbatim
311: *> DY is DOUBLE PRECISION array, dimension (N)
312: *> Workspace to hold the intermediate solution.
313: *> \endverbatim
314: *>
315: *> \param[in] Y_TAIL
316: *> \verbatim
317: *> Y_TAIL is DOUBLE PRECISION array, dimension (N)
318: *> Workspace to hold the trailing bits of the intermediate solution.
319: *> \endverbatim
320: *>
321: *> \param[in] RCOND
322: *> \verbatim
323: *> RCOND is DOUBLE PRECISION
324: *> Reciprocal scaled condition number. This is an estimate of the
325: *> reciprocal Skeel condition number of the matrix A after
326: *> equilibration (if done). If this is less than the machine
327: *> precision (in particular, if it is zero), the matrix is singular
328: *> to working precision. Note that the error may still be small even
329: *> if this number is very small and the matrix appears ill-
330: *> conditioned.
331: *> \endverbatim
332: *>
333: *> \param[in] ITHRESH
334: *> \verbatim
335: *> ITHRESH is INTEGER
336: *> The maximum number of residual computations allowed for
337: *> refinement. The default is 10. For 'aggressive' set to 100 to
338: *> permit convergence using approximate factorizations or
339: *> factorizations other than LU. If the factorization uses a
340: *> technique other than Gaussian elimination, the guarantees in
341: *> ERRS_N and ERRS_C may no longer be trustworthy.
342: *> \endverbatim
343: *>
344: *> \param[in] RTHRESH
345: *> \verbatim
346: *> RTHRESH is DOUBLE PRECISION
347: *> Determines when to stop refinement if the error estimate stops
348: *> decreasing. Refinement will stop when the next solution no longer
349: *> satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
350: *> the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
351: *> default value is 0.5. For 'aggressive' set to 0.9 to permit
352: *> convergence on extremely ill-conditioned matrices. See LAWN 165
353: *> for more details.
354: *> \endverbatim
355: *>
356: *> \param[in] DZ_UB
357: *> \verbatim
358: *> DZ_UB is DOUBLE PRECISION
359: *> Determines when to start considering componentwise convergence.
360: *> Componentwise convergence is only considered after each component
361: *> of the solution Y is stable, which we definte as the relative
362: *> change in each component being less than DZ_UB. The default value
363: *> is 0.25, requiring the first bit to be stable. See LAWN 165 for
364: *> more details.
365: *> \endverbatim
366: *>
367: *> \param[in] IGNORE_CWISE
368: *> \verbatim
369: *> IGNORE_CWISE is LOGICAL
370: *> If .TRUE. then ignore componentwise convergence. Default value
371: *> is .FALSE..
372: *> \endverbatim
373: *>
374: *> \param[out] INFO
375: *> \verbatim
376: *> INFO is INTEGER
377: *> = 0: Successful exit.
378: *> < 0: if INFO = -i, the ith argument to DGETRS had an illegal
379: *> value
380: *> \endverbatim
381: *
382: * Authors:
383: * ========
384: *
385: *> \author Univ. of Tennessee
386: *> \author Univ. of California Berkeley
387: *> \author Univ. of Colorado Denver
388: *> \author NAG Ltd.
389: *
390: *> \date September 2012
391: *
392: *> \ingroup doubleGEcomputational
393: *
394: * =====================================================================
395: SUBROUTINE DLA_GERFSX_EXTENDED( PREC_TYPE, TRANS_TYPE, N, NRHS, A,
396: $ LDA, AF, LDAF, IPIV, COLEQU, C, B,
397: $ LDB, Y, LDY, BERR_OUT, N_NORMS,
398: $ ERRS_N, ERRS_C, RES, AYB, DY,
399: $ Y_TAIL, RCOND, ITHRESH, RTHRESH,
400: $ DZ_UB, IGNORE_CWISE, INFO )
401: *
402: * -- LAPACK computational routine (version 3.4.2) --
403: * -- LAPACK is a software package provided by Univ. of Tennessee, --
404: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
405: * September 2012
406: *
407: * .. Scalar Arguments ..
408: INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
409: $ TRANS_TYPE, N_NORMS, ITHRESH
410: LOGICAL COLEQU, IGNORE_CWISE
411: DOUBLE PRECISION RTHRESH, DZ_UB
412: * ..
413: * .. Array Arguments ..
414: INTEGER IPIV( * )
415: DOUBLE PRECISION A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
416: $ Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
417: DOUBLE PRECISION C( * ), AYB( * ), RCOND, BERR_OUT( * ),
418: $ ERRS_N( NRHS, * ), ERRS_C( NRHS, * )
419: * ..
420: *
421: * =====================================================================
422: *
423: * .. Local Scalars ..
424: CHARACTER TRANS
425: INTEGER CNT, I, J, X_STATE, Z_STATE, Y_PREC_STATE
426: DOUBLE PRECISION YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
427: $ DZRAT, PREVNORMDX, PREV_DZ_Z, DXRATMAX,
428: $ DZRATMAX, DX_X, DZ_Z, FINAL_DX_X, FINAL_DZ_Z,
429: $ EPS, HUGEVAL, INCR_THRESH
430: LOGICAL INCR_PREC
431: * ..
432: * .. Parameters ..
433: INTEGER UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
434: $ NOPROG_STATE, BASE_RESIDUAL, EXTRA_RESIDUAL,
435: $ EXTRA_Y
436: PARAMETER ( UNSTABLE_STATE = 0, WORKING_STATE = 1,
437: $ CONV_STATE = 2, NOPROG_STATE = 3 )
438: PARAMETER ( BASE_RESIDUAL = 0, EXTRA_RESIDUAL = 1,
439: $ EXTRA_Y = 2 )
440: INTEGER FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
441: INTEGER RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
442: INTEGER CMP_ERR_I, PIV_GROWTH_I
443: PARAMETER ( FINAL_NRM_ERR_I = 1, FINAL_CMP_ERR_I = 2,
444: $ BERR_I = 3 )
445: PARAMETER ( RCOND_I = 4, NRM_RCOND_I = 5, NRM_ERR_I = 6 )
446: PARAMETER ( CMP_RCOND_I = 7, CMP_ERR_I = 8,
447: $ PIV_GROWTH_I = 9 )
448: INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
449: $ LA_LINRX_CWISE_I
450: PARAMETER ( LA_LINRX_ITREF_I = 1,
451: $ LA_LINRX_ITHRESH_I = 2 )
452: PARAMETER ( LA_LINRX_CWISE_I = 3 )
453: INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
454: $ LA_LINRX_RCOND_I
455: PARAMETER ( LA_LINRX_TRUST_I = 1, LA_LINRX_ERR_I = 2 )
456: PARAMETER ( LA_LINRX_RCOND_I = 3 )
457: * ..
458: * .. External Subroutines ..
459: EXTERNAL DAXPY, DCOPY, DGETRS, DGEMV, BLAS_DGEMV_X,
460: $ BLAS_DGEMV2_X, DLA_GEAMV, DLA_WWADDW, DLAMCH,
461: $ CHLA_TRANSTYPE, DLA_LIN_BERR
462: DOUBLE PRECISION DLAMCH
463: CHARACTER CHLA_TRANSTYPE
464: * ..
465: * .. Intrinsic Functions ..
466: INTRINSIC ABS, MAX, MIN
467: * ..
468: * .. Executable Statements ..
469: *
470: IF ( INFO.NE.0 ) RETURN
471: TRANS = CHLA_TRANSTYPE(TRANS_TYPE)
472: EPS = DLAMCH( 'Epsilon' )
473: HUGEVAL = DLAMCH( 'Overflow' )
474: * Force HUGEVAL to Inf
475: HUGEVAL = HUGEVAL * HUGEVAL
476: * Using HUGEVAL may lead to spurious underflows.
477: INCR_THRESH = DBLE( N ) * EPS
478: *
479: DO J = 1, NRHS
480: Y_PREC_STATE = EXTRA_RESIDUAL
481: IF ( Y_PREC_STATE .EQ. EXTRA_Y ) THEN
482: DO I = 1, N
483: Y_TAIL( I ) = 0.0D+0
484: END DO
485: END IF
486:
487: DXRAT = 0.0D+0
488: DXRATMAX = 0.0D+0
489: DZRAT = 0.0D+0
490: DZRATMAX = 0.0D+0
491: FINAL_DX_X = HUGEVAL
492: FINAL_DZ_Z = HUGEVAL
493: PREVNORMDX = HUGEVAL
494: PREV_DZ_Z = HUGEVAL
495: DZ_Z = HUGEVAL
496: DX_X = HUGEVAL
497:
498: X_STATE = WORKING_STATE
499: Z_STATE = UNSTABLE_STATE
500: INCR_PREC = .FALSE.
501:
502: DO CNT = 1, ITHRESH
503: *
504: * Compute residual RES = B_s - op(A_s) * Y,
505: * op(A) = A, A**T, or A**H depending on TRANS (and type).
506: *
507: CALL DCOPY( N, B( 1, J ), 1, RES, 1 )
508: IF ( Y_PREC_STATE .EQ. BASE_RESIDUAL ) THEN
509: CALL DGEMV( TRANS, N, N, -1.0D+0, A, LDA, Y( 1, J ), 1,
510: $ 1.0D+0, RES, 1 )
511: ELSE IF ( Y_PREC_STATE .EQ. EXTRA_RESIDUAL ) THEN
512: CALL BLAS_DGEMV_X( TRANS_TYPE, N, N, -1.0D+0, A, LDA,
513: $ Y( 1, J ), 1, 1.0D+0, RES, 1, PREC_TYPE )
514: ELSE
515: CALL BLAS_DGEMV2_X( TRANS_TYPE, N, N, -1.0D+0, A, LDA,
516: $ Y( 1, J ), Y_TAIL, 1, 1.0D+0, RES, 1, PREC_TYPE )
517: END IF
518:
519: ! XXX: RES is no longer needed.
520: CALL DCOPY( N, RES, 1, DY, 1 )
521: CALL DGETRS( TRANS, N, 1, AF, LDAF, IPIV, DY, N, INFO )
522: *
523: * Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
524: *
525: NORMX = 0.0D+0
526: NORMY = 0.0D+0
527: NORMDX = 0.0D+0
528: DZ_Z = 0.0D+0
529: YMIN = HUGEVAL
530: *
531: DO I = 1, N
532: YK = ABS( Y( I, J ) )
533: DYK = ABS( DY( I ) )
534:
535: IF ( YK .NE. 0.0D+0 ) THEN
536: DZ_Z = MAX( DZ_Z, DYK / YK )
537: ELSE IF ( DYK .NE. 0.0D+0 ) THEN
538: DZ_Z = HUGEVAL
539: END IF
540:
541: YMIN = MIN( YMIN, YK )
542:
543: NORMY = MAX( NORMY, YK )
544:
545: IF ( COLEQU ) THEN
546: NORMX = MAX( NORMX, YK * C( I ) )
547: NORMDX = MAX( NORMDX, DYK * C( I ) )
548: ELSE
549: NORMX = NORMY
550: NORMDX = MAX( NORMDX, DYK )
551: END IF
552: END DO
553:
554: IF ( NORMX .NE. 0.0D+0 ) THEN
555: DX_X = NORMDX / NORMX
556: ELSE IF ( NORMDX .EQ. 0.0D+0 ) THEN
557: DX_X = 0.0D+0
558: ELSE
559: DX_X = HUGEVAL
560: END IF
561:
562: DXRAT = NORMDX / PREVNORMDX
563: DZRAT = DZ_Z / PREV_DZ_Z
564: *
565: * Check termination criteria
566: *
567: IF (.NOT.IGNORE_CWISE
568: $ .AND. YMIN*RCOND .LT. INCR_THRESH*NORMY
569: $ .AND. Y_PREC_STATE .LT. EXTRA_Y)
570: $ INCR_PREC = .TRUE.
571:
572: IF ( X_STATE .EQ. NOPROG_STATE .AND. DXRAT .LE. RTHRESH )
573: $ X_STATE = WORKING_STATE
574: IF ( X_STATE .EQ. WORKING_STATE ) THEN
575: IF ( DX_X .LE. EPS ) THEN
576: X_STATE = CONV_STATE
577: ELSE IF ( DXRAT .GT. RTHRESH ) THEN
578: IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
579: INCR_PREC = .TRUE.
580: ELSE
581: X_STATE = NOPROG_STATE
582: END IF
583: ELSE
584: IF ( DXRAT .GT. DXRATMAX ) DXRATMAX = DXRAT
585: END IF
586: IF ( X_STATE .GT. WORKING_STATE ) FINAL_DX_X = DX_X
587: END IF
588:
589: IF ( Z_STATE .EQ. UNSTABLE_STATE .AND. DZ_Z .LE. DZ_UB )
590: $ Z_STATE = WORKING_STATE
591: IF ( Z_STATE .EQ. NOPROG_STATE .AND. DZRAT .LE. RTHRESH )
592: $ Z_STATE = WORKING_STATE
593: IF ( Z_STATE .EQ. WORKING_STATE ) THEN
594: IF ( DZ_Z .LE. EPS ) THEN
595: Z_STATE = CONV_STATE
596: ELSE IF ( DZ_Z .GT. DZ_UB ) THEN
597: Z_STATE = UNSTABLE_STATE
598: DZRATMAX = 0.0D+0
599: FINAL_DZ_Z = HUGEVAL
600: ELSE IF ( DZRAT .GT. RTHRESH ) THEN
601: IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
602: INCR_PREC = .TRUE.
603: ELSE
604: Z_STATE = NOPROG_STATE
605: END IF
606: ELSE
607: IF ( DZRAT .GT. DZRATMAX ) DZRATMAX = DZRAT
608: END IF
609: IF ( Z_STATE .GT. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
610: END IF
611: *
612: * Exit if both normwise and componentwise stopped working,
613: * but if componentwise is unstable, let it go at least two
614: * iterations.
615: *
616: IF ( X_STATE.NE.WORKING_STATE ) THEN
617: IF ( IGNORE_CWISE) GOTO 666
618: IF ( Z_STATE.EQ.NOPROG_STATE .OR. Z_STATE.EQ.CONV_STATE )
619: $ GOTO 666
620: IF ( Z_STATE.EQ.UNSTABLE_STATE .AND. CNT.GT.1 ) GOTO 666
621: END IF
622:
623: IF ( INCR_PREC ) THEN
624: INCR_PREC = .FALSE.
625: Y_PREC_STATE = Y_PREC_STATE + 1
626: DO I = 1, N
627: Y_TAIL( I ) = 0.0D+0
628: END DO
629: END IF
630:
631: PREVNORMDX = NORMDX
632: PREV_DZ_Z = DZ_Z
633: *
634: * Update soluton.
635: *
636: IF ( Y_PREC_STATE .LT. EXTRA_Y ) THEN
637: CALL DAXPY( N, 1.0D+0, DY, 1, Y( 1, J ), 1 )
638: ELSE
639: CALL DLA_WWADDW( N, Y( 1, J ), Y_TAIL, DY )
640: END IF
641:
642: END DO
643: * Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
644: 666 CONTINUE
645: *
646: * Set final_* when cnt hits ithresh.
647: *
648: IF ( X_STATE .EQ. WORKING_STATE ) FINAL_DX_X = DX_X
649: IF ( Z_STATE .EQ. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
650: *
651: * Compute error bounds
652: *
653: IF (N_NORMS .GE. 1) THEN
654: ERRS_N( J, LA_LINRX_ERR_I ) = FINAL_DX_X / (1 - DXRATMAX)
655: END IF
656: IF ( N_NORMS .GE. 2 ) THEN
657: ERRS_C( J, LA_LINRX_ERR_I ) = FINAL_DZ_Z / (1 - DZRATMAX)
658: END IF
659: *
660: * Compute componentwise relative backward error from formula
661: * max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
662: * where abs(Z) is the componentwise absolute value of the matrix
663: * or vector Z.
664: *
665: * Compute residual RES = B_s - op(A_s) * Y,
666: * op(A) = A, A**T, or A**H depending on TRANS (and type).
667: *
668: CALL DCOPY( N, B( 1, J ), 1, RES, 1 )
669: CALL DGEMV( TRANS, N, N, -1.0D+0, A, LDA, Y(1,J), 1, 1.0D+0,
670: $ RES, 1 )
671:
672: DO I = 1, N
673: AYB( I ) = ABS( B( I, J ) )
674: END DO
675: *
676: * Compute abs(op(A_s))*abs(Y) + abs(B_s).
677: *
678: CALL DLA_GEAMV ( TRANS_TYPE, N, N, 1.0D+0,
679: $ A, LDA, Y(1, J), 1, 1.0D+0, AYB, 1 )
680:
681: CALL DLA_LIN_BERR ( N, N, 1, RES, AYB, BERR_OUT( J ) )
682: *
683: * End of loop for each RHS.
684: *
685: END DO
686: *
687: RETURN
688: END
CVSweb interface <joel.bertrand@systella.fr>