File:
[local] /
rpl /
lapack /
blas /
ztrsv.f
Revision
1.11:
download - view:
text,
annotated -
select for diffs -
revision graph
Mon Jan 27 09:28:15 2014 UTC (10 years, 3 months ago) by
bertrand
Branches:
MAIN
CVS tags:
rpl-4_1_24,
rpl-4_1_23,
rpl-4_1_22,
rpl-4_1_21,
rpl-4_1_20,
rpl-4_1_19,
rpl-4_1_18,
rpl-4_1_17,
HEAD
Cohérence.
1: *> \brief \b ZTRSV
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: * Definition:
9: * ===========
10: *
11: * SUBROUTINE ZTRSV(UPLO,TRANS,DIAG,N,A,LDA,X,INCX)
12: *
13: * .. Scalar Arguments ..
14: * INTEGER INCX,LDA,N
15: * CHARACTER DIAG,TRANS,UPLO
16: * ..
17: * .. Array Arguments ..
18: * COMPLEX*16 A(LDA,*),X(*)
19: * ..
20: *
21: *
22: *> \par Purpose:
23: * =============
24: *>
25: *> \verbatim
26: *>
27: *> ZTRSV solves one of the systems of equations
28: *>
29: *> A*x = b, or A**T*x = b, or A**H*x = b,
30: *>
31: *> where b and x are n element vectors and A is an n by n unit, or
32: *> non-unit, upper or lower triangular matrix.
33: *>
34: *> No test for singularity or near-singularity is included in this
35: *> routine. Such tests must be performed before calling this routine.
36: *> \endverbatim
37: *
38: * Arguments:
39: * ==========
40: *
41: *> \param[in] UPLO
42: *> \verbatim
43: *> UPLO is CHARACTER*1
44: *> On entry, UPLO specifies whether the matrix is an upper or
45: *> lower triangular matrix as follows:
46: *>
47: *> UPLO = 'U' or 'u' A is an upper triangular matrix.
48: *>
49: *> UPLO = 'L' or 'l' A is a lower triangular matrix.
50: *> \endverbatim
51: *>
52: *> \param[in] TRANS
53: *> \verbatim
54: *> TRANS is CHARACTER*1
55: *> On entry, TRANS specifies the equations to be solved as
56: *> follows:
57: *>
58: *> TRANS = 'N' or 'n' A*x = b.
59: *>
60: *> TRANS = 'T' or 't' A**T*x = b.
61: *>
62: *> TRANS = 'C' or 'c' A**H*x = b.
63: *> \endverbatim
64: *>
65: *> \param[in] DIAG
66: *> \verbatim
67: *> DIAG is CHARACTER*1
68: *> On entry, DIAG specifies whether or not A is unit
69: *> triangular as follows:
70: *>
71: *> DIAG = 'U' or 'u' A is assumed to be unit triangular.
72: *>
73: *> DIAG = 'N' or 'n' A is not assumed to be unit
74: *> triangular.
75: *> \endverbatim
76: *>
77: *> \param[in] N
78: *> \verbatim
79: *> N is INTEGER
80: *> On entry, N specifies the order of the matrix A.
81: *> N must be at least zero.
82: *> \endverbatim
83: *>
84: *> \param[in] A
85: *> \verbatim
86: *> A is COMPLEX*16 array of DIMENSION ( LDA, n ).
87: *> Before entry with UPLO = 'U' or 'u', the leading n by n
88: *> upper triangular part of the array A must contain the upper
89: *> triangular matrix and the strictly lower triangular part of
90: *> A is not referenced.
91: *> Before entry with UPLO = 'L' or 'l', the leading n by n
92: *> lower triangular part of the array A must contain the lower
93: *> triangular matrix and the strictly upper triangular part of
94: *> A is not referenced.
95: *> Note that when DIAG = 'U' or 'u', the diagonal elements of
96: *> A are not referenced either, but are assumed to be unity.
97: *> \endverbatim
98: *>
99: *> \param[in] LDA
100: *> \verbatim
101: *> LDA is INTEGER
102: *> On entry, LDA specifies the first dimension of A as declared
103: *> in the calling (sub) program. LDA must be at least
104: *> max( 1, n ).
105: *> \endverbatim
106: *>
107: *> \param[in,out] X
108: *> \verbatim
109: *> X is COMPLEX*16 array of dimension at least
110: *> ( 1 + ( n - 1 )*abs( INCX ) ).
111: *> Before entry, the incremented array X must contain the n
112: *> element right-hand side vector b. On exit, X is overwritten
113: *> with the solution vector x.
114: *> \endverbatim
115: *>
116: *> \param[in] INCX
117: *> \verbatim
118: *> INCX is INTEGER
119: *> On entry, INCX specifies the increment for the elements of
120: *> X. INCX must not be zero.
121: *> \endverbatim
122: *
123: * Authors:
124: * ========
125: *
126: *> \author Univ. of Tennessee
127: *> \author Univ. of California Berkeley
128: *> \author Univ. of Colorado Denver
129: *> \author NAG Ltd.
130: *
131: *> \date November 2011
132: *
133: *> \ingroup complex16_blas_level2
134: *
135: *> \par Further Details:
136: * =====================
137: *>
138: *> \verbatim
139: *>
140: *> Level 2 Blas routine.
141: *>
142: *> -- Written on 22-October-1986.
143: *> Jack Dongarra, Argonne National Lab.
144: *> Jeremy Du Croz, Nag Central Office.
145: *> Sven Hammarling, Nag Central Office.
146: *> Richard Hanson, Sandia National Labs.
147: *> \endverbatim
148: *>
149: * =====================================================================
150: SUBROUTINE ZTRSV(UPLO,TRANS,DIAG,N,A,LDA,X,INCX)
151: *
152: * -- Reference BLAS level2 routine (version 3.4.0) --
153: * -- Reference BLAS is a software package provided by Univ. of Tennessee, --
154: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
155: * November 2011
156: *
157: * .. Scalar Arguments ..
158: INTEGER INCX,LDA,N
159: CHARACTER DIAG,TRANS,UPLO
160: * ..
161: * .. Array Arguments ..
162: COMPLEX*16 A(LDA,*),X(*)
163: * ..
164: *
165: * =====================================================================
166: *
167: * .. Parameters ..
168: COMPLEX*16 ZERO
169: PARAMETER (ZERO= (0.0D+0,0.0D+0))
170: * ..
171: * .. Local Scalars ..
172: COMPLEX*16 TEMP
173: INTEGER I,INFO,IX,J,JX,KX
174: LOGICAL NOCONJ,NOUNIT
175: * ..
176: * .. External Functions ..
177: LOGICAL LSAME
178: EXTERNAL LSAME
179: * ..
180: * .. External Subroutines ..
181: EXTERNAL XERBLA
182: * ..
183: * .. Intrinsic Functions ..
184: INTRINSIC DCONJG,MAX
185: * ..
186: *
187: * Test the input parameters.
188: *
189: INFO = 0
190: IF (.NOT.LSAME(UPLO,'U') .AND. .NOT.LSAME(UPLO,'L')) THEN
191: INFO = 1
192: ELSE IF (.NOT.LSAME(TRANS,'N') .AND. .NOT.LSAME(TRANS,'T') .AND.
193: + .NOT.LSAME(TRANS,'C')) THEN
194: INFO = 2
195: ELSE IF (.NOT.LSAME(DIAG,'U') .AND. .NOT.LSAME(DIAG,'N')) THEN
196: INFO = 3
197: ELSE IF (N.LT.0) THEN
198: INFO = 4
199: ELSE IF (LDA.LT.MAX(1,N)) THEN
200: INFO = 6
201: ELSE IF (INCX.EQ.0) THEN
202: INFO = 8
203: END IF
204: IF (INFO.NE.0) THEN
205: CALL XERBLA('ZTRSV ',INFO)
206: RETURN
207: END IF
208: *
209: * Quick return if possible.
210: *
211: IF (N.EQ.0) RETURN
212: *
213: NOCONJ = LSAME(TRANS,'T')
214: NOUNIT = LSAME(DIAG,'N')
215: *
216: * Set up the start point in X if the increment is not unity. This
217: * will be ( N - 1 )*INCX too small for descending loops.
218: *
219: IF (INCX.LE.0) THEN
220: KX = 1 - (N-1)*INCX
221: ELSE IF (INCX.NE.1) THEN
222: KX = 1
223: END IF
224: *
225: * Start the operations. In this version the elements of A are
226: * accessed sequentially with one pass through A.
227: *
228: IF (LSAME(TRANS,'N')) THEN
229: *
230: * Form x := inv( A )*x.
231: *
232: IF (LSAME(UPLO,'U')) THEN
233: IF (INCX.EQ.1) THEN
234: DO 20 J = N,1,-1
235: IF (X(J).NE.ZERO) THEN
236: IF (NOUNIT) X(J) = X(J)/A(J,J)
237: TEMP = X(J)
238: DO 10 I = J - 1,1,-1
239: X(I) = X(I) - TEMP*A(I,J)
240: 10 CONTINUE
241: END IF
242: 20 CONTINUE
243: ELSE
244: JX = KX + (N-1)*INCX
245: DO 40 J = N,1,-1
246: IF (X(JX).NE.ZERO) THEN
247: IF (NOUNIT) X(JX) = X(JX)/A(J,J)
248: TEMP = X(JX)
249: IX = JX
250: DO 30 I = J - 1,1,-1
251: IX = IX - INCX
252: X(IX) = X(IX) - TEMP*A(I,J)
253: 30 CONTINUE
254: END IF
255: JX = JX - INCX
256: 40 CONTINUE
257: END IF
258: ELSE
259: IF (INCX.EQ.1) THEN
260: DO 60 J = 1,N
261: IF (X(J).NE.ZERO) THEN
262: IF (NOUNIT) X(J) = X(J)/A(J,J)
263: TEMP = X(J)
264: DO 50 I = J + 1,N
265: X(I) = X(I) - TEMP*A(I,J)
266: 50 CONTINUE
267: END IF
268: 60 CONTINUE
269: ELSE
270: JX = KX
271: DO 80 J = 1,N
272: IF (X(JX).NE.ZERO) THEN
273: IF (NOUNIT) X(JX) = X(JX)/A(J,J)
274: TEMP = X(JX)
275: IX = JX
276: DO 70 I = J + 1,N
277: IX = IX + INCX
278: X(IX) = X(IX) - TEMP*A(I,J)
279: 70 CONTINUE
280: END IF
281: JX = JX + INCX
282: 80 CONTINUE
283: END IF
284: END IF
285: ELSE
286: *
287: * Form x := inv( A**T )*x or x := inv( A**H )*x.
288: *
289: IF (LSAME(UPLO,'U')) THEN
290: IF (INCX.EQ.1) THEN
291: DO 110 J = 1,N
292: TEMP = X(J)
293: IF (NOCONJ) THEN
294: DO 90 I = 1,J - 1
295: TEMP = TEMP - A(I,J)*X(I)
296: 90 CONTINUE
297: IF (NOUNIT) TEMP = TEMP/A(J,J)
298: ELSE
299: DO 100 I = 1,J - 1
300: TEMP = TEMP - DCONJG(A(I,J))*X(I)
301: 100 CONTINUE
302: IF (NOUNIT) TEMP = TEMP/DCONJG(A(J,J))
303: END IF
304: X(J) = TEMP
305: 110 CONTINUE
306: ELSE
307: JX = KX
308: DO 140 J = 1,N
309: IX = KX
310: TEMP = X(JX)
311: IF (NOCONJ) THEN
312: DO 120 I = 1,J - 1
313: TEMP = TEMP - A(I,J)*X(IX)
314: IX = IX + INCX
315: 120 CONTINUE
316: IF (NOUNIT) TEMP = TEMP/A(J,J)
317: ELSE
318: DO 130 I = 1,J - 1
319: TEMP = TEMP - DCONJG(A(I,J))*X(IX)
320: IX = IX + INCX
321: 130 CONTINUE
322: IF (NOUNIT) TEMP = TEMP/DCONJG(A(J,J))
323: END IF
324: X(JX) = TEMP
325: JX = JX + INCX
326: 140 CONTINUE
327: END IF
328: ELSE
329: IF (INCX.EQ.1) THEN
330: DO 170 J = N,1,-1
331: TEMP = X(J)
332: IF (NOCONJ) THEN
333: DO 150 I = N,J + 1,-1
334: TEMP = TEMP - A(I,J)*X(I)
335: 150 CONTINUE
336: IF (NOUNIT) TEMP = TEMP/A(J,J)
337: ELSE
338: DO 160 I = N,J + 1,-1
339: TEMP = TEMP - DCONJG(A(I,J))*X(I)
340: 160 CONTINUE
341: IF (NOUNIT) TEMP = TEMP/DCONJG(A(J,J))
342: END IF
343: X(J) = TEMP
344: 170 CONTINUE
345: ELSE
346: KX = KX + (N-1)*INCX
347: JX = KX
348: DO 200 J = N,1,-1
349: IX = KX
350: TEMP = X(JX)
351: IF (NOCONJ) THEN
352: DO 180 I = N,J + 1,-1
353: TEMP = TEMP - A(I,J)*X(IX)
354: IX = IX - INCX
355: 180 CONTINUE
356: IF (NOUNIT) TEMP = TEMP/A(J,J)
357: ELSE
358: DO 190 I = N,J + 1,-1
359: TEMP = TEMP - DCONJG(A(I,J))*X(IX)
360: IX = IX - INCX
361: 190 CONTINUE
362: IF (NOUNIT) TEMP = TEMP/DCONJG(A(J,J))
363: END IF
364: X(JX) = TEMP
365: JX = JX - INCX
366: 200 CONTINUE
367: END IF
368: END IF
369: END IF
370: *
371: RETURN
372: *
373: * End of ZTRSV .
374: *
375: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to ztrsv.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / blas