1: *> \brief \b ZHER
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: * Definition:
9: * ===========
10: *
11: * SUBROUTINE ZHER(UPLO,N,ALPHA,X,INCX,A,LDA)
12: *
13: * .. Scalar Arguments ..
14: * DOUBLE PRECISION ALPHA
15: * INTEGER INCX,LDA,N
16: * CHARACTER UPLO
17: * ..
18: * .. Array Arguments ..
19: * COMPLEX*16 A(LDA,*),X(*)
20: * ..
21: *
22: *
23: *> \par Purpose:
24: * =============
25: *>
26: *> \verbatim
27: *>
28: *> ZHER performs the hermitian rank 1 operation
29: *>
30: *> A := alpha*x*x**H + A,
31: *>
32: *> where alpha is a real scalar, x is an n element vector and A is an
33: *> n by n hermitian matrix.
34: *> \endverbatim
35: *
36: * Arguments:
37: * ==========
38: *
39: *> \param[in] UPLO
40: *> \verbatim
41: *> UPLO is CHARACTER*1
42: *> On entry, UPLO specifies whether the upper or lower
43: *> triangular part of the array A is to be referenced as
44: *> follows:
45: *>
46: *> UPLO = 'U' or 'u' Only the upper triangular part of A
47: *> is to be referenced.
48: *>
49: *> UPLO = 'L' or 'l' Only the lower triangular part of A
50: *> is to be referenced.
51: *> \endverbatim
52: *>
53: *> \param[in] N
54: *> \verbatim
55: *> N is INTEGER
56: *> On entry, N specifies the order of the matrix A.
57: *> N must be at least zero.
58: *> \endverbatim
59: *>
60: *> \param[in] ALPHA
61: *> \verbatim
62: *> ALPHA is DOUBLE PRECISION.
63: *> On entry, ALPHA specifies the scalar alpha.
64: *> \endverbatim
65: *>
66: *> \param[in] X
67: *> \verbatim
68: *> X is COMPLEX*16 array, dimension at least
69: *> ( 1 + ( n - 1 )*abs( INCX ) ).
70: *> Before entry, the incremented array X must contain the n
71: *> element vector x.
72: *> \endverbatim
73: *>
74: *> \param[in] INCX
75: *> \verbatim
76: *> INCX is INTEGER
77: *> On entry, INCX specifies the increment for the elements of
78: *> X. INCX must not be zero.
79: *> \endverbatim
80: *>
81: *> \param[in,out] A
82: *> \verbatim
83: *> A is COMPLEX*16 array, dimension ( LDA, N )
84: *> Before entry with UPLO = 'U' or 'u', the leading n by n
85: *> upper triangular part of the array A must contain the upper
86: *> triangular part of the hermitian matrix and the strictly
87: *> lower triangular part of A is not referenced. On exit, the
88: *> upper triangular part of the array A is overwritten by the
89: *> upper triangular part of the updated matrix.
90: *> Before entry with UPLO = 'L' or 'l', the leading n by n
91: *> lower triangular part of the array A must contain the lower
92: *> triangular part of the hermitian matrix and the strictly
93: *> upper triangular part of A is not referenced. On exit, the
94: *> lower triangular part of the array A is overwritten by the
95: *> lower triangular part of the updated matrix.
96: *> Note that the imaginary parts of the diagonal elements need
97: *> not be set, they are assumed to be zero, and on exit they
98: *> are set to zero.
99: *> \endverbatim
100: *>
101: *> \param[in] LDA
102: *> \verbatim
103: *> LDA is INTEGER
104: *> On entry, LDA specifies the first dimension of A as declared
105: *> in the calling (sub) program. LDA must be at least
106: *> max( 1, n ).
107: *> \endverbatim
108: *
109: * Authors:
110: * ========
111: *
112: *> \author Univ. of Tennessee
113: *> \author Univ. of California Berkeley
114: *> \author Univ. of Colorado Denver
115: *> \author NAG Ltd.
116: *
117: *> \ingroup complex16_blas_level2
118: *
119: *> \par Further Details:
120: * =====================
121: *>
122: *> \verbatim
123: *>
124: *> Level 2 Blas routine.
125: *>
126: *> -- Written on 22-October-1986.
127: *> Jack Dongarra, Argonne National Lab.
128: *> Jeremy Du Croz, Nag Central Office.
129: *> Sven Hammarling, Nag Central Office.
130: *> Richard Hanson, Sandia National Labs.
131: *> \endverbatim
132: *>
133: * =====================================================================
134: SUBROUTINE ZHER(UPLO,N,ALPHA,X,INCX,A,LDA)
135: *
136: * -- Reference BLAS level2 routine --
137: * -- Reference BLAS is a software package provided by Univ. of Tennessee, --
138: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
139: *
140: * .. Scalar Arguments ..
141: DOUBLE PRECISION ALPHA
142: INTEGER INCX,LDA,N
143: CHARACTER UPLO
144: * ..
145: * .. Array Arguments ..
146: COMPLEX*16 A(LDA,*),X(*)
147: * ..
148: *
149: * =====================================================================
150: *
151: * .. Parameters ..
152: COMPLEX*16 ZERO
153: PARAMETER (ZERO= (0.0D+0,0.0D+0))
154: * ..
155: * .. Local Scalars ..
156: COMPLEX*16 TEMP
157: INTEGER I,INFO,IX,J,JX,KX
158: * ..
159: * .. External Functions ..
160: LOGICAL LSAME
161: EXTERNAL LSAME
162: * ..
163: * .. External Subroutines ..
164: EXTERNAL XERBLA
165: * ..
166: * .. Intrinsic Functions ..
167: INTRINSIC DBLE,DCONJG,MAX
168: * ..
169: *
170: * Test the input parameters.
171: *
172: INFO = 0
173: IF (.NOT.LSAME(UPLO,'U') .AND. .NOT.LSAME(UPLO,'L')) THEN
174: INFO = 1
175: ELSE IF (N.LT.0) THEN
176: INFO = 2
177: ELSE IF (INCX.EQ.0) THEN
178: INFO = 5
179: ELSE IF (LDA.LT.MAX(1,N)) THEN
180: INFO = 7
181: END IF
182: IF (INFO.NE.0) THEN
183: CALL XERBLA('ZHER ',INFO)
184: RETURN
185: END IF
186: *
187: * Quick return if possible.
188: *
189: IF ((N.EQ.0) .OR. (ALPHA.EQ.DBLE(ZERO))) RETURN
190: *
191: * Set the start point in X if the increment is not unity.
192: *
193: IF (INCX.LE.0) THEN
194: KX = 1 - (N-1)*INCX
195: ELSE IF (INCX.NE.1) THEN
196: KX = 1
197: END IF
198: *
199: * Start the operations. In this version the elements of A are
200: * accessed sequentially with one pass through the triangular part
201: * of A.
202: *
203: IF (LSAME(UPLO,'U')) THEN
204: *
205: * Form A when A is stored in upper triangle.
206: *
207: IF (INCX.EQ.1) THEN
208: DO 20 J = 1,N
209: IF (X(J).NE.ZERO) THEN
210: TEMP = ALPHA*DCONJG(X(J))
211: DO 10 I = 1,J - 1
212: A(I,J) = A(I,J) + X(I)*TEMP
213: 10 CONTINUE
214: A(J,J) = DBLE(A(J,J)) + DBLE(X(J)*TEMP)
215: ELSE
216: A(J,J) = DBLE(A(J,J))
217: END IF
218: 20 CONTINUE
219: ELSE
220: JX = KX
221: DO 40 J = 1,N
222: IF (X(JX).NE.ZERO) THEN
223: TEMP = ALPHA*DCONJG(X(JX))
224: IX = KX
225: DO 30 I = 1,J - 1
226: A(I,J) = A(I,J) + X(IX)*TEMP
227: IX = IX + INCX
228: 30 CONTINUE
229: A(J,J) = DBLE(A(J,J)) + DBLE(X(JX)*TEMP)
230: ELSE
231: A(J,J) = DBLE(A(J,J))
232: END IF
233: JX = JX + INCX
234: 40 CONTINUE
235: END IF
236: ELSE
237: *
238: * Form A when A is stored in lower triangle.
239: *
240: IF (INCX.EQ.1) THEN
241: DO 60 J = 1,N
242: IF (X(J).NE.ZERO) THEN
243: TEMP = ALPHA*DCONJG(X(J))
244: A(J,J) = DBLE(A(J,J)) + DBLE(TEMP*X(J))
245: DO 50 I = J + 1,N
246: A(I,J) = A(I,J) + X(I)*TEMP
247: 50 CONTINUE
248: ELSE
249: A(J,J) = DBLE(A(J,J))
250: END IF
251: 60 CONTINUE
252: ELSE
253: JX = KX
254: DO 80 J = 1,N
255: IF (X(JX).NE.ZERO) THEN
256: TEMP = ALPHA*DCONJG(X(JX))
257: A(J,J) = DBLE(A(J,J)) + DBLE(TEMP*X(JX))
258: IX = JX
259: DO 70 I = J + 1,N
260: IX = IX + INCX
261: A(I,J) = A(I,J) + X(IX)*TEMP
262: 70 CONTINUE
263: ELSE
264: A(J,J) = DBLE(A(J,J))
265: END IF
266: JX = JX + INCX
267: 80 CONTINUE
268: END IF
269: END IF
270: *
271: RETURN
272: *
273: * End of ZHER
274: *
275: END
CVSweb interface <joel.bertrand@systella.fr>