1: *> \brief \b ZTRMM
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: * Definition:
9: * ===========
10: *
11: * SUBROUTINE ZTRMM(SIDE,UPLO,TRANSA,DIAG,M,N,ALPHA,A,LDA,B,LDB)
12: *
13: * .. Scalar Arguments ..
14: * COMPLEX*16 ALPHA
15: * INTEGER LDA,LDB,M,N
16: * CHARACTER DIAG,SIDE,TRANSA,UPLO
17: * ..
18: * .. Array Arguments ..
19: * COMPLEX*16 A(LDA,*),B(LDB,*)
20: * ..
21: *
22: *
23: *> \par Purpose:
24: * =============
25: *>
26: *> \verbatim
27: *>
28: *> ZTRMM performs one of the matrix-matrix operations
29: *>
30: *> B := alpha*op( A )*B, or B := alpha*B*op( A )
31: *>
32: *> where alpha is a scalar, B is an m by n matrix, A is a unit, or
33: *> non-unit, upper or lower triangular matrix and op( A ) is one of
34: *>
35: *> op( A ) = A or op( A ) = A**T or op( A ) = A**H.
36: *> \endverbatim
37: *
38: * Arguments:
39: * ==========
40: *
41: *> \param[in] SIDE
42: *> \verbatim
43: *> SIDE is CHARACTER*1
44: *> On entry, SIDE specifies whether op( A ) multiplies B from
45: *> the left or right as follows:
46: *>
47: *> SIDE = 'L' or 'l' B := alpha*op( A )*B.
48: *>
49: *> SIDE = 'R' or 'r' B := alpha*B*op( A ).
50: *> \endverbatim
51: *>
52: *> \param[in] UPLO
53: *> \verbatim
54: *> UPLO is CHARACTER*1
55: *> On entry, UPLO specifies whether the matrix A is an upper or
56: *> lower triangular matrix as follows:
57: *>
58: *> UPLO = 'U' or 'u' A is an upper triangular matrix.
59: *>
60: *> UPLO = 'L' or 'l' A is a lower triangular matrix.
61: *> \endverbatim
62: *>
63: *> \param[in] TRANSA
64: *> \verbatim
65: *> TRANSA is CHARACTER*1
66: *> On entry, TRANSA specifies the form of op( A ) to be used in
67: *> the matrix multiplication as follows:
68: *>
69: *> TRANSA = 'N' or 'n' op( A ) = A.
70: *>
71: *> TRANSA = 'T' or 't' op( A ) = A**T.
72: *>
73: *> TRANSA = 'C' or 'c' op( A ) = A**H.
74: *> \endverbatim
75: *>
76: *> \param[in] DIAG
77: *> \verbatim
78: *> DIAG is CHARACTER*1
79: *> On entry, DIAG specifies whether or not A is unit triangular
80: *> as follows:
81: *>
82: *> DIAG = 'U' or 'u' A is assumed to be unit triangular.
83: *>
84: *> DIAG = 'N' or 'n' A is not assumed to be unit
85: *> triangular.
86: *> \endverbatim
87: *>
88: *> \param[in] M
89: *> \verbatim
90: *> M is INTEGER
91: *> On entry, M specifies the number of rows of B. M must be at
92: *> least zero.
93: *> \endverbatim
94: *>
95: *> \param[in] N
96: *> \verbatim
97: *> N is INTEGER
98: *> On entry, N specifies the number of columns of B. N must be
99: *> at least zero.
100: *> \endverbatim
101: *>
102: *> \param[in] ALPHA
103: *> \verbatim
104: *> ALPHA is COMPLEX*16
105: *> On entry, ALPHA specifies the scalar alpha. When alpha is
106: *> zero then A is not referenced and B need not be set before
107: *> entry.
108: *> \endverbatim
109: *>
110: *> \param[in] A
111: *> \verbatim
112: *> A is COMPLEX*16 array, dimension ( LDA, k ), where k is m
113: *> when SIDE = 'L' or 'l' and is n when SIDE = 'R' or 'r'.
114: *> Before entry with UPLO = 'U' or 'u', the leading k by k
115: *> upper triangular part of the array A must contain the upper
116: *> triangular matrix and the strictly lower triangular part of
117: *> A is not referenced.
118: *> Before entry with UPLO = 'L' or 'l', the leading k by k
119: *> lower triangular part of the array A must contain the lower
120: *> triangular matrix and the strictly upper triangular part of
121: *> A is not referenced.
122: *> Note that when DIAG = 'U' or 'u', the diagonal elements of
123: *> A are not referenced either, but are assumed to be unity.
124: *> \endverbatim
125: *>
126: *> \param[in] LDA
127: *> \verbatim
128: *> LDA is INTEGER
129: *> On entry, LDA specifies the first dimension of A as declared
130: *> in the calling (sub) program. When SIDE = 'L' or 'l' then
131: *> LDA must be at least max( 1, m ), when SIDE = 'R' or 'r'
132: *> then LDA must be at least max( 1, n ).
133: *> \endverbatim
134: *>
135: *> \param[in,out] B
136: *> \verbatim
137: *> B is COMPLEX*16 array, dimension ( LDB, N ).
138: *> Before entry, the leading m by n part of the array B must
139: *> contain the matrix B, and on exit is overwritten by the
140: *> transformed matrix.
141: *> \endverbatim
142: *>
143: *> \param[in] LDB
144: *> \verbatim
145: *> LDB is INTEGER
146: *> On entry, LDB specifies the first dimension of B as declared
147: *> in the calling (sub) program. LDB must be at least
148: *> max( 1, m ).
149: *> \endverbatim
150: *
151: * Authors:
152: * ========
153: *
154: *> \author Univ. of Tennessee
155: *> \author Univ. of California Berkeley
156: *> \author Univ. of Colorado Denver
157: *> \author NAG Ltd.
158: *
159: *> \ingroup complex16_blas_level3
160: *
161: *> \par Further Details:
162: * =====================
163: *>
164: *> \verbatim
165: *>
166: *> Level 3 Blas routine.
167: *>
168: *> -- Written on 8-February-1989.
169: *> Jack Dongarra, Argonne National Laboratory.
170: *> Iain Duff, AERE Harwell.
171: *> Jeremy Du Croz, Numerical Algorithms Group Ltd.
172: *> Sven Hammarling, Numerical Algorithms Group Ltd.
173: *> \endverbatim
174: *>
175: * =====================================================================
176: SUBROUTINE ZTRMM(SIDE,UPLO,TRANSA,DIAG,M,N,ALPHA,A,LDA,B,LDB)
177: *
178: * -- Reference BLAS level3 routine --
179: * -- Reference BLAS is a software package provided by Univ. of Tennessee, --
180: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
181: *
182: * .. Scalar Arguments ..
183: COMPLEX*16 ALPHA
184: INTEGER LDA,LDB,M,N
185: CHARACTER DIAG,SIDE,TRANSA,UPLO
186: * ..
187: * .. Array Arguments ..
188: COMPLEX*16 A(LDA,*),B(LDB,*)
189: * ..
190: *
191: * =====================================================================
192: *
193: * .. External Functions ..
194: LOGICAL LSAME
195: EXTERNAL LSAME
196: * ..
197: * .. External Subroutines ..
198: EXTERNAL XERBLA
199: * ..
200: * .. Intrinsic Functions ..
201: INTRINSIC DCONJG,MAX
202: * ..
203: * .. Local Scalars ..
204: COMPLEX*16 TEMP
205: INTEGER I,INFO,J,K,NROWA
206: LOGICAL LSIDE,NOCONJ,NOUNIT,UPPER
207: * ..
208: * .. Parameters ..
209: COMPLEX*16 ONE
210: PARAMETER (ONE= (1.0D+0,0.0D+0))
211: COMPLEX*16 ZERO
212: PARAMETER (ZERO= (0.0D+0,0.0D+0))
213: * ..
214: *
215: * Test the input parameters.
216: *
217: LSIDE = LSAME(SIDE,'L')
218: IF (LSIDE) THEN
219: NROWA = M
220: ELSE
221: NROWA = N
222: END IF
223: NOCONJ = LSAME(TRANSA,'T')
224: NOUNIT = LSAME(DIAG,'N')
225: UPPER = LSAME(UPLO,'U')
226: *
227: INFO = 0
228: IF ((.NOT.LSIDE) .AND. (.NOT.LSAME(SIDE,'R'))) THEN
229: INFO = 1
230: ELSE IF ((.NOT.UPPER) .AND. (.NOT.LSAME(UPLO,'L'))) THEN
231: INFO = 2
232: ELSE IF ((.NOT.LSAME(TRANSA,'N')) .AND.
233: + (.NOT.LSAME(TRANSA,'T')) .AND.
234: + (.NOT.LSAME(TRANSA,'C'))) THEN
235: INFO = 3
236: ELSE IF ((.NOT.LSAME(DIAG,'U')) .AND. (.NOT.LSAME(DIAG,'N'))) THEN
237: INFO = 4
238: ELSE IF (M.LT.0) THEN
239: INFO = 5
240: ELSE IF (N.LT.0) THEN
241: INFO = 6
242: ELSE IF (LDA.LT.MAX(1,NROWA)) THEN
243: INFO = 9
244: ELSE IF (LDB.LT.MAX(1,M)) THEN
245: INFO = 11
246: END IF
247: IF (INFO.NE.0) THEN
248: CALL XERBLA('ZTRMM ',INFO)
249: RETURN
250: END IF
251: *
252: * Quick return if possible.
253: *
254: IF (M.EQ.0 .OR. N.EQ.0) RETURN
255: *
256: * And when alpha.eq.zero.
257: *
258: IF (ALPHA.EQ.ZERO) THEN
259: DO 20 J = 1,N
260: DO 10 I = 1,M
261: B(I,J) = ZERO
262: 10 CONTINUE
263: 20 CONTINUE
264: RETURN
265: END IF
266: *
267: * Start the operations.
268: *
269: IF (LSIDE) THEN
270: IF (LSAME(TRANSA,'N')) THEN
271: *
272: * Form B := alpha*A*B.
273: *
274: IF (UPPER) THEN
275: DO 50 J = 1,N
276: DO 40 K = 1,M
277: IF (B(K,J).NE.ZERO) THEN
278: TEMP = ALPHA*B(K,J)
279: DO 30 I = 1,K - 1
280: B(I,J) = B(I,J) + TEMP*A(I,K)
281: 30 CONTINUE
282: IF (NOUNIT) TEMP = TEMP*A(K,K)
283: B(K,J) = TEMP
284: END IF
285: 40 CONTINUE
286: 50 CONTINUE
287: ELSE
288: DO 80 J = 1,N
289: DO 70 K = M,1,-1
290: IF (B(K,J).NE.ZERO) THEN
291: TEMP = ALPHA*B(K,J)
292: B(K,J) = TEMP
293: IF (NOUNIT) B(K,J) = B(K,J)*A(K,K)
294: DO 60 I = K + 1,M
295: B(I,J) = B(I,J) + TEMP*A(I,K)
296: 60 CONTINUE
297: END IF
298: 70 CONTINUE
299: 80 CONTINUE
300: END IF
301: ELSE
302: *
303: * Form B := alpha*A**T*B or B := alpha*A**H*B.
304: *
305: IF (UPPER) THEN
306: DO 120 J = 1,N
307: DO 110 I = M,1,-1
308: TEMP = B(I,J)
309: IF (NOCONJ) THEN
310: IF (NOUNIT) TEMP = TEMP*A(I,I)
311: DO 90 K = 1,I - 1
312: TEMP = TEMP + A(K,I)*B(K,J)
313: 90 CONTINUE
314: ELSE
315: IF (NOUNIT) TEMP = TEMP*DCONJG(A(I,I))
316: DO 100 K = 1,I - 1
317: TEMP = TEMP + DCONJG(A(K,I))*B(K,J)
318: 100 CONTINUE
319: END IF
320: B(I,J) = ALPHA*TEMP
321: 110 CONTINUE
322: 120 CONTINUE
323: ELSE
324: DO 160 J = 1,N
325: DO 150 I = 1,M
326: TEMP = B(I,J)
327: IF (NOCONJ) THEN
328: IF (NOUNIT) TEMP = TEMP*A(I,I)
329: DO 130 K = I + 1,M
330: TEMP = TEMP + A(K,I)*B(K,J)
331: 130 CONTINUE
332: ELSE
333: IF (NOUNIT) TEMP = TEMP*DCONJG(A(I,I))
334: DO 140 K = I + 1,M
335: TEMP = TEMP + DCONJG(A(K,I))*B(K,J)
336: 140 CONTINUE
337: END IF
338: B(I,J) = ALPHA*TEMP
339: 150 CONTINUE
340: 160 CONTINUE
341: END IF
342: END IF
343: ELSE
344: IF (LSAME(TRANSA,'N')) THEN
345: *
346: * Form B := alpha*B*A.
347: *
348: IF (UPPER) THEN
349: DO 200 J = N,1,-1
350: TEMP = ALPHA
351: IF (NOUNIT) TEMP = TEMP*A(J,J)
352: DO 170 I = 1,M
353: B(I,J) = TEMP*B(I,J)
354: 170 CONTINUE
355: DO 190 K = 1,J - 1
356: IF (A(K,J).NE.ZERO) THEN
357: TEMP = ALPHA*A(K,J)
358: DO 180 I = 1,M
359: B(I,J) = B(I,J) + TEMP*B(I,K)
360: 180 CONTINUE
361: END IF
362: 190 CONTINUE
363: 200 CONTINUE
364: ELSE
365: DO 240 J = 1,N
366: TEMP = ALPHA
367: IF (NOUNIT) TEMP = TEMP*A(J,J)
368: DO 210 I = 1,M
369: B(I,J) = TEMP*B(I,J)
370: 210 CONTINUE
371: DO 230 K = J + 1,N
372: IF (A(K,J).NE.ZERO) THEN
373: TEMP = ALPHA*A(K,J)
374: DO 220 I = 1,M
375: B(I,J) = B(I,J) + TEMP*B(I,K)
376: 220 CONTINUE
377: END IF
378: 230 CONTINUE
379: 240 CONTINUE
380: END IF
381: ELSE
382: *
383: * Form B := alpha*B*A**T or B := alpha*B*A**H.
384: *
385: IF (UPPER) THEN
386: DO 280 K = 1,N
387: DO 260 J = 1,K - 1
388: IF (A(J,K).NE.ZERO) THEN
389: IF (NOCONJ) THEN
390: TEMP = ALPHA*A(J,K)
391: ELSE
392: TEMP = ALPHA*DCONJG(A(J,K))
393: END IF
394: DO 250 I = 1,M
395: B(I,J) = B(I,J) + TEMP*B(I,K)
396: 250 CONTINUE
397: END IF
398: 260 CONTINUE
399: TEMP = ALPHA
400: IF (NOUNIT) THEN
401: IF (NOCONJ) THEN
402: TEMP = TEMP*A(K,K)
403: ELSE
404: TEMP = TEMP*DCONJG(A(K,K))
405: END IF
406: END IF
407: IF (TEMP.NE.ONE) THEN
408: DO 270 I = 1,M
409: B(I,K) = TEMP*B(I,K)
410: 270 CONTINUE
411: END IF
412: 280 CONTINUE
413: ELSE
414: DO 320 K = N,1,-1
415: DO 300 J = K + 1,N
416: IF (A(J,K).NE.ZERO) THEN
417: IF (NOCONJ) THEN
418: TEMP = ALPHA*A(J,K)
419: ELSE
420: TEMP = ALPHA*DCONJG(A(J,K))
421: END IF
422: DO 290 I = 1,M
423: B(I,J) = B(I,J) + TEMP*B(I,K)
424: 290 CONTINUE
425: END IF
426: 300 CONTINUE
427: TEMP = ALPHA
428: IF (NOUNIT) THEN
429: IF (NOCONJ) THEN
430: TEMP = TEMP*A(K,K)
431: ELSE
432: TEMP = TEMP*DCONJG(A(K,K))
433: END IF
434: END IF
435: IF (TEMP.NE.ONE) THEN
436: DO 310 I = 1,M
437: B(I,K) = TEMP*B(I,K)
438: 310 CONTINUE
439: END IF
440: 320 CONTINUE
441: END IF
442: END IF
443: END IF
444: *
445: RETURN
446: *
447: * End of ZTRMM
448: *
449: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to ztrmm.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / blas