1: SUBROUTINE ZTRMV(UPLO,TRANS,DIAG,N,A,LDA,X,INCX)
2: * .. Scalar Arguments ..
3: INTEGER INCX,LDA,N
4: CHARACTER DIAG,TRANS,UPLO
5: * ..
6: * .. Array Arguments ..
7: DOUBLE COMPLEX A(LDA,*),X(*)
8: * ..
9: *
10: * Purpose
11: * =======
12: *
13: * ZTRMV performs one of the matrix-vector operations
14: *
15: * x := A*x, or x := A'*x, or x := conjg( A' )*x,
16: *
17: * where x is an n element vector and A is an n by n unit, or non-unit,
18: * upper or lower triangular matrix.
19: *
20: * Arguments
21: * ==========
22: *
23: * UPLO - CHARACTER*1.
24: * On entry, UPLO specifies whether the matrix is an upper or
25: * lower triangular matrix as follows:
26: *
27: * UPLO = 'U' or 'u' A is an upper triangular matrix.
28: *
29: * UPLO = 'L' or 'l' A is a lower triangular matrix.
30: *
31: * Unchanged on exit.
32: *
33: * TRANS - CHARACTER*1.
34: * On entry, TRANS specifies the operation to be performed as
35: * follows:
36: *
37: * TRANS = 'N' or 'n' x := A*x.
38: *
39: * TRANS = 'T' or 't' x := A'*x.
40: *
41: * TRANS = 'C' or 'c' x := conjg( A' )*x.
42: *
43: * Unchanged on exit.
44: *
45: * DIAG - CHARACTER*1.
46: * On entry, DIAG specifies whether or not A is unit
47: * triangular as follows:
48: *
49: * DIAG = 'U' or 'u' A is assumed to be unit triangular.
50: *
51: * DIAG = 'N' or 'n' A is not assumed to be unit
52: * triangular.
53: *
54: * Unchanged on exit.
55: *
56: * N - INTEGER.
57: * On entry, N specifies the order of the matrix A.
58: * N must be at least zero.
59: * Unchanged on exit.
60: *
61: * A - COMPLEX*16 array of DIMENSION ( LDA, n ).
62: * Before entry with UPLO = 'U' or 'u', the leading n by n
63: * upper triangular part of the array A must contain the upper
64: * triangular matrix and the strictly lower triangular part of
65: * A is not referenced.
66: * Before entry with UPLO = 'L' or 'l', the leading n by n
67: * lower triangular part of the array A must contain the lower
68: * triangular matrix and the strictly upper triangular part of
69: * A is not referenced.
70: * Note that when DIAG = 'U' or 'u', the diagonal elements of
71: * A are not referenced either, but are assumed to be unity.
72: * Unchanged on exit.
73: *
74: * LDA - INTEGER.
75: * On entry, LDA specifies the first dimension of A as declared
76: * in the calling (sub) program. LDA must be at least
77: * max( 1, n ).
78: * Unchanged on exit.
79: *
80: * X - COMPLEX*16 array of dimension at least
81: * ( 1 + ( n - 1 )*abs( INCX ) ).
82: * Before entry, the incremented array X must contain the n
83: * element vector x. On exit, X is overwritten with the
84: * tranformed vector x.
85: *
86: * INCX - INTEGER.
87: * On entry, INCX specifies the increment for the elements of
88: * X. INCX must not be zero.
89: * Unchanged on exit.
90: *
91: * Further Details
92: * ===============
93: *
94: * Level 2 Blas routine.
95: *
96: * -- Written on 22-October-1986.
97: * Jack Dongarra, Argonne National Lab.
98: * Jeremy Du Croz, Nag Central Office.
99: * Sven Hammarling, Nag Central Office.
100: * Richard Hanson, Sandia National Labs.
101: *
102: * =====================================================================
103: *
104: * .. Parameters ..
105: DOUBLE COMPLEX ZERO
106: PARAMETER (ZERO= (0.0D+0,0.0D+0))
107: * ..
108: * .. Local Scalars ..
109: DOUBLE COMPLEX TEMP
110: INTEGER I,INFO,IX,J,JX,KX
111: LOGICAL NOCONJ,NOUNIT
112: * ..
113: * .. External Functions ..
114: LOGICAL LSAME
115: EXTERNAL LSAME
116: * ..
117: * .. External Subroutines ..
118: EXTERNAL XERBLA
119: * ..
120: * .. Intrinsic Functions ..
121: INTRINSIC DCONJG,MAX
122: * ..
123: *
124: * Test the input parameters.
125: *
126: INFO = 0
127: IF (.NOT.LSAME(UPLO,'U') .AND. .NOT.LSAME(UPLO,'L')) THEN
128: INFO = 1
129: ELSE IF (.NOT.LSAME(TRANS,'N') .AND. .NOT.LSAME(TRANS,'T') .AND.
130: + .NOT.LSAME(TRANS,'C')) THEN
131: INFO = 2
132: ELSE IF (.NOT.LSAME(DIAG,'U') .AND. .NOT.LSAME(DIAG,'N')) THEN
133: INFO = 3
134: ELSE IF (N.LT.0) THEN
135: INFO = 4
136: ELSE IF (LDA.LT.MAX(1,N)) THEN
137: INFO = 6
138: ELSE IF (INCX.EQ.0) THEN
139: INFO = 8
140: END IF
141: IF (INFO.NE.0) THEN
142: CALL XERBLA('ZTRMV ',INFO)
143: RETURN
144: END IF
145: *
146: * Quick return if possible.
147: *
148: IF (N.EQ.0) RETURN
149: *
150: NOCONJ = LSAME(TRANS,'T')
151: NOUNIT = LSAME(DIAG,'N')
152: *
153: * Set up the start point in X if the increment is not unity. This
154: * will be ( N - 1 )*INCX too small for descending loops.
155: *
156: IF (INCX.LE.0) THEN
157: KX = 1 - (N-1)*INCX
158: ELSE IF (INCX.NE.1) THEN
159: KX = 1
160: END IF
161: *
162: * Start the operations. In this version the elements of A are
163: * accessed sequentially with one pass through A.
164: *
165: IF (LSAME(TRANS,'N')) THEN
166: *
167: * Form x := A*x.
168: *
169: IF (LSAME(UPLO,'U')) THEN
170: IF (INCX.EQ.1) THEN
171: DO 20 J = 1,N
172: IF (X(J).NE.ZERO) THEN
173: TEMP = X(J)
174: DO 10 I = 1,J - 1
175: X(I) = X(I) + TEMP*A(I,J)
176: 10 CONTINUE
177: IF (NOUNIT) X(J) = X(J)*A(J,J)
178: END IF
179: 20 CONTINUE
180: ELSE
181: JX = KX
182: DO 40 J = 1,N
183: IF (X(JX).NE.ZERO) THEN
184: TEMP = X(JX)
185: IX = KX
186: DO 30 I = 1,J - 1
187: X(IX) = X(IX) + TEMP*A(I,J)
188: IX = IX + INCX
189: 30 CONTINUE
190: IF (NOUNIT) X(JX) = X(JX)*A(J,J)
191: END IF
192: JX = JX + INCX
193: 40 CONTINUE
194: END IF
195: ELSE
196: IF (INCX.EQ.1) THEN
197: DO 60 J = N,1,-1
198: IF (X(J).NE.ZERO) THEN
199: TEMP = X(J)
200: DO 50 I = N,J + 1,-1
201: X(I) = X(I) + TEMP*A(I,J)
202: 50 CONTINUE
203: IF (NOUNIT) X(J) = X(J)*A(J,J)
204: END IF
205: 60 CONTINUE
206: ELSE
207: KX = KX + (N-1)*INCX
208: JX = KX
209: DO 80 J = N,1,-1
210: IF (X(JX).NE.ZERO) THEN
211: TEMP = X(JX)
212: IX = KX
213: DO 70 I = N,J + 1,-1
214: X(IX) = X(IX) + TEMP*A(I,J)
215: IX = IX - INCX
216: 70 CONTINUE
217: IF (NOUNIT) X(JX) = X(JX)*A(J,J)
218: END IF
219: JX = JX - INCX
220: 80 CONTINUE
221: END IF
222: END IF
223: ELSE
224: *
225: * Form x := A'*x or x := conjg( A' )*x.
226: *
227: IF (LSAME(UPLO,'U')) THEN
228: IF (INCX.EQ.1) THEN
229: DO 110 J = N,1,-1
230: TEMP = X(J)
231: IF (NOCONJ) THEN
232: IF (NOUNIT) TEMP = TEMP*A(J,J)
233: DO 90 I = J - 1,1,-1
234: TEMP = TEMP + A(I,J)*X(I)
235: 90 CONTINUE
236: ELSE
237: IF (NOUNIT) TEMP = TEMP*DCONJG(A(J,J))
238: DO 100 I = J - 1,1,-1
239: TEMP = TEMP + DCONJG(A(I,J))*X(I)
240: 100 CONTINUE
241: END IF
242: X(J) = TEMP
243: 110 CONTINUE
244: ELSE
245: JX = KX + (N-1)*INCX
246: DO 140 J = N,1,-1
247: TEMP = X(JX)
248: IX = JX
249: IF (NOCONJ) THEN
250: IF (NOUNIT) TEMP = TEMP*A(J,J)
251: DO 120 I = J - 1,1,-1
252: IX = IX - INCX
253: TEMP = TEMP + A(I,J)*X(IX)
254: 120 CONTINUE
255: ELSE
256: IF (NOUNIT) TEMP = TEMP*DCONJG(A(J,J))
257: DO 130 I = J - 1,1,-1
258: IX = IX - INCX
259: TEMP = TEMP + DCONJG(A(I,J))*X(IX)
260: 130 CONTINUE
261: END IF
262: X(JX) = TEMP
263: JX = JX - INCX
264: 140 CONTINUE
265: END IF
266: ELSE
267: IF (INCX.EQ.1) THEN
268: DO 170 J = 1,N
269: TEMP = X(J)
270: IF (NOCONJ) THEN
271: IF (NOUNIT) TEMP = TEMP*A(J,J)
272: DO 150 I = J + 1,N
273: TEMP = TEMP + A(I,J)*X(I)
274: 150 CONTINUE
275: ELSE
276: IF (NOUNIT) TEMP = TEMP*DCONJG(A(J,J))
277: DO 160 I = J + 1,N
278: TEMP = TEMP + DCONJG(A(I,J))*X(I)
279: 160 CONTINUE
280: END IF
281: X(J) = TEMP
282: 170 CONTINUE
283: ELSE
284: JX = KX
285: DO 200 J = 1,N
286: TEMP = X(JX)
287: IX = JX
288: IF (NOCONJ) THEN
289: IF (NOUNIT) TEMP = TEMP*A(J,J)
290: DO 180 I = J + 1,N
291: IX = IX + INCX
292: TEMP = TEMP + A(I,J)*X(IX)
293: 180 CONTINUE
294: ELSE
295: IF (NOUNIT) TEMP = TEMP*DCONJG(A(J,J))
296: DO 190 I = J + 1,N
297: IX = IX + INCX
298: TEMP = TEMP + DCONJG(A(I,J))*X(IX)
299: 190 CONTINUE
300: END IF
301: X(JX) = TEMP
302: JX = JX + INCX
303: 200 CONTINUE
304: END IF
305: END IF
306: END IF
307: *
308: RETURN
309: *
310: * End of ZTRMV .
311: *
312: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to ztrmv.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / blas