1: *> \brief \b DGERFS
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DGERFS + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dgerfs.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dgerfs.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dgerfs.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DGERFS( TRANS, N, NRHS, A, LDA, AF, LDAF, IPIV, B, LDB,
22: * X, LDX, FERR, BERR, WORK, IWORK, INFO )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER TRANS
26: * INTEGER INFO, LDA, LDAF, LDB, LDX, N, NRHS
27: * ..
28: * .. Array Arguments ..
29: * INTEGER IPIV( * ), IWORK( * )
30: * DOUBLE PRECISION A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
31: * $ BERR( * ), FERR( * ), WORK( * ), X( LDX, * )
32: * ..
33: *
34: *
35: *> \par Purpose:
36: * =============
37: *>
38: *> \verbatim
39: *>
40: *> DGERFS improves the computed solution to a system of linear
41: *> equations and provides error bounds and backward error estimates for
42: *> the solution.
43: *> \endverbatim
44: *
45: * Arguments:
46: * ==========
47: *
48: *> \param[in] TRANS
49: *> \verbatim
50: *> TRANS is CHARACTER*1
51: *> Specifies the form of the system of equations:
52: *> = 'N': A * X = B (No transpose)
53: *> = 'T': A**T * X = B (Transpose)
54: *> = 'C': A**H * X = B (Conjugate transpose = Transpose)
55: *> \endverbatim
56: *>
57: *> \param[in] N
58: *> \verbatim
59: *> N is INTEGER
60: *> The order of the matrix A. N >= 0.
61: *> \endverbatim
62: *>
63: *> \param[in] NRHS
64: *> \verbatim
65: *> NRHS is INTEGER
66: *> The number of right hand sides, i.e., the number of columns
67: *> of the matrices B and X. NRHS >= 0.
68: *> \endverbatim
69: *>
70: *> \param[in] A
71: *> \verbatim
72: *> A is DOUBLE PRECISION array, dimension (LDA,N)
73: *> The original N-by-N matrix A.
74: *> \endverbatim
75: *>
76: *> \param[in] LDA
77: *> \verbatim
78: *> LDA is INTEGER
79: *> The leading dimension of the array A. LDA >= max(1,N).
80: *> \endverbatim
81: *>
82: *> \param[in] AF
83: *> \verbatim
84: *> AF is DOUBLE PRECISION array, dimension (LDAF,N)
85: *> The factors L and U from the factorization A = P*L*U
86: *> as computed by DGETRF.
87: *> \endverbatim
88: *>
89: *> \param[in] LDAF
90: *> \verbatim
91: *> LDAF is INTEGER
92: *> The leading dimension of the array AF. LDAF >= max(1,N).
93: *> \endverbatim
94: *>
95: *> \param[in] IPIV
96: *> \verbatim
97: *> IPIV is INTEGER array, dimension (N)
98: *> The pivot indices from DGETRF; for 1<=i<=N, row i of the
99: *> matrix was interchanged with row IPIV(i).
100: *> \endverbatim
101: *>
102: *> \param[in] B
103: *> \verbatim
104: *> B is DOUBLE PRECISION array, dimension (LDB,NRHS)
105: *> The right hand side matrix B.
106: *> \endverbatim
107: *>
108: *> \param[in] LDB
109: *> \verbatim
110: *> LDB is INTEGER
111: *> The leading dimension of the array B. LDB >= max(1,N).
112: *> \endverbatim
113: *>
114: *> \param[in,out] X
115: *> \verbatim
116: *> X is DOUBLE PRECISION array, dimension (LDX,NRHS)
117: *> On entry, the solution matrix X, as computed by DGETRS.
118: *> On exit, the improved solution matrix X.
119: *> \endverbatim
120: *>
121: *> \param[in] LDX
122: *> \verbatim
123: *> LDX is INTEGER
124: *> The leading dimension of the array X. LDX >= max(1,N).
125: *> \endverbatim
126: *>
127: *> \param[out] FERR
128: *> \verbatim
129: *> FERR is DOUBLE PRECISION array, dimension (NRHS)
130: *> The estimated forward error bound for each solution vector
131: *> X(j) (the j-th column of the solution matrix X).
132: *> If XTRUE is the true solution corresponding to X(j), FERR(j)
133: *> is an estimated upper bound for the magnitude of the largest
134: *> element in (X(j) - XTRUE) divided by the magnitude of the
135: *> largest element in X(j). The estimate is as reliable as
136: *> the estimate for RCOND, and is almost always a slight
137: *> overestimate of the true error.
138: *> \endverbatim
139: *>
140: *> \param[out] BERR
141: *> \verbatim
142: *> BERR is DOUBLE PRECISION array, dimension (NRHS)
143: *> The componentwise relative backward error of each solution
144: *> vector X(j) (i.e., the smallest relative change in
145: *> any element of A or B that makes X(j) an exact solution).
146: *> \endverbatim
147: *>
148: *> \param[out] WORK
149: *> \verbatim
150: *> WORK is DOUBLE PRECISION array, dimension (3*N)
151: *> \endverbatim
152: *>
153: *> \param[out] IWORK
154: *> \verbatim
155: *> IWORK is INTEGER array, dimension (N)
156: *> \endverbatim
157: *>
158: *> \param[out] INFO
159: *> \verbatim
160: *> INFO is INTEGER
161: *> = 0: successful exit
162: *> < 0: if INFO = -i, the i-th argument had an illegal value
163: *> \endverbatim
164: *
165: *> \par Internal Parameters:
166: * =========================
167: *>
168: *> \verbatim
169: *> ITMAX is the maximum number of steps of iterative refinement.
170: *> \endverbatim
171: *
172: * Authors:
173: * ========
174: *
175: *> \author Univ. of Tennessee
176: *> \author Univ. of California Berkeley
177: *> \author Univ. of Colorado Denver
178: *> \author NAG Ltd.
179: *
180: *> \ingroup doubleGEcomputational
181: *
182: * =====================================================================
183: SUBROUTINE DGERFS( TRANS, N, NRHS, A, LDA, AF, LDAF, IPIV, B, LDB,
184: $ X, LDX, FERR, BERR, WORK, IWORK, INFO )
185: *
186: * -- LAPACK computational routine --
187: * -- LAPACK is a software package provided by Univ. of Tennessee, --
188: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
189: *
190: * .. Scalar Arguments ..
191: CHARACTER TRANS
192: INTEGER INFO, LDA, LDAF, LDB, LDX, N, NRHS
193: * ..
194: * .. Array Arguments ..
195: INTEGER IPIV( * ), IWORK( * )
196: DOUBLE PRECISION A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
197: $ BERR( * ), FERR( * ), WORK( * ), X( LDX, * )
198: * ..
199: *
200: * =====================================================================
201: *
202: * .. Parameters ..
203: INTEGER ITMAX
204: PARAMETER ( ITMAX = 5 )
205: DOUBLE PRECISION ZERO
206: PARAMETER ( ZERO = 0.0D+0 )
207: DOUBLE PRECISION ONE
208: PARAMETER ( ONE = 1.0D+0 )
209: DOUBLE PRECISION TWO
210: PARAMETER ( TWO = 2.0D+0 )
211: DOUBLE PRECISION THREE
212: PARAMETER ( THREE = 3.0D+0 )
213: * ..
214: * .. Local Scalars ..
215: LOGICAL NOTRAN
216: CHARACTER TRANST
217: INTEGER COUNT, I, J, K, KASE, NZ
218: DOUBLE PRECISION EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN, XK
219: * ..
220: * .. Local Arrays ..
221: INTEGER ISAVE( 3 )
222: * ..
223: * .. External Subroutines ..
224: EXTERNAL DAXPY, DCOPY, DGEMV, DGETRS, DLACN2, XERBLA
225: * ..
226: * .. Intrinsic Functions ..
227: INTRINSIC ABS, MAX
228: * ..
229: * .. External Functions ..
230: LOGICAL LSAME
231: DOUBLE PRECISION DLAMCH
232: EXTERNAL LSAME, DLAMCH
233: * ..
234: * .. Executable Statements ..
235: *
236: * Test the input parameters.
237: *
238: INFO = 0
239: NOTRAN = LSAME( TRANS, 'N' )
240: IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) .AND. .NOT.
241: $ LSAME( TRANS, 'C' ) ) THEN
242: INFO = -1
243: ELSE IF( N.LT.0 ) THEN
244: INFO = -2
245: ELSE IF( NRHS.LT.0 ) THEN
246: INFO = -3
247: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
248: INFO = -5
249: ELSE IF( LDAF.LT.MAX( 1, N ) ) THEN
250: INFO = -7
251: ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
252: INFO = -10
253: ELSE IF( LDX.LT.MAX( 1, N ) ) THEN
254: INFO = -12
255: END IF
256: IF( INFO.NE.0 ) THEN
257: CALL XERBLA( 'DGERFS', -INFO )
258: RETURN
259: END IF
260: *
261: * Quick return if possible
262: *
263: IF( N.EQ.0 .OR. NRHS.EQ.0 ) THEN
264: DO 10 J = 1, NRHS
265: FERR( J ) = ZERO
266: BERR( J ) = ZERO
267: 10 CONTINUE
268: RETURN
269: END IF
270: *
271: IF( NOTRAN ) THEN
272: TRANST = 'T'
273: ELSE
274: TRANST = 'N'
275: END IF
276: *
277: * NZ = maximum number of nonzero elements in each row of A, plus 1
278: *
279: NZ = N + 1
280: EPS = DLAMCH( 'Epsilon' )
281: SAFMIN = DLAMCH( 'Safe minimum' )
282: SAFE1 = NZ*SAFMIN
283: SAFE2 = SAFE1 / EPS
284: *
285: * Do for each right hand side
286: *
287: DO 140 J = 1, NRHS
288: *
289: COUNT = 1
290: LSTRES = THREE
291: 20 CONTINUE
292: *
293: * Loop until stopping criterion is satisfied.
294: *
295: * Compute residual R = B - op(A) * X,
296: * where op(A) = A, A**T, or A**H, depending on TRANS.
297: *
298: CALL DCOPY( N, B( 1, J ), 1, WORK( N+1 ), 1 )
299: CALL DGEMV( TRANS, N, N, -ONE, A, LDA, X( 1, J ), 1, ONE,
300: $ WORK( N+1 ), 1 )
301: *
302: * Compute componentwise relative backward error from formula
303: *
304: * max(i) ( abs(R(i)) / ( abs(op(A))*abs(X) + abs(B) )(i) )
305: *
306: * where abs(Z) is the componentwise absolute value of the matrix
307: * or vector Z. If the i-th component of the denominator is less
308: * than SAFE2, then SAFE1 is added to the i-th components of the
309: * numerator and denominator before dividing.
310: *
311: DO 30 I = 1, N
312: WORK( I ) = ABS( B( I, J ) )
313: 30 CONTINUE
314: *
315: * Compute abs(op(A))*abs(X) + abs(B).
316: *
317: IF( NOTRAN ) THEN
318: DO 50 K = 1, N
319: XK = ABS( X( K, J ) )
320: DO 40 I = 1, N
321: WORK( I ) = WORK( I ) + ABS( A( I, K ) )*XK
322: 40 CONTINUE
323: 50 CONTINUE
324: ELSE
325: DO 70 K = 1, N
326: S = ZERO
327: DO 60 I = 1, N
328: S = S + ABS( A( I, K ) )*ABS( X( I, J ) )
329: 60 CONTINUE
330: WORK( K ) = WORK( K ) + S
331: 70 CONTINUE
332: END IF
333: S = ZERO
334: DO 80 I = 1, N
335: IF( WORK( I ).GT.SAFE2 ) THEN
336: S = MAX( S, ABS( WORK( N+I ) ) / WORK( I ) )
337: ELSE
338: S = MAX( S, ( ABS( WORK( N+I ) )+SAFE1 ) /
339: $ ( WORK( I )+SAFE1 ) )
340: END IF
341: 80 CONTINUE
342: BERR( J ) = S
343: *
344: * Test stopping criterion. Continue iterating if
345: * 1) The residual BERR(J) is larger than machine epsilon, and
346: * 2) BERR(J) decreased by at least a factor of 2 during the
347: * last iteration, and
348: * 3) At most ITMAX iterations tried.
349: *
350: IF( BERR( J ).GT.EPS .AND. TWO*BERR( J ).LE.LSTRES .AND.
351: $ COUNT.LE.ITMAX ) THEN
352: *
353: * Update solution and try again.
354: *
355: CALL DGETRS( TRANS, N, 1, AF, LDAF, IPIV, WORK( N+1 ), N,
356: $ INFO )
357: CALL DAXPY( N, ONE, WORK( N+1 ), 1, X( 1, J ), 1 )
358: LSTRES = BERR( J )
359: COUNT = COUNT + 1
360: GO TO 20
361: END IF
362: *
363: * Bound error from formula
364: *
365: * norm(X - XTRUE) / norm(X) .le. FERR =
366: * norm( abs(inv(op(A)))*
367: * ( abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) ))) / norm(X)
368: *
369: * where
370: * norm(Z) is the magnitude of the largest component of Z
371: * inv(op(A)) is the inverse of op(A)
372: * abs(Z) is the componentwise absolute value of the matrix or
373: * vector Z
374: * NZ is the maximum number of nonzeros in any row of A, plus 1
375: * EPS is machine epsilon
376: *
377: * The i-th component of abs(R)+NZ*EPS*(abs(op(A))*abs(X)+abs(B))
378: * is incremented by SAFE1 if the i-th component of
379: * abs(op(A))*abs(X) + abs(B) is less than SAFE2.
380: *
381: * Use DLACN2 to estimate the infinity-norm of the matrix
382: * inv(op(A)) * diag(W),
383: * where W = abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) )))
384: *
385: DO 90 I = 1, N
386: IF( WORK( I ).GT.SAFE2 ) THEN
387: WORK( I ) = ABS( WORK( N+I ) ) + NZ*EPS*WORK( I )
388: ELSE
389: WORK( I ) = ABS( WORK( N+I ) ) + NZ*EPS*WORK( I ) + SAFE1
390: END IF
391: 90 CONTINUE
392: *
393: KASE = 0
394: 100 CONTINUE
395: CALL DLACN2( N, WORK( 2*N+1 ), WORK( N+1 ), IWORK, FERR( J ),
396: $ KASE, ISAVE )
397: IF( KASE.NE.0 ) THEN
398: IF( KASE.EQ.1 ) THEN
399: *
400: * Multiply by diag(W)*inv(op(A)**T).
401: *
402: CALL DGETRS( TRANST, N, 1, AF, LDAF, IPIV, WORK( N+1 ),
403: $ N, INFO )
404: DO 110 I = 1, N
405: WORK( N+I ) = WORK( I )*WORK( N+I )
406: 110 CONTINUE
407: ELSE
408: *
409: * Multiply by inv(op(A))*diag(W).
410: *
411: DO 120 I = 1, N
412: WORK( N+I ) = WORK( I )*WORK( N+I )
413: 120 CONTINUE
414: CALL DGETRS( TRANS, N, 1, AF, LDAF, IPIV, WORK( N+1 ), N,
415: $ INFO )
416: END IF
417: GO TO 100
418: END IF
419: *
420: * Normalize error.
421: *
422: LSTRES = ZERO
423: DO 130 I = 1, N
424: LSTRES = MAX( LSTRES, ABS( X( I, J ) ) )
425: 130 CONTINUE
426: IF( LSTRES.NE.ZERO )
427: $ FERR( J ) = FERR( J ) / LSTRES
428: *
429: 140 CONTINUE
430: *
431: RETURN
432: *
433: * End of DGERFS
434: *
435: END
CVSweb interface <joel.bertrand@systella.fr>