1: *> \brief \b DGELQT3 recursively computes a LQ factorization of a general real or complex matrix using the compact WY representation of Q.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DGEQRT3 + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dgelqt3.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dgelqt3.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dgelqt3.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * RECURSIVE SUBROUTINE DGELQT3( M, N, A, LDA, T, LDT, INFO )
22: *
23: * .. Scalar Arguments ..
24: * INTEGER INFO, LDA, M, N, LDT
25: * ..
26: * .. Array Arguments ..
27: * DOUBLE PRECISION A( LDA, * ), T( LDT, * )
28: * ..
29: *
30: *
31: *> \par Purpose:
32: * =============
33: *>
34: *> \verbatim
35: *>
36: *> DGELQT3 recursively computes a LQ factorization of a real M-by-N
37: *> matrix A, using the compact WY representation of Q.
38: *>
39: *> Based on the algorithm of Elmroth and Gustavson,
40: *> IBM J. Res. Develop. Vol 44 No. 4 July 2000.
41: *> \endverbatim
42: *
43: * Arguments:
44: * ==========
45: *
46: *> \param[in] M
47: *> \verbatim
48: *> M is INTEGER
49: *> The number of rows of the matrix A. M =< N.
50: *> \endverbatim
51: *>
52: *> \param[in] N
53: *> \verbatim
54: *> N is INTEGER
55: *> The number of columns of the matrix A. N >= 0.
56: *> \endverbatim
57: *>
58: *> \param[in,out] A
59: *> \verbatim
60: *> A is DOUBLE PRECISION array, dimension (LDA,N)
61: *> On entry, the real M-by-N matrix A. On exit, the elements on and
62: *> below the diagonal contain the N-by-N lower triangular matrix L; the
63: *> elements above the diagonal are the rows of V. See below for
64: *> further details.
65: *> \endverbatim
66: *>
67: *> \param[in] LDA
68: *> \verbatim
69: *> LDA is INTEGER
70: *> The leading dimension of the array A. LDA >= max(1,M).
71: *> \endverbatim
72: *>
73: *> \param[out] T
74: *> \verbatim
75: *> T is DOUBLE PRECISION array, dimension (LDT,N)
76: *> The N-by-N upper triangular factor of the block reflector.
77: *> The elements on and above the diagonal contain the block
78: *> reflector T; the elements below the diagonal are not used.
79: *> See below for further details.
80: *> \endverbatim
81: *>
82: *> \param[in] LDT
83: *> \verbatim
84: *> LDT is INTEGER
85: *> The leading dimension of the array T. LDT >= max(1,N).
86: *> \endverbatim
87: *>
88: *> \param[out] INFO
89: *> \verbatim
90: *> INFO is INTEGER
91: *> = 0: successful exit
92: *> < 0: if INFO = -i, the i-th argument had an illegal value
93: *> \endverbatim
94: *
95: * Authors:
96: * ========
97: *
98: *> \author Univ. of Tennessee
99: *> \author Univ. of California Berkeley
100: *> \author Univ. of Colorado Denver
101: *> \author NAG Ltd.
102: *
103: *> \date November 2017
104: *
105: *> \ingroup doubleGEcomputational
106: *
107: *> \par Further Details:
108: * =====================
109: *>
110: *> \verbatim
111: *>
112: *> The matrix V stores the elementary reflectors H(i) in the i-th row
113: *> above the diagonal. For example, if M=5 and N=3, the matrix V is
114: *>
115: *> V = ( 1 v1 v1 v1 v1 )
116: *> ( 1 v2 v2 v2 )
117: *> ( 1 v3 v3 v3 )
118: *>
119: *>
120: *> where the vi's represent the vectors which define H(i), which are returned
121: *> in the matrix A. The 1's along the diagonal of V are not stored in A. The
122: *> block reflector H is then given by
123: *>
124: *> H = I - V * T * V**T
125: *>
126: *> where V**T is the transpose of V.
127: *>
128: *> For details of the algorithm, see Elmroth and Gustavson (cited above).
129: *> \endverbatim
130: *>
131: * =====================================================================
132: RECURSIVE SUBROUTINE DGELQT3( M, N, A, LDA, T, LDT, INFO )
133: *
134: * -- LAPACK computational routine (version 3.8.0) --
135: * -- LAPACK is a software package provided by Univ. of Tennessee, --
136: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
137: * November 2017
138: *
139: * .. Scalar Arguments ..
140: INTEGER INFO, LDA, M, N, LDT
141: * ..
142: * .. Array Arguments ..
143: DOUBLE PRECISION A( LDA, * ), T( LDT, * )
144: * ..
145: *
146: * =====================================================================
147: *
148: * .. Parameters ..
149: DOUBLE PRECISION ONE
150: PARAMETER ( ONE = 1.0D+00 )
151: * ..
152: * .. Local Scalars ..
153: INTEGER I, I1, J, J1, M1, M2, IINFO
154: * ..
155: * .. External Subroutines ..
156: EXTERNAL DLARFG, DTRMM, DGEMM, XERBLA
157: * ..
158: * .. Executable Statements ..
159: *
160: INFO = 0
161: IF( M .LT. 0 ) THEN
162: INFO = -1
163: ELSE IF( N .LT. M ) THEN
164: INFO = -2
165: ELSE IF( LDA .LT. MAX( 1, M ) ) THEN
166: INFO = -4
167: ELSE IF( LDT .LT. MAX( 1, M ) ) THEN
168: INFO = -6
169: END IF
170: IF( INFO.NE.0 ) THEN
171: CALL XERBLA( 'DGELQT3', -INFO )
172: RETURN
173: END IF
174: *
175: IF( M.EQ.1 ) THEN
176: *
177: * Compute Householder transform when N=1
178: *
179: CALL DLARFG( N, A, A( 1, MIN( 2, N ) ), LDA, T )
180: *
181: ELSE
182: *
183: * Otherwise, split A into blocks...
184: *
185: M1 = M/2
186: M2 = M-M1
187: I1 = MIN( M1+1, M )
188: J1 = MIN( M+1, N )
189: *
190: * Compute A(1:M1,1:N) <- (Y1,R1,T1), where Q1 = I - Y1 T1 Y1^H
191: *
192: CALL DGELQT3( M1, N, A, LDA, T, LDT, IINFO )
193: *
194: * Compute A(J1:M,1:N) = Q1^H A(J1:M,1:N) [workspace: T(1:N1,J1:N)]
195: *
196: DO I=1,M2
197: DO J=1,M1
198: T( I+M1, J ) = A( I+M1, J )
199: END DO
200: END DO
201: CALL DTRMM( 'R', 'U', 'T', 'U', M2, M1, ONE,
202: & A, LDA, T( I1, 1 ), LDT )
203: *
204: CALL DGEMM( 'N', 'T', M2, M1, N-M1, ONE, A( I1, I1 ), LDA,
205: & A( 1, I1 ), LDA, ONE, T( I1, 1 ), LDT)
206: *
207: CALL DTRMM( 'R', 'U', 'N', 'N', M2, M1, ONE,
208: & T, LDT, T( I1, 1 ), LDT )
209: *
210: CALL DGEMM( 'N', 'N', M2, N-M1, M1, -ONE, T( I1, 1 ), LDT,
211: & A( 1, I1 ), LDA, ONE, A( I1, I1 ), LDA )
212: *
213: CALL DTRMM( 'R', 'U', 'N', 'U', M2, M1 , ONE,
214: & A, LDA, T( I1, 1 ), LDT )
215: *
216: DO I=1,M2
217: DO J=1,M1
218: A( I+M1, J ) = A( I+M1, J ) - T( I+M1, J )
219: T( I+M1, J )=0
220: END DO
221: END DO
222: *
223: * Compute A(J1:M,J1:N) <- (Y2,R2,T2) where Q2 = I - Y2 T2 Y2^H
224: *
225: CALL DGELQT3( M2, N-M1, A( I1, I1 ), LDA,
226: & T( I1, I1 ), LDT, IINFO )
227: *
228: * Compute T3 = T(J1:N1,1:N) = -T1 Y1^H Y2 T2
229: *
230: DO I=1,M2
231: DO J=1,M1
232: T( J, I+M1 ) = (A( J, I+M1 ))
233: END DO
234: END DO
235: *
236: CALL DTRMM( 'R', 'U', 'T', 'U', M1, M2, ONE,
237: & A( I1, I1 ), LDA, T( 1, I1 ), LDT )
238: *
239: CALL DGEMM( 'N', 'T', M1, M2, N-M, ONE, A( 1, J1 ), LDA,
240: & A( I1, J1 ), LDA, ONE, T( 1, I1 ), LDT )
241: *
242: CALL DTRMM( 'L', 'U', 'N', 'N', M1, M2, -ONE, T, LDT,
243: & T( 1, I1 ), LDT )
244: *
245: CALL DTRMM( 'R', 'U', 'N', 'N', M1, M2, ONE,
246: & T( I1, I1 ), LDT, T( 1, I1 ), LDT )
247: *
248: *
249: *
250: * Y = (Y1,Y2); L = [ L1 0 ]; T = [T1 T3]
251: * [ A(1:N1,J1:N) L2 ] [ 0 T2]
252: *
253: END IF
254: *
255: RETURN
256: *
257: * End of DGELQT3
258: *
259: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dgelqt3.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack