Annotation of rpl/lapack/lapack/dgbrfs.f, revision 1.8
1.8 ! bertrand 1: *> \brief \b DGBRFS
! 2: *
! 3: * =========== DOCUMENTATION ===========
! 4: *
! 5: * Online html documentation available at
! 6: * http://www.netlib.org/lapack/explore-html/
! 7: *
! 8: *> \htmlonly
! 9: *> Download DGBRFS + dependencies
! 10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dgbrfs.f">
! 11: *> [TGZ]</a>
! 12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dgbrfs.f">
! 13: *> [ZIP]</a>
! 14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dgbrfs.f">
! 15: *> [TXT]</a>
! 16: *> \endhtmlonly
! 17: *
! 18: * Definition:
! 19: * ===========
! 20: *
! 21: * SUBROUTINE DGBRFS( TRANS, N, KL, KU, NRHS, AB, LDAB, AFB, LDAFB,
! 22: * IPIV, B, LDB, X, LDX, FERR, BERR, WORK, IWORK,
! 23: * INFO )
! 24: *
! 25: * .. Scalar Arguments ..
! 26: * CHARACTER TRANS
! 27: * INTEGER INFO, KL, KU, LDAB, LDAFB, LDB, LDX, N, NRHS
! 28: * ..
! 29: * .. Array Arguments ..
! 30: * INTEGER IPIV( * ), IWORK( * )
! 31: * DOUBLE PRECISION AB( LDAB, * ), AFB( LDAFB, * ), B( LDB, * ),
! 32: * $ BERR( * ), FERR( * ), WORK( * ), X( LDX, * )
! 33: * ..
! 34: *
! 35: *
! 36: *> \par Purpose:
! 37: * =============
! 38: *>
! 39: *> \verbatim
! 40: *>
! 41: *> DGBRFS improves the computed solution to a system of linear
! 42: *> equations when the coefficient matrix is banded, and provides
! 43: *> error bounds and backward error estimates for the solution.
! 44: *> \endverbatim
! 45: *
! 46: * Arguments:
! 47: * ==========
! 48: *
! 49: *> \param[in] TRANS
! 50: *> \verbatim
! 51: *> TRANS is CHARACTER*1
! 52: *> Specifies the form of the system of equations:
! 53: *> = 'N': A * X = B (No transpose)
! 54: *> = 'T': A**T * X = B (Transpose)
! 55: *> = 'C': A**H * X = B (Conjugate transpose = Transpose)
! 56: *> \endverbatim
! 57: *>
! 58: *> \param[in] N
! 59: *> \verbatim
! 60: *> N is INTEGER
! 61: *> The order of the matrix A. N >= 0.
! 62: *> \endverbatim
! 63: *>
! 64: *> \param[in] KL
! 65: *> \verbatim
! 66: *> KL is INTEGER
! 67: *> The number of subdiagonals within the band of A. KL >= 0.
! 68: *> \endverbatim
! 69: *>
! 70: *> \param[in] KU
! 71: *> \verbatim
! 72: *> KU is INTEGER
! 73: *> The number of superdiagonals within the band of A. KU >= 0.
! 74: *> \endverbatim
! 75: *>
! 76: *> \param[in] NRHS
! 77: *> \verbatim
! 78: *> NRHS is INTEGER
! 79: *> The number of right hand sides, i.e., the number of columns
! 80: *> of the matrices B and X. NRHS >= 0.
! 81: *> \endverbatim
! 82: *>
! 83: *> \param[in] AB
! 84: *> \verbatim
! 85: *> AB is DOUBLE PRECISION array, dimension (LDAB,N)
! 86: *> The original band matrix A, stored in rows 1 to KL+KU+1.
! 87: *> The j-th column of A is stored in the j-th column of the
! 88: *> array AB as follows:
! 89: *> AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(n,j+kl).
! 90: *> \endverbatim
! 91: *>
! 92: *> \param[in] LDAB
! 93: *> \verbatim
! 94: *> LDAB is INTEGER
! 95: *> The leading dimension of the array AB. LDAB >= KL+KU+1.
! 96: *> \endverbatim
! 97: *>
! 98: *> \param[in] AFB
! 99: *> \verbatim
! 100: *> AFB is DOUBLE PRECISION array, dimension (LDAFB,N)
! 101: *> Details of the LU factorization of the band matrix A, as
! 102: *> computed by DGBTRF. U is stored as an upper triangular band
! 103: *> matrix with KL+KU superdiagonals in rows 1 to KL+KU+1, and
! 104: *> the multipliers used during the factorization are stored in
! 105: *> rows KL+KU+2 to 2*KL+KU+1.
! 106: *> \endverbatim
! 107: *>
! 108: *> \param[in] LDAFB
! 109: *> \verbatim
! 110: *> LDAFB is INTEGER
! 111: *> The leading dimension of the array AFB. LDAFB >= 2*KL*KU+1.
! 112: *> \endverbatim
! 113: *>
! 114: *> \param[in] IPIV
! 115: *> \verbatim
! 116: *> IPIV is INTEGER array, dimension (N)
! 117: *> The pivot indices from DGBTRF; for 1<=i<=N, row i of the
! 118: *> matrix was interchanged with row IPIV(i).
! 119: *> \endverbatim
! 120: *>
! 121: *> \param[in] B
! 122: *> \verbatim
! 123: *> B is DOUBLE PRECISION array, dimension (LDB,NRHS)
! 124: *> The right hand side matrix B.
! 125: *> \endverbatim
! 126: *>
! 127: *> \param[in] LDB
! 128: *> \verbatim
! 129: *> LDB is INTEGER
! 130: *> The leading dimension of the array B. LDB >= max(1,N).
! 131: *> \endverbatim
! 132: *>
! 133: *> \param[in,out] X
! 134: *> \verbatim
! 135: *> X is DOUBLE PRECISION array, dimension (LDX,NRHS)
! 136: *> On entry, the solution matrix X, as computed by DGBTRS.
! 137: *> On exit, the improved solution matrix X.
! 138: *> \endverbatim
! 139: *>
! 140: *> \param[in] LDX
! 141: *> \verbatim
! 142: *> LDX is INTEGER
! 143: *> The leading dimension of the array X. LDX >= max(1,N).
! 144: *> \endverbatim
! 145: *>
! 146: *> \param[out] FERR
! 147: *> \verbatim
! 148: *> FERR is DOUBLE PRECISION array, dimension (NRHS)
! 149: *> The estimated forward error bound for each solution vector
! 150: *> X(j) (the j-th column of the solution matrix X).
! 151: *> If XTRUE is the true solution corresponding to X(j), FERR(j)
! 152: *> is an estimated upper bound for the magnitude of the largest
! 153: *> element in (X(j) - XTRUE) divided by the magnitude of the
! 154: *> largest element in X(j). The estimate is as reliable as
! 155: *> the estimate for RCOND, and is almost always a slight
! 156: *> overestimate of the true error.
! 157: *> \endverbatim
! 158: *>
! 159: *> \param[out] BERR
! 160: *> \verbatim
! 161: *> BERR is DOUBLE PRECISION array, dimension (NRHS)
! 162: *> The componentwise relative backward error of each solution
! 163: *> vector X(j) (i.e., the smallest relative change in
! 164: *> any element of A or B that makes X(j) an exact solution).
! 165: *> \endverbatim
! 166: *>
! 167: *> \param[out] WORK
! 168: *> \verbatim
! 169: *> WORK is DOUBLE PRECISION array, dimension (3*N)
! 170: *> \endverbatim
! 171: *>
! 172: *> \param[out] IWORK
! 173: *> \verbatim
! 174: *> IWORK is INTEGER array, dimension (N)
! 175: *> \endverbatim
! 176: *>
! 177: *> \param[out] INFO
! 178: *> \verbatim
! 179: *> INFO is INTEGER
! 180: *> = 0: successful exit
! 181: *> < 0: if INFO = -i, the i-th argument had an illegal value
! 182: *> \endverbatim
! 183: *
! 184: *> \par Internal Parameters:
! 185: * =========================
! 186: *>
! 187: *> \verbatim
! 188: *> ITMAX is the maximum number of steps of iterative refinement.
! 189: *> \endverbatim
! 190: *
! 191: * Authors:
! 192: * ========
! 193: *
! 194: *> \author Univ. of Tennessee
! 195: *> \author Univ. of California Berkeley
! 196: *> \author Univ. of Colorado Denver
! 197: *> \author NAG Ltd.
! 198: *
! 199: *> \date November 2011
! 200: *
! 201: *> \ingroup doubleGBcomputational
! 202: *
! 203: * =====================================================================
1.1 bertrand 204: SUBROUTINE DGBRFS( TRANS, N, KL, KU, NRHS, AB, LDAB, AFB, LDAFB,
205: $ IPIV, B, LDB, X, LDX, FERR, BERR, WORK, IWORK,
206: $ INFO )
207: *
1.8 ! bertrand 208: * -- LAPACK computational routine (version 3.4.0) --
1.1 bertrand 209: * -- LAPACK is a software package provided by Univ. of Tennessee, --
210: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
1.8 ! bertrand 211: * November 2011
1.1 bertrand 212: *
213: * .. Scalar Arguments ..
214: CHARACTER TRANS
215: INTEGER INFO, KL, KU, LDAB, LDAFB, LDB, LDX, N, NRHS
216: * ..
217: * .. Array Arguments ..
218: INTEGER IPIV( * ), IWORK( * )
219: DOUBLE PRECISION AB( LDAB, * ), AFB( LDAFB, * ), B( LDB, * ),
220: $ BERR( * ), FERR( * ), WORK( * ), X( LDX, * )
221: * ..
222: *
223: * =====================================================================
224: *
225: * .. Parameters ..
226: INTEGER ITMAX
227: PARAMETER ( ITMAX = 5 )
228: DOUBLE PRECISION ZERO
229: PARAMETER ( ZERO = 0.0D+0 )
230: DOUBLE PRECISION ONE
231: PARAMETER ( ONE = 1.0D+0 )
232: DOUBLE PRECISION TWO
233: PARAMETER ( TWO = 2.0D+0 )
234: DOUBLE PRECISION THREE
235: PARAMETER ( THREE = 3.0D+0 )
236: * ..
237: * .. Local Scalars ..
238: LOGICAL NOTRAN
239: CHARACTER TRANST
240: INTEGER COUNT, I, J, K, KASE, KK, NZ
241: DOUBLE PRECISION EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN, XK
242: * ..
243: * .. Local Arrays ..
244: INTEGER ISAVE( 3 )
245: * ..
246: * .. External Subroutines ..
247: EXTERNAL DAXPY, DCOPY, DGBMV, DGBTRS, DLACN2, XERBLA
248: * ..
249: * .. Intrinsic Functions ..
250: INTRINSIC ABS, MAX, MIN
251: * ..
252: * .. External Functions ..
253: LOGICAL LSAME
254: DOUBLE PRECISION DLAMCH
255: EXTERNAL LSAME, DLAMCH
256: * ..
257: * .. Executable Statements ..
258: *
259: * Test the input parameters.
260: *
261: INFO = 0
262: NOTRAN = LSAME( TRANS, 'N' )
263: IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) .AND. .NOT.
264: $ LSAME( TRANS, 'C' ) ) THEN
265: INFO = -1
266: ELSE IF( N.LT.0 ) THEN
267: INFO = -2
268: ELSE IF( KL.LT.0 ) THEN
269: INFO = -3
270: ELSE IF( KU.LT.0 ) THEN
271: INFO = -4
272: ELSE IF( NRHS.LT.0 ) THEN
273: INFO = -5
274: ELSE IF( LDAB.LT.KL+KU+1 ) THEN
275: INFO = -7
276: ELSE IF( LDAFB.LT.2*KL+KU+1 ) THEN
277: INFO = -9
278: ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
279: INFO = -12
280: ELSE IF( LDX.LT.MAX( 1, N ) ) THEN
281: INFO = -14
282: END IF
283: IF( INFO.NE.0 ) THEN
284: CALL XERBLA( 'DGBRFS', -INFO )
285: RETURN
286: END IF
287: *
288: * Quick return if possible
289: *
290: IF( N.EQ.0 .OR. NRHS.EQ.0 ) THEN
291: DO 10 J = 1, NRHS
292: FERR( J ) = ZERO
293: BERR( J ) = ZERO
294: 10 CONTINUE
295: RETURN
296: END IF
297: *
298: IF( NOTRAN ) THEN
299: TRANST = 'T'
300: ELSE
301: TRANST = 'N'
302: END IF
303: *
304: * NZ = maximum number of nonzero elements in each row of A, plus 1
305: *
306: NZ = MIN( KL+KU+2, N+1 )
307: EPS = DLAMCH( 'Epsilon' )
308: SAFMIN = DLAMCH( 'Safe minimum' )
309: SAFE1 = NZ*SAFMIN
310: SAFE2 = SAFE1 / EPS
311: *
312: * Do for each right hand side
313: *
314: DO 140 J = 1, NRHS
315: *
316: COUNT = 1
317: LSTRES = THREE
318: 20 CONTINUE
319: *
320: * Loop until stopping criterion is satisfied.
321: *
322: * Compute residual R = B - op(A) * X,
323: * where op(A) = A, A**T, or A**H, depending on TRANS.
324: *
325: CALL DCOPY( N, B( 1, J ), 1, WORK( N+1 ), 1 )
326: CALL DGBMV( TRANS, N, N, KL, KU, -ONE, AB, LDAB, X( 1, J ), 1,
327: $ ONE, WORK( N+1 ), 1 )
328: *
329: * Compute componentwise relative backward error from formula
330: *
331: * max(i) ( abs(R(i)) / ( abs(op(A))*abs(X) + abs(B) )(i) )
332: *
333: * where abs(Z) is the componentwise absolute value of the matrix
334: * or vector Z. If the i-th component of the denominator is less
335: * than SAFE2, then SAFE1 is added to the i-th components of the
336: * numerator and denominator before dividing.
337: *
338: DO 30 I = 1, N
339: WORK( I ) = ABS( B( I, J ) )
340: 30 CONTINUE
341: *
342: * Compute abs(op(A))*abs(X) + abs(B).
343: *
344: IF( NOTRAN ) THEN
345: DO 50 K = 1, N
346: KK = KU + 1 - K
347: XK = ABS( X( K, J ) )
348: DO 40 I = MAX( 1, K-KU ), MIN( N, K+KL )
349: WORK( I ) = WORK( I ) + ABS( AB( KK+I, K ) )*XK
350: 40 CONTINUE
351: 50 CONTINUE
352: ELSE
353: DO 70 K = 1, N
354: S = ZERO
355: KK = KU + 1 - K
356: DO 60 I = MAX( 1, K-KU ), MIN( N, K+KL )
357: S = S + ABS( AB( KK+I, K ) )*ABS( X( I, J ) )
358: 60 CONTINUE
359: WORK( K ) = WORK( K ) + S
360: 70 CONTINUE
361: END IF
362: S = ZERO
363: DO 80 I = 1, N
364: IF( WORK( I ).GT.SAFE2 ) THEN
365: S = MAX( S, ABS( WORK( N+I ) ) / WORK( I ) )
366: ELSE
367: S = MAX( S, ( ABS( WORK( N+I ) )+SAFE1 ) /
368: $ ( WORK( I )+SAFE1 ) )
369: END IF
370: 80 CONTINUE
371: BERR( J ) = S
372: *
373: * Test stopping criterion. Continue iterating if
374: * 1) The residual BERR(J) is larger than machine epsilon, and
375: * 2) BERR(J) decreased by at least a factor of 2 during the
376: * last iteration, and
377: * 3) At most ITMAX iterations tried.
378: *
379: IF( BERR( J ).GT.EPS .AND. TWO*BERR( J ).LE.LSTRES .AND.
380: $ COUNT.LE.ITMAX ) THEN
381: *
382: * Update solution and try again.
383: *
384: CALL DGBTRS( TRANS, N, KL, KU, 1, AFB, LDAFB, IPIV,
385: $ WORK( N+1 ), N, INFO )
386: CALL DAXPY( N, ONE, WORK( N+1 ), 1, X( 1, J ), 1 )
387: LSTRES = BERR( J )
388: COUNT = COUNT + 1
389: GO TO 20
390: END IF
391: *
392: * Bound error from formula
393: *
394: * norm(X - XTRUE) / norm(X) .le. FERR =
395: * norm( abs(inv(op(A)))*
396: * ( abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) ))) / norm(X)
397: *
398: * where
399: * norm(Z) is the magnitude of the largest component of Z
400: * inv(op(A)) is the inverse of op(A)
401: * abs(Z) is the componentwise absolute value of the matrix or
402: * vector Z
403: * NZ is the maximum number of nonzeros in any row of A, plus 1
404: * EPS is machine epsilon
405: *
406: * The i-th component of abs(R)+NZ*EPS*(abs(op(A))*abs(X)+abs(B))
407: * is incremented by SAFE1 if the i-th component of
408: * abs(op(A))*abs(X) + abs(B) is less than SAFE2.
409: *
410: * Use DLACN2 to estimate the infinity-norm of the matrix
411: * inv(op(A)) * diag(W),
412: * where W = abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) )))
413: *
414: DO 90 I = 1, N
415: IF( WORK( I ).GT.SAFE2 ) THEN
416: WORK( I ) = ABS( WORK( N+I ) ) + NZ*EPS*WORK( I )
417: ELSE
418: WORK( I ) = ABS( WORK( N+I ) ) + NZ*EPS*WORK( I ) + SAFE1
419: END IF
420: 90 CONTINUE
421: *
422: KASE = 0
423: 100 CONTINUE
424: CALL DLACN2( N, WORK( 2*N+1 ), WORK( N+1 ), IWORK, FERR( J ),
425: $ KASE, ISAVE )
426: IF( KASE.NE.0 ) THEN
427: IF( KASE.EQ.1 ) THEN
428: *
429: * Multiply by diag(W)*inv(op(A)**T).
430: *
431: CALL DGBTRS( TRANST, N, KL, KU, 1, AFB, LDAFB, IPIV,
432: $ WORK( N+1 ), N, INFO )
433: DO 110 I = 1, N
434: WORK( N+I ) = WORK( N+I )*WORK( I )
435: 110 CONTINUE
436: ELSE
437: *
438: * Multiply by inv(op(A))*diag(W).
439: *
440: DO 120 I = 1, N
441: WORK( N+I ) = WORK( N+I )*WORK( I )
442: 120 CONTINUE
443: CALL DGBTRS( TRANS, N, KL, KU, 1, AFB, LDAFB, IPIV,
444: $ WORK( N+1 ), N, INFO )
445: END IF
446: GO TO 100
447: END IF
448: *
449: * Normalize error.
450: *
451: LSTRES = ZERO
452: DO 130 I = 1, N
453: LSTRES = MAX( LSTRES, ABS( X( I, J ) ) )
454: 130 CONTINUE
455: IF( LSTRES.NE.ZERO )
456: $ FERR( J ) = FERR( J ) / LSTRES
457: *
458: 140 CONTINUE
459: *
460: RETURN
461: *
462: * End of DGBRFS
463: *
464: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dgbrfs.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack