1: *> \brief \b DBBCSD
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DBBCSD + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dbbcsd.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dbbcsd.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dbbcsd.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DBBCSD( JOBU1, JOBU2, JOBV1T, JOBV2T, TRANS, M, P, Q,
22: * THETA, PHI, U1, LDU1, U2, LDU2, V1T, LDV1T,
23: * V2T, LDV2T, B11D, B11E, B12D, B12E, B21D, B21E,
24: * B22D, B22E, WORK, LWORK, INFO )
25: *
26: * .. Scalar Arguments ..
27: * CHARACTER JOBU1, JOBU2, JOBV1T, JOBV2T, TRANS
28: * INTEGER INFO, LDU1, LDU2, LDV1T, LDV2T, LWORK, M, P, Q
29: * ..
30: * .. Array Arguments ..
31: * DOUBLE PRECISION B11D( * ), B11E( * ), B12D( * ), B12E( * ),
32: * $ B21D( * ), B21E( * ), B22D( * ), B22E( * ),
33: * $ PHI( * ), THETA( * ), WORK( * )
34: * DOUBLE PRECISION U1( LDU1, * ), U2( LDU2, * ), V1T( LDV1T, * ),
35: * $ V2T( LDV2T, * )
36: * ..
37: *
38: *
39: *> \par Purpose:
40: * =============
41: *>
42: *> \verbatim
43: *>
44: *> DBBCSD computes the CS decomposition of an orthogonal matrix in
45: *> bidiagonal-block form,
46: *>
47: *>
48: *> [ B11 | B12 0 0 ]
49: *> [ 0 | 0 -I 0 ]
50: *> X = [----------------]
51: *> [ B21 | B22 0 0 ]
52: *> [ 0 | 0 0 I ]
53: *>
54: *> [ C | -S 0 0 ]
55: *> [ U1 | ] [ 0 | 0 -I 0 ] [ V1 | ]**T
56: *> = [---------] [---------------] [---------] .
57: *> [ | U2 ] [ S | C 0 0 ] [ | V2 ]
58: *> [ 0 | 0 0 I ]
59: *>
60: *> X is M-by-M, its top-left block is P-by-Q, and Q must be no larger
61: *> than P, M-P, or M-Q. (If Q is not the smallest index, then X must be
62: *> transposed and/or permuted. This can be done in constant time using
63: *> the TRANS and SIGNS options. See DORCSD for details.)
64: *>
65: *> The bidiagonal matrices B11, B12, B21, and B22 are represented
66: *> implicitly by angles THETA(1:Q) and PHI(1:Q-1).
67: *>
68: *> The orthogonal matrices U1, U2, V1T, and V2T are input/output.
69: *> The input matrices are pre- or post-multiplied by the appropriate
70: *> singular vector matrices.
71: *> \endverbatim
72: *
73: * Arguments:
74: * ==========
75: *
76: *> \param[in] JOBU1
77: *> \verbatim
78: *> JOBU1 is CHARACTER
79: *> = 'Y': U1 is updated;
80: *> otherwise: U1 is not updated.
81: *> \endverbatim
82: *>
83: *> \param[in] JOBU2
84: *> \verbatim
85: *> JOBU2 is CHARACTER
86: *> = 'Y': U2 is updated;
87: *> otherwise: U2 is not updated.
88: *> \endverbatim
89: *>
90: *> \param[in] JOBV1T
91: *> \verbatim
92: *> JOBV1T is CHARACTER
93: *> = 'Y': V1T is updated;
94: *> otherwise: V1T is not updated.
95: *> \endverbatim
96: *>
97: *> \param[in] JOBV2T
98: *> \verbatim
99: *> JOBV2T is CHARACTER
100: *> = 'Y': V2T is updated;
101: *> otherwise: V2T is not updated.
102: *> \endverbatim
103: *>
104: *> \param[in] TRANS
105: *> \verbatim
106: *> TRANS is CHARACTER
107: *> = 'T': X, U1, U2, V1T, and V2T are stored in row-major
108: *> order;
109: *> otherwise: X, U1, U2, V1T, and V2T are stored in column-
110: *> major order.
111: *> \endverbatim
112: *>
113: *> \param[in] M
114: *> \verbatim
115: *> M is INTEGER
116: *> The number of rows and columns in X, the orthogonal matrix in
117: *> bidiagonal-block form.
118: *> \endverbatim
119: *>
120: *> \param[in] P
121: *> \verbatim
122: *> P is INTEGER
123: *> The number of rows in the top-left block of X. 0 <= P <= M.
124: *> \endverbatim
125: *>
126: *> \param[in] Q
127: *> \verbatim
128: *> Q is INTEGER
129: *> The number of columns in the top-left block of X.
130: *> 0 <= Q <= MIN(P,M-P,M-Q).
131: *> \endverbatim
132: *>
133: *> \param[in,out] THETA
134: *> \verbatim
135: *> THETA is DOUBLE PRECISION array, dimension (Q)
136: *> On entry, the angles THETA(1),...,THETA(Q) that, along with
137: *> PHI(1), ...,PHI(Q-1), define the matrix in bidiagonal-block
138: *> form. On exit, the angles whose cosines and sines define the
139: *> diagonal blocks in the CS decomposition.
140: *> \endverbatim
141: *>
142: *> \param[in,out] PHI
143: *> \verbatim
144: *> PHI is DOUBLE PRECISION array, dimension (Q-1)
145: *> The angles PHI(1),...,PHI(Q-1) that, along with THETA(1),...,
146: *> THETA(Q), define the matrix in bidiagonal-block form.
147: *> \endverbatim
148: *>
149: *> \param[in,out] U1
150: *> \verbatim
151: *> U1 is DOUBLE PRECISION array, dimension (LDU1,P)
152: *> On entry, an LDU1-by-P matrix. On exit, U1 is postmultiplied
153: *> by the left singular vector matrix common to [ B11 ; 0 ] and
154: *> [ B12 0 0 ; 0 -I 0 0 ].
155: *> \endverbatim
156: *>
157: *> \param[in] LDU1
158: *> \verbatim
159: *> LDU1 is INTEGER
160: *> The leading dimension of the array U1.
161: *> \endverbatim
162: *>
163: *> \param[in,out] U2
164: *> \verbatim
165: *> U2 is DOUBLE PRECISION array, dimension (LDU2,M-P)
166: *> On entry, an LDU2-by-(M-P) matrix. On exit, U2 is
167: *> postmultiplied by the left singular vector matrix common to
168: *> [ B21 ; 0 ] and [ B22 0 0 ; 0 0 I ].
169: *> \endverbatim
170: *>
171: *> \param[in] LDU2
172: *> \verbatim
173: *> LDU2 is INTEGER
174: *> The leading dimension of the array U2.
175: *> \endverbatim
176: *>
177: *> \param[in,out] V1T
178: *> \verbatim
179: *> V1T is DOUBLE PRECISION array, dimension (LDV1T,Q)
180: *> On entry, a LDV1T-by-Q matrix. On exit, V1T is premultiplied
181: *> by the transpose of the right singular vector
182: *> matrix common to [ B11 ; 0 ] and [ B21 ; 0 ].
183: *> \endverbatim
184: *>
185: *> \param[in] LDV1T
186: *> \verbatim
187: *> LDV1T is INTEGER
188: *> The leading dimension of the array V1T.
189: *> \endverbatim
190: *>
191: *> \param[in,out] V2T
192: *> \verbatim
193: *> V2T is DOUBLE PRECISION array, dimenison (LDV2T,M-Q)
194: *> On entry, a LDV2T-by-(M-Q) matrix. On exit, V2T is
195: *> premultiplied by the transpose of the right
196: *> singular vector matrix common to [ B12 0 0 ; 0 -I 0 ] and
197: *> [ B22 0 0 ; 0 0 I ].
198: *> \endverbatim
199: *>
200: *> \param[in] LDV2T
201: *> \verbatim
202: *> LDV2T is INTEGER
203: *> The leading dimension of the array V2T.
204: *> \endverbatim
205: *>
206: *> \param[out] B11D
207: *> \verbatim
208: *> B11D is DOUBLE PRECISION array, dimension (Q)
209: *> When DBBCSD converges, B11D contains the cosines of THETA(1),
210: *> ..., THETA(Q). If DBBCSD fails to converge, then B11D
211: *> contains the diagonal of the partially reduced top-left
212: *> block.
213: *> \endverbatim
214: *>
215: *> \param[out] B11E
216: *> \verbatim
217: *> B11E is DOUBLE PRECISION array, dimension (Q-1)
218: *> When DBBCSD converges, B11E contains zeros. If DBBCSD fails
219: *> to converge, then B11E contains the superdiagonal of the
220: *> partially reduced top-left block.
221: *> \endverbatim
222: *>
223: *> \param[out] B12D
224: *> \verbatim
225: *> B12D is DOUBLE PRECISION array, dimension (Q)
226: *> When DBBCSD converges, B12D contains the negative sines of
227: *> THETA(1), ..., THETA(Q). If DBBCSD fails to converge, then
228: *> B12D contains the diagonal of the partially reduced top-right
229: *> block.
230: *> \endverbatim
231: *>
232: *> \param[out] B12E
233: *> \verbatim
234: *> B12E is DOUBLE PRECISION array, dimension (Q-1)
235: *> When DBBCSD converges, B12E contains zeros. If DBBCSD fails
236: *> to converge, then B12E contains the subdiagonal of the
237: *> partially reduced top-right block.
238: *> \endverbatim
239: *>
240: *> \param[out] B21D
241: *> \verbatim
242: *> B21D is DOUBLE PRECISION array, dimension (Q)
243: *> When CBBCSD converges, B21D contains the negative sines of
244: *> THETA(1), ..., THETA(Q). If CBBCSD fails to converge, then
245: *> B21D contains the diagonal of the partially reduced bottom-left
246: *> block.
247: *> \endverbatim
248: *>
249: *> \param[out] B21E
250: *> \verbatim
251: *> B21E is DOUBLE PRECISION array, dimension (Q-1)
252: *> When CBBCSD converges, B21E contains zeros. If CBBCSD fails
253: *> to converge, then B21E contains the subdiagonal of the
254: *> partially reduced bottom-left block.
255: *> \endverbatim
256: *>
257: *> \param[out] B22D
258: *> \verbatim
259: *> B22D is DOUBLE PRECISION array, dimension (Q)
260: *> When CBBCSD converges, B22D contains the negative sines of
261: *> THETA(1), ..., THETA(Q). If CBBCSD fails to converge, then
262: *> B22D contains the diagonal of the partially reduced bottom-right
263: *> block.
264: *> \endverbatim
265: *>
266: *> \param[out] B22E
267: *> \verbatim
268: *> B22E is DOUBLE PRECISION array, dimension (Q-1)
269: *> When CBBCSD converges, B22E contains zeros. If CBBCSD fails
270: *> to converge, then B22E contains the subdiagonal of the
271: *> partially reduced bottom-right block.
272: *> \endverbatim
273: *>
274: *> \param[out] WORK
275: *> \verbatim
276: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK))
277: *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
278: *> \endverbatim
279: *>
280: *> \param[in] LWORK
281: *> \verbatim
282: *> LWORK is INTEGER
283: *> The dimension of the array WORK. LWORK >= MAX(1,8*Q).
284: *>
285: *> If LWORK = -1, then a workspace query is assumed; the
286: *> routine only calculates the optimal size of the WORK array,
287: *> returns this value as the first entry of the work array, and
288: *> no error message related to LWORK is issued by XERBLA.
289: *> \endverbatim
290: *>
291: *> \param[out] INFO
292: *> \verbatim
293: *> INFO is INTEGER
294: *> = 0: successful exit.
295: *> < 0: if INFO = -i, the i-th argument had an illegal value.
296: *> > 0: if DBBCSD did not converge, INFO specifies the number
297: *> of nonzero entries in PHI, and B11D, B11E, etc.,
298: *> contain the partially reduced matrix.
299: *> \endverbatim
300: *
301: *> \par Internal Parameters:
302: * =========================
303: *>
304: *> \verbatim
305: *> TOLMUL DOUBLE PRECISION, default = MAX(10,MIN(100,EPS**(-1/8)))
306: *> TOLMUL controls the convergence criterion of the QR loop.
307: *> Angles THETA(i), PHI(i) are rounded to 0 or PI/2 when they
308: *> are within TOLMUL*EPS of either bound.
309: *> \endverbatim
310: *
311: *> \par References:
312: * ================
313: *>
314: *> [1] Brian D. Sutton. Computing the complete CS decomposition. Numer.
315: *> Algorithms, 50(1):33-65, 2009.
316: *
317: * Authors:
318: * ========
319: *
320: *> \author Univ. of Tennessee
321: *> \author Univ. of California Berkeley
322: *> \author Univ. of Colorado Denver
323: *> \author NAG Ltd.
324: *
325: *> \date November 2011
326: *
327: *> \ingroup doubleOTHERcomputational
328: *
329: * =====================================================================
330: SUBROUTINE DBBCSD( JOBU1, JOBU2, JOBV1T, JOBV2T, TRANS, M, P, Q,
331: $ THETA, PHI, U1, LDU1, U2, LDU2, V1T, LDV1T,
332: $ V2T, LDV2T, B11D, B11E, B12D, B12E, B21D, B21E,
333: $ B22D, B22E, WORK, LWORK, INFO )
334: *
335: * -- LAPACK computational routine (version 3.4.0) --
336: * -- LAPACK is a software package provided by Univ. of Tennessee, --
337: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
338: * November 2011
339: *
340: * .. Scalar Arguments ..
341: CHARACTER JOBU1, JOBU2, JOBV1T, JOBV2T, TRANS
342: INTEGER INFO, LDU1, LDU2, LDV1T, LDV2T, LWORK, M, P, Q
343: * ..
344: * .. Array Arguments ..
345: DOUBLE PRECISION B11D( * ), B11E( * ), B12D( * ), B12E( * ),
346: $ B21D( * ), B21E( * ), B22D( * ), B22E( * ),
347: $ PHI( * ), THETA( * ), WORK( * )
348: DOUBLE PRECISION U1( LDU1, * ), U2( LDU2, * ), V1T( LDV1T, * ),
349: $ V2T( LDV2T, * )
350: * ..
351: *
352: * ===================================================================
353: *
354: * .. Parameters ..
355: INTEGER MAXITR
356: PARAMETER ( MAXITR = 6 )
357: DOUBLE PRECISION HUNDRED, MEIGHTH, ONE, PIOVER2, TEN, ZERO
358: PARAMETER ( HUNDRED = 100.0D0, MEIGHTH = -0.125D0,
359: $ ONE = 1.0D0, PIOVER2 = 1.57079632679489662D0,
360: $ TEN = 10.0D0, ZERO = 0.0D0 )
361: DOUBLE PRECISION NEGONECOMPLEX
362: PARAMETER ( NEGONECOMPLEX = -1.0D0 )
363: * ..
364: * .. Local Scalars ..
365: LOGICAL COLMAJOR, LQUERY, RESTART11, RESTART12,
366: $ RESTART21, RESTART22, WANTU1, WANTU2, WANTV1T,
367: $ WANTV2T
368: INTEGER I, IMIN, IMAX, ITER, IU1CS, IU1SN, IU2CS,
369: $ IU2SN, IV1TCS, IV1TSN, IV2TCS, IV2TSN, J,
370: $ LWORKMIN, LWORKOPT, MAXIT, MINI
371: DOUBLE PRECISION B11BULGE, B12BULGE, B21BULGE, B22BULGE, DUMMY,
372: $ EPS, MU, NU, R, SIGMA11, SIGMA21,
373: $ TEMP, THETAMAX, THETAMIN, THRESH, TOL, TOLMUL,
374: $ UNFL, X1, X2, Y1, Y2
375: *
376: * .. External Subroutines ..
377: EXTERNAL DLASR, DSCAL, DSWAP, DLARTGP, DLARTGS, DLAS2,
378: $ XERBLA
379: * ..
380: * .. External Functions ..
381: DOUBLE PRECISION DLAMCH
382: LOGICAL LSAME
383: EXTERNAL LSAME, DLAMCH
384: * ..
385: * .. Intrinsic Functions ..
386: INTRINSIC ABS, ATAN2, COS, MAX, MIN, SIN, SQRT
387: * ..
388: * .. Executable Statements ..
389: *
390: * Test input arguments
391: *
392: INFO = 0
393: LQUERY = LWORK .EQ. -1
394: WANTU1 = LSAME( JOBU1, 'Y' )
395: WANTU2 = LSAME( JOBU2, 'Y' )
396: WANTV1T = LSAME( JOBV1T, 'Y' )
397: WANTV2T = LSAME( JOBV2T, 'Y' )
398: COLMAJOR = .NOT. LSAME( TRANS, 'T' )
399: *
400: IF( M .LT. 0 ) THEN
401: INFO = -6
402: ELSE IF( P .LT. 0 .OR. P .GT. M ) THEN
403: INFO = -7
404: ELSE IF( Q .LT. 0 .OR. Q .GT. M ) THEN
405: INFO = -8
406: ELSE IF( Q .GT. P .OR. Q .GT. M-P .OR. Q .GT. M-Q ) THEN
407: INFO = -8
408: ELSE IF( WANTU1 .AND. LDU1 .LT. P ) THEN
409: INFO = -12
410: ELSE IF( WANTU2 .AND. LDU2 .LT. M-P ) THEN
411: INFO = -14
412: ELSE IF( WANTV1T .AND. LDV1T .LT. Q ) THEN
413: INFO = -16
414: ELSE IF( WANTV2T .AND. LDV2T .LT. M-Q ) THEN
415: INFO = -18
416: END IF
417: *
418: * Quick return if Q = 0
419: *
420: IF( INFO .EQ. 0 .AND. Q .EQ. 0 ) THEN
421: LWORKMIN = 1
422: WORK(1) = LWORKMIN
423: RETURN
424: END IF
425: *
426: * Compute workspace
427: *
428: IF( INFO .EQ. 0 ) THEN
429: IU1CS = 1
430: IU1SN = IU1CS + Q
431: IU2CS = IU1SN + Q
432: IU2SN = IU2CS + Q
433: IV1TCS = IU2SN + Q
434: IV1TSN = IV1TCS + Q
435: IV2TCS = IV1TSN + Q
436: IV2TSN = IV2TCS + Q
437: LWORKOPT = IV2TSN + Q - 1
438: LWORKMIN = LWORKOPT
439: WORK(1) = LWORKOPT
440: IF( LWORK .LT. LWORKMIN .AND. .NOT. LQUERY ) THEN
441: INFO = -28
442: END IF
443: END IF
444: *
445: IF( INFO .NE. 0 ) THEN
446: CALL XERBLA( 'DBBCSD', -INFO )
447: RETURN
448: ELSE IF( LQUERY ) THEN
449: RETURN
450: END IF
451: *
452: * Get machine constants
453: *
454: EPS = DLAMCH( 'Epsilon' )
455: UNFL = DLAMCH( 'Safe minimum' )
456: TOLMUL = MAX( TEN, MIN( HUNDRED, EPS**MEIGHTH ) )
457: TOL = TOLMUL*EPS
458: THRESH = MAX( TOL, MAXITR*Q*Q*UNFL )
459: *
460: * Test for negligible sines or cosines
461: *
462: DO I = 1, Q
463: IF( THETA(I) .LT. THRESH ) THEN
464: THETA(I) = ZERO
465: ELSE IF( THETA(I) .GT. PIOVER2-THRESH ) THEN
466: THETA(I) = PIOVER2
467: END IF
468: END DO
469: DO I = 1, Q-1
470: IF( PHI(I) .LT. THRESH ) THEN
471: PHI(I) = ZERO
472: ELSE IF( PHI(I) .GT. PIOVER2-THRESH ) THEN
473: PHI(I) = PIOVER2
474: END IF
475: END DO
476: *
477: * Initial deflation
478: *
479: IMAX = Q
480: DO WHILE( ( IMAX .GT. 1 ) .AND. ( PHI(IMAX-1) .EQ. ZERO ) )
481: IMAX = IMAX - 1
482: END DO
483: IMIN = IMAX - 1
484: IF ( IMIN .GT. 1 ) THEN
485: DO WHILE( PHI(IMIN-1) .NE. ZERO )
486: IMIN = IMIN - 1
487: IF ( IMIN .LE. 1 ) EXIT
488: END DO
489: END IF
490: *
491: * Initialize iteration counter
492: *
493: MAXIT = MAXITR*Q*Q
494: ITER = 0
495: *
496: * Begin main iteration loop
497: *
498: DO WHILE( IMAX .GT. 1 )
499: *
500: * Compute the matrix entries
501: *
502: B11D(IMIN) = COS( THETA(IMIN) )
503: B21D(IMIN) = -SIN( THETA(IMIN) )
504: DO I = IMIN, IMAX - 1
505: B11E(I) = -SIN( THETA(I) ) * SIN( PHI(I) )
506: B11D(I+1) = COS( THETA(I+1) ) * COS( PHI(I) )
507: B12D(I) = SIN( THETA(I) ) * COS( PHI(I) )
508: B12E(I) = COS( THETA(I+1) ) * SIN( PHI(I) )
509: B21E(I) = -COS( THETA(I) ) * SIN( PHI(I) )
510: B21D(I+1) = -SIN( THETA(I+1) ) * COS( PHI(I) )
511: B22D(I) = COS( THETA(I) ) * COS( PHI(I) )
512: B22E(I) = -SIN( THETA(I+1) ) * SIN( PHI(I) )
513: END DO
514: B12D(IMAX) = SIN( THETA(IMAX) )
515: B22D(IMAX) = COS( THETA(IMAX) )
516: *
517: * Abort if not converging; otherwise, increment ITER
518: *
519: IF( ITER .GT. MAXIT ) THEN
520: INFO = 0
521: DO I = 1, Q
522: IF( PHI(I) .NE. ZERO )
523: $ INFO = INFO + 1
524: END DO
525: RETURN
526: END IF
527: *
528: ITER = ITER + IMAX - IMIN
529: *
530: * Compute shifts
531: *
532: THETAMAX = THETA(IMIN)
533: THETAMIN = THETA(IMIN)
534: DO I = IMIN+1, IMAX
535: IF( THETA(I) > THETAMAX )
536: $ THETAMAX = THETA(I)
537: IF( THETA(I) < THETAMIN )
538: $ THETAMIN = THETA(I)
539: END DO
540: *
541: IF( THETAMAX .GT. PIOVER2 - THRESH ) THEN
542: *
543: * Zero on diagonals of B11 and B22; induce deflation with a
544: * zero shift
545: *
546: MU = ZERO
547: NU = ONE
548: *
549: ELSE IF( THETAMIN .LT. THRESH ) THEN
550: *
551: * Zero on diagonals of B12 and B22; induce deflation with a
552: * zero shift
553: *
554: MU = ONE
555: NU = ZERO
556: *
557: ELSE
558: *
559: * Compute shifts for B11 and B21 and use the lesser
560: *
561: CALL DLAS2( B11D(IMAX-1), B11E(IMAX-1), B11D(IMAX), SIGMA11,
562: $ DUMMY )
563: CALL DLAS2( B21D(IMAX-1), B21E(IMAX-1), B21D(IMAX), SIGMA21,
564: $ DUMMY )
565: *
566: IF( SIGMA11 .LE. SIGMA21 ) THEN
567: MU = SIGMA11
568: NU = SQRT( ONE - MU**2 )
569: IF( MU .LT. THRESH ) THEN
570: MU = ZERO
571: NU = ONE
572: END IF
573: ELSE
574: NU = SIGMA21
575: MU = SQRT( 1.0 - NU**2 )
576: IF( NU .LT. THRESH ) THEN
577: MU = ONE
578: NU = ZERO
579: END IF
580: END IF
581: END IF
582: *
583: * Rotate to produce bulges in B11 and B21
584: *
585: IF( MU .LE. NU ) THEN
586: CALL DLARTGS( B11D(IMIN), B11E(IMIN), MU,
587: $ WORK(IV1TCS+IMIN-1), WORK(IV1TSN+IMIN-1) )
588: ELSE
589: CALL DLARTGS( B21D(IMIN), B21E(IMIN), NU,
590: $ WORK(IV1TCS+IMIN-1), WORK(IV1TSN+IMIN-1) )
591: END IF
592: *
593: TEMP = WORK(IV1TCS+IMIN-1)*B11D(IMIN) +
594: $ WORK(IV1TSN+IMIN-1)*B11E(IMIN)
595: B11E(IMIN) = WORK(IV1TCS+IMIN-1)*B11E(IMIN) -
596: $ WORK(IV1TSN+IMIN-1)*B11D(IMIN)
597: B11D(IMIN) = TEMP
598: B11BULGE = WORK(IV1TSN+IMIN-1)*B11D(IMIN+1)
599: B11D(IMIN+1) = WORK(IV1TCS+IMIN-1)*B11D(IMIN+1)
600: TEMP = WORK(IV1TCS+IMIN-1)*B21D(IMIN) +
601: $ WORK(IV1TSN+IMIN-1)*B21E(IMIN)
602: B21E(IMIN) = WORK(IV1TCS+IMIN-1)*B21E(IMIN) -
603: $ WORK(IV1TSN+IMIN-1)*B21D(IMIN)
604: B21D(IMIN) = TEMP
605: B21BULGE = WORK(IV1TSN+IMIN-1)*B21D(IMIN+1)
606: B21D(IMIN+1) = WORK(IV1TCS+IMIN-1)*B21D(IMIN+1)
607: *
608: * Compute THETA(IMIN)
609: *
610: THETA( IMIN ) = ATAN2( SQRT( B21D(IMIN)**2+B21BULGE**2 ),
611: $ SQRT( B11D(IMIN)**2+B11BULGE**2 ) )
612: *
613: * Chase the bulges in B11(IMIN+1,IMIN) and B21(IMIN+1,IMIN)
614: *
615: IF( B11D(IMIN)**2+B11BULGE**2 .GT. THRESH**2 ) THEN
616: CALL DLARTGP( B11BULGE, B11D(IMIN), WORK(IU1SN+IMIN-1),
617: $ WORK(IU1CS+IMIN-1), R )
618: ELSE IF( MU .LE. NU ) THEN
619: CALL DLARTGS( B11E( IMIN ), B11D( IMIN + 1 ), MU,
620: $ WORK(IU1CS+IMIN-1), WORK(IU1SN+IMIN-1) )
621: ELSE
622: CALL DLARTGS( B12D( IMIN ), B12E( IMIN ), NU,
623: $ WORK(IU1CS+IMIN-1), WORK(IU1SN+IMIN-1) )
624: END IF
625: IF( B21D(IMIN)**2+B21BULGE**2 .GT. THRESH**2 ) THEN
626: CALL DLARTGP( B21BULGE, B21D(IMIN), WORK(IU2SN+IMIN-1),
627: $ WORK(IU2CS+IMIN-1), R )
628: ELSE IF( NU .LT. MU ) THEN
629: CALL DLARTGS( B21E( IMIN ), B21D( IMIN + 1 ), NU,
630: $ WORK(IU2CS+IMIN-1), WORK(IU2SN+IMIN-1) )
631: ELSE
632: CALL DLARTGS( B22D(IMIN), B22E(IMIN), MU,
633: $ WORK(IU2CS+IMIN-1), WORK(IU2SN+IMIN-1) )
634: END IF
635: WORK(IU2CS+IMIN-1) = -WORK(IU2CS+IMIN-1)
636: WORK(IU2SN+IMIN-1) = -WORK(IU2SN+IMIN-1)
637: *
638: TEMP = WORK(IU1CS+IMIN-1)*B11E(IMIN) +
639: $ WORK(IU1SN+IMIN-1)*B11D(IMIN+1)
640: B11D(IMIN+1) = WORK(IU1CS+IMIN-1)*B11D(IMIN+1) -
641: $ WORK(IU1SN+IMIN-1)*B11E(IMIN)
642: B11E(IMIN) = TEMP
643: IF( IMAX .GT. IMIN+1 ) THEN
644: B11BULGE = WORK(IU1SN+IMIN-1)*B11E(IMIN+1)
645: B11E(IMIN+1) = WORK(IU1CS+IMIN-1)*B11E(IMIN+1)
646: END IF
647: TEMP = WORK(IU1CS+IMIN-1)*B12D(IMIN) +
648: $ WORK(IU1SN+IMIN-1)*B12E(IMIN)
649: B12E(IMIN) = WORK(IU1CS+IMIN-1)*B12E(IMIN) -
650: $ WORK(IU1SN+IMIN-1)*B12D(IMIN)
651: B12D(IMIN) = TEMP
652: B12BULGE = WORK(IU1SN+IMIN-1)*B12D(IMIN+1)
653: B12D(IMIN+1) = WORK(IU1CS+IMIN-1)*B12D(IMIN+1)
654: TEMP = WORK(IU2CS+IMIN-1)*B21E(IMIN) +
655: $ WORK(IU2SN+IMIN-1)*B21D(IMIN+1)
656: B21D(IMIN+1) = WORK(IU2CS+IMIN-1)*B21D(IMIN+1) -
657: $ WORK(IU2SN+IMIN-1)*B21E(IMIN)
658: B21E(IMIN) = TEMP
659: IF( IMAX .GT. IMIN+1 ) THEN
660: B21BULGE = WORK(IU2SN+IMIN-1)*B21E(IMIN+1)
661: B21E(IMIN+1) = WORK(IU2CS+IMIN-1)*B21E(IMIN+1)
662: END IF
663: TEMP = WORK(IU2CS+IMIN-1)*B22D(IMIN) +
664: $ WORK(IU2SN+IMIN-1)*B22E(IMIN)
665: B22E(IMIN) = WORK(IU2CS+IMIN-1)*B22E(IMIN) -
666: $ WORK(IU2SN+IMIN-1)*B22D(IMIN)
667: B22D(IMIN) = TEMP
668: B22BULGE = WORK(IU2SN+IMIN-1)*B22D(IMIN+1)
669: B22D(IMIN+1) = WORK(IU2CS+IMIN-1)*B22D(IMIN+1)
670: *
671: * Inner loop: chase bulges from B11(IMIN,IMIN+2),
672: * B12(IMIN,IMIN+1), B21(IMIN,IMIN+2), and B22(IMIN,IMIN+1) to
673: * bottom-right
674: *
675: DO I = IMIN+1, IMAX-1
676: *
677: * Compute PHI(I-1)
678: *
679: X1 = SIN(THETA(I-1))*B11E(I-1) + COS(THETA(I-1))*B21E(I-1)
680: X2 = SIN(THETA(I-1))*B11BULGE + COS(THETA(I-1))*B21BULGE
681: Y1 = SIN(THETA(I-1))*B12D(I-1) + COS(THETA(I-1))*B22D(I-1)
682: Y2 = SIN(THETA(I-1))*B12BULGE + COS(THETA(I-1))*B22BULGE
683: *
684: PHI(I-1) = ATAN2( SQRT(X1**2+X2**2), SQRT(Y1**2+Y2**2) )
685: *
686: * Determine if there are bulges to chase or if a new direct
687: * summand has been reached
688: *
689: RESTART11 = B11E(I-1)**2 + B11BULGE**2 .LE. THRESH**2
690: RESTART21 = B21E(I-1)**2 + B21BULGE**2 .LE. THRESH**2
691: RESTART12 = B12D(I-1)**2 + B12BULGE**2 .LE. THRESH**2
692: RESTART22 = B22D(I-1)**2 + B22BULGE**2 .LE. THRESH**2
693: *
694: * If possible, chase bulges from B11(I-1,I+1), B12(I-1,I),
695: * B21(I-1,I+1), and B22(I-1,I). If necessary, restart bulge-
696: * chasing by applying the original shift again.
697: *
698: IF( .NOT. RESTART11 .AND. .NOT. RESTART21 ) THEN
699: CALL DLARTGP( X2, X1, WORK(IV1TSN+I-1), WORK(IV1TCS+I-1),
700: $ R )
701: ELSE IF( .NOT. RESTART11 .AND. RESTART21 ) THEN
702: CALL DLARTGP( B11BULGE, B11E(I-1), WORK(IV1TSN+I-1),
703: $ WORK(IV1TCS+I-1), R )
704: ELSE IF( RESTART11 .AND. .NOT. RESTART21 ) THEN
705: CALL DLARTGP( B21BULGE, B21E(I-1), WORK(IV1TSN+I-1),
706: $ WORK(IV1TCS+I-1), R )
707: ELSE IF( MU .LE. NU ) THEN
708: CALL DLARTGS( B11D(I), B11E(I), MU, WORK(IV1TCS+I-1),
709: $ WORK(IV1TSN+I-1) )
710: ELSE
711: CALL DLARTGS( B21D(I), B21E(I), NU, WORK(IV1TCS+I-1),
712: $ WORK(IV1TSN+I-1) )
713: END IF
714: WORK(IV1TCS+I-1) = -WORK(IV1TCS+I-1)
715: WORK(IV1TSN+I-1) = -WORK(IV1TSN+I-1)
716: IF( .NOT. RESTART12 .AND. .NOT. RESTART22 ) THEN
717: CALL DLARTGP( Y2, Y1, WORK(IV2TSN+I-1-1),
718: $ WORK(IV2TCS+I-1-1), R )
719: ELSE IF( .NOT. RESTART12 .AND. RESTART22 ) THEN
720: CALL DLARTGP( B12BULGE, B12D(I-1), WORK(IV2TSN+I-1-1),
721: $ WORK(IV2TCS+I-1-1), R )
722: ELSE IF( RESTART12 .AND. .NOT. RESTART22 ) THEN
723: CALL DLARTGP( B22BULGE, B22D(I-1), WORK(IV2TSN+I-1-1),
724: $ WORK(IV2TCS+I-1-1), R )
725: ELSE IF( NU .LT. MU ) THEN
726: CALL DLARTGS( B12E(I-1), B12D(I), NU, WORK(IV2TCS+I-1-1),
727: $ WORK(IV2TSN+I-1-1) )
728: ELSE
729: CALL DLARTGS( B22E(I-1), B22D(I), MU, WORK(IV2TCS+I-1-1),
730: $ WORK(IV2TSN+I-1-1) )
731: END IF
732: *
733: TEMP = WORK(IV1TCS+I-1)*B11D(I) + WORK(IV1TSN+I-1)*B11E(I)
734: B11E(I) = WORK(IV1TCS+I-1)*B11E(I) -
735: $ WORK(IV1TSN+I-1)*B11D(I)
736: B11D(I) = TEMP
737: B11BULGE = WORK(IV1TSN+I-1)*B11D(I+1)
738: B11D(I+1) = WORK(IV1TCS+I-1)*B11D(I+1)
739: TEMP = WORK(IV1TCS+I-1)*B21D(I) + WORK(IV1TSN+I-1)*B21E(I)
740: B21E(I) = WORK(IV1TCS+I-1)*B21E(I) -
741: $ WORK(IV1TSN+I-1)*B21D(I)
742: B21D(I) = TEMP
743: B21BULGE = WORK(IV1TSN+I-1)*B21D(I+1)
744: B21D(I+1) = WORK(IV1TCS+I-1)*B21D(I+1)
745: TEMP = WORK(IV2TCS+I-1-1)*B12E(I-1) +
746: $ WORK(IV2TSN+I-1-1)*B12D(I)
747: B12D(I) = WORK(IV2TCS+I-1-1)*B12D(I) -
748: $ WORK(IV2TSN+I-1-1)*B12E(I-1)
749: B12E(I-1) = TEMP
750: B12BULGE = WORK(IV2TSN+I-1-1)*B12E(I)
751: B12E(I) = WORK(IV2TCS+I-1-1)*B12E(I)
752: TEMP = WORK(IV2TCS+I-1-1)*B22E(I-1) +
753: $ WORK(IV2TSN+I-1-1)*B22D(I)
754: B22D(I) = WORK(IV2TCS+I-1-1)*B22D(I) -
755: $ WORK(IV2TSN+I-1-1)*B22E(I-1)
756: B22E(I-1) = TEMP
757: B22BULGE = WORK(IV2TSN+I-1-1)*B22E(I)
758: B22E(I) = WORK(IV2TCS+I-1-1)*B22E(I)
759: *
760: * Compute THETA(I)
761: *
762: X1 = COS(PHI(I-1))*B11D(I) + SIN(PHI(I-1))*B12E(I-1)
763: X2 = COS(PHI(I-1))*B11BULGE + SIN(PHI(I-1))*B12BULGE
764: Y1 = COS(PHI(I-1))*B21D(I) + SIN(PHI(I-1))*B22E(I-1)
765: Y2 = COS(PHI(I-1))*B21BULGE + SIN(PHI(I-1))*B22BULGE
766: *
767: THETA(I) = ATAN2( SQRT(Y1**2+Y2**2), SQRT(X1**2+X2**2) )
768: *
769: * Determine if there are bulges to chase or if a new direct
770: * summand has been reached
771: *
772: RESTART11 = B11D(I)**2 + B11BULGE**2 .LE. THRESH**2
773: RESTART12 = B12E(I-1)**2 + B12BULGE**2 .LE. THRESH**2
774: RESTART21 = B21D(I)**2 + B21BULGE**2 .LE. THRESH**2
775: RESTART22 = B22E(I-1)**2 + B22BULGE**2 .LE. THRESH**2
776: *
777: * If possible, chase bulges from B11(I+1,I), B12(I+1,I-1),
778: * B21(I+1,I), and B22(I+1,I-1). If necessary, restart bulge-
779: * chasing by applying the original shift again.
780: *
781: IF( .NOT. RESTART11 .AND. .NOT. RESTART12 ) THEN
782: CALL DLARTGP( X2, X1, WORK(IU1SN+I-1), WORK(IU1CS+I-1),
783: $ R )
784: ELSE IF( .NOT. RESTART11 .AND. RESTART12 ) THEN
785: CALL DLARTGP( B11BULGE, B11D(I), WORK(IU1SN+I-1),
786: $ WORK(IU1CS+I-1), R )
787: ELSE IF( RESTART11 .AND. .NOT. RESTART12 ) THEN
788: CALL DLARTGP( B12BULGE, B12E(I-1), WORK(IU1SN+I-1),
789: $ WORK(IU1CS+I-1), R )
790: ELSE IF( MU .LE. NU ) THEN
791: CALL DLARTGS( B11E(I), B11D(I+1), MU, WORK(IU1CS+I-1),
792: $ WORK(IU1SN+I-1) )
793: ELSE
794: CALL DLARTGS( B12D(I), B12E(I), NU, WORK(IU1CS+I-1),
795: $ WORK(IU1SN+I-1) )
796: END IF
797: IF( .NOT. RESTART21 .AND. .NOT. RESTART22 ) THEN
798: CALL DLARTGP( Y2, Y1, WORK(IU2SN+I-1), WORK(IU2CS+I-1),
799: $ R )
800: ELSE IF( .NOT. RESTART21 .AND. RESTART22 ) THEN
801: CALL DLARTGP( B21BULGE, B21D(I), WORK(IU2SN+I-1),
802: $ WORK(IU2CS+I-1), R )
803: ELSE IF( RESTART21 .AND. .NOT. RESTART22 ) THEN
804: CALL DLARTGP( B22BULGE, B22E(I-1), WORK(IU2SN+I-1),
805: $ WORK(IU2CS+I-1), R )
806: ELSE IF( NU .LT. MU ) THEN
807: CALL DLARTGS( B21E(I), B21E(I+1), NU, WORK(IU2CS+I-1),
808: $ WORK(IU2SN+I-1) )
809: ELSE
810: CALL DLARTGS( B22D(I), B22E(I), MU, WORK(IU2CS+I-1),
811: $ WORK(IU2SN+I-1) )
812: END IF
813: WORK(IU2CS+I-1) = -WORK(IU2CS+I-1)
814: WORK(IU2SN+I-1) = -WORK(IU2SN+I-1)
815: *
816: TEMP = WORK(IU1CS+I-1)*B11E(I) + WORK(IU1SN+I-1)*B11D(I+1)
817: B11D(I+1) = WORK(IU1CS+I-1)*B11D(I+1) -
818: $ WORK(IU1SN+I-1)*B11E(I)
819: B11E(I) = TEMP
820: IF( I .LT. IMAX - 1 ) THEN
821: B11BULGE = WORK(IU1SN+I-1)*B11E(I+1)
822: B11E(I+1) = WORK(IU1CS+I-1)*B11E(I+1)
823: END IF
824: TEMP = WORK(IU2CS+I-1)*B21E(I) + WORK(IU2SN+I-1)*B21D(I+1)
825: B21D(I+1) = WORK(IU2CS+I-1)*B21D(I+1) -
826: $ WORK(IU2SN+I-1)*B21E(I)
827: B21E(I) = TEMP
828: IF( I .LT. IMAX - 1 ) THEN
829: B21BULGE = WORK(IU2SN+I-1)*B21E(I+1)
830: B21E(I+1) = WORK(IU2CS+I-1)*B21E(I+1)
831: END IF
832: TEMP = WORK(IU1CS+I-1)*B12D(I) + WORK(IU1SN+I-1)*B12E(I)
833: B12E(I) = WORK(IU1CS+I-1)*B12E(I) - WORK(IU1SN+I-1)*B12D(I)
834: B12D(I) = TEMP
835: B12BULGE = WORK(IU1SN+I-1)*B12D(I+1)
836: B12D(I+1) = WORK(IU1CS+I-1)*B12D(I+1)
837: TEMP = WORK(IU2CS+I-1)*B22D(I) + WORK(IU2SN+I-1)*B22E(I)
838: B22E(I) = WORK(IU2CS+I-1)*B22E(I) - WORK(IU2SN+I-1)*B22D(I)
839: B22D(I) = TEMP
840: B22BULGE = WORK(IU2SN+I-1)*B22D(I+1)
841: B22D(I+1) = WORK(IU2CS+I-1)*B22D(I+1)
842: *
843: END DO
844: *
845: * Compute PHI(IMAX-1)
846: *
847: X1 = SIN(THETA(IMAX-1))*B11E(IMAX-1) +
848: $ COS(THETA(IMAX-1))*B21E(IMAX-1)
849: Y1 = SIN(THETA(IMAX-1))*B12D(IMAX-1) +
850: $ COS(THETA(IMAX-1))*B22D(IMAX-1)
851: Y2 = SIN(THETA(IMAX-1))*B12BULGE + COS(THETA(IMAX-1))*B22BULGE
852: *
853: PHI(IMAX-1) = ATAN2( ABS(X1), SQRT(Y1**2+Y2**2) )
854: *
855: * Chase bulges from B12(IMAX-1,IMAX) and B22(IMAX-1,IMAX)
856: *
857: RESTART12 = B12D(IMAX-1)**2 + B12BULGE**2 .LE. THRESH**2
858: RESTART22 = B22D(IMAX-1)**2 + B22BULGE**2 .LE. THRESH**2
859: *
860: IF( .NOT. RESTART12 .AND. .NOT. RESTART22 ) THEN
861: CALL DLARTGP( Y2, Y1, WORK(IV2TSN+IMAX-1-1),
862: $ WORK(IV2TCS+IMAX-1-1), R )
863: ELSE IF( .NOT. RESTART12 .AND. RESTART22 ) THEN
864: CALL DLARTGP( B12BULGE, B12D(IMAX-1), WORK(IV2TSN+IMAX-1-1),
865: $ WORK(IV2TCS+IMAX-1-1), R )
866: ELSE IF( RESTART12 .AND. .NOT. RESTART22 ) THEN
867: CALL DLARTGP( B22BULGE, B22D(IMAX-1), WORK(IV2TSN+IMAX-1-1),
868: $ WORK(IV2TCS+IMAX-1-1), R )
869: ELSE IF( NU .LT. MU ) THEN
870: CALL DLARTGS( B12E(IMAX-1), B12D(IMAX), NU,
871: $ WORK(IV2TCS+IMAX-1-1), WORK(IV2TSN+IMAX-1-1) )
872: ELSE
873: CALL DLARTGS( B22E(IMAX-1), B22D(IMAX), MU,
874: $ WORK(IV2TCS+IMAX-1-1), WORK(IV2TSN+IMAX-1-1) )
875: END IF
876: *
877: TEMP = WORK(IV2TCS+IMAX-1-1)*B12E(IMAX-1) +
878: $ WORK(IV2TSN+IMAX-1-1)*B12D(IMAX)
879: B12D(IMAX) = WORK(IV2TCS+IMAX-1-1)*B12D(IMAX) -
880: $ WORK(IV2TSN+IMAX-1-1)*B12E(IMAX-1)
881: B12E(IMAX-1) = TEMP
882: TEMP = WORK(IV2TCS+IMAX-1-1)*B22E(IMAX-1) +
883: $ WORK(IV2TSN+IMAX-1-1)*B22D(IMAX)
884: B22D(IMAX) = WORK(IV2TCS+IMAX-1-1)*B22D(IMAX) -
885: $ WORK(IV2TSN+IMAX-1-1)*B22E(IMAX-1)
886: B22E(IMAX-1) = TEMP
887: *
888: * Update singular vectors
889: *
890: IF( WANTU1 ) THEN
891: IF( COLMAJOR ) THEN
892: CALL DLASR( 'R', 'V', 'F', P, IMAX-IMIN+1,
893: $ WORK(IU1CS+IMIN-1), WORK(IU1SN+IMIN-1),
894: $ U1(1,IMIN), LDU1 )
895: ELSE
896: CALL DLASR( 'L', 'V', 'F', IMAX-IMIN+1, P,
897: $ WORK(IU1CS+IMIN-1), WORK(IU1SN+IMIN-1),
898: $ U1(IMIN,1), LDU1 )
899: END IF
900: END IF
901: IF( WANTU2 ) THEN
902: IF( COLMAJOR ) THEN
903: CALL DLASR( 'R', 'V', 'F', M-P, IMAX-IMIN+1,
904: $ WORK(IU2CS+IMIN-1), WORK(IU2SN+IMIN-1),
905: $ U2(1,IMIN), LDU2 )
906: ELSE
907: CALL DLASR( 'L', 'V', 'F', IMAX-IMIN+1, M-P,
908: $ WORK(IU2CS+IMIN-1), WORK(IU2SN+IMIN-1),
909: $ U2(IMIN,1), LDU2 )
910: END IF
911: END IF
912: IF( WANTV1T ) THEN
913: IF( COLMAJOR ) THEN
914: CALL DLASR( 'L', 'V', 'F', IMAX-IMIN+1, Q,
915: $ WORK(IV1TCS+IMIN-1), WORK(IV1TSN+IMIN-1),
916: $ V1T(IMIN,1), LDV1T )
917: ELSE
918: CALL DLASR( 'R', 'V', 'F', Q, IMAX-IMIN+1,
919: $ WORK(IV1TCS+IMIN-1), WORK(IV1TSN+IMIN-1),
920: $ V1T(1,IMIN), LDV1T )
921: END IF
922: END IF
923: IF( WANTV2T ) THEN
924: IF( COLMAJOR ) THEN
925: CALL DLASR( 'L', 'V', 'F', IMAX-IMIN+1, M-Q,
926: $ WORK(IV2TCS+IMIN-1), WORK(IV2TSN+IMIN-1),
927: $ V2T(IMIN,1), LDV2T )
928: ELSE
929: CALL DLASR( 'R', 'V', 'F', M-Q, IMAX-IMIN+1,
930: $ WORK(IV2TCS+IMIN-1), WORK(IV2TSN+IMIN-1),
931: $ V2T(1,IMIN), LDV2T )
932: END IF
933: END IF
934: *
935: * Fix signs on B11(IMAX-1,IMAX) and B21(IMAX-1,IMAX)
936: *
937: IF( B11E(IMAX-1)+B21E(IMAX-1) .GT. 0 ) THEN
938: B11D(IMAX) = -B11D(IMAX)
939: B21D(IMAX) = -B21D(IMAX)
940: IF( WANTV1T ) THEN
941: IF( COLMAJOR ) THEN
942: CALL DSCAL( Q, NEGONECOMPLEX, V1T(IMAX,1), LDV1T )
943: ELSE
944: CALL DSCAL( Q, NEGONECOMPLEX, V1T(1,IMAX), 1 )
945: END IF
946: END IF
947: END IF
948: *
949: * Compute THETA(IMAX)
950: *
951: X1 = COS(PHI(IMAX-1))*B11D(IMAX) +
952: $ SIN(PHI(IMAX-1))*B12E(IMAX-1)
953: Y1 = COS(PHI(IMAX-1))*B21D(IMAX) +
954: $ SIN(PHI(IMAX-1))*B22E(IMAX-1)
955: *
956: THETA(IMAX) = ATAN2( ABS(Y1), ABS(X1) )
957: *
958: * Fix signs on B11(IMAX,IMAX), B12(IMAX,IMAX-1), B21(IMAX,IMAX),
959: * and B22(IMAX,IMAX-1)
960: *
961: IF( B11D(IMAX)+B12E(IMAX-1) .LT. 0 ) THEN
962: B12D(IMAX) = -B12D(IMAX)
963: IF( WANTU1 ) THEN
964: IF( COLMAJOR ) THEN
965: CALL DSCAL( P, NEGONECOMPLEX, U1(1,IMAX), 1 )
966: ELSE
967: CALL DSCAL( P, NEGONECOMPLEX, U1(IMAX,1), LDU1 )
968: END IF
969: END IF
970: END IF
971: IF( B21D(IMAX)+B22E(IMAX-1) .GT. 0 ) THEN
972: B22D(IMAX) = -B22D(IMAX)
973: IF( WANTU2 ) THEN
974: IF( COLMAJOR ) THEN
975: CALL DSCAL( M-P, NEGONECOMPLEX, U2(1,IMAX), 1 )
976: ELSE
977: CALL DSCAL( M-P, NEGONECOMPLEX, U2(IMAX,1), LDU2 )
978: END IF
979: END IF
980: END IF
981: *
982: * Fix signs on B12(IMAX,IMAX) and B22(IMAX,IMAX)
983: *
984: IF( B12D(IMAX)+B22D(IMAX) .LT. 0 ) THEN
985: IF( WANTV2T ) THEN
986: IF( COLMAJOR ) THEN
987: CALL DSCAL( M-Q, NEGONECOMPLEX, V2T(IMAX,1), LDV2T )
988: ELSE
989: CALL DSCAL( M-Q, NEGONECOMPLEX, V2T(1,IMAX), 1 )
990: END IF
991: END IF
992: END IF
993: *
994: * Test for negligible sines or cosines
995: *
996: DO I = IMIN, IMAX
997: IF( THETA(I) .LT. THRESH ) THEN
998: THETA(I) = ZERO
999: ELSE IF( THETA(I) .GT. PIOVER2-THRESH ) THEN
1000: THETA(I) = PIOVER2
1001: END IF
1002: END DO
1003: DO I = IMIN, IMAX-1
1004: IF( PHI(I) .LT. THRESH ) THEN
1005: PHI(I) = ZERO
1006: ELSE IF( PHI(I) .GT. PIOVER2-THRESH ) THEN
1007: PHI(I) = PIOVER2
1008: END IF
1009: END DO
1010: *
1011: * Deflate
1012: *
1013: IF (IMAX .GT. 1) THEN
1014: DO WHILE( PHI(IMAX-1) .EQ. ZERO )
1015: IMAX = IMAX - 1
1016: IF (IMAX .LE. 1) EXIT
1017: END DO
1018: END IF
1019: IF( IMIN .GT. IMAX - 1 )
1020: $ IMIN = IMAX - 1
1021: IF (IMIN .GT. 1) THEN
1022: DO WHILE (PHI(IMIN-1) .NE. ZERO)
1023: IMIN = IMIN - 1
1024: IF (IMIN .LE. 1) EXIT
1025: END DO
1026: END IF
1027: *
1028: * Repeat main iteration loop
1029: *
1030: END DO
1031: *
1032: * Postprocessing: order THETA from least to greatest
1033: *
1034: DO I = 1, Q
1035: *
1036: MINI = I
1037: THETAMIN = THETA(I)
1038: DO J = I+1, Q
1039: IF( THETA(J) .LT. THETAMIN ) THEN
1040: MINI = J
1041: THETAMIN = THETA(J)
1042: END IF
1043: END DO
1044: *
1045: IF( MINI .NE. I ) THEN
1046: THETA(MINI) = THETA(I)
1047: THETA(I) = THETAMIN
1048: IF( COLMAJOR ) THEN
1049: IF( WANTU1 )
1050: $ CALL DSWAP( P, U1(1,I), 1, U1(1,MINI), 1 )
1051: IF( WANTU2 )
1052: $ CALL DSWAP( M-P, U2(1,I), 1, U2(1,MINI), 1 )
1053: IF( WANTV1T )
1054: $ CALL DSWAP( Q, V1T(I,1), LDV1T, V1T(MINI,1), LDV1T )
1055: IF( WANTV2T )
1056: $ CALL DSWAP( M-Q, V2T(I,1), LDV2T, V2T(MINI,1),
1057: $ LDV2T )
1058: ELSE
1059: IF( WANTU1 )
1060: $ CALL DSWAP( P, U1(I,1), LDU1, U1(MINI,1), LDU1 )
1061: IF( WANTU2 )
1062: $ CALL DSWAP( M-P, U2(I,1), LDU2, U2(MINI,1), LDU2 )
1063: IF( WANTV1T )
1064: $ CALL DSWAP( Q, V1T(1,I), 1, V1T(1,MINI), 1 )
1065: IF( WANTV2T )
1066: $ CALL DSWAP( M-Q, V2T(1,I), 1, V2T(1,MINI), 1 )
1067: END IF
1068: END IF
1069: *
1070: END DO
1071: *
1072: RETURN
1073: *
1074: * End of DBBCSD
1075: *
1076: END
1077:
CVSweb interface <joel.bertrand@systella.fr>