1: *> \brief \b DGEBD2 reduces a general matrix to bidiagonal form using an unblocked algorithm.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DGEBD2 + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dgebd2.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dgebd2.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dgebd2.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DGEBD2( M, N, A, LDA, D, E, TAUQ, TAUP, WORK, INFO )
22: *
23: * .. Scalar Arguments ..
24: * INTEGER INFO, LDA, M, N
25: * ..
26: * .. Array Arguments ..
27: * DOUBLE PRECISION A( LDA, * ), D( * ), E( * ), TAUP( * ),
28: * $ TAUQ( * ), WORK( * )
29: * ..
30: *
31: *
32: *> \par Purpose:
33: * =============
34: *>
35: *> \verbatim
36: *>
37: *> DGEBD2 reduces a real general m by n matrix A to upper or lower
38: *> bidiagonal form B by an orthogonal transformation: Q**T * A * P = B.
39: *>
40: *> If m >= n, B is upper bidiagonal; if m < n, B is lower bidiagonal.
41: *> \endverbatim
42: *
43: * Arguments:
44: * ==========
45: *
46: *> \param[in] M
47: *> \verbatim
48: *> M is INTEGER
49: *> The number of rows in the matrix A. M >= 0.
50: *> \endverbatim
51: *>
52: *> \param[in] N
53: *> \verbatim
54: *> N is INTEGER
55: *> The number of columns in the matrix A. N >= 0.
56: *> \endverbatim
57: *>
58: *> \param[in,out] A
59: *> \verbatim
60: *> A is DOUBLE PRECISION array, dimension (LDA,N)
61: *> On entry, the m by n general matrix to be reduced.
62: *> On exit,
63: *> if m >= n, the diagonal and the first superdiagonal are
64: *> overwritten with the upper bidiagonal matrix B; the
65: *> elements below the diagonal, with the array TAUQ, represent
66: *> the orthogonal matrix Q as a product of elementary
67: *> reflectors, and the elements above the first superdiagonal,
68: *> with the array TAUP, represent the orthogonal matrix P as
69: *> a product of elementary reflectors;
70: *> if m < n, the diagonal and the first subdiagonal are
71: *> overwritten with the lower bidiagonal matrix B; the
72: *> elements below the first subdiagonal, with the array TAUQ,
73: *> represent the orthogonal matrix Q as a product of
74: *> elementary reflectors, and the elements above the diagonal,
75: *> with the array TAUP, represent the orthogonal matrix P as
76: *> a product of elementary reflectors.
77: *> See Further Details.
78: *> \endverbatim
79: *>
80: *> \param[in] LDA
81: *> \verbatim
82: *> LDA is INTEGER
83: *> The leading dimension of the array A. LDA >= max(1,M).
84: *> \endverbatim
85: *>
86: *> \param[out] D
87: *> \verbatim
88: *> D is DOUBLE PRECISION array, dimension (min(M,N))
89: *> The diagonal elements of the bidiagonal matrix B:
90: *> D(i) = A(i,i).
91: *> \endverbatim
92: *>
93: *> \param[out] E
94: *> \verbatim
95: *> E is DOUBLE PRECISION array, dimension (min(M,N)-1)
96: *> The off-diagonal elements of the bidiagonal matrix B:
97: *> if m >= n, E(i) = A(i,i+1) for i = 1,2,...,n-1;
98: *> if m < n, E(i) = A(i+1,i) for i = 1,2,...,m-1.
99: *> \endverbatim
100: *>
101: *> \param[out] TAUQ
102: *> \verbatim
103: *> TAUQ is DOUBLE PRECISION array dimension (min(M,N))
104: *> The scalar factors of the elementary reflectors which
105: *> represent the orthogonal matrix Q. See Further Details.
106: *> \endverbatim
107: *>
108: *> \param[out] TAUP
109: *> \verbatim
110: *> TAUP is DOUBLE PRECISION array, dimension (min(M,N))
111: *> The scalar factors of the elementary reflectors which
112: *> represent the orthogonal matrix P. See Further Details.
113: *> \endverbatim
114: *>
115: *> \param[out] WORK
116: *> \verbatim
117: *> WORK is DOUBLE PRECISION array, dimension (max(M,N))
118: *> \endverbatim
119: *>
120: *> \param[out] INFO
121: *> \verbatim
122: *> INFO is INTEGER
123: *> = 0: successful exit.
124: *> < 0: if INFO = -i, the i-th argument had an illegal value.
125: *> \endverbatim
126: *
127: * Authors:
128: * ========
129: *
130: *> \author Univ. of Tennessee
131: *> \author Univ. of California Berkeley
132: *> \author Univ. of Colorado Denver
133: *> \author NAG Ltd.
134: *
135: *> \date September 2012
136: *
137: *> \ingroup doubleGEcomputational
138: *
139: *> \par Further Details:
140: * =====================
141: *>
142: *> \verbatim
143: *>
144: *> The matrices Q and P are represented as products of elementary
145: *> reflectors:
146: *>
147: *> If m >= n,
148: *>
149: *> Q = H(1) H(2) . . . H(n) and P = G(1) G(2) . . . G(n-1)
150: *>
151: *> Each H(i) and G(i) has the form:
152: *>
153: *> H(i) = I - tauq * v * v**T and G(i) = I - taup * u * u**T
154: *>
155: *> where tauq and taup are real scalars, and v and u are real vectors;
156: *> v(1:i-1) = 0, v(i) = 1, and v(i+1:m) is stored on exit in A(i+1:m,i);
157: *> u(1:i) = 0, u(i+1) = 1, and u(i+2:n) is stored on exit in A(i,i+2:n);
158: *> tauq is stored in TAUQ(i) and taup in TAUP(i).
159: *>
160: *> If m < n,
161: *>
162: *> Q = H(1) H(2) . . . H(m-1) and P = G(1) G(2) . . . G(m)
163: *>
164: *> Each H(i) and G(i) has the form:
165: *>
166: *> H(i) = I - tauq * v * v**T and G(i) = I - taup * u * u**T
167: *>
168: *> where tauq and taup are real scalars, and v and u are real vectors;
169: *> v(1:i) = 0, v(i+1) = 1, and v(i+2:m) is stored on exit in A(i+2:m,i);
170: *> u(1:i-1) = 0, u(i) = 1, and u(i+1:n) is stored on exit in A(i,i+1:n);
171: *> tauq is stored in TAUQ(i) and taup in TAUP(i).
172: *>
173: *> The contents of A on exit are illustrated by the following examples:
174: *>
175: *> m = 6 and n = 5 (m > n): m = 5 and n = 6 (m < n):
176: *>
177: *> ( d e u1 u1 u1 ) ( d u1 u1 u1 u1 u1 )
178: *> ( v1 d e u2 u2 ) ( e d u2 u2 u2 u2 )
179: *> ( v1 v2 d e u3 ) ( v1 e d u3 u3 u3 )
180: *> ( v1 v2 v3 d e ) ( v1 v2 e d u4 u4 )
181: *> ( v1 v2 v3 v4 d ) ( v1 v2 v3 e d u5 )
182: *> ( v1 v2 v3 v4 v5 )
183: *>
184: *> where d and e denote diagonal and off-diagonal elements of B, vi
185: *> denotes an element of the vector defining H(i), and ui an element of
186: *> the vector defining G(i).
187: *> \endverbatim
188: *>
189: * =====================================================================
190: SUBROUTINE DGEBD2( M, N, A, LDA, D, E, TAUQ, TAUP, WORK, INFO )
191: *
192: * -- LAPACK computational routine (version 3.4.2) --
193: * -- LAPACK is a software package provided by Univ. of Tennessee, --
194: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
195: * September 2012
196: *
197: * .. Scalar Arguments ..
198: INTEGER INFO, LDA, M, N
199: * ..
200: * .. Array Arguments ..
201: DOUBLE PRECISION A( LDA, * ), D( * ), E( * ), TAUP( * ),
202: $ TAUQ( * ), WORK( * )
203: * ..
204: *
205: * =====================================================================
206: *
207: * .. Parameters ..
208: DOUBLE PRECISION ZERO, ONE
209: PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
210: * ..
211: * .. Local Scalars ..
212: INTEGER I
213: * ..
214: * .. External Subroutines ..
215: EXTERNAL DLARF, DLARFG, XERBLA
216: * ..
217: * .. Intrinsic Functions ..
218: INTRINSIC MAX, MIN
219: * ..
220: * .. Executable Statements ..
221: *
222: * Test the input parameters
223: *
224: INFO = 0
225: IF( M.LT.0 ) THEN
226: INFO = -1
227: ELSE IF( N.LT.0 ) THEN
228: INFO = -2
229: ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
230: INFO = -4
231: END IF
232: IF( INFO.LT.0 ) THEN
233: CALL XERBLA( 'DGEBD2', -INFO )
234: RETURN
235: END IF
236: *
237: IF( M.GE.N ) THEN
238: *
239: * Reduce to upper bidiagonal form
240: *
241: DO 10 I = 1, N
242: *
243: * Generate elementary reflector H(i) to annihilate A(i+1:m,i)
244: *
245: CALL DLARFG( M-I+1, A( I, I ), A( MIN( I+1, M ), I ), 1,
246: $ TAUQ( I ) )
247: D( I ) = A( I, I )
248: A( I, I ) = ONE
249: *
250: * Apply H(i) to A(i:m,i+1:n) from the left
251: *
252: IF( I.LT.N )
253: $ CALL DLARF( 'Left', M-I+1, N-I, A( I, I ), 1, TAUQ( I ),
254: $ A( I, I+1 ), LDA, WORK )
255: A( I, I ) = D( I )
256: *
257: IF( I.LT.N ) THEN
258: *
259: * Generate elementary reflector G(i) to annihilate
260: * A(i,i+2:n)
261: *
262: CALL DLARFG( N-I, A( I, I+1 ), A( I, MIN( I+2, N ) ),
263: $ LDA, TAUP( I ) )
264: E( I ) = A( I, I+1 )
265: A( I, I+1 ) = ONE
266: *
267: * Apply G(i) to A(i+1:m,i+1:n) from the right
268: *
269: CALL DLARF( 'Right', M-I, N-I, A( I, I+1 ), LDA,
270: $ TAUP( I ), A( I+1, I+1 ), LDA, WORK )
271: A( I, I+1 ) = E( I )
272: ELSE
273: TAUP( I ) = ZERO
274: END IF
275: 10 CONTINUE
276: ELSE
277: *
278: * Reduce to lower bidiagonal form
279: *
280: DO 20 I = 1, M
281: *
282: * Generate elementary reflector G(i) to annihilate A(i,i+1:n)
283: *
284: CALL DLARFG( N-I+1, A( I, I ), A( I, MIN( I+1, N ) ), LDA,
285: $ TAUP( I ) )
286: D( I ) = A( I, I )
287: A( I, I ) = ONE
288: *
289: * Apply G(i) to A(i+1:m,i:n) from the right
290: *
291: IF( I.LT.M )
292: $ CALL DLARF( 'Right', M-I, N-I+1, A( I, I ), LDA,
293: $ TAUP( I ), A( I+1, I ), LDA, WORK )
294: A( I, I ) = D( I )
295: *
296: IF( I.LT.M ) THEN
297: *
298: * Generate elementary reflector H(i) to annihilate
299: * A(i+2:m,i)
300: *
301: CALL DLARFG( M-I, A( I+1, I ), A( MIN( I+2, M ), I ), 1,
302: $ TAUQ( I ) )
303: E( I ) = A( I+1, I )
304: A( I+1, I ) = ONE
305: *
306: * Apply H(i) to A(i+1:m,i+1:n) from the left
307: *
308: CALL DLARF( 'Left', M-I, N-I, A( I+1, I ), 1, TAUQ( I ),
309: $ A( I+1, I+1 ), LDA, WORK )
310: A( I+1, I ) = E( I )
311: ELSE
312: TAUQ( I ) = ZERO
313: END IF
314: 20 CONTINUE
315: END IF
316: RETURN
317: *
318: * End of DGEBD2
319: *
320: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dgebd2.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack