Annotation of rpl/lapack/lapack/dgeesx.f, revision 1.3
1.1 bertrand 1: SUBROUTINE DGEESX( JOBVS, SORT, SELECT, SENSE, N, A, LDA, SDIM,
2: $ WR, WI, VS, LDVS, RCONDE, RCONDV, WORK, LWORK,
3: $ IWORK, LIWORK, BWORK, INFO )
4: *
5: * -- LAPACK driver routine (version 3.2) --
6: * -- LAPACK is a software package provided by Univ. of Tennessee, --
7: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
8: * November 2006
9: *
10: * .. Scalar Arguments ..
11: CHARACTER JOBVS, SENSE, SORT
12: INTEGER INFO, LDA, LDVS, LIWORK, LWORK, N, SDIM
13: DOUBLE PRECISION RCONDE, RCONDV
14: * ..
15: * .. Array Arguments ..
16: LOGICAL BWORK( * )
17: INTEGER IWORK( * )
18: DOUBLE PRECISION A( LDA, * ), VS( LDVS, * ), WI( * ), WORK( * ),
19: $ WR( * )
20: * ..
21: * .. Function Arguments ..
22: LOGICAL SELECT
23: EXTERNAL SELECT
24: * ..
25: *
26: * Purpose
27: * =======
28: *
29: * DGEESX computes for an N-by-N real nonsymmetric matrix A, the
30: * eigenvalues, the real Schur form T, and, optionally, the matrix of
31: * Schur vectors Z. This gives the Schur factorization A = Z*T*(Z**T).
32: *
33: * Optionally, it also orders the eigenvalues on the diagonal of the
34: * real Schur form so that selected eigenvalues are at the top left;
35: * computes a reciprocal condition number for the average of the
36: * selected eigenvalues (RCONDE); and computes a reciprocal condition
37: * number for the right invariant subspace corresponding to the
38: * selected eigenvalues (RCONDV). The leading columns of Z form an
39: * orthonormal basis for this invariant subspace.
40: *
41: * For further explanation of the reciprocal condition numbers RCONDE
42: * and RCONDV, see Section 4.10 of the LAPACK Users' Guide (where
43: * these quantities are called s and sep respectively).
44: *
45: * A real matrix is in real Schur form if it is upper quasi-triangular
46: * with 1-by-1 and 2-by-2 blocks. 2-by-2 blocks will be standardized in
47: * the form
48: * [ a b ]
49: * [ c a ]
50: *
51: * where b*c < 0. The eigenvalues of such a block are a +- sqrt(bc).
52: *
53: * Arguments
54: * =========
55: *
56: * JOBVS (input) CHARACTER*1
57: * = 'N': Schur vectors are not computed;
58: * = 'V': Schur vectors are computed.
59: *
60: * SORT (input) CHARACTER*1
61: * Specifies whether or not to order the eigenvalues on the
62: * diagonal of the Schur form.
63: * = 'N': Eigenvalues are not ordered;
64: * = 'S': Eigenvalues are ordered (see SELECT).
65: *
66: * SELECT (external procedure) LOGICAL FUNCTION of two DOUBLE PRECISION arguments
67: * SELECT must be declared EXTERNAL in the calling subroutine.
68: * If SORT = 'S', SELECT is used to select eigenvalues to sort
69: * to the top left of the Schur form.
70: * If SORT = 'N', SELECT is not referenced.
71: * An eigenvalue WR(j)+sqrt(-1)*WI(j) is selected if
72: * SELECT(WR(j),WI(j)) is true; i.e., if either one of a
73: * complex conjugate pair of eigenvalues is selected, then both
74: * are. Note that a selected complex eigenvalue may no longer
75: * satisfy SELECT(WR(j),WI(j)) = .TRUE. after ordering, since
76: * ordering may change the value of complex eigenvalues
77: * (especially if the eigenvalue is ill-conditioned); in this
78: * case INFO may be set to N+3 (see INFO below).
79: *
80: * SENSE (input) CHARACTER*1
81: * Determines which reciprocal condition numbers are computed.
82: * = 'N': None are computed;
83: * = 'E': Computed for average of selected eigenvalues only;
84: * = 'V': Computed for selected right invariant subspace only;
85: * = 'B': Computed for both.
86: * If SENSE = 'E', 'V' or 'B', SORT must equal 'S'.
87: *
88: * N (input) INTEGER
89: * The order of the matrix A. N >= 0.
90: *
91: * A (input/output) DOUBLE PRECISION array, dimension (LDA, N)
92: * On entry, the N-by-N matrix A.
93: * On exit, A is overwritten by its real Schur form T.
94: *
95: * LDA (input) INTEGER
96: * The leading dimension of the array A. LDA >= max(1,N).
97: *
98: * SDIM (output) INTEGER
99: * If SORT = 'N', SDIM = 0.
100: * If SORT = 'S', SDIM = number of eigenvalues (after sorting)
101: * for which SELECT is true. (Complex conjugate
102: * pairs for which SELECT is true for either
103: * eigenvalue count as 2.)
104: *
105: * WR (output) DOUBLE PRECISION array, dimension (N)
106: * WI (output) DOUBLE PRECISION array, dimension (N)
107: * WR and WI contain the real and imaginary parts, respectively,
108: * of the computed eigenvalues, in the same order that they
109: * appear on the diagonal of the output Schur form T. Complex
110: * conjugate pairs of eigenvalues appear consecutively with the
111: * eigenvalue having the positive imaginary part first.
112: *
113: * VS (output) DOUBLE PRECISION array, dimension (LDVS,N)
114: * If JOBVS = 'V', VS contains the orthogonal matrix Z of Schur
115: * vectors.
116: * If JOBVS = 'N', VS is not referenced.
117: *
118: * LDVS (input) INTEGER
119: * The leading dimension of the array VS. LDVS >= 1, and if
120: * JOBVS = 'V', LDVS >= N.
121: *
122: * RCONDE (output) DOUBLE PRECISION
123: * If SENSE = 'E' or 'B', RCONDE contains the reciprocal
124: * condition number for the average of the selected eigenvalues.
125: * Not referenced if SENSE = 'N' or 'V'.
126: *
127: * RCONDV (output) DOUBLE PRECISION
128: * If SENSE = 'V' or 'B', RCONDV contains the reciprocal
129: * condition number for the selected right invariant subspace.
130: * Not referenced if SENSE = 'N' or 'E'.
131: *
132: * WORK (workspace/output) DOUBLE PRECISION array, dimension (MAX(1,LWORK))
133: * On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
134: *
135: * LWORK (input) INTEGER
136: * The dimension of the array WORK. LWORK >= max(1,3*N).
137: * Also, if SENSE = 'E' or 'V' or 'B',
138: * LWORK >= N+2*SDIM*(N-SDIM), where SDIM is the number of
139: * selected eigenvalues computed by this routine. Note that
140: * N+2*SDIM*(N-SDIM) <= N+N*N/2. Note also that an error is only
141: * returned if LWORK < max(1,3*N), but if SENSE = 'E' or 'V' or
142: * 'B' this may not be large enough.
143: * For good performance, LWORK must generally be larger.
144: *
145: * If LWORK = -1, then a workspace query is assumed; the routine
146: * only calculates upper bounds on the optimal sizes of the
147: * arrays WORK and IWORK, returns these values as the first
148: * entries of the WORK and IWORK arrays, and no error messages
149: * related to LWORK or LIWORK are issued by XERBLA.
150: *
151: * IWORK (workspace/output) INTEGER array, dimension (MAX(1,LIWORK))
152: * On exit, if INFO = 0, IWORK(1) returns the optimal LIWORK.
153: *
154: * LIWORK (input) INTEGER
155: * The dimension of the array IWORK.
156: * LIWORK >= 1; if SENSE = 'V' or 'B', LIWORK >= SDIM*(N-SDIM).
157: * Note that SDIM*(N-SDIM) <= N*N/4. Note also that an error is
158: * only returned if LIWORK < 1, but if SENSE = 'V' or 'B' this
159: * may not be large enough.
160: *
161: * If LIWORK = -1, then a workspace query is assumed; the
162: * routine only calculates upper bounds on the optimal sizes of
163: * the arrays WORK and IWORK, returns these values as the first
164: * entries of the WORK and IWORK arrays, and no error messages
165: * related to LWORK or LIWORK are issued by XERBLA.
166: *
167: * BWORK (workspace) LOGICAL array, dimension (N)
168: * Not referenced if SORT = 'N'.
169: *
170: * INFO (output) INTEGER
171: * = 0: successful exit
172: * < 0: if INFO = -i, the i-th argument had an illegal value.
173: * > 0: if INFO = i, and i is
174: * <= N: the QR algorithm failed to compute all the
175: * eigenvalues; elements 1:ILO-1 and i+1:N of WR and WI
176: * contain those eigenvalues which have converged; if
177: * JOBVS = 'V', VS contains the transformation which
178: * reduces A to its partially converged Schur form.
179: * = N+1: the eigenvalues could not be reordered because some
180: * eigenvalues were too close to separate (the problem
181: * is very ill-conditioned);
182: * = N+2: after reordering, roundoff changed values of some
183: * complex eigenvalues so that leading eigenvalues in
184: * the Schur form no longer satisfy SELECT=.TRUE. This
185: * could also be caused by underflow due to scaling.
186: *
187: * =====================================================================
188: *
189: * .. Parameters ..
190: DOUBLE PRECISION ZERO, ONE
191: PARAMETER ( ZERO = 0.0D0, ONE = 1.0D0 )
192: * ..
193: * .. Local Scalars ..
194: LOGICAL CURSL, LASTSL, LQUERY, LST2SL, SCALEA, WANTSB,
195: $ WANTSE, WANTSN, WANTST, WANTSV, WANTVS
196: INTEGER HSWORK, I, I1, I2, IBAL, ICOND, IERR, IEVAL,
197: $ IHI, ILO, INXT, IP, ITAU, IWRK, LIWRK, LWRK,
198: $ MAXWRK, MINWRK
199: DOUBLE PRECISION ANRM, BIGNUM, CSCALE, EPS, SMLNUM
200: * ..
201: * .. Local Arrays ..
202: DOUBLE PRECISION DUM( 1 )
203: * ..
204: * .. External Subroutines ..
205: EXTERNAL DCOPY, DGEBAK, DGEBAL, DGEHRD, DHSEQR, DLACPY,
206: $ DLASCL, DORGHR, DSWAP, DTRSEN, XERBLA
207: * ..
208: * .. External Functions ..
209: LOGICAL LSAME
210: INTEGER ILAENV
211: DOUBLE PRECISION DLAMCH, DLANGE
212: EXTERNAL LSAME, ILAENV, DLABAD, DLAMCH, DLANGE
213: * ..
214: * .. Intrinsic Functions ..
215: INTRINSIC MAX, SQRT
216: * ..
217: * .. Executable Statements ..
218: *
219: * Test the input arguments
220: *
221: INFO = 0
222: WANTVS = LSAME( JOBVS, 'V' )
223: WANTST = LSAME( SORT, 'S' )
224: WANTSN = LSAME( SENSE, 'N' )
225: WANTSE = LSAME( SENSE, 'E' )
226: WANTSV = LSAME( SENSE, 'V' )
227: WANTSB = LSAME( SENSE, 'B' )
228: LQUERY = ( LWORK.EQ.-1 .OR. LIWORK.EQ.-1 )
229: IF( ( .NOT.WANTVS ) .AND. ( .NOT.LSAME( JOBVS, 'N' ) ) ) THEN
230: INFO = -1
231: ELSE IF( ( .NOT.WANTST ) .AND. ( .NOT.LSAME( SORT, 'N' ) ) ) THEN
232: INFO = -2
233: ELSE IF( .NOT.( WANTSN .OR. WANTSE .OR. WANTSV .OR. WANTSB ) .OR.
234: $ ( .NOT.WANTST .AND. .NOT.WANTSN ) ) THEN
235: INFO = -4
236: ELSE IF( N.LT.0 ) THEN
237: INFO = -5
238: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
239: INFO = -7
240: ELSE IF( LDVS.LT.1 .OR. ( WANTVS .AND. LDVS.LT.N ) ) THEN
241: INFO = -12
242: END IF
243: *
244: * Compute workspace
245: * (Note: Comments in the code beginning "RWorkspace:" describe the
246: * minimal amount of real workspace needed at that point in the
247: * code, as well as the preferred amount for good performance.
248: * IWorkspace refers to integer workspace.
249: * NB refers to the optimal block size for the immediately
250: * following subroutine, as returned by ILAENV.
251: * HSWORK refers to the workspace preferred by DHSEQR, as
252: * calculated below. HSWORK is computed assuming ILO=1 and IHI=N,
253: * the worst case.
254: * If SENSE = 'E', 'V' or 'B', then the amount of workspace needed
255: * depends on SDIM, which is computed by the routine DTRSEN later
256: * in the code.)
257: *
258: IF( INFO.EQ.0 ) THEN
259: LIWRK = 1
260: IF( N.EQ.0 ) THEN
261: MINWRK = 1
262: LWRK = 1
263: ELSE
264: MAXWRK = 2*N + N*ILAENV( 1, 'DGEHRD', ' ', N, 1, N, 0 )
265: MINWRK = 3*N
266: *
267: CALL DHSEQR( 'S', JOBVS, N, 1, N, A, LDA, WR, WI, VS, LDVS,
268: $ WORK, -1, IEVAL )
269: HSWORK = WORK( 1 )
270: *
271: IF( .NOT.WANTVS ) THEN
272: MAXWRK = MAX( MAXWRK, N + HSWORK )
273: ELSE
274: MAXWRK = MAX( MAXWRK, 2*N + ( N - 1 )*ILAENV( 1,
275: $ 'DORGHR', ' ', N, 1, N, -1 ) )
276: MAXWRK = MAX( MAXWRK, N + HSWORK )
277: END IF
278: LWRK = MAXWRK
279: IF( .NOT.WANTSN )
280: $ LWRK = MAX( LWRK, N + ( N*N )/2 )
281: IF( WANTSV .OR. WANTSB )
282: $ LIWRK = ( N*N )/4
283: END IF
284: IWORK( 1 ) = LIWRK
285: WORK( 1 ) = LWRK
286: *
287: IF( LWORK.LT.MINWRK .AND. .NOT.LQUERY ) THEN
288: INFO = -16
289: ELSE IF( LIWORK.LT.1 .AND. .NOT.LQUERY ) THEN
290: INFO = -18
291: END IF
292: END IF
293: *
294: IF( INFO.NE.0 ) THEN
295: CALL XERBLA( 'DGEESX', -INFO )
296: RETURN
297: END IF
298: *
299: * Quick return if possible
300: *
301: IF( N.EQ.0 ) THEN
302: SDIM = 0
303: RETURN
304: END IF
305: *
306: * Get machine constants
307: *
308: EPS = DLAMCH( 'P' )
309: SMLNUM = DLAMCH( 'S' )
310: BIGNUM = ONE / SMLNUM
311: CALL DLABAD( SMLNUM, BIGNUM )
312: SMLNUM = SQRT( SMLNUM ) / EPS
313: BIGNUM = ONE / SMLNUM
314: *
315: * Scale A if max element outside range [SMLNUM,BIGNUM]
316: *
317: ANRM = DLANGE( 'M', N, N, A, LDA, DUM )
318: SCALEA = .FALSE.
319: IF( ANRM.GT.ZERO .AND. ANRM.LT.SMLNUM ) THEN
320: SCALEA = .TRUE.
321: CSCALE = SMLNUM
322: ELSE IF( ANRM.GT.BIGNUM ) THEN
323: SCALEA = .TRUE.
324: CSCALE = BIGNUM
325: END IF
326: IF( SCALEA )
327: $ CALL DLASCL( 'G', 0, 0, ANRM, CSCALE, N, N, A, LDA, IERR )
328: *
329: * Permute the matrix to make it more nearly triangular
330: * (RWorkspace: need N)
331: *
332: IBAL = 1
333: CALL DGEBAL( 'P', N, A, LDA, ILO, IHI, WORK( IBAL ), IERR )
334: *
335: * Reduce to upper Hessenberg form
336: * (RWorkspace: need 3*N, prefer 2*N+N*NB)
337: *
338: ITAU = N + IBAL
339: IWRK = N + ITAU
340: CALL DGEHRD( N, ILO, IHI, A, LDA, WORK( ITAU ), WORK( IWRK ),
341: $ LWORK-IWRK+1, IERR )
342: *
343: IF( WANTVS ) THEN
344: *
345: * Copy Householder vectors to VS
346: *
347: CALL DLACPY( 'L', N, N, A, LDA, VS, LDVS )
348: *
349: * Generate orthogonal matrix in VS
350: * (RWorkspace: need 3*N-1, prefer 2*N+(N-1)*NB)
351: *
352: CALL DORGHR( N, ILO, IHI, VS, LDVS, WORK( ITAU ), WORK( IWRK ),
353: $ LWORK-IWRK+1, IERR )
354: END IF
355: *
356: SDIM = 0
357: *
358: * Perform QR iteration, accumulating Schur vectors in VS if desired
359: * (RWorkspace: need N+1, prefer N+HSWORK (see comments) )
360: *
361: IWRK = ITAU
362: CALL DHSEQR( 'S', JOBVS, N, ILO, IHI, A, LDA, WR, WI, VS, LDVS,
363: $ WORK( IWRK ), LWORK-IWRK+1, IEVAL )
364: IF( IEVAL.GT.0 )
365: $ INFO = IEVAL
366: *
367: * Sort eigenvalues if desired
368: *
369: IF( WANTST .AND. INFO.EQ.0 ) THEN
370: IF( SCALEA ) THEN
371: CALL DLASCL( 'G', 0, 0, CSCALE, ANRM, N, 1, WR, N, IERR )
372: CALL DLASCL( 'G', 0, 0, CSCALE, ANRM, N, 1, WI, N, IERR )
373: END IF
374: DO 10 I = 1, N
375: BWORK( I ) = SELECT( WR( I ), WI( I ) )
376: 10 CONTINUE
377: *
378: * Reorder eigenvalues, transform Schur vectors, and compute
379: * reciprocal condition numbers
380: * (RWorkspace: if SENSE is not 'N', need N+2*SDIM*(N-SDIM)
381: * otherwise, need N )
382: * (IWorkspace: if SENSE is 'V' or 'B', need SDIM*(N-SDIM)
383: * otherwise, need 0 )
384: *
385: CALL DTRSEN( SENSE, JOBVS, BWORK, N, A, LDA, VS, LDVS, WR, WI,
386: $ SDIM, RCONDE, RCONDV, WORK( IWRK ), LWORK-IWRK+1,
387: $ IWORK, LIWORK, ICOND )
388: IF( .NOT.WANTSN )
389: $ MAXWRK = MAX( MAXWRK, N+2*SDIM*( N-SDIM ) )
390: IF( ICOND.EQ.-15 ) THEN
391: *
392: * Not enough real workspace
393: *
394: INFO = -16
395: ELSE IF( ICOND.EQ.-17 ) THEN
396: *
397: * Not enough integer workspace
398: *
399: INFO = -18
400: ELSE IF( ICOND.GT.0 ) THEN
401: *
402: * DTRSEN failed to reorder or to restore standard Schur form
403: *
404: INFO = ICOND + N
405: END IF
406: END IF
407: *
408: IF( WANTVS ) THEN
409: *
410: * Undo balancing
411: * (RWorkspace: need N)
412: *
413: CALL DGEBAK( 'P', 'R', N, ILO, IHI, WORK( IBAL ), N, VS, LDVS,
414: $ IERR )
415: END IF
416: *
417: IF( SCALEA ) THEN
418: *
419: * Undo scaling for the Schur form of A
420: *
421: CALL DLASCL( 'H', 0, 0, CSCALE, ANRM, N, N, A, LDA, IERR )
422: CALL DCOPY( N, A, LDA+1, WR, 1 )
423: IF( ( WANTSV .OR. WANTSB ) .AND. INFO.EQ.0 ) THEN
424: DUM( 1 ) = RCONDV
425: CALL DLASCL( 'G', 0, 0, CSCALE, ANRM, 1, 1, DUM, 1, IERR )
426: RCONDV = DUM( 1 )
427: END IF
428: IF( CSCALE.EQ.SMLNUM ) THEN
429: *
430: * If scaling back towards underflow, adjust WI if an
431: * offdiagonal element of a 2-by-2 block in the Schur form
432: * underflows.
433: *
434: IF( IEVAL.GT.0 ) THEN
435: I1 = IEVAL + 1
436: I2 = IHI - 1
437: CALL DLASCL( 'G', 0, 0, CSCALE, ANRM, ILO-1, 1, WI, N,
438: $ IERR )
439: ELSE IF( WANTST ) THEN
440: I1 = 1
441: I2 = N - 1
442: ELSE
443: I1 = ILO
444: I2 = IHI - 1
445: END IF
446: INXT = I1 - 1
447: DO 20 I = I1, I2
448: IF( I.LT.INXT )
449: $ GO TO 20
450: IF( WI( I ).EQ.ZERO ) THEN
451: INXT = I + 1
452: ELSE
453: IF( A( I+1, I ).EQ.ZERO ) THEN
454: WI( I ) = ZERO
455: WI( I+1 ) = ZERO
456: ELSE IF( A( I+1, I ).NE.ZERO .AND. A( I, I+1 ).EQ.
457: $ ZERO ) THEN
458: WI( I ) = ZERO
459: WI( I+1 ) = ZERO
460: IF( I.GT.1 )
461: $ CALL DSWAP( I-1, A( 1, I ), 1, A( 1, I+1 ), 1 )
462: IF( N.GT.I+1 )
463: $ CALL DSWAP( N-I-1, A( I, I+2 ), LDA,
464: $ A( I+1, I+2 ), LDA )
465: CALL DSWAP( N, VS( 1, I ), 1, VS( 1, I+1 ), 1 )
466: A( I, I+1 ) = A( I+1, I )
467: A( I+1, I ) = ZERO
468: END IF
469: INXT = I + 2
470: END IF
471: 20 CONTINUE
472: END IF
473: CALL DLASCL( 'G', 0, 0, CSCALE, ANRM, N-IEVAL, 1,
474: $ WI( IEVAL+1 ), MAX( N-IEVAL, 1 ), IERR )
475: END IF
476: *
477: IF( WANTST .AND. INFO.EQ.0 ) THEN
478: *
479: * Check if reordering successful
480: *
481: LASTSL = .TRUE.
482: LST2SL = .TRUE.
483: SDIM = 0
484: IP = 0
485: DO 30 I = 1, N
486: CURSL = SELECT( WR( I ), WI( I ) )
487: IF( WI( I ).EQ.ZERO ) THEN
488: IF( CURSL )
489: $ SDIM = SDIM + 1
490: IP = 0
491: IF( CURSL .AND. .NOT.LASTSL )
492: $ INFO = N + 2
493: ELSE
494: IF( IP.EQ.1 ) THEN
495: *
496: * Last eigenvalue of conjugate pair
497: *
498: CURSL = CURSL .OR. LASTSL
499: LASTSL = CURSL
500: IF( CURSL )
501: $ SDIM = SDIM + 2
502: IP = -1
503: IF( CURSL .AND. .NOT.LST2SL )
504: $ INFO = N + 2
505: ELSE
506: *
507: * First eigenvalue of conjugate pair
508: *
509: IP = 1
510: END IF
511: END IF
512: LST2SL = LASTSL
513: LASTSL = CURSL
514: 30 CONTINUE
515: END IF
516: *
517: WORK( 1 ) = MAXWRK
518: IF( WANTSV .OR. WANTSB ) THEN
519: IWORK( 1 ) = MAX( 1, SDIM*( N-SDIM ) )
520: ELSE
521: IWORK( 1 ) = 1
522: END IF
523: *
524: RETURN
525: *
526: * End of DGEESX
527: *
528: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dgeesx.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack