1: *> \brief \b DGECON
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DGECON + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dgecon.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dgecon.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dgecon.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DGECON( NORM, N, A, LDA, ANORM, RCOND, WORK, IWORK,
22: * INFO )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER NORM
26: * INTEGER INFO, LDA, N
27: * DOUBLE PRECISION ANORM, RCOND
28: * ..
29: * .. Array Arguments ..
30: * INTEGER IWORK( * )
31: * DOUBLE PRECISION A( LDA, * ), WORK( * )
32: * ..
33: *
34: *
35: *> \par Purpose:
36: * =============
37: *>
38: *> \verbatim
39: *>
40: *> DGECON estimates the reciprocal of the condition number of a general
41: *> real matrix A, in either the 1-norm or the infinity-norm, using
42: *> the LU factorization computed by DGETRF.
43: *>
44: *> An estimate is obtained for norm(inv(A)), and the reciprocal of the
45: *> condition number is computed as
46: *> RCOND = 1 / ( norm(A) * norm(inv(A)) ).
47: *> \endverbatim
48: *
49: * Arguments:
50: * ==========
51: *
52: *> \param[in] NORM
53: *> \verbatim
54: *> NORM is CHARACTER*1
55: *> Specifies whether the 1-norm condition number or the
56: *> infinity-norm condition number is required:
57: *> = '1' or 'O': 1-norm;
58: *> = 'I': Infinity-norm.
59: *> \endverbatim
60: *>
61: *> \param[in] N
62: *> \verbatim
63: *> N is INTEGER
64: *> The order of the matrix A. N >= 0.
65: *> \endverbatim
66: *>
67: *> \param[in] A
68: *> \verbatim
69: *> A is DOUBLE PRECISION array, dimension (LDA,N)
70: *> The factors L and U from the factorization A = P*L*U
71: *> as computed by DGETRF.
72: *> \endverbatim
73: *>
74: *> \param[in] LDA
75: *> \verbatim
76: *> LDA is INTEGER
77: *> The leading dimension of the array A. LDA >= max(1,N).
78: *> \endverbatim
79: *>
80: *> \param[in] ANORM
81: *> \verbatim
82: *> ANORM is DOUBLE PRECISION
83: *> If NORM = '1' or 'O', the 1-norm of the original matrix A.
84: *> If NORM = 'I', the infinity-norm of the original matrix A.
85: *> \endverbatim
86: *>
87: *> \param[out] RCOND
88: *> \verbatim
89: *> RCOND is DOUBLE PRECISION
90: *> The reciprocal of the condition number of the matrix A,
91: *> computed as RCOND = 1/(norm(A) * norm(inv(A))).
92: *> \endverbatim
93: *>
94: *> \param[out] WORK
95: *> \verbatim
96: *> WORK is DOUBLE PRECISION array, dimension (4*N)
97: *> \endverbatim
98: *>
99: *> \param[out] IWORK
100: *> \verbatim
101: *> IWORK is INTEGER array, dimension (N)
102: *> \endverbatim
103: *>
104: *> \param[out] INFO
105: *> \verbatim
106: *> INFO is INTEGER
107: *> = 0: successful exit
108: *> < 0: if INFO = -i, the i-th argument had an illegal value
109: *> \endverbatim
110: *
111: * Authors:
112: * ========
113: *
114: *> \author Univ. of Tennessee
115: *> \author Univ. of California Berkeley
116: *> \author Univ. of Colorado Denver
117: *> \author NAG Ltd.
118: *
119: *> \ingroup doubleGEcomputational
120: *
121: * =====================================================================
122: SUBROUTINE DGECON( NORM, N, A, LDA, ANORM, RCOND, WORK, IWORK,
123: $ INFO )
124: *
125: * -- LAPACK computational routine --
126: * -- LAPACK is a software package provided by Univ. of Tennessee, --
127: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
128: *
129: * .. Scalar Arguments ..
130: CHARACTER NORM
131: INTEGER INFO, LDA, N
132: DOUBLE PRECISION ANORM, RCOND
133: * ..
134: * .. Array Arguments ..
135: INTEGER IWORK( * )
136: DOUBLE PRECISION A( LDA, * ), WORK( * )
137: * ..
138: *
139: * =====================================================================
140: *
141: * .. Parameters ..
142: DOUBLE PRECISION ONE, ZERO
143: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
144: * ..
145: * .. Local Scalars ..
146: LOGICAL ONENRM
147: CHARACTER NORMIN
148: INTEGER IX, KASE, KASE1
149: DOUBLE PRECISION AINVNM, SCALE, SL, SMLNUM, SU
150: * ..
151: * .. Local Arrays ..
152: INTEGER ISAVE( 3 )
153: * ..
154: * .. External Functions ..
155: LOGICAL LSAME
156: INTEGER IDAMAX
157: DOUBLE PRECISION DLAMCH
158: EXTERNAL LSAME, IDAMAX, DLAMCH
159: * ..
160: * .. External Subroutines ..
161: EXTERNAL DLACN2, DLATRS, DRSCL, XERBLA
162: * ..
163: * .. Intrinsic Functions ..
164: INTRINSIC ABS, MAX
165: * ..
166: * .. Executable Statements ..
167: *
168: * Test the input parameters.
169: *
170: INFO = 0
171: ONENRM = NORM.EQ.'1' .OR. LSAME( NORM, 'O' )
172: IF( .NOT.ONENRM .AND. .NOT.LSAME( NORM, 'I' ) ) THEN
173: INFO = -1
174: ELSE IF( N.LT.0 ) THEN
175: INFO = -2
176: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
177: INFO = -4
178: ELSE IF( ANORM.LT.ZERO ) THEN
179: INFO = -5
180: END IF
181: IF( INFO.NE.0 ) THEN
182: CALL XERBLA( 'DGECON', -INFO )
183: RETURN
184: END IF
185: *
186: * Quick return if possible
187: *
188: RCOND = ZERO
189: IF( N.EQ.0 ) THEN
190: RCOND = ONE
191: RETURN
192: ELSE IF( ANORM.EQ.ZERO ) THEN
193: RETURN
194: END IF
195: *
196: SMLNUM = DLAMCH( 'Safe minimum' )
197: *
198: * Estimate the norm of inv(A).
199: *
200: AINVNM = ZERO
201: NORMIN = 'N'
202: IF( ONENRM ) THEN
203: KASE1 = 1
204: ELSE
205: KASE1 = 2
206: END IF
207: KASE = 0
208: 10 CONTINUE
209: CALL DLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
210: IF( KASE.NE.0 ) THEN
211: IF( KASE.EQ.KASE1 ) THEN
212: *
213: * Multiply by inv(L).
214: *
215: CALL DLATRS( 'Lower', 'No transpose', 'Unit', NORMIN, N, A,
216: $ LDA, WORK, SL, WORK( 2*N+1 ), INFO )
217: *
218: * Multiply by inv(U).
219: *
220: CALL DLATRS( 'Upper', 'No transpose', 'Non-unit', NORMIN, N,
221: $ A, LDA, WORK, SU, WORK( 3*N+1 ), INFO )
222: ELSE
223: *
224: * Multiply by inv(U**T).
225: *
226: CALL DLATRS( 'Upper', 'Transpose', 'Non-unit', NORMIN, N, A,
227: $ LDA, WORK, SU, WORK( 3*N+1 ), INFO )
228: *
229: * Multiply by inv(L**T).
230: *
231: CALL DLATRS( 'Lower', 'Transpose', 'Unit', NORMIN, N, A,
232: $ LDA, WORK, SL, WORK( 2*N+1 ), INFO )
233: END IF
234: *
235: * Divide X by 1/(SL*SU) if doing so will not cause overflow.
236: *
237: SCALE = SL*SU
238: NORMIN = 'Y'
239: IF( SCALE.NE.ONE ) THEN
240: IX = IDAMAX( N, WORK, 1 )
241: IF( SCALE.LT.ABS( WORK( IX ) )*SMLNUM .OR. SCALE.EQ.ZERO )
242: $ GO TO 20
243: CALL DRSCL( N, SCALE, WORK, 1 )
244: END IF
245: GO TO 10
246: END IF
247: *
248: * Compute the estimate of the reciprocal condition number.
249: *
250: IF( AINVNM.NE.ZERO )
251: $ RCOND = ( ONE / AINVNM ) / ANORM
252: *
253: 20 CONTINUE
254: RETURN
255: *
256: * End of DGECON
257: *
258: END
CVSweb interface <joel.bertrand@systella.fr>