1: *> \brief \b ZDOTU
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: * Definition:
9: * ===========
10: *
11: * COMPLEX*16 FUNCTION ZDOTU(N,ZX,INCX,ZY,INCY)
12: *
13: * .. Scalar Arguments ..
14: * INTEGER INCX,INCY,N
15: * ..
16: * .. Array Arguments ..
17: * COMPLEX*16 ZX(*),ZY(*)
18: * ..
19: *
20: *
21: *> \par Purpose:
22: * =============
23: *>
24: *> \verbatim
25: *>
26: *> ZDOTU forms the dot product of two vectors.
27: *> \endverbatim
28: *
29: * Authors:
30: * ========
31: *
32: *> \author Univ. of Tennessee
33: *> \author Univ. of California Berkeley
34: *> \author Univ. of Colorado Denver
35: *> \author NAG Ltd.
36: *
37: *> \date November 2011
38: *
39: *> \ingroup complex16_blas_level1
40: *
41: *> \par Further Details:
42: * =====================
43: *>
44: *> \verbatim
45: *>
46: *> jack dongarra, 3/11/78.
47: *> modified 12/3/93, array(1) declarations changed to array(*)
48: *> \endverbatim
49: *>
50: * =====================================================================
51: COMPLEX*16 FUNCTION ZDOTU(N,ZX,INCX,ZY,INCY)
52: *
53: * -- Reference BLAS level1 routine (version 3.4.0) --
54: * -- Reference BLAS is a software package provided by Univ. of Tennessee, --
55: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
56: * November 2011
57: *
58: * .. Scalar Arguments ..
59: INTEGER INCX,INCY,N
60: * ..
61: * .. Array Arguments ..
62: COMPLEX*16 ZX(*),ZY(*)
63: * ..
64: *
65: * =====================================================================
66: *
67: * .. Local Scalars ..
68: COMPLEX*16 ZTEMP
69: INTEGER I,IX,IY
70: * ..
71: ZTEMP = (0.0d0,0.0d0)
72: ZDOTU = (0.0d0,0.0d0)
73: IF (N.LE.0) RETURN
74: IF (INCX.EQ.1 .AND. INCY.EQ.1) THEN
75: *
76: * code for both increments equal to 1
77: *
78: DO I = 1,N
79: ZTEMP = ZTEMP + ZX(I)*ZY(I)
80: END DO
81: ELSE
82: *
83: * code for unequal increments or equal increments
84: * not equal to 1
85: *
86: IX = 1
87: IY = 1
88: IF (INCX.LT.0) IX = (-N+1)*INCX + 1
89: IF (INCY.LT.0) IY = (-N+1)*INCY + 1
90: DO I = 1,N
91: ZTEMP = ZTEMP + ZX(IX)*ZY(IY)
92: IX = IX + INCX
93: IY = IY + INCY
94: END DO
95: END IF
96: ZDOTU = ZTEMP
97: RETURN
98: END
CVSweb interface <joel.bertrand@systella.fr>