Return to zaxpy.f CVS log

Up to [local] / rpl / lapack / blas

Cohérence.

    1: *> \brief \b ZAXPY
    2: *
    3: *  =========== DOCUMENTATION ===========
    4: *
    5: * Online html documentation available at 
    6: *            http://www.netlib.org/lapack/explore-html/ 
    7: *
    8: *  Definition:
    9: *  ===========
   10: *
   11: *       SUBROUTINE ZAXPY(N,ZA,ZX,INCX,ZY,INCY)
   12: * 
   13: *       .. Scalar Arguments ..
   14: *       COMPLEX*16 ZA
   15: *       INTEGER INCX,INCY,N
   16: *       ..
   17: *       .. Array Arguments ..
   18: *       COMPLEX*16 ZX(*),ZY(*)
   19: *       ..
   20: *  
   21: *
   22: *> \par Purpose:
   23: *  =============
   24: *>
   25: *> \verbatim
   26: *>
   27: *>    ZAXPY constant times a vector plus a vector.
   28: *> \endverbatim
   29: *
   30: *  Authors:
   31: *  ========
   32: *
   33: *> \author Univ. of Tennessee 
   34: *> \author Univ. of California Berkeley 
   35: *> \author Univ. of Colorado Denver 
   36: *> \author NAG Ltd. 
   37: *
   38: *> \date November 2011
   39: *
   40: *> \ingroup complex16_blas_level1
   41: *
   42: *> \par Further Details:
   43: *  =====================
   44: *>
   45: *> \verbatim
   46: *>
   47: *>     jack dongarra, 3/11/78.
   48: *>     modified 12/3/93, array(1) declarations changed to array(*)
   49: *> \endverbatim
   50: *>
   51: *  =====================================================================
   52:       SUBROUTINE ZAXPY(N,ZA,ZX,INCX,ZY,INCY)
   53: *
   54: *  -- Reference BLAS level1 routine (version 3.4.0) --
   55: *  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
   56: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
   57: *     November 2011
   58: *
   59: *     .. Scalar Arguments ..
   60:       COMPLEX*16 ZA
   61:       INTEGER INCX,INCY,N
   62: *     ..
   63: *     .. Array Arguments ..
   64:       COMPLEX*16 ZX(*),ZY(*)
   65: *     ..
   66: *
   67: *  =====================================================================
   68: *
   69: *     .. Local Scalars ..
   70:       INTEGER I,IX,IY
   71: *     ..
   72: *     .. External Functions ..
   73:       DOUBLE PRECISION DCABS1
   74:       EXTERNAL DCABS1
   75: *     ..
   76:       IF (N.LE.0) RETURN
   77:       IF (DCABS1(ZA).EQ.0.0d0) RETURN
   78:       IF (INCX.EQ.1 .AND. INCY.EQ.1) THEN
   79: *
   80: *        code for both increments equal to 1
   81: *
   82:          DO I = 1,N
   83:             ZY(I) = ZY(I) + ZA*ZX(I)
   84:          END DO
   85:       ELSE
   86: *
   87: *        code for unequal increments or equal increments
   88: *          not equal to 1
   89: *
   90:          IX = 1
   91:          IY = 1
   92:          IF (INCX.LT.0) IX = (-N+1)*INCX + 1
   93:          IF (INCY.LT.0) IY = (-N+1)*INCY + 1
   94:          DO I = 1,N
   95:             ZY(IY) = ZY(IY) + ZA*ZX(IX)
   96:             IX = IX + INCX
   97:             IY = IY + INCY
   98:          END DO
   99:       END IF
  100: *
  101:       RETURN
  102:       END