1: SUBROUTINE DTPMV(UPLO,TRANS,DIAG,N,AP,X,INCX)
2: * .. Scalar Arguments ..
3: INTEGER INCX,N
4: CHARACTER DIAG,TRANS,UPLO
5: * ..
6: * .. Array Arguments ..
7: DOUBLE PRECISION AP(*),X(*)
8: * ..
9: *
10: * Purpose
11: * =======
12: *
13: * DTPMV performs one of the matrix-vector operations
14: *
15: * x := A*x, or x := A**T*x,
16: *
17: * where x is an n element vector and A is an n by n unit, or non-unit,
18: * upper or lower triangular matrix, supplied in packed form.
19: *
20: * Arguments
21: * ==========
22: *
23: * UPLO - CHARACTER*1.
24: * On entry, UPLO specifies whether the matrix is an upper or
25: * lower triangular matrix as follows:
26: *
27: * UPLO = 'U' or 'u' A is an upper triangular matrix.
28: *
29: * UPLO = 'L' or 'l' A is a lower triangular matrix.
30: *
31: * Unchanged on exit.
32: *
33: * TRANS - CHARACTER*1.
34: * On entry, TRANS specifies the operation to be performed as
35: * follows:
36: *
37: * TRANS = 'N' or 'n' x := A*x.
38: *
39: * TRANS = 'T' or 't' x := A**T*x.
40: *
41: * TRANS = 'C' or 'c' x := A**T*x.
42: *
43: * Unchanged on exit.
44: *
45: * DIAG - CHARACTER*1.
46: * On entry, DIAG specifies whether or not A is unit
47: * triangular as follows:
48: *
49: * DIAG = 'U' or 'u' A is assumed to be unit triangular.
50: *
51: * DIAG = 'N' or 'n' A is not assumed to be unit
52: * triangular.
53: *
54: * Unchanged on exit.
55: *
56: * N - INTEGER.
57: * On entry, N specifies the order of the matrix A.
58: * N must be at least zero.
59: * Unchanged on exit.
60: *
61: * AP - DOUBLE PRECISION array of DIMENSION at least
62: * ( ( n*( n + 1 ) )/2 ).
63: * Before entry with UPLO = 'U' or 'u', the array AP must
64: * contain the upper triangular matrix packed sequentially,
65: * column by column, so that AP( 1 ) contains a( 1, 1 ),
66: * AP( 2 ) and AP( 3 ) contain a( 1, 2 ) and a( 2, 2 )
67: * respectively, and so on.
68: * Before entry with UPLO = 'L' or 'l', the array AP must
69: * contain the lower triangular matrix packed sequentially,
70: * column by column, so that AP( 1 ) contains a( 1, 1 ),
71: * AP( 2 ) and AP( 3 ) contain a( 2, 1 ) and a( 3, 1 )
72: * respectively, and so on.
73: * Note that when DIAG = 'U' or 'u', the diagonal elements of
74: * A are not referenced, but are assumed to be unity.
75: * Unchanged on exit.
76: *
77: * X - DOUBLE PRECISION array of dimension at least
78: * ( 1 + ( n - 1 )*abs( INCX ) ).
79: * Before entry, the incremented array X must contain the n
80: * element vector x. On exit, X is overwritten with the
81: * tranformed vector x.
82: *
83: * INCX - INTEGER.
84: * On entry, INCX specifies the increment for the elements of
85: * X. INCX must not be zero.
86: * Unchanged on exit.
87: *
88: * Further Details
89: * ===============
90: *
91: * Level 2 Blas routine.
92: * The vector and matrix arguments are not referenced when N = 0, or M = 0
93: *
94: * -- Written on 22-October-1986.
95: * Jack Dongarra, Argonne National Lab.
96: * Jeremy Du Croz, Nag Central Office.
97: * Sven Hammarling, Nag Central Office.
98: * Richard Hanson, Sandia National Labs.
99: *
100: * =====================================================================
101: *
102: * .. Parameters ..
103: DOUBLE PRECISION ZERO
104: PARAMETER (ZERO=0.0D+0)
105: * ..
106: * .. Local Scalars ..
107: DOUBLE PRECISION TEMP
108: INTEGER I,INFO,IX,J,JX,K,KK,KX
109: LOGICAL NOUNIT
110: * ..
111: * .. External Functions ..
112: LOGICAL LSAME
113: EXTERNAL LSAME
114: * ..
115: * .. External Subroutines ..
116: EXTERNAL XERBLA
117: * ..
118: *
119: * Test the input parameters.
120: *
121: INFO = 0
122: IF (.NOT.LSAME(UPLO,'U') .AND. .NOT.LSAME(UPLO,'L')) THEN
123: INFO = 1
124: ELSE IF (.NOT.LSAME(TRANS,'N') .AND. .NOT.LSAME(TRANS,'T') .AND.
125: + .NOT.LSAME(TRANS,'C')) THEN
126: INFO = 2
127: ELSE IF (.NOT.LSAME(DIAG,'U') .AND. .NOT.LSAME(DIAG,'N')) THEN
128: INFO = 3
129: ELSE IF (N.LT.0) THEN
130: INFO = 4
131: ELSE IF (INCX.EQ.0) THEN
132: INFO = 7
133: END IF
134: IF (INFO.NE.0) THEN
135: CALL XERBLA('DTPMV ',INFO)
136: RETURN
137: END IF
138: *
139: * Quick return if possible.
140: *
141: IF (N.EQ.0) RETURN
142: *
143: NOUNIT = LSAME(DIAG,'N')
144: *
145: * Set up the start point in X if the increment is not unity. This
146: * will be ( N - 1 )*INCX too small for descending loops.
147: *
148: IF (INCX.LE.0) THEN
149: KX = 1 - (N-1)*INCX
150: ELSE IF (INCX.NE.1) THEN
151: KX = 1
152: END IF
153: *
154: * Start the operations. In this version the elements of AP are
155: * accessed sequentially with one pass through AP.
156: *
157: IF (LSAME(TRANS,'N')) THEN
158: *
159: * Form x:= A*x.
160: *
161: IF (LSAME(UPLO,'U')) THEN
162: KK = 1
163: IF (INCX.EQ.1) THEN
164: DO 20 J = 1,N
165: IF (X(J).NE.ZERO) THEN
166: TEMP = X(J)
167: K = KK
168: DO 10 I = 1,J - 1
169: X(I) = X(I) + TEMP*AP(K)
170: K = K + 1
171: 10 CONTINUE
172: IF (NOUNIT) X(J) = X(J)*AP(KK+J-1)
173: END IF
174: KK = KK + J
175: 20 CONTINUE
176: ELSE
177: JX = KX
178: DO 40 J = 1,N
179: IF (X(JX).NE.ZERO) THEN
180: TEMP = X(JX)
181: IX = KX
182: DO 30 K = KK,KK + J - 2
183: X(IX) = X(IX) + TEMP*AP(K)
184: IX = IX + INCX
185: 30 CONTINUE
186: IF (NOUNIT) X(JX) = X(JX)*AP(KK+J-1)
187: END IF
188: JX = JX + INCX
189: KK = KK + J
190: 40 CONTINUE
191: END IF
192: ELSE
193: KK = (N* (N+1))/2
194: IF (INCX.EQ.1) THEN
195: DO 60 J = N,1,-1
196: IF (X(J).NE.ZERO) THEN
197: TEMP = X(J)
198: K = KK
199: DO 50 I = N,J + 1,-1
200: X(I) = X(I) + TEMP*AP(K)
201: K = K - 1
202: 50 CONTINUE
203: IF (NOUNIT) X(J) = X(J)*AP(KK-N+J)
204: END IF
205: KK = KK - (N-J+1)
206: 60 CONTINUE
207: ELSE
208: KX = KX + (N-1)*INCX
209: JX = KX
210: DO 80 J = N,1,-1
211: IF (X(JX).NE.ZERO) THEN
212: TEMP = X(JX)
213: IX = KX
214: DO 70 K = KK,KK - (N- (J+1)),-1
215: X(IX) = X(IX) + TEMP*AP(K)
216: IX = IX - INCX
217: 70 CONTINUE
218: IF (NOUNIT) X(JX) = X(JX)*AP(KK-N+J)
219: END IF
220: JX = JX - INCX
221: KK = KK - (N-J+1)
222: 80 CONTINUE
223: END IF
224: END IF
225: ELSE
226: *
227: * Form x := A**T*x.
228: *
229: IF (LSAME(UPLO,'U')) THEN
230: KK = (N* (N+1))/2
231: IF (INCX.EQ.1) THEN
232: DO 100 J = N,1,-1
233: TEMP = X(J)
234: IF (NOUNIT) TEMP = TEMP*AP(KK)
235: K = KK - 1
236: DO 90 I = J - 1,1,-1
237: TEMP = TEMP + AP(K)*X(I)
238: K = K - 1
239: 90 CONTINUE
240: X(J) = TEMP
241: KK = KK - J
242: 100 CONTINUE
243: ELSE
244: JX = KX + (N-1)*INCX
245: DO 120 J = N,1,-1
246: TEMP = X(JX)
247: IX = JX
248: IF (NOUNIT) TEMP = TEMP*AP(KK)
249: DO 110 K = KK - 1,KK - J + 1,-1
250: IX = IX - INCX
251: TEMP = TEMP + AP(K)*X(IX)
252: 110 CONTINUE
253: X(JX) = TEMP
254: JX = JX - INCX
255: KK = KK - J
256: 120 CONTINUE
257: END IF
258: ELSE
259: KK = 1
260: IF (INCX.EQ.1) THEN
261: DO 140 J = 1,N
262: TEMP = X(J)
263: IF (NOUNIT) TEMP = TEMP*AP(KK)
264: K = KK + 1
265: DO 130 I = J + 1,N
266: TEMP = TEMP + AP(K)*X(I)
267: K = K + 1
268: 130 CONTINUE
269: X(J) = TEMP
270: KK = KK + (N-J+1)
271: 140 CONTINUE
272: ELSE
273: JX = KX
274: DO 160 J = 1,N
275: TEMP = X(JX)
276: IX = JX
277: IF (NOUNIT) TEMP = TEMP*AP(KK)
278: DO 150 K = KK + 1,KK + N - J
279: IX = IX + INCX
280: TEMP = TEMP + AP(K)*X(IX)
281: 150 CONTINUE
282: X(JX) = TEMP
283: JX = JX + INCX
284: KK = KK + (N-J+1)
285: 160 CONTINUE
286: END IF
287: END IF
288: END IF
289: *
290: RETURN
291: *
292: * End of DTPMV .
293: *
294: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dtpmv.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / blas