Annotation of rpl/lapack/lapack/dgebal.f, revision 1.14
1.9 bertrand 1: *> \brief \b DGEBAL
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DGEBAL + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dgebal.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dgebal.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dgebal.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DGEBAL( JOB, N, A, LDA, ILO, IHI, SCALE, INFO )
22: *
23: * .. Scalar Arguments ..
24: * CHARACTER JOB
25: * INTEGER IHI, ILO, INFO, LDA, N
26: * ..
27: * .. Array Arguments ..
28: * DOUBLE PRECISION A( LDA, * ), SCALE( * )
29: * ..
30: *
31: *
32: *> \par Purpose:
33: * =============
34: *>
35: *> \verbatim
36: *>
37: *> DGEBAL balances a general real matrix A. This involves, first,
38: *> permuting A by a similarity transformation to isolate eigenvalues
39: *> in the first 1 to ILO-1 and last IHI+1 to N elements on the
40: *> diagonal; and second, applying a diagonal similarity transformation
41: *> to rows and columns ILO to IHI to make the rows and columns as
42: *> close in norm as possible. Both steps are optional.
43: *>
44: *> Balancing may reduce the 1-norm of the matrix, and improve the
45: *> accuracy of the computed eigenvalues and/or eigenvectors.
46: *> \endverbatim
47: *
48: * Arguments:
49: * ==========
50: *
51: *> \param[in] JOB
52: *> \verbatim
53: *> JOB is CHARACTER*1
54: *> Specifies the operations to be performed on A:
55: *> = 'N': none: simply set ILO = 1, IHI = N, SCALE(I) = 1.0
56: *> for i = 1,...,N;
57: *> = 'P': permute only;
58: *> = 'S': scale only;
59: *> = 'B': both permute and scale.
60: *> \endverbatim
61: *>
62: *> \param[in] N
63: *> \verbatim
64: *> N is INTEGER
65: *> The order of the matrix A. N >= 0.
66: *> \endverbatim
67: *>
68: *> \param[in,out] A
69: *> \verbatim
70: *> A is DOUBLE array, dimension (LDA,N)
71: *> On entry, the input matrix A.
72: *> On exit, A is overwritten by the balanced matrix.
73: *> If JOB = 'N', A is not referenced.
74: *> See Further Details.
75: *> \endverbatim
76: *>
77: *> \param[in] LDA
78: *> \verbatim
79: *> LDA is INTEGER
80: *> The leading dimension of the array A. LDA >= max(1,N).
81: *> \endverbatim
82: *>
83: *> \param[out] ILO
84: *> \verbatim
85: *> ILO is INTEGER
86: *> \endverbatim
87: *> \param[out] IHI
88: *> \verbatim
89: *> IHI is INTEGER
90: *> ILO and IHI are set to integers such that on exit
91: *> A(i,j) = 0 if i > j and j = 1,...,ILO-1 or I = IHI+1,...,N.
92: *> If JOB = 'N' or 'S', ILO = 1 and IHI = N.
93: *> \endverbatim
94: *>
95: *> \param[out] SCALE
96: *> \verbatim
97: *> SCALE is DOUBLE array, dimension (N)
98: *> Details of the permutations and scaling factors applied to
99: *> A. If P(j) is the index of the row and column interchanged
100: *> with row and column j and D(j) is the scaling factor
101: *> applied to row and column j, then
102: *> SCALE(j) = P(j) for j = 1,...,ILO-1
103: *> = D(j) for j = ILO,...,IHI
104: *> = P(j) for j = IHI+1,...,N.
105: *> The order in which the interchanges are made is N to IHI+1,
106: *> then 1 to ILO-1.
107: *> \endverbatim
108: *>
109: *> \param[out] INFO
110: *> \verbatim
111: *> INFO is INTEGER
112: *> = 0: successful exit.
113: *> < 0: if INFO = -i, the i-th argument had an illegal value.
114: *> \endverbatim
115: *
116: * Authors:
117: * ========
118: *
119: *> \author Univ. of Tennessee
120: *> \author Univ. of California Berkeley
121: *> \author Univ. of Colorado Denver
122: *> \author NAG Ltd.
123: *
1.13 bertrand 124: *> \date November 2013
1.9 bertrand 125: *
126: *> \ingroup doubleGEcomputational
127: *
128: *> \par Further Details:
129: * =====================
130: *>
131: *> \verbatim
132: *>
133: *> The permutations consist of row and column interchanges which put
134: *> the matrix in the form
135: *>
136: *> ( T1 X Y )
137: *> P A P = ( 0 B Z )
138: *> ( 0 0 T2 )
139: *>
140: *> where T1 and T2 are upper triangular matrices whose eigenvalues lie
141: *> along the diagonal. The column indices ILO and IHI mark the starting
142: *> and ending columns of the submatrix B. Balancing consists of applying
143: *> a diagonal similarity transformation inv(D) * B * D to make the
144: *> 1-norms of each row of B and its corresponding column nearly equal.
145: *> The output matrix is
146: *>
147: *> ( T1 X*D Y )
148: *> ( 0 inv(D)*B*D inv(D)*Z ).
149: *> ( 0 0 T2 )
150: *>
151: *> Information about the permutations P and the diagonal matrix D is
152: *> returned in the vector SCALE.
153: *>
154: *> This subroutine is based on the EISPACK routine BALANC.
155: *>
156: *> Modified by Tzu-Yi Chen, Computer Science Division, University of
157: *> California at Berkeley, USA
158: *> \endverbatim
159: *>
160: * =====================================================================
1.1 bertrand 161: SUBROUTINE DGEBAL( JOB, N, A, LDA, ILO, IHI, SCALE, INFO )
162: *
1.13 bertrand 163: * -- LAPACK computational routine (version 3.5.0) --
1.1 bertrand 164: * -- LAPACK is a software package provided by Univ. of Tennessee, --
165: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
1.13 bertrand 166: * November 2013
1.1 bertrand 167: *
168: * .. Scalar Arguments ..
169: CHARACTER JOB
170: INTEGER IHI, ILO, INFO, LDA, N
171: * ..
172: * .. Array Arguments ..
173: DOUBLE PRECISION A( LDA, * ), SCALE( * )
174: * ..
175: *
176: * =====================================================================
177: *
178: * .. Parameters ..
179: DOUBLE PRECISION ZERO, ONE
180: PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
181: DOUBLE PRECISION SCLFAC
182: PARAMETER ( SCLFAC = 2.0D+0 )
183: DOUBLE PRECISION FACTOR
184: PARAMETER ( FACTOR = 0.95D+0 )
185: * ..
186: * .. Local Scalars ..
187: LOGICAL NOCONV
188: INTEGER I, ICA, IEXC, IRA, J, K, L, M
189: DOUBLE PRECISION C, CA, F, G, R, RA, S, SFMAX1, SFMAX2, SFMIN1,
190: $ SFMIN2
191: * ..
192: * .. External Functions ..
1.5 bertrand 193: LOGICAL DISNAN, LSAME
1.1 bertrand 194: INTEGER IDAMAX
1.13 bertrand 195: DOUBLE PRECISION DLAMCH, DNRM2
196: EXTERNAL DISNAN, LSAME, IDAMAX, DLAMCH, DNRM2
1.1 bertrand 197: * ..
198: * .. External Subroutines ..
199: EXTERNAL DSCAL, DSWAP, XERBLA
200: * ..
201: * .. Intrinsic Functions ..
202: INTRINSIC ABS, MAX, MIN
203: * ..
204: * .. Executable Statements ..
205: *
206: * Test the input parameters
207: *
208: INFO = 0
209: IF( .NOT.LSAME( JOB, 'N' ) .AND. .NOT.LSAME( JOB, 'P' ) .AND.
210: $ .NOT.LSAME( JOB, 'S' ) .AND. .NOT.LSAME( JOB, 'B' ) ) THEN
211: INFO = -1
212: ELSE IF( N.LT.0 ) THEN
213: INFO = -2
214: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
215: INFO = -4
216: END IF
217: IF( INFO.NE.0 ) THEN
218: CALL XERBLA( 'DGEBAL', -INFO )
219: RETURN
220: END IF
221: *
222: K = 1
223: L = N
224: *
225: IF( N.EQ.0 )
226: $ GO TO 210
227: *
228: IF( LSAME( JOB, 'N' ) ) THEN
229: DO 10 I = 1, N
230: SCALE( I ) = ONE
231: 10 CONTINUE
232: GO TO 210
233: END IF
234: *
235: IF( LSAME( JOB, 'S' ) )
236: $ GO TO 120
237: *
238: * Permutation to isolate eigenvalues if possible
239: *
240: GO TO 50
241: *
242: * Row and column exchange.
243: *
244: 20 CONTINUE
245: SCALE( M ) = J
246: IF( J.EQ.M )
247: $ GO TO 30
248: *
249: CALL DSWAP( L, A( 1, J ), 1, A( 1, M ), 1 )
250: CALL DSWAP( N-K+1, A( J, K ), LDA, A( M, K ), LDA )
251: *
252: 30 CONTINUE
253: GO TO ( 40, 80 )IEXC
254: *
255: * Search for rows isolating an eigenvalue and push them down.
256: *
257: 40 CONTINUE
258: IF( L.EQ.1 )
259: $ GO TO 210
260: L = L - 1
261: *
262: 50 CONTINUE
263: DO 70 J = L, 1, -1
264: *
265: DO 60 I = 1, L
266: IF( I.EQ.J )
267: $ GO TO 60
268: IF( A( J, I ).NE.ZERO )
269: $ GO TO 70
270: 60 CONTINUE
271: *
272: M = L
273: IEXC = 1
274: GO TO 20
275: 70 CONTINUE
276: *
277: GO TO 90
278: *
279: * Search for columns isolating an eigenvalue and push them left.
280: *
281: 80 CONTINUE
282: K = K + 1
283: *
284: 90 CONTINUE
285: DO 110 J = K, L
286: *
287: DO 100 I = K, L
288: IF( I.EQ.J )
289: $ GO TO 100
290: IF( A( I, J ).NE.ZERO )
291: $ GO TO 110
292: 100 CONTINUE
293: *
294: M = K
295: IEXC = 2
296: GO TO 20
297: 110 CONTINUE
298: *
299: 120 CONTINUE
300: DO 130 I = K, L
301: SCALE( I ) = ONE
302: 130 CONTINUE
303: *
304: IF( LSAME( JOB, 'P' ) )
305: $ GO TO 210
306: *
307: * Balance the submatrix in rows K to L.
308: *
309: * Iterative loop for norm reduction
310: *
311: SFMIN1 = DLAMCH( 'S' ) / DLAMCH( 'P' )
312: SFMAX1 = ONE / SFMIN1
313: SFMIN2 = SFMIN1*SCLFAC
314: SFMAX2 = ONE / SFMIN2
1.13 bertrand 315: *
1.1 bertrand 316: 140 CONTINUE
317: NOCONV = .FALSE.
318: *
319: DO 200 I = K, L
320: *
1.13 bertrand 321: C = DNRM2( L-K+1, A( K, I ), 1 )
322: R = DNRM2( L-K+1, A( I, K ), LDA )
1.1 bertrand 323: ICA = IDAMAX( L, A( 1, I ), 1 )
324: CA = ABS( A( ICA, I ) )
325: IRA = IDAMAX( N-K+1, A( I, K ), LDA )
326: RA = ABS( A( I, IRA+K-1 ) )
327: *
328: * Guard against zero C or R due to underflow.
329: *
330: IF( C.EQ.ZERO .OR. R.EQ.ZERO )
331: $ GO TO 200
332: G = R / SCLFAC
333: F = ONE
334: S = C + R
335: 160 CONTINUE
336: IF( C.GE.G .OR. MAX( F, C, CA ).GE.SFMAX2 .OR.
337: $ MIN( R, G, RA ).LE.SFMIN2 )GO TO 170
1.5 bertrand 338: IF( DISNAN( C+F+CA+R+G+RA ) ) THEN
339: *
340: * Exit if NaN to avoid infinite loop
341: *
342: INFO = -3
343: CALL XERBLA( 'DGEBAL', -INFO )
344: RETURN
345: END IF
1.1 bertrand 346: F = F*SCLFAC
347: C = C*SCLFAC
348: CA = CA*SCLFAC
349: R = R / SCLFAC
350: G = G / SCLFAC
351: RA = RA / SCLFAC
352: GO TO 160
353: *
354: 170 CONTINUE
355: G = C / SCLFAC
356: 180 CONTINUE
357: IF( G.LT.R .OR. MAX( R, RA ).GE.SFMAX2 .OR.
358: $ MIN( F, C, G, CA ).LE.SFMIN2 )GO TO 190
359: F = F / SCLFAC
360: C = C / SCLFAC
361: G = G / SCLFAC
362: CA = CA / SCLFAC
363: R = R*SCLFAC
364: RA = RA*SCLFAC
365: GO TO 180
366: *
367: * Now balance.
368: *
369: 190 CONTINUE
370: IF( ( C+R ).GE.FACTOR*S )
371: $ GO TO 200
372: IF( F.LT.ONE .AND. SCALE( I ).LT.ONE ) THEN
373: IF( F*SCALE( I ).LE.SFMIN1 )
374: $ GO TO 200
375: END IF
376: IF( F.GT.ONE .AND. SCALE( I ).GT.ONE ) THEN
377: IF( SCALE( I ).GE.SFMAX1 / F )
378: $ GO TO 200
379: END IF
380: G = ONE / F
381: SCALE( I ) = SCALE( I )*F
382: NOCONV = .TRUE.
383: *
384: CALL DSCAL( N-K+1, G, A( I, K ), LDA )
385: CALL DSCAL( L, F, A( 1, I ), 1 )
386: *
387: 200 CONTINUE
388: *
389: IF( NOCONV )
390: $ GO TO 140
391: *
392: 210 CONTINUE
393: ILO = K
394: IHI = L
395: *
396: RETURN
397: *
398: * End of DGEBAL
399: *
400: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dgebal.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack